-
-
Notifications
You must be signed in to change notification settings - Fork 353
/
SpMillerColumnPresenter.class.st
100 lines (76 loc) · 2.78 KB
/
SpMillerColumnPresenter.class.st
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
"
I am a miller columns widget, aka cascading lists.
I am composed of presenters flowing to the right.
Every time that one of my inner presenters is activated, I ""dive in"" that element, showing a new presenter for the activated element to the right of the current selection.
You have to set me:
- presenterBlock: aBlock that receives a model as argument and returns a SpecMillerPresenter or compatible (read below)
- a first presenter using either
- setModel: with a model that calculates the initial presenter using the presenter block if already available
- setPresenter: with a SpecMillerPresenter or compatible (read below)
SpecMillerColumnPresenter works on SpecMillerPresenter or compatible objects.
All presenters inside this one should be polymorphic, defining:
- whenActivatedDo:, an event that will invoke a valuable with a selection object (understanding #selectedObject)
"
Class {
#name : #SpMillerColumnPresenter,
#superclass : #SpPresenter,
#instVars : [
'newPresenterBlock'
],
#category : #'Spec2-Core-Miller'
}
{ #category : #initialization }
SpMillerColumnPresenter >> addPresenter: newSubPresenter [
newSubPresenter whenActivatedDo: [ :selection |
self changeSelection: selection selectedItem from: newSubPresenter ].
newSubPresenter owner: self.
layout add: newSubPresenter.
]
{ #category : #initialization }
SpMillerColumnPresenter >> changeSelection: selection from: aPresenter [
| selectedPresenterIndex |
selectedPresenterIndex := self presenters indexOf: aPresenter.
self resetTo: selectedPresenterIndex.
self pushModel: selection.
]
{ #category : #initialization }
SpMillerColumnPresenter >> initialize [
super initialize.
newPresenterBlock := [ :model | Error signal: 'should provide a new presenter block' ]
]
{ #category : #initialization }
SpMillerColumnPresenter >> initializeWidgets [
layout := SpBoxLayout newHorizontal
]
{ #category : #initialization }
SpMillerColumnPresenter >> newPresenterFor: aModel [
^ newPresenterBlock value: aModel
]
{ #category : #accessing }
SpMillerColumnPresenter >> presenterBlock: aBlockClosure [
newPresenterBlock := aBlockClosure
]
{ #category : #accessing }
SpMillerColumnPresenter >> presenters [
^ layout presenters
]
{ #category : #model }
SpMillerColumnPresenter >> pushModel: aModel [
self addPresenter: (self newPresenterFor: aModel)
]
{ #category : #initialization }
SpMillerColumnPresenter >> resetTo: anIndex [
"Remove all presenters up to anIndex.
0 means to remove all elements."
self presenters copy withIndexDo: [ :presenter :index |
index <= anIndex ifFalse: [ layout remove: presenter ] ]
]
{ #category : #model }
SpMillerColumnPresenter >> setRootModel: aModel [
self resetTo: 0.
self pushModel: aModel
]
{ #category : #accessing }
SpMillerColumnPresenter >> size [
^ self presenters size
]