add ReStatementsAfterReturnConditionalRule

this PR is a proposition for a new rule for "Method returning in conditional but still having statements". #6326

src/General-Rules-Tests/ReStatementsAfterReturnConditionalRuleTest.class.st

@@ -0,0 +1,33 @@
+Class {
+	#name : 'ReStatementsAfterReturnConditionalRuleTest',
+	#superclass : 'ReAbstractRuleTestCase',
+	#category : 'General-Rules-Tests-Migrated',
+	#package : 'General-Rules-Tests',
+	#tag : 'Migrated'
+}
+
+{ #category : 'tests' }
+ReStatementsAfterReturnConditionalRuleTest >> testRule [
+
+	| critiques |
+	self class
+		compile: 'method 1 = 1 ifTrue: [ ^ 1 ] ifFalse: [ ^ 2 ]. 2'
+		classified: 'test-helper'.
+	[
+	critiques := self myCritiquesOnMethod: self class >> #method.
+	self assert: critiques size equals: 1 ] ensure: [
+		(self class >> #method) removeFromSystem ]
+]
+
+{ #category : 'tests' }
+ReStatementsAfterReturnConditionalRuleTest >> testRuleNotViolated [
+
+	| critiques |
+	self class
+		compile: 'method 1 = 1 ifTrue: [ ^ 1 ] ifFalse: [ ^ 2 ].'
+		classified: 'test-helper'.
+	[
+	critiques := self myCritiquesOnMethod: self class >> #method.
+	self assertEmpty: critiques ] ensure: [
+		(self class >> #method) removeFromSystem ]
+]

src/General-Rules/ReStatementsAfterReturnConditionalRule.class.st

@@ -0,0 +1,45 @@
+"
+This smell arise when statements are written after a condition that return within 2 branch.
+
+For exemple : 
+
+method 
+	1 = 1 
+	fTrue: [ ^ 1 ] ifFalse: [ ^ 2 ]. 
+	2
+"
+Class {
+	#name : 'ReStatementsAfterReturnConditionalRule',
+	#superclass : 'ReNodeBasedRule',
+	#category : 'General-Rules-Migrated',
+	#package : 'General-Rules',
+	#tag : 'Migrated'
+}
+
+{ #category : 'running' }
+ReStatementsAfterReturnConditionalRule >> basicCheck: aNode [
+
+	aNode isMessage ifFalse: [ ^ false ].
+	(self selectorList includes: aNode selector) ifFalse: [ ^ false ].
+	aNode arguments do: [ :arg |
+		(arg isBlock and: [ arg statements last isReturn ]) ifFalse: [ ^ false ] ].
+	^ aNode ~= aNode methodNode statements last
+]
+
+{ #category : 'accessing' }
+ReStatementsAfterReturnConditionalRule >> group [
+
+	^ 'Potential Bugs'
+]
+
+{ #category : 'accessing' }
+ReStatementsAfterReturnConditionalRule >> name [
+
+	^ 'statements written after conditional return'
+]
+
+{ #category : 'utilities' }
+ReStatementsAfterReturnConditionalRule >> selectorList [
+
+	^ #(#ifTrue:ifFalse: #ifFalse:ifTrue: #ifNil:ifNotNil: #ifNotNil:ifNil: #ifEmpty:ifNotEmpty: #ifNotEmpty:ifEmpty: #ifExists:ifAbsent:)
+]