-
-
Notifications
You must be signed in to change notification settings - Fork 353
/
ReferenceFinder.class.st
263 lines (222 loc) · 6.69 KB
/
ReferenceFinder.class.st
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
"
Finds reference paths between objects to help find memory leaks. It finds the shortest paths between the objects.
If you want to find a path between the ""Smalltalk"" global dictionary and some instance of a class, you can use the findPathToInstanceOf: method. For example, ""ReferenceFinder findPathToInstanceOf: WriteStream"" will find a reference path between Smalltalk and an instance of WriteStream.
"
Class {
#name : #ReferenceFinder,
#superclass : #Object,
#instVars : [
'backlinks',
'objectsLeft',
'testBlock',
'foundBlock'
],
#category : #'ReferenceFinder-Core-Base'
}
{ #category : #accessing }
ReferenceFinder class >> findAllPathsTo: anObject [
"self findAllPathsTo: (Object compiledMethodAt: #printString)"
^self findAllPathsTo: anObject from: Smalltalk
]
{ #category : #accessing }
ReferenceFinder class >> findAllPathsTo: anObject from: fromObject [
"self findAllPathsTo: (Object compiledMethodAt: #printString) from: Object"
^(self new)
startFrom: fromObject;
findAllPaths: [:each | each == anObject]
]
{ #category : #accessing }
ReferenceFinder class >> findAllPathsToInstanceOf: aBehavior [
"self findAllPathsToInstanceOf: RefactoringBrowser"
^self findAllPathsToInstanceOf: aBehavior from: Smalltalk
]
{ #category : #accessing }
ReferenceFinder class >> findAllPathsToInstanceOf: aBehavior from: fromObject [
"self findAllPathsToInstanceOf: RefactoringBrowser from: ScheduledControllers"
^(self new)
startFrom: fromObject;
findAllPaths: [:each | each class == aBehavior]
]
{ #category : #accessing }
ReferenceFinder class >> findPathTo: anObject [
^self findPathTo: anObject from: Smalltalk
]
{ #category : #accessing }
ReferenceFinder class >> findPathTo: anObject from: fromObject [
"self findPathTo: RefactoringManager instance from: Object"
^(self new)
startFrom: fromObject;
findPath: [:each | each == anObject]
]
{ #category : #accessing }
ReferenceFinder class >> findPathToInstanceOf: aBehavior [
^self findPathToInstanceOf: aBehavior from: Smalltalk
]
{ #category : #accessing }
ReferenceFinder class >> findPathToInstanceOf: aBehavior from: fromObject [
"self findPathToInstanceOf: RefactoringManager from: Object"
^(self new)
startFrom: fromObject;
findPath: [:each | each class == aBehavior]
]
{ #category : #private }
ReferenceFinder >> _object: anObject at: anInteger [
"Answer the value of an indexable field in anObject. Fail if the
argument anInteger is not an Integer or is out of bounds."
^anObject basicAt: anInteger
]
{ #category : #private }
ReferenceFinder >> _object: anObject instVarAt: anInteger [
"Answer with a fixed variable in anObject. The numbering of the variables
corresponds to the named instance variables. Fail if the index is not an
Integer or is not the index of a fixed variable."
^anObject instVarAt: anInteger
]
{ #category : #private }
ReferenceFinder >> _objectClass: anObject [
"Answer the object which is the argument's class."
^anObject class
]
{ #category : #private }
ReferenceFinder >> _objectSize: anObject [
"Answer the number of indexable fields in the argument anObject.
This value is the same as the largest legal subscript."
^anObject basicSize
]
{ #category : #private }
ReferenceFinder >> addBacklinkFrom: newObject to: anObject [
backlinks last at: newObject put: anObject
]
{ #category : #private }
ReferenceFinder >> addBacklinkLevel [
backlinks add: self identityDictionaryClass new
]
{ #category : #private }
ReferenceFinder >> backlinkFor: anObject [
| toObject |
backlinks do:
[:each |
toObject := each at: anObject ifAbsent: [nil].
toObject notNil ifTrue: [^toObject]].
^nil
]
{ #category : #private }
ReferenceFinder >> computePathFor: anObject [
| path object |
path := OrderedCollection new.
object := anObject.
[object isNil] whileFalse:
[path add: object.
object := self backlinkFor: object].
^path reverse
]
{ #category : #private }
ReferenceFinder >> find [
self searchForObject
]
{ #category : #accessing }
ReferenceFinder >> findAllPaths: aBlock [
| paths |
paths := OrderedCollection new.
foundBlock := [:path | paths add: path].
testBlock := aBlock.
self find.
^paths
]
{ #category : #accessing }
ReferenceFinder >> findPath: aBlock [
foundBlock := [:path | ^path].
testBlock := aBlock.
self find.
^nil
]
{ #category : #private }
ReferenceFinder >> hasSearched: newObject [
^backlinks anySatisfy: [:each | each includesKey: newObject]
]
{ #category : #private }
ReferenceFinder >> identityDictionaryClass [
^IdentityDictionary
]
{ #category : #accessing }
ReferenceFinder >> ignore: anObject [
self addBacklinkFrom: anObject to: anObject
]
{ #category : #initialization }
ReferenceFinder >> initialize [
self startFrom: Smalltalk
]
{ #category : #private }
ReferenceFinder >> printToDoNotice [
self
crTrace:
'Level ' , backlinks size printString , ' with '
, objectsLeft size printString , ' objects to search'
]
{ #category : #private }
ReferenceFinder >> processLinkTo: newObject from: anObject [
newObject class instSize + newObject basicSize = 0
ifTrue:
[^(testBlock value: newObject)
ifTrue:
[(self computePathFor: anObject)
add: newObject;
yourself]
ifFalse: [nil]].
(self hasSearched: newObject)
ifFalse:
[(testBlock value: newObject)
ifTrue:
[^(self computePathFor: anObject)
add: newObject;
yourself].
objectsLeft add: newObject.
self addBacklinkFrom: newObject to: anObject].
^nil
]
{ #category : #private }
ReferenceFinder >> searchForObject [
[| objects |
self printToDoNotice.
objects := objectsLeft.
objectsLeft := OrderedCollection new.
self addBacklinkLevel.
objects do:
[:each |
| path |
(path := self searchVariablesIn: each) notNil
ifTrue: [foundBlock value: path].
(path := self searchIndicesIn: each) notNil
ifTrue: [foundBlock value: path]].
objectsLeft isEmpty]
whileFalse
]
{ #category : #private }
ReferenceFinder >> searchIndicesIn: anObject [
| class |
class := self _objectClass: anObject.
class isBits ifTrue: [^nil].
class isWeak ifTrue: [^nil].
1 to: (self _objectSize: anObject) do:
[:i | | path |
path := self processLinkTo: (self _object: anObject at: i) from: anObject.
path notNil ifTrue: [^path]].
^nil
]
{ #category : #private }
ReferenceFinder >> searchVariablesIn: anObject [
| class |
class := self _objectClass: anObject.
1 to: class instSize do:
[:i | | path |
path := self processLinkTo: (self _object: anObject instVarAt: i) from: anObject.
path notNil ifTrue: [^path]].
^nil
]
{ #category : #initialization }
ReferenceFinder >> startFrom: anObject [
backlinks := OrderedCollection new.
self addBacklinkLevel.
objectsLeft := OrderedCollection with: anObject.
backlinks last at: anObject put: nil
]