-
-
Notifications
You must be signed in to change notification settings - Fork 353
/
RBConjunctiveCondition.class.st
93 lines (79 loc) · 2.04 KB
/
RBConjunctiveCondition.class.st
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
"
I am a refactoring condition combining two other conditions by a boolean AND.
I am created by sending the binary message #& to another condition (left) with another condition (right) as its argument.
Checking this conditions holds true, if my left and my right condition is true.
"
Class {
#name : #RBConjunctiveCondition,
#superclass : #RBAbstractCondition,
#instVars : [
'left',
'right',
'failed'
],
#category : #'Refactoring-Core-Conditions'
}
{ #category : #checking }
RBConjunctiveCondition >> check [
left check
ifFalse:
[failed := #leftFailed.
^false].
right check
ifFalse:
[failed := #rightFailed.
^false].
^true
]
{ #category : #private }
RBConjunctiveCondition >> errorBlockFor: aBoolean [
^aBoolean
ifTrue: [nil]
ifFalse:
[failed = #leftFailed ifTrue: [left errorBlock] ifFalse: [right errorBlock]]
]
{ #category : #private }
RBConjunctiveCondition >> errorMacro [
^errorMacro isNil
ifTrue: [self longMacro]
ifFalse: [super errorMacro]
]
{ #category : #private }
RBConjunctiveCondition >> errorStringFor: aBoolean [
^aBoolean
ifTrue: [self neitherFailed]
ifFalse: [self perform: failed]
]
{ #category : #'initialize-release' }
RBConjunctiveCondition >> left: aCondition right: aCondition2 [
left := aCondition.
right := aCondition2.
failed := #unknownFailed
]
{ #category : #private }
RBConjunctiveCondition >> leftFailed [
^left errorStringFor: false
]
{ #category : #private }
RBConjunctiveCondition >> longMacro [
^'(' , left errorMacro , ') <1?AND:OR> (' , right errorMacro , ')'
]
{ #category : #private }
RBConjunctiveCondition >> neitherFailed [
^(left errorStringFor: true) , ' AND ' , (right errorStringFor: true)
]
{ #category : #printing }
RBConjunctiveCondition >> printOn: aStream [
aStream
print: left;
nextPutAll: ' & ';
print: right
]
{ #category : #private }
RBConjunctiveCondition >> rightFailed [
^right errorStringFor: false
]
{ #category : #private }
RBConjunctiveCondition >> unknownFailed [
^(left errorStringFor: false) , ' OR ' , (right errorStringFor: false)
]