-
-
Notifications
You must be signed in to change notification settings - Fork 353
/
PropertySlot.class.st
85 lines (70 loc) · 2.22 KB
/
PropertySlot.class.st
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
"
I am a Slot that does not allocate one field for each slot. Instead, all PropertySlots of the whole hierarchy are allocated in a dictionary that is stored in an invisible slot (see PropertyBaseSlot)
Keep in mind:
- I am slower than instance variables
- there is the overhead of the Dictionary. Only if there are multiple ones of me in the class hierarchy you will save memory
"
Class {
#name : #PropertySlot,
#superclass : #Slot,
#instVars : [
'baseSlot'
],
#category : #'Slot-Examples-Base'
}
{ #category : #'code generation' }
PropertySlot >> emitStore: methodBuilder [
| tempName |
tempName := Object new.
methodBuilder
addTemp: tempName;
storeTemp: tempName;
popTop;
pushInstVar: baseSlot index;
pushLiteral: self name;
pushTemp: tempName;
send: #at:put:
]
{ #category : #'code generation' }
PropertySlot >> emitValue: methodBuilder [
methodBuilder
pushInstVar: baseSlot index;
pushLiteral: self name;
pushLiteral: nil;
send: #at:ifAbsent:
]
{ #category : #testing }
PropertySlot >> isAccessedIn: aMethod [
(baseSlot isAccessedIn: aMethod) ifFalse: [ ^false ].
^super isAccessedIn: aMethod
]
{ #category : #testing }
PropertySlot >> isReadIn: aMethod [
(baseSlot isReadIn: aMethod) ifFalse: [ ^false ].
^super isReadIn: aMethod
]
{ #category : #testing }
PropertySlot >> isWrittenIn: aMethod [
(baseSlot isWrittenIn: aMethod) ifFalse: [ ^false ].
^super isWrittenIn: aMethod
]
{ #category : #'class building' }
PropertySlot >> layoutChanged: aClass [
super layoutChanged: aClass.
"we check on the slot level as the slot is hidden"
(baseSlot notNil and: [aClass classLayout hasSlotNamed: baseSlot name]) ifTrue: [
baseSlot := aClass classLayout slotNamed: baseSlot name. "make sure we all use the same baseSlot"
^self. ].
"here we need to be more clever: if a subclass defines it,
move the difiniton here"
self flag: #pharoTodo.
aClass addSlot: (baseSlot := #'_propertyBaseSlot' => BaseSlot default: Dictionary new).
]
{ #category : #'meta-object-protocol' }
PropertySlot >> read: anObject [
^ (baseSlot read: anObject) at: self name ifAbsent: nil
]
{ #category : #'meta-object-protocol' }
PropertySlot >> write: aValue to: anObject [
^ (baseSlot read: anObject) at: self name put: aValue
]