-
-
Notifications
You must be signed in to change notification settings - Fork 353
/
Collection.class.st
1301 lines (1033 loc) · 38.4 KB
/
Collection.class.st
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
"
I am the abstract superclass of all classes that represent a group of elements.
"
Class {
#name : #Collection,
#superclass : #Object,
#category : #'Collections-Abstract-Base'
}
{ #category : #'instance creation' }
Collection class >> empty [
^ self new
]
{ #category : #testing }
Collection class >> isAbstract [
^self name = #Collection
]
{ #category : #'instance creation' }
Collection class >> with: anObject [
"Answer an instance of me containing anObject."
^ self empty
add: anObject;
yourself
]
{ #category : #'instance creation' }
Collection class >> with: firstObject with: secondObject [
"Answer an instance of me containing the two arguments as elements."
^ self new
add: firstObject;
add: secondObject;
yourself
]
{ #category : #'instance creation' }
Collection class >> with: firstObject with: secondObject with: thirdObject [
"Answer an instance of me containing the three arguments as elements."
^ self new
add: firstObject;
add: secondObject;
add: thirdObject;
yourself
]
{ #category : #'instance creation' }
Collection class >> with: firstObject with: secondObject with: thirdObject with: fourthObject [
"Answer an instance of me, containing the four arguments as the elements."
^ self new
add: firstObject;
add: secondObject;
add: thirdObject;
add: fourthObject;
yourself
]
{ #category : #'instance creation' }
Collection class >> with: firstObject with: secondObject with: thirdObject with: fourthObject with: fifthObject [
"Answer an instance of me, containing the five arguments as the elements."
^ self new
add: firstObject;
add: secondObject;
add: thirdObject;
add: fourthObject;
add: fifthObject;
yourself
]
{ #category : #'instance creation' }
Collection class >> with: firstObject with: secondObject with: thirdObject with: fourthObject with: fifthObject with: sixthObject [
"Answer an instance of me, containing the six arguments as the elements."
^ self new
add: firstObject;
add: secondObject;
add: thirdObject;
add: fourthObject;
add: fifthObject;
add: sixthObject;
yourself
]
{ #category : #'instance creation' }
Collection class >> withAll: aCollection [
"Create a new collection containing all the elements from aCollection."
^ (self new: aCollection size)
addAll: aCollection;
yourself
]
{ #category : #enumerating }
Collection >> & aCollection [
"#(1 2 3 4) & #(1 2 4 6 7) >>> #(1 2 4)"
^ self intersection: aCollection
]
{ #category : #copying }
Collection >> , aCollection [
"Concatenate the receiver with the argument."
"#(1 2 3) , #(4 5 6) >>> #(1 2 3 4 5 6)"
^self copy addAll: aCollection; yourself
]
{ #category : #enumerating }
Collection >> \ aCollection [
"Return all the elements in self that are not in aCollection"
"'abc' \ 'cbe' >>> 'a'."
^ self difference: aCollection
]
{ #category : #adapting }
Collection >> adaptToCollection: rcvr andSend: selector [
"If I am involved in arithmetic with another Collection, return a Collection of
the results of each element combined with the scalar in that expression."
(rcvr isSequenceable and: [ self isSequenceable ]) ifFalse:
[self error: 'Only sequenceable collections may be combined arithmetically'].
^ rcvr with: self collect:
[:rcvrElement :myElement | rcvrElement perform: selector with: myElement]
]
{ #category : #adapting }
Collection >> adaptToNumber: rcvr andSend: selector [
"If I am involved in arithmetic with a scalar, return a Collection of
the results of each element combined with the scalar in that expression."
^ self collect: [:element | rcvr perform: selector with: element]
]
{ #category : #adapting }
Collection >> adaptToPoint: rcvr andSend: selector [
"If I am involved in arithmetic with a scalar, return a Collection of
the results of each element combined with the scalar in that expression."
^ self collect: [:element | rcvr perform: selector with: element]
]
{ #category : #adding }
Collection >> add: newObject [
"Include newObject as one of the receiver's elements. Answer newObject.
ArrayedCollections cannot respond to this message."
self subclassResponsibility
]
{ #category : #adding }
Collection >> add: newObject withOccurrences: anInteger [
"Add newObject anInteger times to the receiver. Answer newObject."
anInteger timesRepeat: [self add: newObject].
^ newObject
]
{ #category : #adding }
Collection >> addAll: aCollection [
"Include all the elements of aCollection as the receiver's elements. Answer
aCollection. Actually, any object responding to #do: can be used as argument."
aCollection do: [:each | self add: each].
^ aCollection
]
{ #category : #adding }
Collection >> addIfNotPresent: anObject [
"Include anObject as one of the receiver's elements, but only if there
is no such element already. Anwser anObject."
(self includes: anObject) ifFalse: [self add: anObject].
^ anObject
]
{ #category : #enumerating }
Collection >> allSatisfy: aBlock [
"Evaluate aBlock with the elements of the receiver.
If aBlock returns false for any element return false.
Otherwise return true."
"#(1 2) allSatisfy: [ :each | each even ] >>> false"
"#(2 4) allSatisfy: [ :each | each even ] >>> true"
self do: [:each | (aBlock value: each) ifFalse: [^ false]].
^ true
]
{ #category : #accessing }
Collection >> anyOne [
"Answer a representative sample of the receiver. It raises an error when the collection is empty. This method can be helpful when needing to preinfer the nature of the contents of semi-homogeneous collections."
"#(1 2 3) anyOne >>> 1"
"
([#() anyOne] on: SubscriptOutOfBounds do: [ :ex | 'whatever' ]) >>> 'whatever'
"
self emptyCheck.
self do: [:each | ^ each]
]
{ #category : #enumerating }
Collection >> anySatisfy: aBlock [
"Evaluate aBlock with the elements of the receiver.
If aBlock returns true for any element return true.
Otherwise return false."
"#(1 3) anySatisfy: [ :each | each even ] >>> false"
"#(1 2) anySatisfy: [ :each | each even ] >>> true"
self do: [:each | (aBlock value: each) ifTrue: [^ true]].
^ false
]
{ #category : #converting }
Collection >> asArray [
"Answer an Array whose elements are the elements of the receiver.
Implementation note: Cannot use ''Array withAll: self'' as that only
works for SequenceableCollections which support the replacement
primitive."
| newArray index |
newArray := Array new: self size.
index := 0.
self do: [:each | newArray at: (index := index + 1) put: each].
^ newArray
]
{ #category : #converting }
Collection >> asBag [
"Answer a Bag whose elements are the elements of the receiver."
^ Bag withAll: self
]
{ #category : #converting }
Collection >> asByteArray [
"Answer a ByteArray whose elements are the elements of the receiver.
Implementation note: Cannot use ''ByteArray withAll: self'' as that only
works for SequenceableCollections which support the replacement
primitive."
| array index |
array := ByteArray new: self size.
index := 0.
self do: [:each | array at: (index := index + 1) put: each].
^ array
]
{ #category : #converting }
Collection >> asCharacterSet [
"Answer a CharacterSet whose elements are the unique elements of the receiver.
The reciever should only contain characters."
^ CharacterSet newFrom: self
]
{ #category : #printing }
Collection >> asCommaString [
"Return collection printed as 'a, b, c' "
"#( 'a' 'b' 'c') asCommaString >>> 'a, b, c'"
^String streamContents: [:s | self asStringOn: s delimiter: ', ']
]
{ #category : #printing }
Collection >> asCommaStringAnd [
"Return collection printed as 'a, b and c' "
"#( 'a' 'b' 'c') asCommaStringAnd >>> 'a, b and c'"
^String streamContents: [:s | self asStringOn: s delimiter: ', ' last: ' and ']
]
{ #category : #converting }
Collection >> asDictionary [
^ self as: Dictionary
]
{ #category : #converting }
Collection >> asIdentitySet [
^(IdentitySet new: self size) addAll: self; yourself
]
{ #category : #converting }
Collection >> asOrderedCollection [
"Answer an OrderedCollection whose elements are the elements of the
receiver. The order in which elements are added depends on the order
in which the receiver enumerates its elements. In the case of unordered
collections, the ordering is not necessarily the same for multiple
requests for the conversion."
^ self as: OrderedCollection
]
{ #category : #converting }
Collection >> asOrderedDictionary [
^ self as: OrderedDictionary
]
{ #category : #converting }
Collection >> asSet [
"Answer a Set whose elements are the unique elements of the receiver."
^ Set withAll: self
]
{ #category : #converting }
Collection >> asSortedCollection [
"Answer a SortedCollection whose elements are the elements of the receiver. The sort order is the default less than or equal. Note that you should use #sorted: if you don't really need a SortedCollection, but a sorted collection."
^ self as: SortedCollection
]
{ #category : #converting }
Collection >> asSortedCollection: aSortBlock [
"Answer a SortedCollection whose elements are the elements of the receiver. The sort order is defined by the argument, aSortBlock. Note that this is better to use #sorted: if you don't really need a SortedCollection, but a sorted collection!!"
| aSortedCollection |
aSortedCollection := SortedCollection new: self size.
aSortedCollection sortBlock: aSortBlock.
aSortedCollection addAll: self.
^ aSortedCollection
]
{ #category : #printing }
Collection >> asStringOn: aStream delimiter: delimString [
"Print elements on a stream separated
with a delimiter String like: 'a, b, c'
Uses #asString instead of #print:."
self do: [:elem | aStream nextPutAll: elem asString]
separatedBy: [aStream nextPutAll: delimString]
]
{ #category : #printing }
Collection >> asStringOn: aStream delimiter: delimString last: lastDelimString [
"Print elements on a stream separated
with a delimiter between all the elements and with
a special one before the last like: 'a, b and c'.
Uses #asString instead of #print:
Note: Feel free to improve the code to detect the last element."
| n sz |
n := 1.
sz := self size.
self do: [:elem |
n := n + 1.
aStream nextPutAll: elem asString]
separatedBy: [
aStream nextPutAll: (n = sz ifTrue: [lastDelimString] ifFalse: [delimString])]
]
{ #category : #enumerating }
Collection >> associationsDo: aBlock [
"Evaluate aBlock for each of the receiver's elements (key/value
associations). If any non-association is within, the error is not caught now,
but later, when a key or value message is sent to it."
self do: aBlock
]
{ #category : #accessing }
Collection >> capacity [
"Answer the current capacity of the receiver."
^ self size
]
{ #category : #enumerating }
Collection >> collect: aBlock [
"Evaluate aBlock with each of the receiver's elements as the argument.
Collect the resulting values into a collection like the receiver. Answer
the new collection."
| newCollection |
newCollection := self species new.
self do: [:each | newCollection add: (aBlock value: each)].
^ newCollection
]
{ #category : #enumerating }
Collection >> collect: aBlock as: aClass [
"Evaluate aBlock with each of the receiver's elements as the argument.
Collect the resulting values into an instance of aClass. Answer the resulting collection."
^(aClass new: self size) fillFrom: self with: aBlock
]
{ #category : #enumerating }
Collection >> collect: aBlock into: aCollection [
"Evaluate aBlock with each of the receiver's elements as the argument.
Collect the resulting values into aCollection. Answer aCollection."
^aCollection fillFrom: self with: aBlock
]
{ #category : #enumerating }
Collection >> collect: collectBlock thenDo: doBlock [
"Utility method to improve readability."
^ self do: [ :each|
doBlock value: (collectBlock value: each)]
]
{ #category : #enumerating }
Collection >> collect: collectBlock thenReject: selectBlock [
"Utility method to improve readability."
^ (self collect: collectBlock) reject: selectBlock
]
{ #category : #enumerating }
Collection >> collect: collectBlock thenSelect: selectBlock [
"Utility method to improve readability."
^ (self collect: collectBlock) select: selectBlock
]
{ #category : #testing }
Collection >> contains: aBlock [
"VW compatibility"
^self anySatisfy: aBlock
]
{ #category : #'filter streaming' }
Collection >> contents [
^ self
]
{ #category : #copying }
Collection >> copyEmpty [
^ self species new
]
{ #category : #copying }
Collection >> copyWith: newElement [
"Answer a new collection with newElement added (as last
element if sequenceable)."
^ self copy
add: newElement;
yourself
]
{ #category : #copying }
Collection >> copyWithDependent: newElement [
"Answer a new collection with newElement added (as last
element if sequenceable)."
^self copyWith: newElement
]
{ #category : #copying }
Collection >> copyWithout: oldElement [
"Answer a copy of the receiver that does not contain any
elements equal to oldElement."
"('fred the bear' copyWithout: $e) >>> 'frd th bar'"
"(#(2 3 4 5 5 6) copyWithout: 5) >>> #(2 3 4 6)"
^ self reject: [:each | each = oldElement]
]
{ #category : #copying }
Collection >> copyWithoutAll: aCollection [
"Answer a copy of the receiver that does not contain any elements
equal to those in aCollection."
^ self reject: [:each | aCollection includes: each]
]
{ #category : #copying }
Collection >> copyWithoutDuplicates [
"Answer a copy of the receiver without any duplicated elements"
"(#(2 3 4 4 5 6) copyWithoutDuplicates) >>> #(2 3 4 5 6)"
"(#('do' 'la' 'si' 'do' 'la') copyWithoutDuplicates) >>> #('la' 'do' 'si')"
"(#(#do #la #si #do #la) copyWithoutDuplicates) >>> #(#la #do #si)"
^ self asSet asArray
]
{ #category : #enumerating }
Collection >> count: aBlock [
"Evaluate aBlock with each of the receiver's elements as the argument.
Answer the number of elements that answered true."
"#(1 2 3 4) count: [ :each | each even ] >>> true"
| sum |
sum := 0.
self do: [:each | (aBlock value: each) ifTrue: [sum := sum + 1]].
^ sum
]
{ #category : #enumerating }
Collection >> detect: aBlock [
"Evaluate aBlock with each of the receiver's elements as the argument.
Answer the first element for which aBlock evaluates to true."
"(#(1 2 3 4) detect: [ :each | each even ]) >>> 2"
^ self detect: aBlock ifNone: [self errorNotFound: aBlock]
]
{ #category : #enumerating }
Collection >> detect: aBlock ifFound: foundBlock [
"Evaluate aBlock with each of the receiver's elements as the argument.
If some element evaluates aBlock to true, then cull this element into
foundBlock.
If no element matches the criteria then do nothing.
Always returns self to avoid misuse and a potential isNil check on the sender."
"(#(1 2) detect: [ :each | each even ] ifFound: [ ^'yay!' ]) >>> 'yay'"
"(#(1 3) detect: [ :each | each even ] ifFound: [ ^'yay!' ]) >>> #(1 3)"
self
detect: aBlock
ifFound: foundBlock
ifNone: [
"Do nothing on purpose"
]
]
{ #category : #enumerating }
Collection >> detect: aBlock ifFound: foundBlock ifNone: exceptionBlock [
"Evaluate aBlock with each of the receiver's elements as the argument.
If some element evaluates aBlock to true, then cull this element into
foundBlock and answer the result of this evaluation.
If none evaluate to true, then evaluate exceptionBlock."
self
do: [ :each |
(aBlock value: each)
ifTrue: [ ^ foundBlock cull: each ] ].
^ exceptionBlock value
]
{ #category : #enumerating }
Collection >> detect: aBlock ifNone: exceptionBlock [
"Evaluate aBlock with each of the receiver's elements as the argument.
Answer the first element for which aBlock evaluates to true. If none
evaluate to true, then evaluate the argument, exceptionBlock."
^ self detect: aBlock ifFound: [ :element | element ] ifNone: exceptionBlock
]
{ #category : #enumerating }
Collection >> detectMax: aBlock [
"Evaluate aBlock with each of the receiver's elements as the argument.
Answer the element for which aBlock evaluates to the highest magnitude.
If collection empty, return nil. This method might also be called elect:."
| maxElement maxValue |
self do: [:each | | val |
maxValue == nil
ifFalse: [
(val := aBlock value: each) > maxValue ifTrue: [
maxElement := each.
maxValue := val]]
ifTrue: ["first element"
maxElement := each.
maxValue := aBlock value: each].
"Note that there is no way to get the first element that works
for all kinds of Collections. Must test every one."].
^ maxElement
]
{ #category : #enumerating }
Collection >> detectMin: aBlock [
"Evaluate aBlock with each of the receiver's elements as the argument.
Answer the element for which aBlock evaluates to the lowest number.
If collection empty, return nil."
| minElement minValue |
self do: [:each | | val |
minValue == nil
ifFalse: [
(val := aBlock value: each) < minValue ifTrue: [
minElement := each.
minValue := val]]
ifTrue: ["first element"
minElement := each.
minValue := aBlock value: each].
"Note that there is no way to get the first element that works
for all kinds of Collections. Must test every one."].
^ minElement
]
{ #category : #enumerating }
Collection >> detectSum: aBlock [
"Evaluate aBlock with each of the receiver's elements as the argument.
Return the sum of the answers."
| sum |
sum := 0.
self do: [:each |
sum := (aBlock value: each) + sum].
^ sum
]
{ #category : #enumerating }
Collection >> difference: aCollection [
"Answer the set theoretic difference of two collections. Pay attention that the difference is not commutative, hence the order is important."
"(#(a b c d e f) difference: #(a b z k))>>> #(#f #d #e #c)"
"(#(a b z k) difference: #(a b c d e f)) >>> #(#k #z)"
| set |
set := self asSet
removeAllFoundIn: aCollection;
yourself.
^ self species withAll: set asArray
]
{ #category : #enumerating }
Collection >> do: aBlock [
"Evaluate aBlock with each of the receiver's elements as the argument."
self subclassResponsibility
]
{ #category : #enumerating }
Collection >> do: elementBlock separatedBy: separatorBlock [
"Evaluate the elementBlock for all elements in the receiver,
and evaluate the separatorBlock between."
"(String streamContents: [:s | #(1 2 3) do: [:each | s << each asString] separatedBy: [s << ', ']]) >>> '1, 2, 3'"
| beforeFirst |
beforeFirst := true.
self do:
[:each |
beforeFirst
ifTrue: [beforeFirst := false]
ifFalse: [separatorBlock value].
elementBlock value: each]
]
{ #category : #enumerating }
Collection >> do: aBlock without: anItem [
"Enumerate all elements in the receiver.
Execute aBlock for those elements that are not equal to the given item"
^ self do: [:each | anItem = each ifFalse: [aBlock value: each]]
]
{ #category : #private }
Collection >> emptyCheck [
self isEmpty ifTrue: [self errorEmptyCollection]
]
{ #category : #private }
Collection >> errorEmptyCollection [
"Signal a CollectionIsEmpty exception"
CollectionIsEmpty signalWith: self
]
{ #category : #private }
Collection >> errorNotFound: anObject [
"Raise a NotFound exception."
NotFound signalFor: anObject
]
{ #category : #private }
Collection >> errorSizeMismatch [
"Signal a SizeMismatch exception"
SizeMismatch signal
]
{ #category : #private }
Collection >> fillFrom: aCollection with: aBlock [
"Evaluate aBlock with each of aCollections's elements as the argument.
Collect the resulting values into self. Answer self."
aCollection do: [ :each |
self add: (aBlock value: each) ]
]
{ #category : #enumerating }
Collection >> findFirstInByteString: aByteString startingAt: start [
"Find the index of first character starting at start in aByteString that is included in the receiver.
Default is to use a naive algorithm.
Subclasses might want to implement a more efficient scheme"
start to: aByteString size do:
[:index |
(self includes: (aByteString at: index)) ifTrue: [^ index]].
^ 0
]
{ #category : #enumerating }
Collection >> flatCollect: aBlock [
"Evaluate aBlock for each of the receiver's elements and answer the
list of all resulting values flatten one level. Assumes that aBlock returns some kind
of collection for each element. Equivalent to the lisp's mapcan"
"( #((3 4) (1 2)) flatCollect: [:each | each ] )>>> #(3 4 1 2)"
"( #(3 4 1 2) flatCollect: [:each | { each } ] ) >>> #(3 4 1 2)"
^ self flatCollect: aBlock as: self species
]
{ #category : #enumerating }
Collection >> flatCollect: aBlock as: aCollectionClass [
"Evaluate aBlock for each of the receiver's elements and answer the
list of all resulting values flatten one level. Assumes that aBlock returns some kind
of collection for each element. Equivalent to the lisp's mapcan"
| col |
col := OrderedCollection new: self size.
self do: [ :each | col addAll: (aBlock value: each) ].
^ aCollectionClass withAll: col
]
{ #category : #enumerating }
Collection >> flatCollectAsSet: aBlock [
"Evaluate aBlock for each of the receiver's elements and answer the
list of all resulting values flatten one level. Assumes that aBlock returns some kind
of collection for each element. Equivalent to the lisp's mapcan"
^ self flatCollect: aBlock as: Set
]
{ #category : #enumerating }
Collection >> flattenOn: aStream [
self do: [ :each | (each isCollection and: [each isString not])
ifTrue: [each flattenOn: aStream]
ifFalse: [aStream nextPut: each]].
]
{ #category : #enumerating }
Collection >> flattened [
"Flattens a collection of collections (no matter how many levels of collections exist). Strings are considered atoms and, as such, won't be flattened"
"( #(1 #(2 3) #(4 #(5))) flattened ) >>> #(1 2 3 4 5)"
"( #('string1' #('string2' 'string3')) flattened ) >>> #('string1' 'string2' 'string3')"
^ Array streamContents: [ :stream | self flattenOn: stream].
]
{ #category : #enumerating }
Collection >> fold: binaryBlock [
"Evaluate the block with the first two elements of the receiver, then with the result of the first evaluation and the next element, and so on. Answer the result of the final evaluation. If the receiver is empty, raise an error. If the receiver has a single element, answer that element."
"( #('if' 'it' 'is' 'to' 'be' 'it' 'is' 'up' 'to' 'me') fold: [:a :b | a, ' ', b] ) >>> 'if it is to be it is up to me'"
^self reduce: binaryBlock
]
{ #category : #enumerating }
Collection >> gather: aBlock [
"This method is kept for compatibility reasons, use flatCollect: instead."
^ self flatCollect: aBlock.
]
{ #category : #enumerating }
Collection >> groupedBy: aBlock [
"Answer a dictionary whose keys are the result of evaluating aBlock for all my elements, and the value for each key is the selection of my elements that evaluated to that key. Uses species."
| groups |
groups := OrderedDictionary new.
self do: [ :each |
(groups at: (aBlock value: each) ifAbsentPut: [ OrderedCollection new ]) add: each ].
self species ~~ OrderedCollection ifTrue: [
groups associationsDo: [ :association |
association value: (self species withAll: association value) ]].
^ groups
]
{ #category : #enumerating }
Collection >> groupedBy: aBlock having: aSelectionBlock [
"Like in SQL operation - Split the recievers contents into collections of
elements for which keyBlock returns the same results, and return those
collections allowed by selectBlock."
^ (self groupedBy: aBlock) select: aSelectionBlock
]
{ #category : #comparing }
Collection >> hash [
"Answer an integer hash value for the receiver such that,
-- the hash value of an unchanged object is constant over time, and
-- two equal objects have equal hash values"
| hash |
hash := self species hash.
self size <= 10 ifTrue:
[self do: [:elem | hash := hash bitXor: elem hash]].
^hash bitXor: self size hash
]
{ #category : #testing }
Collection >> identityIncludes: anObject [
"Answer whether anObject is one of the receiver's elements."
self do: [:each | anObject == each ifTrue: [^true]].
^false
]
{ #category : #testing }
Collection >> ifEmpty: aBlock [
"Evaluate the given block, answering its value if the receiver is empty, otherwise answer the receiver."
"Note that the fact that this method returns its receiver in case the receiver is not empty allows one to write expressions like the following ones: self classifyMethodAs: (myProtocol ifEmpty: ['As yet unclassified'])"
^ self isEmpty
ifTrue: [ aBlock value ]
ifFalse: [ self ]
]
{ #category : #testing }
Collection >> ifEmpty: emptyBlock ifNotEmpty: notEmptyBlock [
"Evaluate emptyBlock if I'm empty, notEmptyBlock otherwise"
"If the notEmptyBlock has an argument, eval with the receiver as its argument"
^ self isEmpty
ifTrue: [ emptyBlock value ]
ifFalse: [ notEmptyBlock cull: self ]
]
{ #category : #testing }
Collection >> ifNotEmpty: aBlock [
"Evaluate the given block with the receiver as argument, answering its value
unless the receiver is empty, in which case answer the receiver."
^ self isEmpty
ifTrue: [ self ]
ifFalse: [ aBlock cull: self ]
]
{ #category : #testing }
Collection >> ifNotEmpty: notEmptyBlock ifEmpty: emptyBlock [
"Evaluate emptyBlock if I'm empty, notEmptyBlock otherwise
If the notEmptyBlock has an argument, eval with the receiver as its argument"
^ self isEmpty
ifTrue: [ emptyBlock value ]
ifFalse: [ notEmptyBlock cull: self ]
]
{ #category : #testing }
Collection >> includes: anObject [
"Answer whether anObject is one of the receiver's elements."
^ self anySatisfy: [:each | each = anObject]
]
{ #category : #testing }
Collection >> includesAll: aCollection [
"Answer whether all the elements of aCollection are in the receiver."
aCollection do: [:elem | (self includes: elem) ifFalse: [^ false]].
^ true
]
{ #category : #testing }
Collection >> includesAllOf: aCollection [
self
deprecated: 'Please use #includesAll: instead'
transformWith: '`@receiver includesAllOf: `@statements' -> '`@receiver includesAll: `@statements'.
^ self includesAll: aCollection
]
{ #category : #testing }
Collection >> includesAny: aCollection [
"Answer whether any element of aCollection is one of the receiver's elements."
aCollection do: [:elem | (self includes: elem) ifTrue: [^ true]].
^ false
]
{ #category : #testing }
Collection >> includesAnyOf: aCollection [
self flag: 'use includesAny: instead'.
^ self includesAny: aCollection.
]
{ #category : #testing }
Collection >> includesSubstringAnywhere: testString [
"Answer whether the receiver includes, anywhere in its nested structure, a string that has testString as a substring"
self do:
[:element |
(element isString)
ifTrue:
[(element includesSubstring: testString) ifTrue: [^ true]].
(element isCollection)
ifTrue:
[(element includesSubstringAnywhere: testString) ifTrue: [^ true]]].
^ false
"#(first (second third) ((allSentMessages ('Elvis' includes:)))) includesSubstringAnywhere: 'lvi'"
]
{ #category : #enumerating }
Collection >> inject: thisValue into: binaryBlock [
"Accumulate a running value associated with evaluating the argument, binaryBlock, with the current value of the argument, thisValue, and the receiver as block arguments."
"( #(1 2 3) inject: 0 into: [ :sum :each | sum + each ] ) >>> 6"
| nextValue |
nextValue := thisValue.
self do: [:each | nextValue := binaryBlock value: nextValue value: each].
^nextValue
]
{ #category : #enumerating }
Collection >> intersection: aCollection [
"Answer the set theoretic intersection of two collections."
"(#(1 2 3 4) intersection: #(3 4 5)) >>> #(3 4)"
"(#(1 2 3 4) intersection: #()) >>> #()"
"(#() intersection: #(1 2 3 4)) >>> #()"
^ self species withAll: (self asSet intersection: aCollection) asArray
]
{ #category : #testing }
Collection >> isCollection [
"Return true if the receiver is some sort of Collection and responds to basic collection messages such as #size and #do:"
^true
]
{ #category : #testing }
Collection >> isEmpty [
"Answer whether the receiver contains any elements."
^self size = 0
]
{ #category : #testing }
Collection >> isEmptyOrNil [
"Answer whether the receiver contains any elements, or is nil. Useful in numerous situations where one wishes the same reaction to an empty collection or to nil"
^ self isEmpty
]
{ #category : #testing }
Collection >> isNotEmpty [
"Answer whether the receiver contains any elements."
^ self isEmpty not
]
{ #category : #testing }
Collection >> isSequenceable [
^ false
]
{ #category : #'math functions' }
Collection >> median [
"Return the middle element, or as close as we can get."
"{1 . 2 . 3 . 4 . 5} median >>> 3"
^ self asSortedCollection median
]
{ #category : #enumerating }
Collection >> noneSatisfy: aBlock [
"Evaluate aBlock with the elements of the receiver. If aBlock returns false for all elements return true. Otherwise return false"
self do: [:item | (aBlock value: item) ifTrue: [^ false]].
^ true
]
{ #category : #testing }
Collection >> notEmpty [
"Answer whether the receiver contains any elements."
"use isNotEmpty for consistency with isEmpty"
^ self isEmpty not
]
{ #category : #enumerating }
Collection >> occurrencesOf: anObject [
"Answer how many of the receiver's elements are equal to anObject."
| tally |
tally := 0.
self do: [:each | anObject = each ifTrue: [tally := tally + 1]].
^tally
]
{ #category : #printing }
Collection >> printElementsOn: aStream [
"The original code used #skip:, but some streams do not support that,
and we don't really need it."
aStream nextPut: $(.