-
Notifications
You must be signed in to change notification settings - Fork 26
/
ersip_siphdr.erl
347 lines (321 loc) · 12 KB
/
ersip_siphdr.erl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
%%
%% Copyright (c) 2018 Dmitry Poroh
%% All rights reserved.
%% Distributed under the terms of the MIT License. See the LICENSE file.
%%
%% SIP Headers Helpers
%%
-module(ersip_siphdr).
-export([all_known_headers/0,
parse_header/2,
copy_headers/3,
copy_header/3,
set_header/3
]).
-export_type([known_header/0]).
%%%===================================================================
%%% Types
%%%===================================================================
-type known_header() :: from
| to
| callid
| cseq
| maxforwards
| topmost_via
| content_type
| allow
| route
| record_route
| supported
| unsupported
| require
| proxy_require
| contact
| expires
| minexpires
| date.
-record(descr, {name :: binary(),
required :: header_required(),
parse_fun :: parse_fun_type(),
assemble_fun :: undefined | assemble_fun_type()
}).
-type descr() :: #descr{}.
-type parse_fun_type() :: fun((ersip_hdr:header()) -> parse_fun_result()).
-type parse_fun_result() :: {ok, Value :: term()}
| {error, Reason :: term()}.
-type assemble_fun_type() :: fun((Name :: binary(), Value :: term()) -> ersip_hdr:header()).
%%%===================================================================
%%% API
%%%===================================================================
all_known_headers() ->
[from,
to,
callid,
cseq,
maxforwards,
topmost_via,
content_type,
allow,
supported,
unsupported,
require,
proxy_require,
route,
record_route,
contact,
expires,
minexpires,
date
].
-spec parse_header(known_header(), ersip_sipmsg:sipmsg()) -> ValueOrError when
ValueOrError :: {ok, term()}
| {error, term()}.
parse_header(HdrAtom, Msg) when is_atom(HdrAtom) ->
Descr = header_descr(HdrAtom),
case get_header(Descr, Msg) of
{ok, no_header} ->
{ok, no_header};
{ok, Hdr} ->
parse_header_by_descr(Descr, Hdr);
{error, _} = Error ->
Error
end.
-spec copy_header(Header, SrcSipMsg, DstSipMsg) -> NewDstSipMsg when
Header :: known_header() | binary(),
SrcSipMsg :: ersip_sipmsg:sipmsg(),
DstSipMsg :: ersip_sipmsg:sipmsg(),
NewDstSipMsg :: ersip_sipmsg:sipmsg().
copy_header(HdrAtom, SrcMsg, DstMsg0) ->
DstMsg1 =
case maps:find(HdrAtom, ersip_sipmsg:headers(SrcMsg)) of
{ok, Value} ->
DstHeaders0 = ersip_sipmsg:headers(DstMsg0),
ersip_sipmsg:set_headers(DstHeaders0#{HdrAtom => Value}, DstMsg0);
error->
DstMsg0
end,
copy_raw_header(HdrAtom, SrcMsg, DstMsg1).
-spec copy_headers(HeaderList, SrcSipMsg, DstSipMsg) -> NewDstSipMsg when
HeaderList :: [known_header() | binary()],
SrcSipMsg :: ersip_sipmsg:sipmsg(),
DstSipMsg :: ersip_sipmsg:sipmsg(),
NewDstSipMsg :: ersip_sipmsg:sipmsg().
copy_headers(HeaderList, SrcSipMsg, DstSipMsg) ->
lists:foldl(fun(Header, CurMsg) ->
copy_header(Header, SrcSipMsg, CurMsg)
end,
DstSipMsg,
HeaderList).
-spec set_header(known_header(), Value :: term(), ersip_sipmsg:sipmsg()) -> ersip_sipmsg:sipmsg().
set_header(Header, Value, SipMsg) when is_atom(Header) ->
#descr{name = Name,
assemble_fun = AssembleF
} = header_descr(Header),
PrintName = ersip_hdr_names:print_form(Name),
OldHeaders = ersip_sipmsg:headers(SipMsg),
OldRawMsg = ersip_sipmsg:raw_message(SipMsg),
RawHdr = AssembleF(PrintName, Value),
IsDeleted = ersip_hdr:is_empty(RawHdr),
NewHeaders =
case IsDeleted of
true ->
maps:remove(Header, OldHeaders);
false ->
OldHeaders#{Header => Value}
end,
NewRawMsg =
case IsDeleted of
true ->
ersip_msg:del_header(RawHdr, OldRawMsg);
false ->
ersip_msg:set_header(RawHdr, OldRawMsg)
end,
SipMsg1 = ersip_sipmsg:set_headers(NewHeaders, SipMsg),
SipMsg2 = ersip_sipmsg:set_raw_message(NewRawMsg, SipMsg1),
SipMsg2.
%%%===================================================================
%%% Internal implementation
%%%===================================================================
-type header_required() :: all %% Header required for all requests/responses
| optional %% Header is optional for all requests/responses
| with_body %% Header required if body is not empty
| requests. %% Header is required in requests
-record(required_essentials, {type :: ersip_msg:type(),
method :: ersip_method:method(),
status :: undefined | ersip_status:code(),
has_body :: boolean()
}).
-type required_essentials() :: #required_essentials{}.
-spec parse_header_by_descr(descr(), ersip_hdr:header()) -> Result when
Result :: {ok, Value :: term()}
| {error, term()}.
parse_header_by_descr(#descr{parse_fun = F}, Hdr) ->
F(Hdr).
-spec get_header(descr(), ersip_sipmsg:sipmsg()) -> Result when
Result :: {ok, ersip_hdr:header()}
| {ok, no_header}
| {error, {no_required_header, binary()}}.
get_header(#descr{name = N} = D, SipMsg) ->
Hdr = ersip_msg:get(N, ersip_sipmsg:raw_message(SipMsg)),
Required = is_required(SipMsg, D#descr.required),
case ersip_hdr:is_empty(Hdr) of
true ->
case Required of
true ->
{error, {no_required_header, N}};
false ->
{ok, no_header}
end;
false ->
{ok, Hdr}
end.
-spec is_required(ersip_sipmsg:sipmsg() | required_essentials(), header_required()) -> boolean().
is_required(_, all) ->
true;
is_required(_, optional) ->
false;
is_required(#required_essentials{type = request}, requests) ->
true;
is_required(#required_essentials{has_body = true}, with_body) ->
true;
is_required(#required_essentials{}, _) ->
false;
is_required(SipMsg, R) ->
is_required(required_essentials(SipMsg), R).
-spec required_essentials(ersip_sipmsg:sipmsg()) -> required_essentials().
required_essentials(SipMsg) ->
Type = ersip_sipmsg:type(SipMsg),
#required_essentials{
type = Type,
method = ersip_sipmsg:method(SipMsg),
status = ersip_sipmsg:status(SipMsg),
has_body = ersip_sipmsg:has_body(SipMsg)
}.
-spec copy_raw_header(HeaderName, SrcSipMsg, DstSipMsg) -> NewDstSipMsg when
HeaderName :: binary() | ersip_siphdr:known_header(),
SrcSipMsg :: ersip_sipmsg:sipmsg(),
DstSipMsg :: ersip_sipmsg:sipmsg(),
NewDstSipMsg :: ersip_sipmsg:sipmsg().
copy_raw_header(Header, SrcSipMsg, DstSipMsg) when is_binary(Header) ->
SrcRawMsg = ersip_sipmsg:raw_message(SrcSipMsg),
SrcH = ersip_msg:get(Header, SrcRawMsg),
DstRawMsg = ersip_sipmsg:raw_message(DstSipMsg),
NewDstRawMsg = ersip_msg:set_header(SrcH, DstRawMsg),
ersip_sipmsg:set_raw_message(NewDstRawMsg, DstSipMsg);
copy_raw_header(HdrAtom, SrcSipMsg, DstSipMsg) when is_atom(HdrAtom) ->
#descr{name = Name} = header_descr(HdrAtom),
copy_raw_header(Name, SrcSipMsg, DstSipMsg).
%%%
%%% Headers description
%%%
-spec header_descr(known_header()) -> #descr{}.
header_descr(from) ->
#descr{name = <<"from">>,
required = all,
parse_fun = fun ersip_hdr_fromto:parse/1,
assemble_fun = fun ersip_hdr_fromto:build/2
};
header_descr(to) ->
#descr{name = <<"to">>,
required = all,
parse_fun = fun ersip_hdr_fromto:parse/1,
assemble_fun = fun ersip_hdr_fromto:build/2
};
header_descr(cseq) ->
#descr{name = <<"cseq">>,
required = all,
parse_fun = fun ersip_hdr_cseq:parse/1,
assemble_fun = fun ersip_hdr_cseq:build/2
};
header_descr(callid) ->
#descr{name = <<"call-id">>,
required = all,
parse_fun = fun ersip_hdr_callid:parse/1,
assemble_fun = fun ersip_hdr_callid:build/2
};
header_descr(maxforwards) ->
#descr{name = <<"max-forwards">>,
required = optional, %% It was optional in RFC2543
parse_fun = fun ersip_hdr_maxforwards:parse/1,
assemble_fun = fun ersip_hdr_maxforwards:build/2
};
header_descr(topmost_via) ->
%% Note We trim Via header on connection receive so responses on
%% UA does not contain Via.
#descr{name = <<"via">>,
required = requests,
parse_fun = fun ersip_hdr_via:topmost_via/1,
assemble_fun = undefined
};
header_descr(content_type) ->
#descr{name = <<"content-type">>,
required = with_body,
parse_fun = fun ersip_hdr_content_type:parse/1,
assemble_fun = fun ersip_hdr_content_type:build/2
};
header_descr(route) ->
#descr{name = <<"route">>,
required = optional,
parse_fun = fun ersip_hdr_route:parse/1,
assemble_fun = fun ersip_hdr_route:build/2
};
header_descr(record_route) ->
#descr{name = <<"record-route">>,
required = optional,
parse_fun = fun ersip_hdr_route:parse/1,
assemble_fun = fun ersip_hdr_route:build/2
};
header_descr(allow) ->
#descr{name = <<"allow">>,
required = optional,
parse_fun = fun ersip_hdr_allow:parse/1,
assemble_fun = fun ersip_hdr_allow:build/2
};
header_descr(supported) ->
#descr{name = <<"supported">>,
required = optional,
parse_fun = fun ersip_hdr_opttag_list:parse/1,
assemble_fun = fun ersip_hdr_opttag_list:build/2
};
header_descr(unsupported) ->
#descr{name = <<"unsupported">>,
required = optional,
parse_fun = fun ersip_hdr_opttag_list:parse/1,
assemble_fun = fun ersip_hdr_opttag_list:build/2
};
header_descr(require) ->
#descr{name = <<"require">>,
required = optional,
parse_fun = fun ersip_hdr_opttag_list:parse/1,
assemble_fun = fun ersip_hdr_opttag_list:build/2
};
header_descr(proxy_require) ->
#descr{name = <<"proxy-require">>,
required = optional,
parse_fun = fun ersip_hdr_opttag_list:parse/1,
assemble_fun = fun ersip_hdr_opttag_list:build/2
};
header_descr(contact) ->
#descr{name = <<"contact">>,
required = optional,
parse_fun = fun ersip_hdr_contact_list:parse/1,
assemble_fun = fun ersip_hdr_contact_list:build/2
};
header_descr(expires) ->
#descr{name = <<"expires">>,
required = optional,
parse_fun = fun ersip_hdr_expires:parse/1,
assemble_fun = fun ersip_hdr_expires:build/2
};
header_descr(minexpires) ->
#descr{name = <<"min-expires">>,
required = optional,
parse_fun = fun ersip_hdr_expires:parse/1,
assemble_fun = fun ersip_hdr_expires:build/2
};
header_descr(date) ->
#descr{name = <<"date">>,
required = optional,
parse_fun = fun ersip_hdr_date:parse/1,
assemble_fun = fun ersip_hdr_date:build/2
}.