-
Notifications
You must be signed in to change notification settings - Fork 42
/
Asset.pm
3060 lines (2309 loc) · 89.7 KB
/
Asset.pm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
package WebGUI::Asset;
=head1 LEGAL
-------------------------------------------------------------------
WebGUI is Copyright 2001-2009 Plain Black Corporation.
-------------------------------------------------------------------
Please read the legal notices (docs/legal.txt) and the license
(docs/license.txt) that came with this distribution before using
this software.
-------------------------------------------------------------------
http://www.plainblack.com info@plainblack.com
-------------------------------------------------------------------
=cut
use Scalar::Util qw( blessed weaken );
use Clone qw(clone);
use JSON;
use HTML::Packer;
use Moose;
use WebGUI::Types;
use Data::Dumper;
use WebGUI::FormBuilder;
use WebGUI::Definition::Asset;
define assetName => ['asset', 'Asset'];
define tableName => 'assetData';
define icon => 'assets.gif';
property title => (
tab => "properties",
label => ['99','Asset'],
hoverHelp => ['99 description','Asset'],
fieldType => 'text',
builder => '_default_title',
lazy => 1,
);
sub _default_title {
return 'Untitled';
}
around title => sub {
my $orig = shift;
my $self = shift;
if (@_ > 0) {
my $title = shift;
$title = WebGUI::HTML::filter($title, 'all');
$title = $self->_default_title if $title eq '';
unshift @_, $title;
}
$self->$orig(@_);
};
property menuTitle => (
tab => "properties",
label => ['411','Asset'],
hoverHelp => ['411 description','Asset'],
uiLevel => 1,
fieldType => 'text',
builder => '_default_menuTitle',
lazy => 1,
);
sub _default_menuTitle {
my $self = shift;
return $self->title;
}
around menuTitle => sub {
my $orig = shift;
my $self = shift;
if (@_ > 0) {
my $title = shift;
$title = WebGUI::HTML::filter($title, 'all');
$title = $self->_default_menuTitle if $title eq '';
unshift @_, $title;
}
$self->$orig(@_);
};
property url => (
tab => "properties",
label => ['104','Asset'],
hoverHelp => ['104 description','Asset'],
uiLevel => 3,
fieldType => 'text',
lazy => 1,
builder => '_default_url',
);
sub _default_url {
return $_[0]->fixUrl;
}
around url => sub {
my $orig = shift;
my $self = shift;
if (@_ > 0) {
my $url = $_[0];
$url = $self->fixUrl($url);
unshift @_, $url;
}
$self->$orig(@_);
};
property isHidden => (
tab => "display",
label => ['886','Asset'],
hoverHelp => ['886 description','Asset'],
uiLevel => 6,
fieldType => 'yesNo',
default => 0,
);
property newWindow => (
tab => "display",
label => ['940','Asset'],
hoverHelp => ['940 description','Asset'],
uiLevel => 9,
fieldType => 'yesNo',
default => 0,
);
property encryptPage => (
fieldType => 'yesNo',
noFormPost => sub { return $_[0]->session->config->get("sslEnabled"); },
tab => "security",
label => ['encrypt page','Asset'],
hoverHelp => ['encrypt page description','Asset'],
uiLevel => 6,
default => 0,
);
property ownerUserId => (
tab => "security",
label => ['108','Asset'],
hoverHelp => ['108 description','Asset'],
uiLevel => 6,
fieldType => 'user',
default => '3',
trigger => sub { shift->_set_ownerUserId(@_) } ,
);
sub _set_ownerUserId {
return;
}
property groupIdView => (
tab => "security",
label => ['872','Asset'],
hoverHelp => ['872 description','Asset'],
uiLevel => 6,
fieldType => 'group',
default => '7',
trigger => sub { shift->_set_groupIdView(@_) },
);
sub _set_groupIdView {
return;
}
property groupIdEdit => (
tab => "security",
label => ['871','Asset'],
excludeGroups => [1,7],
hoverHelp => ['871 description','Asset'],
uiLevel => 6,
fieldType => 'group',
default => '4',
trigger => sub { shift->_set_groupIdEdit(@_) } ,
);
sub _set_groupIdEdit {
return;
}
property synopsis => (
tab => "meta",
label => ['412','Asset'],
hoverHelp => ['412 description','Asset'],
uiLevel => 3,
fieldType => 'textarea',
default => undef,
);
property extraHeadTags => (
tab => "meta",
label => ["extra head tags",'Asset'],
hoverHelp => ['extra head tags description','Asset'],
uiLevel => 5,
fieldType => 'codearea',
default => undef,
customDrawMethod=> 'drawExtraHeadTags',
);
around extraHeadTags => sub {
my $orig = shift;
my $self = shift;
if (@_ > 0) {
my $unpacked = $_[0];
my $packed = $unpacked; ##Undo magic aliasing since a reference is passed below
return if !defined $packed;
HTML::Packer::minify( \$packed, {
remove_newlines => 1,
do_javascript => "shrink",
do_stylesheet => "minify",
} );
$self->extraHeadTagsPacked($packed);
}
$self->$orig(@_);
};
property extraHeadTagsPacked => (
fieldType => 'hidden',
default => undef,
noFormPost => 1,
init_args => undef,
);
property usePackedHeadTags => (
tab => "meta",
label => ['usePackedHeadTags label','Asset'],
hoverHelp => ['usePackedHeadTags description','Asset'],
uiLevel => 7,
fieldType => 'yesNo',
default => 0,
);
property isPackage => (
label => ["make package",'Asset'],
tab => "meta",
hoverHelp => ['make package description','Asset'],
uiLevel => 7,
fieldType => 'yesNo',
default => 0,
);
property isPrototype => (
tab => "meta",
label => ["make prototype",'Asset'],
hoverHelp => ['make prototype description','Asset'],
uiLevel => 9,
fieldType => 'yesNo',
default => 0,
);
property isExportable => (
tab => 'meta',
label => ['make asset exportable','Asset'],
hoverHelp => ['make asset exportable description','Asset'],
uiLevel => 9,
fieldType => 'yesNo',
default => 1,
);
property inheritUrlFromParent => (
tab => 'meta',
label => ['does asset inherit URL from parent','Asset'],
hoverHelp => ['does asset inherit URL from parent description','Asset'],
uiLevel => 9,
fieldType => 'yesNo',
default => 0,
trigger => \&_set_inheritUrlFromParent,
);
sub _set_inheritUrlFromParent {
my ($self, $new, $old) = @_;
if ($new && ($new != $old)) {
$self->url($self->url);
}
};
property status => (
noFormPost => 1,
fieldType => 'text',
default => 'approved',
);
property lastModified => (
noFormPost => 1,
fieldType => 'DateTime',
default => sub { return time() },
);
property assetSize => (
noFormPost => 1,
fieldType => 'integer',
default => 0,
);
property tagId => (
noFormPost => 1,
fieldType => 'guid',
default => 0,
);
property skipNotification => (
autoGenerate => 0,
noFormPost => 1,
fieldType => 'yesNo',
default => 0,
);
has session => (
is => 'ro',
required => 1,
);
has assetId => (
is => 'ro',
lazy => 1,
default => sub { shift->session->id->generate() },
);
has revisionDate => (
is => 'rw',
);
has uiLevel => (
is => 'ro',
default => 1,
init_arg => undef,
);
property revisedBy => (
is => 'rw',
noFormPost => 1,
fieldType => 'guid',
);
has [qw/parentId lineage
creationDate createdBy
state stateChanged stateChangedBy
isLockedBy isSystem lastExportedAs/] => (
is => 'rw',
);
has className => (
is => 'ro',
builder => '_build_className',
lazy => 1,
init_arg => undef,
);
sub _build_className {
my $self = shift;
return ref $self;
}
has keywords => (
is => 'rw',
builder => '_build_assetKeywords',
lazy => 1,
traits => [ 'WebGUI::Definition::Meta::Settable' ],
);
sub _build_assetKeywords {
my $self = shift;
my $session = $self->session;
my $keywords = WebGUI::Keyword->new($session);
return $keywords->getKeywordsForAsset({asset => $self, });
}
around BUILDARGS => sub {
my $orig = shift;
my $className = shift;
##Original arguments start here.
if (ref $_[0] eq 'HASH') {
return $className->$orig(@_);
}
my $session = shift;
my $assetId = shift;
my $revisionDate = shift;
unless ($assetId) {
WebGUI::Error::InvalidParam->throw(error => "Asset constructor new() requires an assetId.");
}
if ( $revisionDate eq '' ) {
$revisionDate = $className->getCurrentRevisionDate( $session, $assetId );
if ($revisionDate eq '') {
WebGUI::Error::InvalidParam->throw(error => "Cannot find revision date for assetId", param => $assetId);
}
}
elsif ( $revisionDate =~ /[^0-9]/) {
WebGUI::Error::InvalidParam->throw(error => "Invalid revision date given", param => $revisionDate);
}
my $properties = $session->cache->get("asset".$assetId.$revisionDate);
unless (exists $properties->{assetId}) { # can we get it from cache?
my $sql = "select * from asset";
my $where = " where asset.assetId=?";
my $placeHolders = [$assetId];
# join all the tables
foreach my $table ($className->meta->get_tables) {
$sql .= ",".$table;
$where .= " and (asset.assetId=".$table.".assetId and ".$table.".revisionDate=?)";
push @$placeHolders, $revisionDate;
}
# fetch properties
$properties = $session->db->quickHashRef($sql.$where, $placeHolders);
unless (exists $properties->{assetId}) {
$session->log->error("Asset $assetId $className $revisionDate is missing properties. Consult your database tables for corruption. ");
return undef;
}
$session->cache->set("asset".$assetId.$revisionDate, $properties, 60*60*24);
}
if (defined $properties) {
$properties->{session} = $session;
return $className->$orig($properties);
}
$session->log->error("Something went wrong trying to instanciate a '$className' with assetId '$assetId', but I don't know what!");
return undef;
};
use WebGUI::AssetBranch;
use WebGUI::AssetClipboard;
use WebGUI::AssetExportHtml;
use WebGUI::AssetLineage;
use WebGUI::AssetMetaData;
use WebGUI::AssetPackage;
use WebGUI::AssetTrash;
use WebGUI::AssetVersioning;
use WebGUI::Exception;
use strict;
use Tie::IxHash;
require WebGUI::AdminConsole;
require WebGUI::Asset::Shortcut;
use WebGUI::Form;
use WebGUI::HTML;
use WebGUI::FormBuilder;
use WebGUI::Keyword;
require WebGUI::ProgressBar;
use WebGUI::ProgressTree;
use Monkey::Patch;
use WebGUI::Fork;
use WebGUI::Search::Index;
use WebGUI::TabForm;
use WebGUI::PassiveAnalytics::Logging;
use WebGUI::Form::ButtonGroup;
use WebGUI::PassiveProfiling;
=head1 NAME
Package WebGUI::Asset
=head1 DESCRIPTION
Package to manipulate items in WebGUI's asset system.
=head1 SYNOPSIS
An asset is the basic class of content in WebGUI. This handles security, urls, and other basic information common to all content items.
The following modules are mixed in via declaration of the same package: AssetBranch.pm, AssetClipboard.pm, AssetExportHtml.pm, AssetLineage.pm, AssetMetaData.pm, AssetPackage.pm, AssetTrash.pm, AssetVersioning.pm.
A lineage is a concatenated series of sequence numbers, each six digits long, that explain an asset's position in its familiy tree. Lineage describes who the asset's ancestors are, how many ancestors the asset has in its family tree (lineage length), and the asset's position (rank) amongst its siblings. In addition, lineage provides enough information about an asset to generate a list of its siblings and descendants.
use WebGUI::Asset;
=head1 METHODS
These methods are available from this class:
=cut
#-------------------------------------------------------------------
=head2 addEditLabel ( )
Generate an internationalized label for the add/edit screens that says
whether you're adding or editing an Asset, for clarity.
=cut
sub addEditLabel {
my $self = shift;
my $i18n = WebGUI::International->new($self->session,'Asset_Wobject');
my $addEdit = ($self->session->form->process("func") eq 'add') ? $i18n->get('add') : $i18n->get('edit');
return $addEdit.' '.$self->getName;
}
#----------------------------------------------------------------------------
=head2 addEditSaveButtons ( form )
Add the save buttons to the given form. Used by www_add and www_edit to modify
the asset edit form.
=cut
sub addEditSaveButtons {
my ( $self, $form ) = @_;
my $session = $self->session;
my $i18n = WebGUI::International->new($session, "Asset");
###
# Buttons
my $buttonGroup = WebGUI::Form::ButtonGroup->new( $session,
name => "saveButtons",
rowClass => 'saveButtons',
);
# # Approved status
# $buttonGroup->addButton( 'checkbox', {
# name => 'approved',
# id => 'approveCheckbox',
# value => 'approved',
# label => $i18n->get('560', 'WebGUI'),
# checked => ( $session->setting->get( 'versionTagMode' ) eq 'autoCommit' ? 1 : 0 ),
# } );
$buttonGroup->addButton( "submit", {
name => "save",
id => 'saveButton',
value => $i18n->get('save'),
} );
if ( $session->config->get("enableSaveAndCommit") ) {
$buttonGroup->addButton( 'Submit', {
name => "saveAndCommit",
id => 'saveAndCommitButton',
value => $i18n->get("save and commit"),
} );
}
$buttonGroup->addButton( 'Submit', {
name => "saveAndReturn",
id => 'saveAndReturnButton',
value => $i18n->get("apply"),
} );
$buttonGroup->addButton( 'Submit', {
name => 'cancel',
id => 'cancelButton',
value => $i18n->get('cancel','WebGUI'),
} );
return $form->addFieldAt( $buttonGroup, 0 );
}
#----------------------------------------------------------------------------
=head2 addEditSaveTabs ( form )
Add the tabs to the form for editing or saving the asset's properties.
This is broken out so that additional tabs with i18n'ed labels can be
added by subclasses or by Roles.
=cut
sub addEditSaveTabs {
my ( $self, $form ) = @_;
my $session = $self->session;
my $i18n = WebGUI::International->new($session, "Asset");
# Not using loop to maintain correct order
$form->addTab( name => "properties", label => $i18n->get("properties") );
$form->addTab( name => "display", label => $i18n->get(105) );
$form->addTab( name => "security", label => $i18n->get(107) );
$form->addTab( name => "meta", label => $i18n->get("Metadata") );
return $form;
}
#-------------------------------------------------------------------
=head2 addMissing ( url )
Displays a message to the admin that they have requested a non-existent page and give them an option to create it.
=head3 url
The missing URL.
=cut
sub addMissing {
my $self = shift;
my $assetUrl = shift;
return undef unless ($self->session->isAdminOn);
my $i18n = WebGUI::International->new($self->session, "Asset");
my $output = $i18n->get("missing page query");
$output .= '<ul>
<li><a href="'.$self->getUrl("func=add;className=WebGUI::Asset::Wobject::Layout;url=".$assetUrl).'">'.$i18n->get("add the missing page").'</a></li>
<li><a href="'.$self->getUrl.'">'.$i18n->get("493","WebGUI").'</a></li>
</ul>';
return $output;
}
#-------------------------------------------------------------------
=head2 canAdd ( session, [userId, groupId] )
Verifies that the user has the privileges necessary to add this type of asset and that the requested asset
can be added as a child of this asset. Return a boolean.
A class method.
=head3 session
The session variable.
=head3 userId
Unique hash identifier for a user. If not supplied, current user.
=head3 groupId
Only developers extending this method should use this parameter. By default WebGUI will check groups in this order, whichever is defined:
=over 4
=item *
Group id assigned in the config file for each asset.
=item *
Group assigned by the developer in the asset itself if s/he extended this method to do so.
=item *
The "turn admin on" group which is group id 12.
=back
=cut
sub canAdd {
my $className = shift;
# just in case we get called as object method
$className = $className->get('className') if blessed $className;
my $session = shift;
my $userId = shift || $session->user->userId;
my $user = WebGUI::User->new($session, $userId);
my $subclassGroupId = shift;
my $addPrivsGroup = $session->config->get("assets/".$className."/addGroup");
my $groupId = $addPrivsGroup || $subclassGroupId || '12';
my $validParent = $className->validParent($session);
return $user->isInGroup($groupId) && $validParent;
}
#-------------------------------------------------------------------
=head2 canEdit ( [userId] )
Verifies group and user permissions to be able to edit asset. Returns 1 if owner is userId, otherwise returns the result checking if the user is a member of the group that can edit.
=head3 userId
Unique hash identifier for a user. If not supplied, current user.
=cut
sub canEdit {
my $self = shift;
my $userId = shift || $self->session->user->userId;
if ($userId eq $self->get("ownerUserId")) {
return 1;
}
my $user = WebGUI::User->new($self->session, $userId);
return $user->isInGroup($self->get("groupIdEdit"));
}
#-------------------------------------------------------------------
=head2 canView ( [userId] )
Verifies group and user permissions to be able to view asset. Returns 1 if user is owner of asset. Returns 1 if within the visibility date range of the asset AND user in the View group of asset. Otherwise, returns the result of the canEdit.
Only the owner and the editors can always see the asset, regardless of time/date restrictions on the asset.
=head3 userId
Unique hash identifier for a user. If not specified, uses current userId.
=cut
sub canView {
my $self = shift;
my $userId = shift;
my $user;
if (defined $userId) {
$user = WebGUI::User->new($self->session, $userId);
}
else {
$user = $self->session->user;
$userId = $user->userId();
}
if ($userId eq $self->ownerUserId) {
return 1;
}
elsif ($user->isInGroup($self->groupIdView)) {
return 1;
}
return $self->canEdit($userId);
}
#-------------------------------------------------------------------
=head2 checkView ( )
Returns error messages if a user can't view due to publishing problems,
otherwise it sets the cookie and returns undef. This is sort of a hack
until we find something better.
If SSL in enabled in the config file, and the asset has encryptPage set, and
HTTPS is set and SSLPROXY is not set in the ENV, then this page is redirected
to SSL.
=cut
sub checkView {
my $self = shift;
return $self->session->privilege->noAccess() unless $self->canView;
my $session = $self->session;
my ($conf, $response) = $self->session->quick(qw(config response));
if ($conf->get("sslEnabled") && $self->get("encryptPage") && ! $self->session->request->secure) {
# getUrl already changes url to https if 'encryptPage'
$response->setRedirect($self->getUrl);
$response->sendHeader;
return "chunked";
}
elsif ($session->isAdminOn && $self->get("state") =~ /^trash/) { # show em trash
my $queryFrag = "func=manageTrash";
if ($self->session->form->process('revision')) {
$queryFrag .= ";revision=".$self->session->form->process('revision');
}
$response->setRedirect($self->getUrl($queryFrag));
$response->sendHeader;
return "chunked";
}
elsif ($session->isAdminOn && $self->get("state") =~ /^clipboard/) { # show em clipboard
my $queryFrag = "func=manageClipboard";
if ($self->session->form->process('revision')) {
$queryFrag .= ";revision=".$self->session->form->process('revision');
}
$response->setRedirect($self->getUrl($queryFrag));
$response->sendHeader;
return "chunked";
}
elsif ($self->get("state") ne "published") { # tell em it doesn't exist anymore
$session->response->status(410);
my $notFound = WebGUI::Asset->getNotFound($self->session);
$self->session->asset($notFound);
return $notFound->www_view;
}
$self->logView();
return undef;
}
#-------------------------------------------------------------------
=head2 cloneFromDb ( )
Fetches a new fresh clone of this object from the database. Often used after
calling commit on version tags.
Returns the new Asset object.
=cut
sub cloneFromDb {
my $self = shift;
return WebGUI::Asset->newById($self->session,
$self->getId,
$self->revisionDate
);
}
#-------------------------------------------------------------------
=head2 extraHeadTags ( value )
Returns extraHeadTags
=head3 value
If specified, stores it, but also updates extraHeadTagsPacked with the packed version.
=cut
#-------------------------------------------------------------------
=head2 dispatch ( $fragment )
Based on the URL and query parameters in the current request, call internal methods
like www_view, www_edit, etc. If no query parameter is present, then it returns the output
from the www_view method. If the requested method does not exist in the object, it returns
the output from the www_view method.
=head3 $fragment
Any leftover part of the requested URL.
=cut
sub dispatch {
my ($self, $fragment) = @_;
return undef if $fragment;
my $session = $self->session;
my $state = $self->get('state');
##Only allow interaction with assets in certain states
return if $state ne 'published' && $state ne 'archived' && !$session->isAdminOn;
# needed for tests that call straight here but otherwise redundant with same in WebGUI.pm
local $SIG{__DIE__} = sub { WebGUI::Error::RunTime->throw( message => $_[0] ); };
for my $func ( $session->form->param('func'), 'view' ) {
# if there's no output from the user specified func, try view next
my $viewing = $func eq 'view' ? 1 : 0;
my $sub = $self->can('www_'.$func);
if (!$sub && $func ne 'view') {
$sub = $self->can('www_view');
$viewing = 1;
}
return undef unless $sub;
my $output = eval { $self->$sub(); };
if ( $@ ) {
my $e = Exception::Class->caught();
# previously, this only handled WebGUI::Error::ObjectNotFound::Template
my $errstr = sprintf(
"Couldn't call method ``%s'' on asset for url ``%s'': Error: ``%s''",
"www_$func", $session->url->getRequestedUrl, $e->error,
);
$errstr .= " templateId: " . $e->templateId if $e->can('templateId') and $e->templateId;
$errstr .= " assetId: " . $e->assetId if $e->can('assetId') and $e->assetId;
$session->log->error($errstr);
$e->rethrow if $session->request->env->{'webgui.debug'};
}
return $output if $output || $viewing;
}
return ''; # not reached
}
#-------------------------------------------------------------------
=head2 drawExtraHeadTags ( )
Draw the Extra Head Tags. Done with a customDrawMethod because the Template
will override this.
=cut
sub drawExtraHeadTags {
my ($self, $params) = @_;
return WebGUI::Form::codearea($self->session, {
name => $params->{name},
value => $self->get($params->{name}),
defaultValue => undef,
});
}
#-------------------------------------------------------------------
=head2 fixUrl ( [value] )
Returns a URL, removing invalid characters and making it unique by
adding a digit to the end if necessary. URLs are not allowed to be
children of the extrasURL, the uploadsURL, or any defined passthruURL.
If not URL is passed, a URL will be constructed from the Asset's
parent and the menuTitle.
Assets have a maximum length of 250 characters. Any URL longer than
250 characters will be truncated to the initial 220 characters.
URLs will be passed through $session->url->urlize to make them WebGUI compliant.
That includes any languages specific constraints set up in the default language pack.
=head3 value
Any text string. Most likely will have been the Asset's name or title. If the string is not passed
in, then a url will be constructed from
=cut
sub fixUrl {
my $self = shift;
my $url = shift;
# build a URL from the parent
unless ($url) {
if (my $parent = $self->getParent) {
$url = $parent->url;
}
$url =~ s/(.*)\..*/$1/;
$url .= '/'.$self->menuTitle;
}
# if we're inheriting the URL from our parent, set that appropriately
if ($self->inheritUrlFromParent) {
# if we're inheriting the URL from our parent, set that appropriately
my @parts = split(m{/}, $url);
# don't do anything unless we need to
my $inheritUrl = $self->getParent->get('url') . '/' . $parts[-1];
$url = $inheritUrl if $url ne $inheritUrl;
}
$url = $self->session->url->urlize($url);
# fix urls used by uploads and extras
# and those beginning with http
my @badUrls = (
$self->session->url->make_urlmap_work($self->session->config->get("extrasURL")),
$self->session->url->make_urlmap_work($self->session->config->get("uploadsURL")),
);
foreach my $badUrl (@badUrls) {
$badUrl =~ s{ / $ }{}x; # Remove trailing slashes from the end of the URL
if ($badUrl =~ /^http/) {
$badUrl =~ s{ ^ http .* / } {}x; #Remove everything but the final path fragment from the badUrl
}
else {
$badUrl =~ s{ ^ / }{}x; #Remove leading slashes from bare URLs
}
if ($url =~ /^$badUrl/) {
$url = "_".$url;
}
}
# urls can't be longer than 250 characters
if (length($url) > 250) {
$url = substr($url,0,220);
}
# remove multiple extensions from the url if there are some
$url =~ s{
(\.\w+)* # Strip off any number of extensions
(?=/) # Followed by a slash
}{}xg; # And delete all of them in the string
# add automatic extension if we're supposed to
if ($self->session->setting->get("urlExtension") ne "" #don't add an extension if one isn't set
&& !($url =~ /\./) # don't add an extension of the url already contains a dot
&& $url ne lc($self->getId) # but don't assign it the original time
) {
$url .= ".".$self->session->setting->get("urlExtension");
}
# make sure the url isn't empty after all that filtering
if ($url eq "") {
$url = $self->getId;
}
# check to see if the url already exists or not, and increment it if it does
if ($self->urlExists($self->session, $url, {assetId=>$self->getId})) {
my @parts = split(/\./,$url);
if ($parts[0] =~ /(.*?)(\d+$)/) {
$parts[0] = $1.($2+1);
}
else {
$parts[0] .= "2";
}
$url = join(".",@parts);
@_ = ($self, $url);
goto $self->can('fixUrl');
}
return $url;
}
#-------------------------------------------------------------------
=head2 forkWithStatusPage ($args)
Kicks off a WebGUI::Fork running $method with $args (from the args hashref)
and redirects to a ProgressTree status page to show the progress. The
following arguments are required in $args:
=head3 method
The name of the WebGUI::Asset method to call
=head3 args
The arguments to pass that method (see WebGUI::Fork)
=head3 plugin
The WebGUI::Operation::Fork plugin to render (e.g. ProgressTree)
=head3 title
An key in Asset's i18n hash for the title of the rendered console page
=head3 redirect
The full url to redirect to after the fork has finished.
=cut
sub forkWithStatusPage {
my ( $self, $args ) = @_;
my $session = $self->session;
my $process = WebGUI::Fork->start( $session, 'WebGUI::Asset', $args->{method}, $args->{args} );
if ( my $groupId = $args->{groupId} ) {
$process->setGroup($groupId);
}
my $method = $session->form->get('proceed') || 'manageTrash';
my $i18n = WebGUI::International->new( $session, 'Asset' );
my $pairs = $process->contentPairs(
$args->{plugin}, {
title => $i18n->get( $args->{title} ),
icon => 'assets',
dialog => $args->{dialog},
message => $args->{message},
proceed => $args->{redirect} || '',
}
);
$session->response->setRedirect( $self->getUrl($pairs) );