-
-
Notifications
You must be signed in to change notification settings - Fork 354
/
PluggableButtonMorph.class.st
1367 lines (1070 loc) · 35.9 KB
/
PluggableButtonMorph.class.st
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
"
A PluggableButtonMorph is a combination of an indicator for a boolean value stored in its model and an action button. The action of a button is often, but not always, to toggle the boolean value that it shows. Its pluggable selectors are:
getStateSelector fetch a boolean value from the model
actionSelector invoke this button's action on the model
getLabelSelector fetch this button's lable from the model
getMenuSelector fetch a pop-up menu for this button from the model
Any of the above selectors can be nil, meaning that the model does not supply behavior for the given action, and the default behavior should be used. For example, if getStateSelector is nil, then this button shows the state of a read-only boolean that is always false.
The model informs its view(s) of changes by sending #changed: to itself with getStateSelector as a parameter. The view tells the model when the button is pressed by sending actionSelector.
If the actionSelector takes one or more arguments, then the following are relevant:
arguments A list of arguments to provide when the actionSelector is called.
argumentsProvider The object that is sent the argumentSelector to obtain arguments, if dynamic
argumentsSelector The message sent to the argumentProvider to obtain the arguments.
Options:
askBeforeChanging have model ask user before allowing a change that could lose edits
triggerOnMouseDown do this button's action on mouse down (vs. up) transition
shortcutCharacter a place to record an optional shortcut key
"
Class {
#name : #PluggableButtonMorph,
#superclass : #AlignmentMorph,
#instVars : [
'model',
'label',
'icon',
'getIconSelector',
'getStateSelector',
'actionSelector',
'font',
'getLabelSelector',
'getMenuSelector',
'shortcutCharacter',
'askBeforeChanging',
'triggerOnMouseDown',
'offColor',
'onColor',
'feedbackColor',
'showSelectionFeedback',
'allButtons',
'arguments',
'argumentsProvider',
'argumentsSelector',
'enabled',
'actionBlock',
'getColorSelector',
'getEnabledSelector',
'getFontSelector',
'labelMorph',
'iconMorph',
'iconPosition',
'lastState'
],
#category : #'Morphic-Widgets-Basic-Buttons'
}
{ #category : #shortcuts }
PluggableButtonMorph class >> buildPluggableButtonShortcutsOn: aBuilder [
<keymap>
(aBuilder shortcut: #action1)
category: #PluggableButtonMorph
default: Character space asKeyCombination | Character cr asKeyCombination
do: [ :target :morph :event | morph performAction ].
]
{ #category : #examples }
PluggableButtonMorph class >> exampleButtonNoAction [
<sampleInstance>
<exampleWidget>
^ PluggableButtonMorph
newButtonFor: nil
action: nil
label: 'A Button'
help: 'This is a button'
]
{ #category : #'instance creation' }
PluggableButtonMorph class >> newButtonFor: aModel action: actionSel label: stringOrText help: helpText [
"Answer a new button."
^self
newButtonFor: aModel
getState: nil
action: actionSel
arguments: nil
getEnabled: nil
label: stringOrText
help: helpText
]
{ #category : #'instance creation' }
PluggableButtonMorph class >> newButtonFor: aModel getState: stateSel action: actionSel arguments: args getEnabled: enabledSel label: label help: helpText [
"Answer a new button."
| b |
b := self on: aModel getState: stateSel action: actionSel.
b
arguments: (args ifNil: [{b}]);
hResizing: #shrinkWrap;
vResizing: #shrinkWrap;
label: label ;
getEnabledSelector: enabledSel;
setBalloonText: helpText;
extent: b minExtent;
hResizing: #rigid;
vResizing: #rigid.
^b
]
{ #category : #'instance creation' }
PluggableButtonMorph class >> on: anObject [
^ self on: anObject getState: #isOn action: #switch
]
{ #category : #'instance creation' }
PluggableButtonMorph class >> on: anObject getState: getStateSel action: actionSel [
^ self new
on: anObject
getState: getStateSel
action: actionSel
label: nil
icon: nil
menu: nil
]
{ #category : #'instance creation' }
PluggableButtonMorph class >> on: anObject getState: getStateSel action: actionSel label: labelSel [
^ self new
on: anObject
getState: getStateSel
action: actionSel
label: labelSel
icon: nil
menu: nil
]
{ #category : #'instance creation' }
PluggableButtonMorph class >> on: anObject getState: getStateSel action: actionSel label: labelSel icon: iconSel menu: menuSel [
^ self new
on: anObject
getState: getStateSel
action: actionSel
label: labelSel
icon: iconSel
menu: menuSel
]
{ #category : #'instance creation' }
PluggableButtonMorph class >> on: anObject getState: getStateSel action: actionSel label: labelSel menu: menuSel [
^ self new
on: anObject
getState: getStateSel
action: actionSel
label: labelSel
icon: nil
menu: menuSel
]
{ #category : #accessing }
PluggableButtonMorph >> action [
"Answer the action selector."
^self actionSelector
]
{ #category : #accessing }
PluggableButtonMorph >> action: aSymbol [
"Set actionSelector to be the action defined by aSymbol."
actionSelector := aSymbol.
]
{ #category : #accessing }
PluggableButtonMorph >> actionBlock [
^ actionBlock
]
{ #category : #accessing }
PluggableButtonMorph >> actionBlock: aBlock [
"an action can be either specified by a block or a selector. If the block is set it takes priority over selector."
actionBlock := aBlock
]
{ #category : #accessing }
PluggableButtonMorph >> actionSelector [
"Answer the receiver's actionSelector"
^ actionSelector
]
{ #category : #accessing }
PluggableButtonMorph >> actionSelector: aSymbol [
"Set actionSelector to be the action defined by aSymbol.
SimpleButtonMorph cross-compatibility"
actionSelector := aSymbol.
]
{ #category : #'event handling' }
PluggableButtonMorph >> addStandardHaloMenuItemsTo: aMenu hand: aHandMorph [
aMenu add: 'browse action' selector: #browseAction.
aMenu addLine.
super addStandardHaloMenuItemsTo: aMenu hand: aHandMorph.
]
{ #category : #updating }
PluggableButtonMorph >> adoptColor: aColor [
"Go through paneColorChanged instead."
self paneColorChanged
]
{ #category : #updating }
PluggableButtonMorph >> adoptPaneColor: aColor [
super adoptPaneColor: aColor.
aColor ifNil: [^self].
self adoptColor: self colorToUse
]
{ #category : #accessing }
PluggableButtonMorph >> arguments [
"Answer the static arguments.
SimpleButtonMorph cross-compatibility."
^arguments
]
{ #category : #arguments }
PluggableButtonMorph >> arguments: args [
"If the receiver takes argument(s) that are static, they can be filled by calling this. If its argument(s) are to be dynamically determined, then use an argumentProvider and argumentSelector instead"
arguments := args
]
{ #category : #arguments }
PluggableButtonMorph >> argumentsProvider: anObject argumentsSelector: aSelector [
"Set the argument provider and selector"
argumentsProvider := anObject.
argumentsSelector := aSelector
]
{ #category : #accessing }
PluggableButtonMorph >> askBeforeChanging [
^ askBeforeChanging
]
{ #category : #accessing }
PluggableButtonMorph >> askBeforeChanging: aBoolean [
"If this preference is turned on, then give the model an opportunity to ask the user before accepting a change that might cause unaccepted edits to be lost."
askBeforeChanging := aBoolean.
]
{ #category : #accessing }
PluggableButtonMorph >> availableBorderStyles [
"Return the selectors of the the available border styles for each state.
Must match the order of interactionStates."
^#(normalBorderStyle mouseOverBorderStyle pressedBorderStyle disabledBorderStyle
selectedBorderStyle selectedPressedBorderStyle selectedMouseOverBorderStyle selectedDisabledBorderStyle)
]
{ #category : #accessing }
PluggableButtonMorph >> availableFillStyles [
"Return the selectors of the the available fill styles for each state.
Must match the order of interactionStates."
^#(normalFillStyle mouseOverFillStyle pressedFillStyle disabledFillStyle
selectedFillStyle selectedPressedFillStyle selectedMouseOverFillStyle selectedDisabledFillStyle)
]
{ #category : #accessing }
PluggableButtonMorph >> beIconBottom [
"show icon top to label"
iconPosition := #bottom.
self update: getIconSelector
]
{ #category : #accessing }
PluggableButtonMorph >> beIconLeft [
"show icon left to label"
iconPosition := #left.
self update: getIconSelector
]
{ #category : #accessing }
PluggableButtonMorph >> beIconRight [
"show icon right to label"
iconPosition := #right.
self update: getIconSelector
]
{ #category : #accessing }
PluggableButtonMorph >> beIconTop [
"show icon top to label"
iconPosition := #top.
self update: getIconSelector
]
{ #category : #accessing }
PluggableButtonMorph >> borderStyleToUse [
"Return the borderStyle to use for the receiver."
^ self perform: (self availableBorderStyles at: (self interactionStates indexOf: self interactionState))
]
{ #category : #private }
PluggableButtonMorph >> browseAction [
| classDefiningAction |
classDefiningAction := self model class whichClassIncludesSelector: self actionSelector.
Smalltalk tools browser openOnClass: classDefiningAction selector: self actionSelector.
]
{ #category : #updating }
PluggableButtonMorph >> changed [
"Update the fillStyle here."
|lc pc bs|
self assureExtension.
extension borderStyle: (bs := self borderStyleToUse).
borderColor := bs style.
borderWidth := bs width.
extension fillStyle: self fillStyleToUse.
self layoutInset: (self theme buttonLabelInsetFor: self).
self privateColor: self fillStyle asColor.
(self labelMorph respondsTo: #interactionState:)
ifTrue: [self labelMorph interactionState: self interactionState]
ifFalse: [(self labelMorph isNil
or: [label isMorph]) ifFalse: [
pc := self normalColor.
lc := self enabled
ifTrue: [pc contrastingBlackAndWhiteColor]
ifFalse: [pc contrastingBlackAndWhiteColor muchDarker].
self labelMorph color: lc]].
super changed
]
{ #category : #accessing }
PluggableButtonMorph >> color: aColor [
"Check to avoid repeats of the same color."
aColor ifNil: [ ^ self ].
(aColor = self color and: [ self getModelState = self lastState ]) ifTrue: [ ^ self ].
super color: aColor
]
{ #category : #accessing }
PluggableButtonMorph >> colorToUse [
"Answer the color we should use."
|c|
c := self getModelState
ifTrue: [onColor
ifNil: [self paneColor]
ifNotNil: [onColor isTransparent
ifTrue: [self paneColor]
ifFalse: [onColor]]]
ifFalse: [offColor
ifNil: [self paneColor]
ifNotNil: [offColor isTransparent
ifTrue: [self paneColor]
ifFalse: [offColor]]].
^c
]
{ #category : #accessing }
PluggableButtonMorph >> contentHolder [
"Answer the alignment morph for extra control."
^self submorphs first
]
{ #category : #accessing }
PluggableButtonMorph >> cornerStyle: aSymbol [
"Adjust the layout inset."
super cornerStyle: aSymbol.
self layoutInset: (self theme buttonLabelInsetFor: self)
]
{ #category : #initialization }
PluggableButtonMorph >> defaultBorderWidth [
"answer the default border width for the receiver"
^ self theme borderWidth
]
{ #category : #initialization }
PluggableButtonMorph >> defaultColor [
"answer the default color/fill style for the receiver"
^ self containingWindow ifNil: [Color lightGreen] ifNotNil: [:w | w defaultBackgroundColor]
]
{ #category : #accessing }
PluggableButtonMorph >> disable [
"Disable the button."
self enabled: false
]
{ #category : #accessing }
PluggableButtonMorph >> disabledBorderStyle [
"Return the disabled borderStyle of the receiver."
^self theme buttonDisabledBorderStyleFor: self
]
{ #category : #accessing }
PluggableButtonMorph >> disabledFillStyle [
"Return the disabled fillStyle of the receiver."
^self theme buttonDisabledFillStyleFor: self
]
{ #category : #drawing }
PluggableButtonMorph >> drawSubmorphsOn: aCanvas [
"Display submorphs back to front.
Draw the focus here since we are using inset bounds
for the focus rectangle."
super drawSubmorphsOn: aCanvas.
self hasKeyboardFocus ifTrue: [self drawKeyboardFocusOn: aCanvas]
]
{ #category : #accessing }
PluggableButtonMorph >> enable [
"Enable the button."
self enabled: true
]
{ #category : #accessing }
PluggableButtonMorph >> enabled [
^ enabled ifNil: [enabled := true]
]
{ #category : #accessing }
PluggableButtonMorph >> enabled: aBoolean [
"Set the enabled state of the receiver."
enabled = aBoolean ifTrue: [^self].
enabled := aBoolean.
self updateLabelEnablement.
self changed
]
{ #category : #accessing }
PluggableButtonMorph >> feedbackColor: aColor [
"Set the color of this button's selection feedback border."
feedbackColor := aColor.
self changed.
]
{ #category : #accessing }
PluggableButtonMorph >> fillStyleToUse [
"Return the fillStyle to use for the receiver."
^self perform: (self availableFillStyles at: (
self interactionStates indexOf: self interactionState))
]
{ #category : #accessing }
PluggableButtonMorph >> focusBounds [
"Answer the bounds for drawing the focus indication."
^self theme buttonFocusBoundsFor: self
]
{ #category : #accessing }
PluggableButtonMorph >> focusColor [
"Answer the keyboard focus indication color."
^self color contrastingBlackAndWhiteColor
]
{ #category : #accessing }
PluggableButtonMorph >> focusIndicatorCornerRadius [
"Answer the corner radius preferred for the focus indicator
for the receiver for themes that support this."
^self theme buttonFocusIndicatorCornerRadiusFor: self
]
{ #category : #accessing }
PluggableButtonMorph >> font [
^ font
]
{ #category : #accessing }
PluggableButtonMorph >> font: anObject [
font := anObject.
self update: getLabelSelector.
]
{ #category : #accessing }
PluggableButtonMorph >> getColorSelector [
^getColorSelector
]
{ #category : #accessing }
PluggableButtonMorph >> getColorSelector: aSymbol [
getColorSelector := aSymbol.
self update: getColorSelector.
]
{ #category : #accessing }
PluggableButtonMorph >> getEnabledSelector [
^getEnabledSelector
]
{ #category : #accessing }
PluggableButtonMorph >> getEnabledSelector: aSymbol [
getEnabledSelector := aSymbol.
self update: aSymbol.
]
{ #category : #accessing }
PluggableButtonMorph >> getFontSelector [
^ getFontSelector
]
{ #category : #accessing }
PluggableButtonMorph >> getFontSelector: anObject [
getFontSelector := anObject.
self update: getFontSelector.
]
{ #category : #private }
PluggableButtonMorph >> getMenu: shiftPressed [
"Answer the menu for this button, supplying an empty menu to be filled in. If the menu selector takes an extra argument, pass in the current state of the shift key."
| menu |
getMenuSelector isNil ifTrue: [^nil].
menu := UIManager default newMenuIn: self for: model.
getMenuSelector numArgs = 1
ifTrue: [^model perform: getMenuSelector with: menu].
getMenuSelector numArgs = 2
ifTrue:
[^model
perform: getMenuSelector
with: menu
with: shiftPressed].
^self error: 'The getMenuSelector must be a 1- or 2-keyword symbol'
]
{ #category : #accessing }
PluggableButtonMorph >> getMenuSelector: aSymbol [
"Set the menu selector."
getMenuSelector := aSymbol
]
{ #category : #accessing }
PluggableButtonMorph >> getModelState [
"Answer the result of sending the receiver's model the getStateSelector message.
If the selector expects arguments then supply as for the actionSelector."
model ifNil: [^ false].
^getStateSelector ifNil: [false]
ifNotNil: [getStateSelector numArgs = 0
ifTrue: [model perform: getStateSelector]
ifFalse: [argumentsProvider ifNotNil: [
arguments := argumentsProvider perform: argumentsSelector].
model perform: getStateSelector withEnoughArguments: arguments]]
]
{ #category : #'event handling' }
PluggableButtonMorph >> handlesKeyboard: evt [
"Answer true, we'll handle spacebar for pressing plus the usual
tab navigation."
^true
]
{ #category : #'event handling' }
PluggableButtonMorph >> handlesMouseDown: evt [
^ true
]
{ #category : #'event handling' }
PluggableButtonMorph >> handlesMouseOver: evt [
^ true
]
{ #category : #'event handling' }
PluggableButtonMorph >> handlesMouseOverDragging: evt [
^ true
]
{ #category : #balloon }
PluggableButtonMorph >> helpText [
^ self balloonText
]
{ #category : #balloon }
PluggableButtonMorph >> helpText: aString [
self setBalloonText: aString
]
{ #category : #accessing }
PluggableButtonMorph >> icon [
^ icon
]
{ #category : #accessing }
PluggableButtonMorph >> icon: anIcon [
icon := anIcon
]
{ #category : #accessing }
PluggableButtonMorph >> iconPosition [
"Position of the icon.
#left - Icon will be left to the label
#right - Icon will be right to the label
#top - Icon will be top to the label"
^ iconPosition ifNil: [ iconPosition := #left ]
]
{ #category : #drawing }
PluggableButtonMorph >> indicateModalChild [
"Flash the button border."
|fs c w d|
fs := self fillStyle.
c := self color alphaMixed: 0.5 with: Color black.
w := self world.
d := 0.
self assureExtension.
2 timesRepeat: [
(Delay forDuration: d milliSeconds) wait.
d := 200.
extension fillStyle: c.
self privateColor: c.
self invalidRect: self bounds.
w ifNotNil: [w displayWorldSafely].
(Delay forDuration: d milliSeconds) wait.
self fillStyle: fs.
w ifNotNil: [w displayWorldSafely].
self invalidRect: self bounds]
]
{ #category : #initialization }
PluggableButtonMorph >> initialize [
"Initialize the state of the receiver."
super initialize.
self
rubberBandCells: false;
listDirection: #topToBottom;
hResizing: #shrinkWrap;
vResizing: #shrinkWrap;
wrapCentering: #center;
cellPositioning: #center.
enabled := true.
self initializeLabelMorph. "this is a safe guard for enabled: among others."
askBeforeChanging := false.
triggerOnMouseDown := false.
showSelectionFeedback := false.
arguments := #().
self
layoutInset: (self theme buttonLabelInsetFor: self);
extent: 20 @ 15;
lastState: false;
cornerStyle: (self theme buttonCornerStyleIn: nil);
borderStyle: (self theme buttonNormalBorderStyleFor: self).
self clipSubmorphs: true
]
{ #category : #initialization }
PluggableButtonMorph >> initializeLabelMorph [
labelMorph := LabelMorph new
extent: 0 @ 0;
yourself "this is a safe guard for enabled: among others."
]
{ #category : #keymapping }
PluggableButtonMorph >> initializeShortcuts: aKMDispatcher [
super initializeShortcuts: aKMDispatcher.
aKMDispatcher attachCategory: #MorphFocusNavigation.
aKMDispatcher attachCategory: #PluggableButtonMorph
]
{ #category : #accessing }
PluggableButtonMorph >> interactionState [
"Return the state that the receiver is in, #pressed, #normal etc.."
|state mo|
state := self getModelState.
mo := (self valueOfProperty: #mouseEntered) == true.
^(self enabled ifNil: [true])
ifTrue: [showSelectionFeedback
ifTrue: [state
ifTrue: [#selectedPressed]
ifFalse: [#pressed]]
ifFalse: [mo
ifTrue: [state
ifTrue: [#selectedMouseOver]
ifFalse: [#mouseOver]]
ifFalse: [state
ifTrue: [#selected]
ifFalse: [#normal]]]]
ifFalse: [state
ifTrue: [#selectedDisabled]
ifFalse: [#disabled]]
]
{ #category : #accessing }
PluggableButtonMorph >> interactionStates [
"Return all the states that the receiver may be in at any given moment."
^#(normal mouseOver pressed disabled
selected selectedPressed selectedMouseOver selectedDisabled)
]
{ #category : #private }
PluggableButtonMorph >> invokeMenu: evt [
"Invoke my menu in response to the given event."
| menu |
menu := self getMenu: evt shiftPressed.
menu ifNotNil: [menu popUpEvent: evt in: self world]
]
{ #category : #accessing }
PluggableButtonMorph >> isDefault [
"Answer whether the button is considered to be a default one."
^self valueOfProperty: #isDefault ifAbsent: [false]
]
{ #category : #accessing }
PluggableButtonMorph >> isDefault: aBoolean [
"Set whether the button is to be considered default."
aBoolean
ifTrue: [self setProperty: #isDefault toValue: true]
ifFalse: [self removeProperty: #isDefault].
self changed
]
{ #category : #keyboard }
PluggableButtonMorph >> keyStroke: event [
"Process spacebar for action and tab keys for navigation."
(self navigationKey: event) ifTrue: [^self].
(event keyCharacter = Character space or: [event keyCharacter = Character cr])
ifTrue: [self performAction]
]
{ #category : #keyboard }
PluggableButtonMorph >> keyboardFocusChange: aBoolean [
"The message is sent to a morph when its keyboard focus changes.
Update for focus feedback."
super keyboardFocusChange: aBoolean.
self focusChanged
]
{ #category : #accessing }
PluggableButtonMorph >> label [
"Answer the DisplayObject used as this button's label."
^ label
]
{ #category : #accessing }
PluggableButtonMorph >> label: aStringOrTextOrMorph [
"Label this button with the given string or morph."
font ifNil: [
self label: aStringOrTextOrMorph font: self theme buttonFont]
ifNotNil: [ self label: aStringOrTextOrMorph font: font ]
]
{ #category : #accessing }
PluggableButtonMorph >> label: aStringOrTextOrMorph font: aFont [
"Label this button with the given string or morph."
| containerMorph |
self removeAllMorphs.
"nest label in a row for centering"
containerMorph := AlignmentMorph new
borderWidth: 0;
layoutInset: 0;
cellInset: 2;
color: Color transparent;
hResizing: #shrinkWrap;
vResizing: #spaceFill;
wrapCentering: #center;
listCentering: #center;
cellPositioning: #center;
yourself.
(self iconPosition == #top or: [ self iconPosition == #bottom ])
ifTrue: [ containerMorph setAsColumn ]
ifFalse: [ containerMorph setAsRow ].
label := aStringOrTextOrMorph.
self label ifNotNil: [
labelMorph := self label isMorph
ifTrue: [ self label ]
ifFalse: [ self newLabel: aFont ].
containerMorph addMorph: labelMorph ].
self icon ifNotNil: [
iconMorph := self icon asMorph.
((self iconPosition == #right) or: [ self iconPosition == #bottom ])
ifTrue: [ containerMorph addMorphBack: iconMorph ]
ifFalse: [ containerMorph addMorphFront: iconMorph ] ].
self addMorph: containerMorph.
self updateLabelEnablement
]
{ #category : #accessing }
PluggableButtonMorph >> labelMorph [
"Answer the actual label morph."
^ labelMorph
]
{ #category : #accessing }
PluggableButtonMorph >> lastState [
^ lastState
]
{ #category : #accessing }
PluggableButtonMorph >> lastState: anObject [
lastState := anObject
]
{ #category : #accessing }
PluggableButtonMorph >> minHeight [
"Consult the theme also."
^super minHeight max: self theme buttonMinHeight
]
{ #category : #accessing }
PluggableButtonMorph >> minWidth [
"Consult the theme also."
^super minWidth max: self theme buttonMinWidth
]
{ #category : #accessing }
PluggableButtonMorph >> model [
"Answer the receiver's model."
^model
]
{ #category : #accessing }
PluggableButtonMorph >> model: anObject [
"Set my model and make me me a dependent of the given object."
model ifNotNil: [model removeDependent: self].
anObject ifNotNil: [anObject addDependent: self].
model := anObject.
]
{ #category : #'event handling' }
PluggableButtonMorph >> mouseDown: evt [
"Details: If this button is triggered on mouse down or the event is the menu gesture, handle it immediately. Otherwise, make a list of buttons (including the receiver) for mouseMove feedback. This allows a simple radio-button effect among the button submorphs of a given morph."
self enabled ifFalse: [^self].
allButtons := nil.
evt yellowButtonPressed ifTrue: [^ self invokeMenu: evt].
self wantsKeyboardFocusOnMouseDown
ifTrue: [self takeKeyboardFocus].
triggerOnMouseDown
ifTrue: [ self performAction: evt ]
ifFalse: [
allButtons := owner submorphs select: [:m | m class = self class].
self updateFeedbackForEvt: evt].
]
{ #category : #'event handling' }
PluggableButtonMorph >> mouseEnter: evt [
"Update the appearance."
self setProperty: #mouseEntered toValue: true.
self changed.
"0.09375 is exact in floating point so no cumulative rounding error will occur"
self color: (self color adjustBrightness: -0.09375).
super mouseEnter: evt
]
{ #category : #'event handling' }
PluggableButtonMorph >> mouseLeave: evt [
"Update the appearance."
self setProperty: #mouseEntered toValue: false.
self changed.
"0.09375 is exact in floating point so no cumulative rounding error will occur"
self color: (self color adjustBrightness: 0.09375).
super mouseLeave: evt
]
{ #category : #'event handling' }
PluggableButtonMorph >> mouseLeaveDragging: evt [
self mouseLeave: evt
]
{ #category : #'event handling' }
PluggableButtonMorph >> mouseMove: evt [
allButtons ifNil: [^ self].
allButtons do: [:m | m updateFeedbackForEvt: evt].
]
{ #category : #style }
PluggableButtonMorph >> mouseOverBorderStyle [
"Return the mouse over borderStyle of the receiver."
^self theme buttonMouseOverBorderStyleFor: self
]
{ #category : #style }
PluggableButtonMorph >> mouseOverFillStyle [
"Return the mouse over fillStyle of the receiver."
^self theme buttonMouseOverFillStyleFor: self
]
{ #category : #'event handling' }
PluggableButtonMorph >> mouseUp: evt [
"Perform the button action if the mouse pointer is in a button in the group.
Optimised feedback updates."
|all|
all := allButtons copy.
all ifNotNil: [all do: [:m |
m showSelectionFeedback ifTrue: [
m showSelectionFeedback: false; changed; layoutChanged]]].
all ifNil: [^ self].
allButtons := nil.
all do: [:m |
(m containsPoint: evt cursorPoint) ifTrue: [m enabled ifTrue: [ m performAction: evt ]]].
self showSelectionFeedback ifTrue: [self changed]
]
{ #category : #accessing }
PluggableButtonMorph >> newLabel [
"Answer a new label for the receiver."
|lbl|
lbl := self theme buttonLabelFor: self.
font ifNotNil: [lbl font: font.
lbl extent: lbl optimalExtent ].
^lbl
]
{ #category : #accessing }
PluggableButtonMorph >> newLabel: aFont [
"Answer a new label for the receiver with the given font."
^self newLabel
font: aFont
]