-
-
Notifications
You must be signed in to change notification settings - Fork 353
/
FreeTypeCache.class.st
268 lines (224 loc) · 6.28 KB
/
FreeTypeCache.class.st
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
"
Cache for freetype fonts
"
Class {
#name : #FreeTypeCache,
#superclass : #Object,
#instVars : [
'maximumSize',
'used',
'fontTable',
'fifo'
],
#pools : [
'FreeTypeCacheConstants'
],
#classInstVars : [
'current'
],
#category : #'FreeType-Cache'
}
{ #category : #cleanup }
FreeTypeCache class >> cleanUp [
self clearCurrent
]
{ #category : #'system startup' }
FreeTypeCache class >> clearCacheOnShutdown [
"answer true if the cache should be cleared on image shutdown"
^true
]
{ #category : #cleanup }
FreeTypeCache class >> clearCurrent [
"
self clearCurrent.
"
current := nil
]
{ #category : #accessing }
FreeTypeCache class >> current [
^ current ifNil: [ current := self new ]
]
{ #category : #accessing }
FreeTypeCache class >> defaultMaximumSize [
"answer the default maximumSize in bytes"
^1024*5000 "5 Megabytes"
]
{ #category : #'initialize-release' }
FreeTypeCache class >> initialize [
SessionManager default
registerGuiClassNamed: self name
atPriority: 10.
]
{ #category : #'system startup' }
FreeTypeCache class >> shutDown: isImageQuitting [
isImageQuitting ifFalse: [ ^ self ].
(current notNil and: [ self clearCacheOnShutdown ])
ifTrue:[
self current removeAll.
current := nil ]
]
{ #category : #'system startup' }
FreeTypeCache class >> startUp: isImageStarting [
isImageStarting ifFalse: [ ^ self ].
self current removeAll.
current := nil
]
{ #category : #'add-remove' }
FreeTypeCache >> atFont: aFreeTypeFont charCode: charCodeInteger type: typeFlag [
| entry charCodeTable typeTable |
(charCodeTable := fontTable at: aFreeTypeFont ifAbsent:[])
ifNotNil:[
(typeTable := charCodeTable at: charCodeInteger ifAbsent:[])
ifNotNil:[
(entry := typeTable at: typeFlag ifAbsent:[])
ifNotNil:[
fifo moveDown: entry.
^entry object]]].
self error: 'Not found'
]
{ #category : #'add-remove' }
FreeTypeCache >> atFont: aFreeTypeFont charCode: charCodeInteger type: typeFlag ifAbsentPut: aBlock [
| charCodeTable typeTable entry v vSize |
charCodeTable := fontTable at: aFreeTypeFont ifAbsentPut:[self dictionaryClass new: 60].
typeTable := charCodeTable at: charCodeInteger ifAbsentPut:[self dictionaryClass new: 10].
entry := typeTable at: typeFlag ifAbsent:[].
entry
ifNotNil:[
fifo moveDown: entry.
^entry object].
v := aFreeTypeFont mutex criticalReleasingOnError: aBlock.
vSize := self sizeOf: v.
(maximumSize notNil and:[vSize > maximumSize])
ifTrue:[^v].
used := used + vSize.
entry := (self fifoEntryClass new
font: aFreeTypeFont;
charCode: charCodeInteger;
type: typeFlag;
object: v;
yourself).
typeTable at: typeFlag put: entry.
fifo addLast: entry.
maximumSize ifNotNil:[self shrinkTo: maximumSize].
^v
]
{ #category : #'add-remove' }
FreeTypeCache >> atFont: aFreeTypeFont charCode: charCodeInteger type: typeFlag put: anObject [
| charCodeTable typeTable anObjectSize oldEntry oldEntrySize entry |
anObjectSize := self sizeOf: anObject.
(maximumSize notNil and:[anObjectSize > maximumSize])
ifTrue:[^anObject].
(charCodeTable := fontTable at: aFreeTypeFont ifAbsentPut:[self dictionaryClass new: 60])
ifNotNil:[
(typeTable := charCodeTable at: charCodeInteger ifAbsentPut:[self dictionaryClass new: 10])
ifNotNil:[
oldEntry := typeTable at: typeFlag ifAbsent:[].
oldEntrySize := (oldEntry
ifNil:[0]
ifNotNil:[self sizeOf: oldEntry object]).
entry := (self fifoEntryClass new
font: aFreeTypeFont;
charCode: charCodeInteger;
type: typeFlag;
object: anObject;
yourself).
typeTable at: typeFlag put: entry]].
used := used + anObjectSize - oldEntrySize.
oldEntry ifNotNil: [fifo remove: oldEntry].
fifo addLast: entry.
maximumSize ifNotNil:[self shrinkTo: maximumSize].
^anObject
]
{ #category : #public }
FreeTypeCache >> cacheSize [
^ self maximumSize / 1024
]
{ #category : #public }
FreeTypeCache >> cacheSize: anInteger [
self maximumSize: (anInteger * 1024)
]
{ #category : #private }
FreeTypeCache >> dictionaryClass [
^Dictionary
]
{ #category : #private }
FreeTypeCache >> fifoClass [
^FreeTypeCacheLinkedList
]
{ #category : #private }
FreeTypeCache >> fifoEntryClass [
^FreeTypeCacheEntry
]
{ #category : #initialization }
FreeTypeCache >> initialize [
super initialize.
maximumSize := self class defaultMaximumSize.
fontTable := self dictionaryClass new: 100.
used := 0.
fifo := self fifoClass new
]
{ #category : #public }
FreeTypeCache >> maximumSize [
^ maximumSize
]
{ #category : #public }
FreeTypeCache >> maximumSize: anIntegerOrNil [
maximumSize := anIntegerOrNil.
maximumSize ifNotNil:[
used > maximumSize
ifTrue:["shrink"
self shrinkTo: maximumSize]]
]
{ #category : #'add-remove' }
FreeTypeCache >> removeAll [
fontTable := self dictionaryClass new: 100.
fifo := self fifoClass new.
used := 0.
]
{ #category : #'add-remove' }
FreeTypeCache >> removeAllForFont: aFreeTypeFont [
| toRemove |
(fontTable includesKey: aFreeTypeFont) ifFalse:[^self].
toRemove := IdentitySet new.
fifo do:[:entry |
entry font = aFreeTypeFont
ifTrue:[toRemove add: entry]].
toRemove do:[:entry | | d |
fifo remove: entry.
d := (fontTable at: entry font) at: entry charCode.
d removeKey: entry type.
used := used - (self sizeOf: entry object) ].
]
{ #category : #'add-remove' }
FreeTypeCache >> removeAllForType: typeFlag [
| toRemove |
toRemove := IdentitySet new.
fifo do:[:entry |
entry type = typeFlag
ifTrue:[toRemove add: entry]].
toRemove do:[:entry | | d |
fifo remove: entry.
d := (fontTable at: entry font) at: entry charCode.
d removeKey: entry type.
used := used - (self sizeOf: entry object) ].
]
{ #category : #public }
FreeTypeCache >> report [
"answer a description of the current state of the cache"
| usedPercent |
usedPercent := maximumSize
ifNil: [0]
ifNotNil: [(used * 100 / maximumSize) asFloat rounded].
^usedPercent asString,'% Full (maximumSize: ', maximumSize asString, ' , used: ', used asString,')'
]
{ #category : #private }
FreeTypeCache >> shrinkTo: newSize [
"if the used size is greater than newSize, then remove all the receiver's entries"
used > newSize ifTrue:[self removeAll]
]
{ #category : #public }
FreeTypeCache >> sizeOf: anObject [
^(anObject isKindOf: Form)
ifTrue:[(anObject bitsSize * 4) + 32]
ifFalse:[4]
]