-
-
Notifications
You must be signed in to change notification settings - Fork 353
/
UndefinedObject.class.st
282 lines (216 loc) · 7.44 KB
/
UndefinedObject.class.st
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
"
I describe the behavior of my sole instance, nil. nil represents a prior value for variables that have not been initialized, or for results which are meaningless.
"
Class {
#name : #UndefinedObject,
#superclass : #Object,
#category : #'Kernel-Objects'
}
{ #category : #accessing }
UndefinedObject class >> allInstances [
"It is well known there is a single instance"
^Array with: nil
]
{ #category : #accessing }
UndefinedObject class >> allInstancesDo: aBlock [
"It is well known there is a single instance"
aBlock value: nil
]
{ #category : #'instance creation' }
UndefinedObject class >> new [
self error: 'You may not create any more undefined objects--use nil'
]
{ #category : #'dependents access' }
UndefinedObject >> addDependent: ignored [
"Refer to the comment in Object|dependents."
self error: 'Nil should not have dependents'
]
{ #category : #'class hierarchy' }
UndefinedObject >> addSubclass: aClass [
"Ignored -- necessary to support disjoint class hierarchies"
]
{ #category : #'class hierarchy' }
UndefinedObject >> allSuperclassesDo: aBlockContext [
"Ignored -- necessary to support disjoint class hierarchies"
]
{ #category : #'sets support' }
UndefinedObject >> asSetElement [
"Since nil is a singleton, we need only a single wrapper instance to represent it in set,
created in advance"
^ SetElement withNil
]
{ #category : #accessing }
UndefinedObject >> at: index put: anObject [
self shouldNotImplement
]
{ #category : #'bottom context' }
UndefinedObject >> canHandleSignal: exception [
"When no more handler (on:do:) context left in sender chain this gets called"
^ false
]
{ #category : #'class hierarchy' }
UndefinedObject >> classBuilder [
"Answer the object responsible of creating subclasses of myself in the system."
^ self classInstaller new builder
]
{ #category : #'class hierarchy' }
UndefinedObject >> classInstaller [
"Answer the class responsible of creating classes in the system."
^ Smalltalk classInstaller
]
{ #category : #copying }
UndefinedObject >> deepCopy [
"Only one instance of UndefinedObject should ever be made, so answer
with self."
]
{ #category : #'reflective operations' }
UndefinedObject >> doesNotUnderstand: aMessage [
<debuggerCompleteToSender>
"Handle the fact that there was an attempt to send the given message to an Undeclared variable (nil), hence the receiver does not understand this message (typically #new)."
"Testing: (3 activeProcess)"
| exception resumeValue node |
(node := self findUndeclaredVariableIn: thisContext sender sourceNodeExecuted) ifNil: [
^super doesNotUnderstand: aMessage ].
(exception := VariableNotDeclared new)
message: aMessage;
variableNode: node;
receiver: self.
resumeValue := exception signal.
^ exception reachedDefaultHandler
ifTrue: [ aMessage sentTo: self ]
ifFalse: [ resumeValue ] .
]
{ #category : #'class hierarchy' }
UndefinedObject >> environment [
"Necessary to support disjoint class hierarchies."
^self class environment
]
{ #category : #'reflective operations' }
UndefinedObject >> findUndeclaredVariableIn: ast [
"Walk the ast of the current statment and find the undeclared variable node, or nil (if none).
Assumes there is only one such variable in an executing statement"
ast nodesDo: [:node |
(node isVariable and: [ node isUndeclared]) ifTrue: [ ^node ]].
^nil
]
{ #category : #'bottom context' }
UndefinedObject >> handleSignal: exception [
"When no more handler (on:do:) context left in sender chain this gets called. Return from signal with default action."
^ exception resumeUnchecked: exception defaultAction
]
{ #category : #testing }
UndefinedObject >> ifNil: aBlock [
"A convenient test, in conjunction with Object ifNil:"
^ aBlock value
]
{ #category : #testing }
UndefinedObject >> ifNil: nilBlock ifNotNil: ifNotNilBlock [
"If the receiver is not nil, pass it as argument to the ifNotNilBlock block. else execute the nilBlock block "
"(nil ifNil: [42] ifNotNil: [:o | o +3 ] ) >>> 42"
"(3 ifNil: [42] ifNotNil: [:o | o +3 ]) >>> 6"
^ nilBlock value
]
{ #category : #testing }
UndefinedObject >> ifNotNil: aBlock [
"If the receiver is not nil, pass it as argument to the block."
"(2 ifNotNil: [ :o | o + 3]) >>> 5"
"(nil ifNotNil: [:o | o +3 ]) >>> nil"
^ self
]
{ #category : #testing }
UndefinedObject >> ifNotNil: ifNotNilBlock ifNil: nilBlock [
"If the receiver is not nil, pass it as argument to the ifNotNilBlock block. else execute the nilBlock block "
"(nil ifNotNil: [:o | o +3 ] ifNil: [42]) >>> 42"
"(3 ifNotNil: [:o | o +3 ] ifNil: [42]) >>> 6"
^ nilBlock value
]
{ #category : #testing }
UndefinedObject >> isEmptyOrNil [
"Answer whether the receiver contains any elements, or is nil. Useful in numerous situations where one wishes the same reaction to an empty collection or to nil"
^ true
]
{ #category : #testing }
UndefinedObject >> isLiteral [
^ true
]
{ #category : #testing }
UndefinedObject >> isNil [
"Refer to the comment in Object|isNil."
^true
]
{ #category : #testing }
UndefinedObject >> isNotNil [
"Refer to the comment in Object|isNotNil."
^false
]
{ #category : #'class hierarchy' }
UndefinedObject >> literalScannedAs: scannedLiteral notifying: requestor [
^ scannedLiteral
]
{ #category : #testing }
UndefinedObject >> notNil [
"Refer to the comment in Object|notNil."
^false
]
{ #category : #printing }
UndefinedObject >> printOn: aStream [
"Refer to the comment in Object|printOn:."
aStream nextPutAll: 'nil'
]
{ #category : #'class hierarchy' }
UndefinedObject >> removeSubclass: aClass [
"Ignored -- necessary to support disjoint class hierarchies"
]
{ #category : #copying }
UndefinedObject >> shallowCopy [
"Only one instance of UndefinedObject should ever be made, so answer
with self."
]
{ #category : #printing }
UndefinedObject >> storeOn: aStream [
"Refer to the comment in Object|storeOn:."
aStream nextPutAll: 'nil'
]
{ #category : #'class hierarchy' }
UndefinedObject >> subclass: nameOfClass
instanceVariableNames: instVarNames
classVariableNames: classVarNames
poolDictionaries: poolDictnames
category: category [
"Calling this method is now considered an accident. If you really want to create a class with a nil superclass, then create the class and then set the superclass using #superclass:"
self traceCr: ('Attempt to create ', nameOfClass, ' as a subclass of nil. Possibly a class is being loaded before its superclass.').
^ Object
subclass: nameOfClass
instanceVariableNames: instVarNames
classVariableNames: classVarNames
poolDictionaries: poolDictnames
category: category
]
{ #category : #'class hierarchy' }
UndefinedObject >> subclassDefinerClass [
"For disjunct class hierarchies -- how should subclasses of nil be evaluated"
^self class subclassDefinerClass
]
{ #category : #'class hierarchy' }
UndefinedObject >> subclasses [
"Return all the subclasses of nil"
| classList |
classList := Array new writeStream.
self subclassesDo:[:class| classList nextPut: class].
^classList contents
]
{ #category : #'class hierarchy' }
UndefinedObject >> subclassesDo: aBlock [
"Evaluate aBlock with all subclasses of nil. Others are not direct subclasses of Class."
^ Class subclassesDo: [:cl |
cl isMeta ifTrue: [aBlock value: cl soleInstance]].
]
{ #category : #'class hierarchy' }
UndefinedObject >> typeOfClass [
"Necessary to support disjoint class hierarchies."
^#normal
]
{ #category : #copying }
UndefinedObject >> veryDeepCopyWith: deepCopier [
"Return self. I can't be copied. Do not record me."
]