-
Notifications
You must be signed in to change notification settings - Fork 160
/
trace_translators.jl
967 lines (787 loc) · 32.3 KB
/
trace_translators.jl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
import ForwardDiff
import MacroTools
import LinearAlgebra
import Parameters: @with_kw, @unpack
#######################
# trace transform DSL #
#######################
# See this math writeup for an understanding of how this code works:
# docs/tex/mcmc.pdf
"""
TraceTransformDSLProgram
A program compiled from the [Trace Transform DSL](@ref).
"""
mutable struct TraceTransformDSLProgram
fn!::Function
inverse::Union{Nothing,TraceTransformDSLProgram}
end
"""
pair_bijections!(f1::TraceTransformDSLProgram, f2::TraceTransformDSLProgram)
Assert that a pair of bijections contsructed using the [Trace Transform DSL](@ref) are
inverses of one another.
"""
function pair_bijections!(f1::TraceTransformDSLProgram, f2::TraceTransformDSLProgram)
f1.inverse = f2
f2.inverse = f1
return nothing
end
"""
is_involution!(f::TraceTransformDSLProgram)
Assert that a bijection constructed with the [Trace Transform DSL](@ref) is its own inverse.
"""
function is_involution!(f::TraceTransformDSLProgram)
f.inverse = f
return nothing
end
"""
b::TraceTransformDSLProgram = inverse(a::TraceTransformDSLProgram)
Obtain the inverse of a bijection that was constructed with the [Trace Transform DSL](@ref).
The inverse must have been associated with the bijection either via
[`pair_bijections!`](@ref) or [`is_involution!`])(@ref).
"""
function inverse(bijection::TraceTransformDSLProgram)
if isnothing(bijection.inverse)
error("inverse bijection was not defined")
end
return bijection.inverse
end
struct ModelInputTraceToken{T}
args::T
end
struct AuxInputTraceToken{T}
args::T
end
struct ModelInputTraceRetValToken
end
struct AuxInputTraceRetValToken
end
struct ModelOutputTraceToken
end
struct AuxOutputTraceToken
end
struct ModelInputAddress{T}
addr::T
end
struct AuxInputAddress{T}
addr::T
end
struct ModelOutputAddress{T}
addr::T
end
struct AuxOutputAddress{T}
addr::T
end
Base.getindex(::ModelInputTraceToken, addr) = ModelInputAddress(addr) # model_in[addr]
Base.getindex(::ModelOutputTraceToken, addr) = ModelOutputAddress(addr) # model_out[addr]
Base.getindex(::AuxInputTraceToken, addr) = AuxInputAddress(addr) # aux_in[addr]
Base.getindex(::AuxOutputTraceToken, addr) = AuxOutputAddress(addr) # aux_out[addr]
Base.getindex(::ModelInputTraceToken) = ModelInputTraceRetvalToken() # model_in[]
Base.getindex(::AuxInputTraceToken) = AuxInputTraceRetValToken() # aux_in[]
get_args(token::ModelInputTraceToken) = token.args # get_args(model_in)
get_args(token::AuxInputTraceToken) = token.args # get_args(aux_in)
const bij_state = gensym("bij_state")
"""
@transform f[(params...)] (in1 [,in2]) to (out1 [,out2])
..
end
Write a program in the [Trace Transform DSL](@ref).
"""
macro transform(f_expr, src_expr, to_symbol::Symbol, dest_expr, body)
syntax_err = """valid syntactic forms:
@transform f (..) to (..) begin .. end
@transform f(..) (..) to (..) begin .. end"""
err = false
if MacroTools.@capture(f_expr, f_(args__))
elseif MacroTools.@capture(f_expr, f_)
args = []
else
err = true
end
err = err || (to_symbol != :to)
if MacroTools.@capture(src_expr, (model_in_, aux_in_))
elseif MacroTools.@capture(src_expr, (model_in_))
aux_in = gensym("dummy_aux")
else
err = true
end
if MacroTools.@capture(dest_expr, (model_out_, aux_out_))
elseif MacroTools.@capture(dest_expr, (model_out_))
aux_out = gensym("dummy_aux")
else
err = true
end
if err error(syntax_err) end
fn! = gensym(Symbol(f, "_fn!"))
return quote
# mutates the state
function $fn!(
$(esc(bij_state))::Union{FirstPassState,JacobianPassState},
$(map(esc, args)...))
model_args = get_model_args($(esc(bij_state)))
aux_args = get_aux_args($(esc(bij_state)))
$(esc(model_in)) = ModelInputTraceToken(model_args)
$(esc(model_out)) = ModelOutputTraceToken()
$(esc(aux_in)) = AuxInputTraceToken(aux_args)
$(esc(aux_out)) = AuxOutputTraceToken()
$(esc(body))
return nothing
end
Core.@__doc__ $(esc(f)) = TraceTransformDSLProgram($fn!, nothing)
end
end
macro tcall(ex)
MacroTools.@capture(ex, f_(args__)) || error("expected syntax: f(..)")
return quote $(esc(f)).fn!($(esc(bij_state)), $(map(esc, args)...)) end
end
# handlers
struct DiscreteAnn end
struct ContinuousAnn end
const DISCRETE = [:discrete, :disc]
const CONTINUOUS = [:continuous, :cont]
function typed(annotation::Symbol)
if annotation in DISCRETE
return DiscreteAnn()
elseif annotation in CONTINUOUS
return ContinuousAnn()
else
error("error")
end
end
"""
@read(<source>, <annotation>)
Macro for reading the value of a random choice from an input trace in the [Trace Transform DSL](@ref).
<source> is of the form <trace>[<addr>] where <trace> is an input trace, and <annotation>
is either :discrete or :continuous.
"""
macro read(src, ann::QuoteNode)
return quote read($(esc(bij_state)), $(esc(src)), $(esc(typed(ann.value)))) end
end
"""
@write(<destination>, <value>, <annotation>)
Macro for writing the value of a random choice to an output trace in the [Trace Transform DSL](@ref).
<destination> is of the form <trace>[<addr>] where <trace> is an input trace, and
<annotation> is either :discrete or :continuous.
"""
macro write(dest, val, ann::QuoteNode)
return quote write($(esc(bij_state)), $(esc(dest)), $(esc(val)), $(esc(typed(ann.value)))) end
end
"""
@copy(<source>, <destination>)
Macro for copying the value of a random choice (or a whole namespace of random choices)
from an input trace to an output trace in the [Trace Transform DSL](@ref).
<destination> is of the form <trace>[<addr>] where <trace> is an input trace,
and <annotation> is either :discrete or :continuous.
"""
macro copy(src, dest)
return quote copy($(esc(bij_state)), $(esc(src)), $(esc(dest))) end
end
# TODO make more consistent by allowing us to read any hierarchical address,
# including return values of intermediate calls, not just the top-level call.
# TODO add haskey(model_in, addr), and haskey(aux_in, addr)
################################
# first pass through transform #
################################
struct FirstPassResults
"subset of the output model choice map ``t'``"
constraints::ChoiceMap
"output proposal choice map ``u'``"
u_back::ChoiceMap
t_cont_reads::Dict
u_cont_reads::Dict
t_cont_writes::Dict
u_cont_writes::Dict
t_copy_reads::DynamicSelection
u_copy_reads::DynamicSelection
end
function FirstPassResults()
return FirstPassResults(
choicemap(), choicemap(),
Dict(), Dict(), Dict(), Dict(),
DynamicSelection(), DynamicSelection())
end
struct FirstPassState
"Trace containing the input model choice map ``t``"
model_trace::Trace
model_choices::ChoiceMap
"The input proposal choice map ``u``"
aux_trace::Union{Trace,Nothing}
aux_choices::ChoiceMap
results::FirstPassResults
end
FirstPassState(model_trace::Trace, aux_trace::Trace) =
FirstPassState(model_trace, get_choices(model_trace),
aux_trace, get_choices(aux_trace), FirstPassResults())
FirstPassState(model_trace::Trace, aux_trace::Nothing) =
FirstPassState(model_trace, get_choices(model_trace),
aux_trace, EmptyChoiceMap(), FirstPassResults())
function get_model_args(state::FirstPassState)
return get_args(state.model_trace)
end
function get_aux_args(state::FirstPassState)
return state.aux_trace === nothing ? () : get_args(state.aux_trace)
end
function run_first_pass(transform::TraceTransformDSLProgram, model_trace, aux_trace)
state = FirstPassState(model_trace, aux_trace)
transform.fn!(state) # TODO allow for other args to top-level transform function
return state.results
end
function read(state::FirstPassState, src::ModelInputTraceRetValToken, ::DiscreteAnn)
return get_retval(state.model_trace)
end
function read(state::FirstPassState, src::AuxInputTraceRetValToken, ::DiscreteAnn)
return get_retval(state.aux_trace)
end
function read(state::FirstPassState, src::ModelInputAddress, ::DiscreteAnn)
addr = src.addr
return state.model_trace[addr]
end
function read(state::FirstPassState, src::ModelInputAddress, ::ContinuousAnn)
addr = src.addr
state.results.t_cont_reads[addr] = state.model_choices[addr]
return state.model_trace[addr]
end
function read(state::FirstPassState, src::AuxInputAddress, ::DiscreteAnn)
addr = src.addr
return state.aux_trace[addr]
end
function read(state::FirstPassState, src::AuxInputAddress, ::ContinuousAnn)
addr = src.addr
state.results.u_cont_reads[addr] = state.aux_choices[addr]
return state.aux_trace[addr]
end
function write(state::FirstPassState, dest::ModelOutputAddress, value, ::DiscreteAnn)
addr = dest.addr
state.results.constraints[addr] = value
return value
end
function write(state::FirstPassState, dest::ModelOutputAddress, value, ::ContinuousAnn)
addr = dest.addr
has_value(state.results.constraints, addr) && error("Model address $addr already written to")
state.results.constraints[addr] = value
state.results.t_cont_writes[addr] = value
return value
end
function write(state::FirstPassState, dest::AuxOutputAddress, value, ::DiscreteAnn)
addr = dest.addr
state.results.u_back[addr] = value
return value
end
function write(state::FirstPassState, dest::AuxOutputAddress, value, ::ContinuousAnn)
addr = dest.addr
has_value(state.results.u_back, addr) && error("Proposal address $addr already written to")
state.results.u_back[addr] = value
state.results.u_cont_writes[addr] = value
return value
end
function copy(state::FirstPassState, src::ModelInputAddress, dest::ModelOutputAddress)
from_addr, to_addr = src.addr, dest.addr
model_choices = get_choices(state.model_trace)
push!(state.results.t_copy_reads, from_addr)
if has_value(model_choices, from_addr)
state.results.constraints[to_addr] = model_choices[from_addr]
else
set_submap!(state.results.constraints, to_addr, get_submap(model_choices, from_addr))
end
return nothing
end
function copy(state::FirstPassState, src::ModelInputAddress, dest::AuxOutputAddress)
from_addr, to_addr = src.addr, dest.addr
model_choices = get_choices(state.model_trace)
push!(state.results.t_copy_reads, from_addr)
if has_value(model_choices, from_addr)
state.results.u_back[to_addr] = model_choices[from_addr]
else
set_submap!(state.results.u_back, to_addr, get_submap(model_choices, from_addr))
end
return nothing
end
function copy(state::FirstPassState, src::AuxInputAddress, dest::AuxOutputAddress)
from_addr, to_addr = src.addr, dest.addr
push!(state.results.u_copy_reads, from_addr)
aux_choices = get_choices(state.aux_trace)
if has_value(aux_choices, from_addr)
state.results.u_back[to_addr] = aux_choices[from_addr]
else
set_submap!(state.results.u_back, to_addr, get_submap(aux_choices, from_addr))
end
return nothing
end
function copy(state::FirstPassState, src::AuxInputAddress, dest::ModelOutputAddress)
from_addr, to_addr = src.addr, dest.addr
push!(state.results.u_copy_reads, from_addr)
aux_choices = get_choices(state.aux_trace)
if has_value(aux_choices, from_addr)
state.results.constraints[to_addr] = aux_choices[from_addr]
else
set_submap!(state.results.constraints, to_addr, get_submap(aux_choices, from_addr))
end
return nothing
end
#####################################################################
# second pass through transform (gets automatically differentiated) #
#####################################################################
struct JacobianPassState{T<:Real}
model_trace::Trace
aux_trace::Union{Trace,Nothing}
input_arr::AbstractArray{T}
output_arr::Array{T}
t_key_to_index::Dict
u_key_to_index::Dict
cont_constraints_key_to_index::Dict
cont_u_back_key_to_index::Dict
end
function get_model_args(state::JacobianPassState)
return get_args(state.model_trace)
end
function get_aux_args(state::JacobianPassState)
return state.aux_trace === nothing ? () : get_args(state.aux_trace)
end
function read(state::JacobianPassState, src::ModelInputTraceRetValToken, ::DiscreteAnn)
return get_retval(state.model_trace)
end
function read(state::JacobianPassState, src::AuxInputTraceRetValToken, ::DiscreteAnn)
return get_retval(state.aux_trace)
end
function read(state::JacobianPassState, src::ModelInputAddress, ::DiscreteAnn)
addr = src.addr
return state.model_trace[addr]
end
function read(state::JacobianPassState, src::AuxInputAddress, ::DiscreteAnn)
addr = src.addr
return state.aux_trace[addr]
end
function _read_continuous(input_arr, addr_info::Int)
return input_arr[addr_info]
end
function _read_continuous(input_arr, addr_info::Tuple{Int,Int})
# TODO to handle things other than vectors, store shape in addr info and reshape?
(start_idx, len) = addr_info
return input_arr[start_idx:start_idx+len-1]
end
function read(state::JacobianPassState, src::ModelInputAddress, ::ContinuousAnn)
addr = src.addr
if haskey(state.t_key_to_index, addr)
return _read_continuous(state.input_arr, state.t_key_to_index[addr])
else
return state.model_trace[addr]
end
end
function read(state::JacobianPassState, src::AuxInputAddress, ::ContinuousAnn)
addr = src.addr
if haskey(state.u_key_to_index, addr)
return _read_continuous(state.input_arr, state.u_key_to_index[addr])
else
return state.aux_trace[addr]
end
end
function write(state::JacobianPassState, dest::ModelOutputAddress, value, ::DiscreteAnn)
return value
end
function write(state::JacobianPassState, dest::AuxOutputAddress, value, ::DiscreteAnn)
return value
end
function _write_continuous(output_arr, addr_info::Int, value)
return output_arr[addr_info] = value
end
function _write_continuous(output_arr, addr_info::Tuple{Int,Int}, value)
(start_idx, len) = addr_info
return output_arr[start_idx:start_idx+len-1] = value
end
function write(state::JacobianPassState, dest::AuxOutputAddress, value, ::ContinuousAnn)
addr = dest.addr
return _write_continuous(state.output_arr, state.cont_u_back_key_to_index[addr], value)
end
function write(state::JacobianPassState, dest::ModelOutputAddress, value, ::ContinuousAnn)
addr = dest.addr
return _write_continuous(state.output_arr, state.cont_constraints_key_to_index[addr], value)
end
function copy(state::JacobianPassState, src, dest)
return nothing
end
#################################
# computing jacobian correction #
#################################
discard_skip_read_addr(addr, discard::ChoiceMap) = !has_value(discard, addr)
discard_skip_read_addr(addr, discard::Nothing) = false
function store_addr_info!(dict::Dict, addr, value::Real, next_index::Int)
dict[addr] = next_index
return 1 # number of elements of array
end
function store_addr_info!(dict::Dict, addr, value::AbstractArray{<:Real}, next_index::Int)
len = length(value)
dict[addr] = (next_index, len)
return len # number of elements of array
end
function assemble_input_array_and_maps(t_cont_reads, t_copy_reads,
u_cont_reads, u_copy_reads,
discard::Union{ChoiceMap,Nothing})
input_arr = Vector{Float64}()
next_input_index = 1
t_key_to_index = Dict()
for (addr, v) in t_cont_reads
if addr in t_copy_reads
continue
end
if discard_skip_read_addr(addr, discard)
# note: only happens when the model is unchanged
continue
end
next_input_index += store_addr_info!(t_key_to_index, addr, v, next_input_index)
append!(input_arr, v)
end
u_key_to_index = Dict()
for (addr, v) in u_cont_reads
if addr in u_copy_reads
continue
end
next_input_index += store_addr_info!(u_key_to_index, addr, v, next_input_index)
append!(input_arr, v)
end
return (t_key_to_index, u_key_to_index, input_arr)
end
function assemble_output_maps(t_cont_writes, u_cont_writes)
next_output_index = 1
cont_constraints_key_to_index = Dict()
for (addr, v) in t_cont_writes
next_output_index +=
store_addr_info!(cont_constraints_key_to_index, addr, v, next_output_index)
end
cont_u_back_key_to_index = Dict()
for (addr, v) in u_cont_writes
next_output_index +=
store_addr_info!(cont_u_back_key_to_index, addr, v, next_output_index)
end
return (cont_constraints_key_to_index, cont_u_back_key_to_index, next_output_index-1)
end
function jacobian_correction(transform::TraceTransformDSLProgram,
prev_model_trace, proposal_trace, first_pass_results, discard)
# create input array and mappings input addresses that are needed for Jacobian
# exclude addresses that were copied explicitly to another address
(t_key_to_index, u_key_to_index, input_arr) = assemble_input_array_and_maps(
first_pass_results.t_cont_reads,
first_pass_results.t_copy_reads,
first_pass_results.u_cont_reads,
first_pass_results.u_copy_reads, discard)
# create mappings for output addresses that are needed for Jacobian
(cont_constraints_key_to_index, cont_u_back_key_to_index, n_output) = assemble_output_maps(
first_pass_results.t_cont_writes,
first_pass_results.u_cont_writes)
# this function is the partial application of the continuous part of the
# transform, with inputs corresponding to a particular superset of the
# columns of the reduced Jacobian matrix
function f_array(input_arr::AbstractArray{T}) where {T <: Real}
# closing over:
# - trace, u
# - u_key_to_index, t_key_to_index, cont_constraints_key_to_index, cont_u_back_key_to_index
# - proposal_args, proposal_retval
output_arr = Vector{T}(undef, n_output)
jacobian_pass_state = JacobianPassState(
prev_model_trace, proposal_trace, input_arr, output_arr,
t_key_to_index, u_key_to_index,
cont_constraints_key_to_index,
cont_u_back_key_to_index)
# mutates the state
transform.fn!(jacobian_pass_state)
# return the output array
output_arr
end
# compute Jacobian matrix of f_array, where columns are inputs, rows are outputs
J = ForwardDiff.jacobian(f_array, input_arr)
@assert size(J)[2] == length(input_arr)
num_outputs = size(J)[1]
if size(J) != (num_outputs, num_outputs)
error("Jacobian was not square (size was $(size(J)); the function may not be an bijection")
end
# log absolute value of Jacobian determinant
correction = LinearAlgebra.logabsdet(J)[1]
if isinf(correction)
@error "Weight correction is infinite; the function may not be an bijection"
end
return correction
end
function check_round_trip(trace, trace_rt)
choices = get_choices(trace)
choices_rt = get_choices(trace_rt)
if !isapprox(choices, choices_rt)
@error("choices: $(sprint(show, "text/plain", choices))")
@error("choices after round trip: $(sprint(show, "text/plain", choices_rt))")
error("transform round trip check failed")
end
return nothing
end
function check_round_trip(
prev_model_trace, prev_model_trace_rt,
forward_proposal_trace, forward_proposal_trace_rt)
check_round_trip(prev_model_trace, prev_model_trace_rt)
check_round_trip(forward_proposal_trace, forward_proposal_trace_rt)
return nothing
end
################################
# TraceTranslator #
################################
"Abstract type for trace translators."
abstract type TraceTranslator end
"""
(new_trace, log_weight) = (translator::TraceTranslator)(trace)
Apply a trace translator on an input trace, returning a new trace and an incremental
log weight.
"""
(translator::TraceTranslator)(trace::Trace; kwargs...) = error("Not implemented.")
################################
# DeterministicTraceTranslator #
################################
"""
translator = DeterministicTraceTranslator(;
p_new::GenerativeFunction, p_args::Tuple=();
new_observations::ChoiceMap=EmptyChoiceMap()
f::TraceTransformDSLProgram)
Constructor for a deterministic trace translator.
Run the translator with:
(output_trace, log_weight) = translator(input_trace)
"""
@with_kw mutable struct DeterministicTraceTranslator <: TraceTranslator
p_new::GenerativeFunction
p_args::Tuple = ()
new_observations::ChoiceMap = EmptyChoiceMap()
f::TraceTransformDSLProgram # a bijection
end
function inverse(translator::DeterministicTraceTranslator,
prev_model_trace::Trace, prev_observations::ChoiceMap=EmptyChoiceMap())
return DeterministicTraceTranslator(
get_gen_fn(prev_model_trace), get_args(prev_model_trace),
prev_observations, inverse(translator.f))
end
function run_transform(translator::DeterministicTraceTranslator,
prev_model_trace::Trace)
@unpack p_new, p_args, new_observations, f = translator
first_pass_results = run_first_pass(f, prev_model_trace, nothing)
log_abs_determinant = jacobian_correction(
f, prev_model_trace, nothing, first_pass_results, nothing)
constraints = merge(first_pass_results.constraints, new_observations)
(new_model_trace, _) = generate(p_new, p_args, constraints)
return (new_model_trace, log_abs_determinant)
end
function (translator::DeterministicTraceTranslator)(
prev_model_trace::Trace; check=false, prev_observations=EmptyChoiceMap())
# apply trace transform
(new_model_trace, log_abs_determinant) =
run_transform(translator, prev_model_trace)
# compute log weight
prev_model_score = get_score(prev_model_trace)
new_model_score = get_score(new_model_trace)
log_weight = new_model_score - prev_model_score + log_abs_determinant
if check
check_observations(get_choices(new_model_trace),
translator.new_observations)
inverter = inverse(translator, prev_model_trace)
prev_model_trace_rt, _ = run_transform(inverter, new_model_trace)
check_round_trip(prev_model_trace, prev_model_trace_rt)
end
return (new_model_trace, log_weight)
end
##########################
# GeneralTraceTranslator #
##########################
"""
translator = GeneralTraceTranslator(;
p_new::GenerativeFunction,
p_new_args::Tuple = (),
new_observations::ChoiceMap = EmptyChoiceMap(),
q_forward::GenerativeFunction,
q_forward_args::Tuple = (),
q_backward::GenerativeFunction,
q_backward_args::Tuple = (),
f::TraceTransformDSLProgram)
Constructor for a general trace translator.
Run the translator with:
(output_trace, log_weight) = translator(input_trace; check=false, prev_observations=EmptyChoiceMap())
Use `check` to enable a bijection check (this requires that the transform `f` has been
paired with its inverse using [`pair_bijections!](@ref) or [`is_involution`](@ref)).
If `check` is enabled, then `prev_observations` is a choice map containing the observed
random choices in the previous trace.
"""
@with_kw mutable struct GeneralTraceTranslator <: TraceTranslator
p_new::GenerativeFunction
p_new_args::Tuple = ()
new_observations::ChoiceMap = EmptyChoiceMap()
q_forward::GenerativeFunction
q_forward_args::Tuple = ()
q_backward::GenerativeFunction
q_backward_args::Tuple = ()
f::TraceTransformDSLProgram # a bijection
end
function inverse(translator::GeneralTraceTranslator, prev_model_trace::Trace,
prev_observations::ChoiceMap=EmptyChoiceMap())
return GeneralTraceTranslator(
get_gen_fn(prev_model_trace), get_args(prev_model_trace),
prev_observations, translator.q_backward, translator.q_backward_args,
translator.q_forward, translator.q_forward_args,
inverse(translator.f))
end
function run_transform(translator::GeneralTraceTranslator,
prev_model_trace::Trace, forward_proposal_trace::Trace)
@unpack f, new_observations = translator
@unpack p_new, p_new_args, q_backward, q_backward_args = translator
first_pass_results = run_first_pass(f, prev_model_trace, forward_proposal_trace)
log_abs_determinant = jacobian_correction(
f, prev_model_trace, forward_proposal_trace, first_pass_results, nothing)
constraints = merge(first_pass_results.constraints, new_observations)
(new_model_trace, _) = generate(p_new, p_new_args, constraints)
backward_proposal_trace, = generate(
q_backward, (new_model_trace, q_backward_args...), first_pass_results.u_back)
return (new_model_trace, backward_proposal_trace, log_abs_determinant)
end
function (translator::GeneralTraceTranslator)(
prev_model_trace::Trace; check=false, prev_observations=EmptyChoiceMap())
# sample auxiliary trace
forward_proposal_trace =
simulate(translator.q_forward, (prev_model_trace, translator.q_forward_args...,))
# apply trace transform
(new_model_trace, backward_proposal_trace, log_abs_determinant) =
run_transform(translator, prev_model_trace, forward_proposal_trace)
# compute log weight
prev_model_score = get_score(prev_model_trace)
new_model_score = get_score(new_model_trace)
forward_proposal_score = get_score(forward_proposal_trace)
backward_proposal_score = get_score(backward_proposal_trace)
log_weight = new_model_score - prev_model_score +
backward_proposal_score + forward_proposal_score + log_abs_determinant
if check
inverter = inverse(translator, prev_model_trace, prev_observations)
(prev_model_trace_rt, forward_proposal_trace_rt, _) =
run_transform(inverter, new_model_trace, backward_proposal_trace)
check_round_trip(prev_model_trace, prev_model_trace_rt,
forward_proposal_trace, forward_proposal_trace_rt)
end
return (new_model_trace, log_weight)
end
##################################
# SimpleExtendingTraceTranslator #
##################################
"""
translator = SimpleExtendingTraceTranslator(;
p_new_args::Tuple = (),
p_argdiffs::Tuple = (),
new_observations::ChoiceMap = EmptyChoiceMap(),
q_forward::GenerativeFunction,
q_forward_args::Tuple = ())
Constructor for a simple extending trace translator.
Run the translator with:
(output_trace, log_weight) = translator(input_trace)
"""
@with_kw mutable struct SimpleExtendingTraceTranslator <: TraceTranslator
p_new_args::Tuple = ()
p_argdiffs::Tuple = ()
new_observations::ChoiceMap = EmptyChoiceMap()
q_forward::GenerativeFunction
q_forward_args::Tuple = ()
end
function (translator::SimpleExtendingTraceTranslator)(prev_model_trace::Trace)
# simulate from auxiliary program
forward_proposal_trace =
simulate(translator.q_forward, (prev_model_trace, translator.q_forward_args...,))
forward_proposal_score = get_score(forward_proposal_trace)
# computing the new trace via update
constraints = merge(get_choices(forward_proposal_trace), translator.new_observations)
(new_model_trace, log_model_weight, _, discard) = update(
prev_model_trace, translator.p_new_args,
translator.p_argdiffs, constraints)
if !isempty(discard)
@error("Can only extend the trace with random choices, not remove them.")
error("Invalid SimpleExtendingTraceTranslator")
end
log_weight = log_model_weight - forward_proposal_score
return (new_model_trace, log_weight)
end
############################
# SymmetricTraceTranslator #
############################
const TransformFunction = Union{TraceTransformDSLProgram,Function}
"""
translator = SymmetricTraceTranslator(;
q::GenerativeFunction,
q_args::Tuple = (),
involution::Union{TraceTransformDSLProgram,Function})
Constructor for a symmetric trace translator.
The involution is either constructed via the [`@transform`](@ref) macro (recommended),
or can be provided as a Julia function.
Run the translator with:
(output_trace, log_weight) = translator(input_trace; check=false, observations=EmptyChoiceMap())
Use `check` to enable the involution check (this requires that the transform `f` has been
marked with [`is_involution`](@ref)).
If `check` is enabled, then `observations` is a choice map containing the observed random
choices, and the check will additionally ensure they are not mutated by the involution.
"""
@with_kw mutable struct SymmetricTraceTranslator{T <: TransformFunction} <: TraceTranslator
q::GenerativeFunction
q_args::Tuple = ()
involution::T # an involution
end
function inverse(translator::SymmetricTraceTranslator, prev_model_trace=nothing)
return translator
end
function run_transform(translator::SymmetricTraceTranslator,
prev_model_trace::Trace, forward_proposal_trace::Trace)
@unpack involution, q, q_args = translator
first_pass_results = run_first_pass(involution, prev_model_trace, forward_proposal_trace)
(new_model_trace, log_model_weight, _, discard) = update(
prev_model_trace, get_args(prev_model_trace),
map((_) -> NoChange(), get_args(prev_model_trace)),
first_pass_results.constraints)
log_abs_determinant = jacobian_correction(
involution, prev_model_trace, forward_proposal_trace, first_pass_results, discard)
backward_proposal_trace, = generate(
q, (new_model_trace, q_args...), first_pass_results.u_back)
return (new_model_trace, backward_proposal_trace, log_abs_determinant)
end
function (translator::SymmetricTraceTranslator{TraceTransformDSLProgram})(
prev_model_trace::Trace; check=false, observations=EmptyChoiceMap())
# simulate from auxiliary program
forward_proposal_trace =
simulate(translator.q, (prev_model_trace, translator.q_args...,))
# apply trace transform
(new_model_trace, backward_proposal_trace, log_abs_determinant) =
run_transform(translator, prev_model_trace, forward_proposal_trace)
# compute log weight
prev_model_score = get_score(prev_model_trace)
new_model_score = get_score(new_model_trace)
forward_proposal_score = get_score(forward_proposal_trace)
backward_proposal_score = get_score(backward_proposal_trace)
log_weight = new_model_score - prev_model_score +
backward_proposal_score - forward_proposal_score + log_abs_determinant
if check
check_observations(get_choices(new_model_trace), observations)
(prev_model_trace_rt, forward_proposal_trace_rt, _) =
run_transform(translator, new_model_trace, backward_proposal_trace)
check_round_trip(prev_model_trace, prev_model_trace_rt,
forward_proposal_trace, forward_proposal_trace_rt)
end
return (new_model_trace, log_weight)
end
function (translator::SymmetricTraceTranslator{<:Function})(
prev_model_trace::Trace; check=false, observations=EmptyChoiceMap())
forward_trace = simulate(translator.q, (prev_model_trace, translator.q_args...,))
forward_score = get_score(forward_trace)
forward_choices = get_choices(forward_trace)
forward_retval = get_retval(forward_trace)
(new_model_trace, backward_choices, log_weight) = translator.involution(
prev_model_trace, forward_choices, forward_retval, translator.q_args)
(backward_score, backward_retval) =
assess(translator.q, (new_model_trace, translator.q_args...), backward_choices)
log_weight += (backward_score - forward_score)
if check
check_observations(get_choices(new_model_trace), observations)
(prev_model_trace_rt, forward_choices_rt, _) = translator.involution(
new_model_trace, backward_choices, backward_retval, translator.q_args)
(forward_trace_rt, _) = generate(
translator.q, (prev_model_trace, translator.q_args...), forward_choices_rt)
check_round_trip(prev_model_trace, prev_model_trace_rt,
forward_trace, forward_trace_rt)
end
return (new_model_trace, log_weight)
end
export @transform
export @read, @write, @copy, @tcall
export TraceTransformDSLProgram, pair_bijections!, is_involution!, inverse
export TraceTranslator, DeterministicTraceTranslator, SymmetricTraceTranslator,
SimpleExtendingTraceTranslator, GeneralTraceTranslator