-
Notifications
You must be signed in to change notification settings - Fork 68
/
CrashReportsMailer.class.st
360 lines (336 loc) · 13 KB
/
CrashReportsMailer.class.st
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
"
This class generates an almost complete crash report that still needs editing for categories and then posts it after editing.
"
Class {
#name : #CrashReportsMailer,
#superclass : #Object,
#instVars : [
'mailDirectory',
'destination',
'startDate',
'endDate',
'rs',
'causes',
'soloTime',
'meetingTime'
],
#pools : [
'ChronologyConstants'
],
#category : #'Cog-Scripts'
}
{ #category : #'instance creation' }
CrashReportsMailer class >> mailDirectory: aFileDirectoryOrString destination: anEmailAddress week: startDate [
^self new
mailDirectory: aFileDirectoryOrString
destination: anEmailAddress
startDate: (TimeStamp fromSeconds: startDate asDate asSeconds)
endDate: (TimeStamp fromSeconds: (startDate asDate addDays: 7) asSeconds)
"(self mailDirectory: '/Users/eliot/Library/Mail/IMAP-emiranda@ussc9-mail01.qwaq.com/INBOX.imapmbox/Messages'
destination: 'eng@teleplace.com'
week: '05/15/2010') generateReport"
]
{ #category : #'instance creation' }
CrashReportsMailer class >> mailDirectory: aFileDirectoryOrString destination: anEmailAddress week: startDateString soloTime: soloDurationOrString meetingTime: meetingDurationOrString [
| startDate |
startDate := ((startDateString includes: $-)
ifTrue: [(#(2 3 1) collect: [:i| (startDateString subStrings: '-') at: i]) fold: [:a :b| a,'/',b]]
ifFalse: [startDateString]) asDate.
^self new
mailDirectory: aFileDirectoryOrString
destination: anEmailAddress
startDate: (TimeStamp fromSeconds: startDate asSeconds)
endDate: (TimeStamp fromSeconds: (startDate addDays: 7) asSeconds - 1)
soloTime: soloDurationOrString asDuration
meetingTime: meetingDurationOrString asDuration
"(self mailDirectory: '/Users/eliot/Library/Mail/IMAP-emiranda@ussc9-mail01.qwaq.com/INBOX.imapmbox/Messages'
destination: 'eng@teleplace.com'
week: '05/15/2010'
soloTime: '20:19:38:55'
meetingTime: '7:23:44:45') generateReport"
]
{ #category : #reporting }
CrashReportsMailer >> addReportFor: lines [
rs resetContents;
tab;
nextPutAll: ((lines detect: [:l| l beginsWith: 'Subject:']) ifNotNil:
[:l| l allButFirst: (l indexOfSubCollection: ' Teleplace Bug')]);
crtab: 2;
nextPutAll: (lines detect: [:l| l beginsWith: 'Date:']);
cr.
((lines anySatisfy: [:l| (l beginsWith: 'OS Version') and: [l includesSubstring: 'Mac OS X']])
ifTrue: [self reportForMacOS: lines]
ifFalse: [(lines anySatisfy: [:l| l beginsWith: 'Module:'])
ifTrue: [self reportForOldWin32: lines]
ifFalse: [self reportForNewWin32: lines]]) ifNotNil:
[:cause|
(causes at: cause ifAbsentPut: [OrderedCollection new])
addLast: rs contents]
]
{ #category : #parsing }
CrashReportsMailer >> breakIntoLines: aString [
^self pruneBogusEmptyLines:
(Array streamContents:
[:os| | is ss char |
is := aString readStream.
ss := ReadWriteStream on: String new.
[is atEnd] whileFalse:
[(char := is next) = Character lf
ifTrue:
[os nextPut: ss contents.
ss resetContents]
ifFalse: [ss nextPut: char]].
ss position > 0 ifTrue:
[os nextPut: ss contents]])
]
{ #category : #parsing }
CrashReportsMailer >> candidateMessagesDo: aBlock [
"Evaluate aBlock with the file names of every file newer than the start date minus some slop"
| start |
start := (startDate minusDays: 7) asSeconds.
mailDirectory entries do:
[:dirEntry|
((dirEntry name endsWith: '.emlx')
and: [dirEntry creationTime > start]) ifTrue:
[aBlock value: dirEntry name]]
]
{ #category : #reporting }
CrashReportsMailer >> collectReportSummaries [
self candidateMessagesDo:
[:fn|
self ifCrashReport: fn do:
[:lines|
self addReportFor: lines]]
]
{ #category : #reporting }
CrashReportsMailer >> generateFinalReport [
| count numMac ws |
count := causes inject: 0 into: [:sum :collection| sum + collection size].
rs reset.
rs print: count; nextPutAll: ' VM Crashes. ? OpenGL. ? Audio plugin. ? Video plugin. ? Python plugin. ? core VM. ? unknown.'; cr.
numMac := (causes keys select: [:k| k beginsWith: 'Mac:']) size.
rs nextPutAll: 'win: '; print: count- numMac; cr.
rs nextPutAll: 'mac: '; print: numMac; cr; cr.
self reportCrashRates: count.
causes keys asSortedCollection do:
[:k|
(causes at: k) do:
[:report| rs nextPutAll: report].
rs nextPutAll: k; cr; cr].
(ws := Workspace new contents: rs contents)
acceptAction: [:s| (UIManager default confirm: 'Sure you want to send?') ifTrue:
[self mailReport: s.
ws acceptAction:
[(UIManager default confirm: 'You''ve already sent this. Sure you want to send again?') ifTrue:
[self mailReport: s]]]];
openLabel: 'Customer VM Crashes ', startDate date printString, ' to ', endDate date printString;
shouldStyle: false
]
{ #category : #reporting }
CrashReportsMailer >> generateReport [
causes := Dictionary new.
self collectReportSummaries.
self generateFinalReport
]
{ #category : #parsing }
CrashReportsMailer >> ifCrashReport: fileName do: aBlock [
"Answer the evaluation of aBlock with the lines for fileName if it is a crash report, or nil if not."
| file lines subject |
file := mailDirectory oldFileNamed: fileName.
lines := [file contentsOfEntireFile]
on: Error
do: [:ex|
file close.
Transcript nextPutAll: fileName; nextPutAll: ': '; nextPutAll: ex messageText; flush.
^nil].
lines := self breakIntoLines: lines.
subject := lines detect: [:l| l beginsWith: 'Subject:'] ifNone: [^nil].
(subject includesSubstring: 'Teleplace Bug Report: ') ifFalse: [^nil].
#('@qwaq.com' '@teleplace.com' '@chonkaa.com' 'craig@netjam.org' 'skysound@mac.com') do:
[:localEmail| (subject includesSubstring: localEmail caseSensitive: false) ifTrue: [^nil]].
(lines anySatisfy:
[:l|
((l beginsWith: 'OS Version') and: [l includesSubstring: 'Mac OS X'])
or: [l beginsWith: 'Operating System:']]) ifFalse: [^nil].
^aBlock value: lines
]
{ #category : #reporting }
CrashReportsMailer >> macOSDateFor: dateString [
| tokens |
tokens := dateString subStrings: ' -.+'.
^TimeStamp
date: (Date year: tokens first asInteger month: tokens second asInteger day: tokens third asInteger)
time: tokens fourth asTime
]
{ #category : #'initialize-release' }
CrashReportsMailer >> mailDirectory: aFileDirectoryOrString destination: anEmailAddress startDate: startTimestamp endDate: endTimestamp [
mailDirectory := aFileDirectoryOrString isString
ifTrue: [FileDirectory on: aFileDirectoryOrString]
ifFalse: [aFileDirectoryOrString].
destination := anEmailAddress.
startDate := startTimestamp.
endDate := endTimestamp.
rs := ReadWriteStream on: (String new: 256)
]
{ #category : #'initialize-release' }
CrashReportsMailer >> mailDirectory: aFileDirectoryOrString destination: anEmailAddress startDate: startTimestamp endDate: endTimestamp soloTime: soloDuration meetingTime: meetingDuration [
mailDirectory := aFileDirectoryOrString isString
ifTrue: [FileDirectory on: aFileDirectoryOrString]
ifFalse: [aFileDirectoryOrString].
destination := anEmailAddress.
startDate := startTimestamp.
endDate := endTimestamp.
soloTime := soloDuration.
meetingTime := meetingDuration.
rs := ReadWriteStream on: (String new: 256)
]
{ #category : #mailing }
CrashReportsMailer >> mailReport: aText [
| msg |
msg := MailMessage new
setField: 'from' toString: 'eliot@teleplace.com';
setField: 'to' toString: destination;
setField: 'subject' toString: 'Customer VM Crashes ',
(startDate date printFormat: #(3 2 1 $/ 1 2)),
' - ',
((endDate - 1 seconds) date printFormat: #(3 2 1 $/ 1 2));
body: (MIMEDocument contentType: 'text/plain' content: aText asString).
SMTPClient
deliverMailFrom: msg from
to: (Array with: msg to)
text: msg text
usingServer: MailComposition new smtpServer
]
{ #category : #parsing }
CrashReportsMailer >> pruneBogusEmptyLines: lines [
"Eliminate duplicate empty lines from broken CR-LF to LF-LF conversions."
| firstEmpty lastEmpty |
(firstEmpty := lines findFirst: [:l| l isEmpty]) = 0 ifTrue:
[^lines].
lastEmpty := firstEmpty.
[(lines at: lastEmpty + 2) isEmpty] whileTrue:
[lastEmpty := lastEmpty + 2].
^(lines copyFrom: 1 to: firstEmpty - 1),
((firstEmpty + 1 to: lastEmpty - 1 by: 2) collect: [:i| lines at: i]),
(lines copyFrom: lastEmpty + 1 to: lines size)
]
{ #category : #reporting }
CrashReportsMailer >> reportCrashRates: count [
{ soloTime. meetingTime }
with: #('solo hours: ' 'meeting hours: ')
do: [:time :label|
rs nextPutAll: label; print: (time asSeconds / SecondsInHour) rounded;
space; nextPut: $(; print: time; nextPut: $); cr].
rs cr.
{ soloTime. meetingTime }
with: #('solo' 'meeting')
do: [:time :label|
{ SecondsInHour. SecondsInDay }
with: #('hour' 'day')
do: [:period :periodLabel| | rate |
rate := count / (time asSeconds / period).
rs print: (rate roundTo: (rate >= 1 ifTrue: [0.1] ifFalse: [0.001]));
nextPutAll: ' crashes per '; nextPutAll: label; space; nextPutAll: periodLabel; cr]].
rs cr; cr
]
{ #category : #reporting }
CrashReportsMailer >> reportForMacOS: lines [
| thread dateAndTime cStackTop cstIdx |
thread := Integer readFrom: ((lines detect: [:l| l beginsWith: 'Crashed Thread: ']) allButFirst: 15) readStream skipSeparators.
thread := 'Thread ', thread printString, ' Crashed'.
lines withIndexDo:
[:l :i|
(l beginsWith: 'Date/Time:') ifTrue:
[dateAndTime := l allButFirst: 11].
((l beginsWith: thread)
and: [i < lines size]) ifTrue:
[cStackTop := lines at: (cstIdx := i + 1)]].
[cstIdx <= lines size
and: [(lines at: cstIdx) notEmpty]] whileTrue:
[(((lines at: cstIdx) includesSubstring: ' _sigtramp ')
and: [((lines at: cstIdx + 1) includesSubstring: ' ??? ')
and: [((lines at: cstIdx + 1) includesSubstring: '0xffffffff 0 + 4294967295')]]) ifTrue:
[cStackTop := lines at: cstIdx + 2.
cstIdx := lines size].
cstIdx := cstIdx + 1].
dateAndTime := self macOSDateFor: dateAndTime.
(dateAndTime between: startDate and: endDate) ifFalse:
[^nil].
^'Mac:', (cStackTop allButFirst: (cStackTop indexOf: Character space))
]
{ #category : #reporting }
CrashReportsMailer >> reportForNewWin32: lines [
| dateAndTime reason stStackTop cStackTop |
lines withIndexDo:
[:l :i|
(l beginsWith: 'Session Summary:') ifTrue:
[^nil]. "Not a VM bug report, ignore it."
(dateAndTime isNil
and: [(l beginsWith: '--------------------')
and: [i < lines size]]) ifTrue:
[dateAndTime := lines at: i + 1].
((l beginsWith: 'Smalltalk stack dump:')
and: [i < lines size]) ifTrue:
[stStackTop := lines at: i + 1].
((l beginsWith: 'Stack backtrace:')
and: [i < lines size]) ifTrue:
[cStackTop := lines at: i + 1]].
dateAndTime isNil ifTrue:
[^nil].
dateAndTime := self win32DateFor: dateAndTime.
(dateAndTime between: startDate and: endDate) ifFalse:
[^nil].
reason := (lines detect: [:l| l beginsWith: 'Reason: '] ifNone: []) ifNotNil: [:rl| rl allButFirst: 8].
"a stack entry looks like
0x9c2490 I NetNameResolver class>localHostAddress 271185968: a(n) NetNameResolver class
t293325136 s BlockClosure>on:do:"
stStackTop ifNotNil:
[stStackTop := (stStackTop subStrings: ' ') allButFirst: 2.
stStackTop := stStackTop first: (stStackTop findFirst: [:t| t first isDigit]) - 1.
stStackTop := stStackTop fold: [:a :b| a, ' ', b]].
^String streamContents:
[:s|
reason ifNotNil: [s nextPutAll: reason; cr].
stStackTop ifNotNil: [s nextPutAll: stStackTop; cr].
cStackTop ifNotNil: [s nextPutAll: cStackTop]]
]
{ #category : #reporting }
CrashReportsMailer >> reportForOldWin32: lines [
| dateAndTime module idx stackTop |
lines withIndexDo:
[:l :i|
(dateAndTime isNil
and: [(l beginsWith: '--------------------')
and: [i < lines size]]) ifTrue:
[dateAndTime := lines at: i + 1].
((l beginsWith: 'Stack dump:')
and: [i < lines size]) ifTrue:
"Occasionally there is a bogus blank line between the label and the first entry"
[(stackTop := (lines at: i + 1) isEmpty) ifTrue:
[stackTop := lines at: i + 2]]].
dateAndTime := self win32DateFor: dateAndTime.
(dateAndTime between: startDate and: endDate) ifFalse:
[^nil].
module := (lines detect: [:l| l beginsWith: 'Module: ']) allButFirst: 8.
(idx := module indexOfSubCollection: '\Teleplace') > 0 ifTrue:
[module := module copyFrom: idx to: module size].
(module first isLetter and: [module second = $:]) ifTrue:
[module := module allButFirst: 2].
"a stack entry looks like
0x9c2490 I NetNameResolver class>localHostAddress 271185968: a(n) NetNameResolver class
293325136 s BlockClosure>on:do:
but if there is no stack there may be any old crap after Stack dump: so squash errors."
[stackTop := (stackTop subStrings: ' ') allButFirst: 2.
stackTop := stackTop first: (stackTop findFirst: [:t| t first isDigit]) - 1.
stackTop := stackTop fold: [:a :b| a, ' ', b]]
on: Error
do: [:ex| stackTop := '?'].
^stackTop, ' in ', module
]
{ #category : #reporting }
CrashReportsMailer >> win32DateFor: dateAndTimeString [
"transform 'Thu Jun 24 14:11:18 2010' to 'Jun 24 2010 14:11:18' to allow parsing"
| tokens |
tokens := dateAndTimeString subStrings: ' '.
^({ tokens second. tokens third. tokens fifth. tokens fourth } fold: [:a :b| a, ' ', b]) asTimeStamp
]