-
Notifications
You must be signed in to change notification settings - Fork 68
/
DBAbstractConstraint.class.st
196 lines (159 loc) · 5.36 KB
/
DBAbstractConstraint.class.st
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
"
I am an abstract class representing a system-maintainable relationship (or ""constraint"") between a set of variables. I supply a strength instance variable; concrete subclasses provide a means of storing the constrained variables and other information required to represent a constraint.
Instance variables:
strength the strength of this constraint <Strength>
"
Class {
#name : #DBAbstractConstraint,
#superclass : #Object,
#instVars : [
'strength'
],
#category : #'CogBenchmarks-DeltaBlue'
}
{ #category : #adding }
DBAbstractConstraint >> addConstraint [
"Activate this constraint and attempt to satisfy it."
self addToGraph.
DBPlanner current incrementalAdd: self.
]
{ #category : #adding }
DBAbstractConstraint >> addToGraph [
"Add myself to the constraint graph."
self subclassResponsibility
]
{ #category : #planning }
DBAbstractConstraint >> chooseMethod: mark [
"Decide if I can be satisfied and record that decision. The output of
the choosen method must not have the given mark and must have a
walkabout strength less than that of this constraint."
self subclassResponsibility
]
{ #category : #adding }
DBAbstractConstraint >> destroyConstraint [
"Deactivate this constraint, remove it from the constraint graph,
possibly causing other constraints to be satisfied, and destroy it."
(self isSatisfied) ifTrue: [DBPlanner current incrementalRemove: self].
self removeFromGraph.
self release.
]
{ #category : #planning }
DBAbstractConstraint >> execute [
"Enforce this constraint. Assume that it is satisfied."
self subclassResponsibility
]
{ #category : #planning }
DBAbstractConstraint >> inputsDo: aBlock [
"Assume that I am satisfied. Evaluate the given block on all my current
input variables."
self subclassResponsibility
]
{ #category : #planning }
DBAbstractConstraint >> inputsKnown: mark [
"Assume that I am satisfied. Answer true if all my current inputs are
known. A variable is known if either a) it is 'stay' (i.e. it is a
constant at plan execution time), b) it has the given mark (indicating
that it has been computed by a constraint appearing earlier in the
plan), or c) it is not determined by any constraint."
self inputsDo:
[ :v |
(v mark = mark or: [v stay or: [v determinedBy isNil]]) ifFalse:
[^false]].
^true
]
{ #category : #testing }
DBAbstractConstraint >> isInput [
"Normal constraints are not input constraints. An input constraint is
one that depends on external state, such as the mouse, the keyboard,
a clock, or some arbitrary piece of imperative code."
^false
]
{ #category : #testing }
DBAbstractConstraint >> isSatisfied [
"Answer true if this constraint is satisfied in the current solution."
self subclassResponsibility
]
{ #category : #printing }
DBAbstractConstraint >> longPrintOn: aStream [
aStream nextPut: $(.
self shortPrintOn: aStream.
aStream space; nextPutAll: self strength printString.
(self isSatisfied)
ifTrue:
[aStream cr; space; space; space.
self inputsDo:
[ :in | aStream nextPutAll: 'v', in printString, ' '].
aStream nextPutAll: '-> '.
aStream nextPutAll: 'v', self output printString]
ifFalse:
[aStream space; nextPutAll: 'UNSATISFIED'].
aStream nextPut: $); cr.
]
{ #category : #planning }
DBAbstractConstraint >> markUnsatisfied [
"Record the fact that I am unsatisfied."
self subclassResponsibility
]
{ #category : #planning }
DBAbstractConstraint >> output [
"Answer my current output variable. Raise an error if I am not
currently satisfied."
self subclassResponsibility
]
{ #category : #printing }
DBAbstractConstraint >> printOn: aStream [
self shortPrintOn: aStream
]
{ #category : #planning }
DBAbstractConstraint >> recalculate [
"Calculate the walkabout strength, the stay flag, and, if it is 'stay',
the value for the current output of this constraint. Assume this
constraint is satisfied."
self subclassResponsibility
]
{ #category : #adding }
DBAbstractConstraint >> removeFromGraph [
"Remove myself from the constraint graph."
self subclassResponsibility
]
{ #category : #planning }
DBAbstractConstraint >> satisfy: mark [
"Attempt to find a way to enforce this (still unsatisfied) constraint.
If successful, record the solution, perhaps modifying the current
dataflow graph. Answer the constraint that this constraint overrides,
if there is one, or nil, if there isn't."
| overridden out |
self chooseMethod: mark.
self isSatisfied
ifTrue: "constraint can be satisfied"
["mark inputs to allow cycle detection in addPropagate"
self inputsDo: [ :in | in mark: mark].
out := self output.
overridden := out determinedBy.
overridden ifNotNil: [overridden markUnsatisfied].
out determinedBy: self.
(DBPlanner current addPropagate: self mark: mark) ifFalse:
[self notify:
('Cycle encountered adding:\ ',
self printString,
'\Constraint removed.') withCRs.
^nil].
out mark: mark]
ifFalse: "constraint cannot be satisfied"
[overridden := nil.
(strength sameAs: (DBStrength required)) ifTrue:
[self notify: 'Failed to satisfy a required constraint']].
^ overridden
]
{ #category : #printing }
DBAbstractConstraint >> shortPrintOn: aStream [
aStream nextPutAll: self class name, '(', self printString, ')'.
]
{ #category : #accessing }
DBAbstractConstraint >> strength [
^ strength
]
{ #category : #accessing }
DBAbstractConstraint >> strength: anObject [
strength := anObject
]