/
NE10_fir.neon.s
2094 lines (1685 loc) · 71.4 KB
/
NE10_fir.neon.s
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
@
@ Copyright 2012-16 ARM Limited and Contributors.
@ All rights reserved.
@
@ Redistribution and use in source and binary forms, with or without
@ modification, are permitted provided that the following conditions are met:
@ * Redistributions of source code must retain the above copyright
@ notice, this list of conditions and the following disclaimer.
@ * Redistributions in binary form must reproduce the above copyright
@ notice, this list of conditions and the following disclaimer in the
@ documentation and/or other materials provided with the distribution.
@ * Neither the name of ARM Limited nor the
@ names of its contributors may be used to endorse or promote products
@ derived from this software without specific prior written permission.
@
@ THIS SOFTWARE IS PROVIDED BY ARM LIMITED AND CONTRIBUTORS "AS IS" AND
@ ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
@ WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
@ DISCLAIMED. IN NO EVENT SHALL ARM LIMITED AND CONTRIBUTORS BE LIABLE FOR ANY
@ DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
@ (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
@ LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
@ ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
@ (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
@ SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
@
@/*
@ * NE10 Library : dsp/NE10_fir.neon.s
@ */
@/*
@ * Note:
@ * 1. Currently, this is for soft VFP EABI, not for hard vfpv3 ABI yet
@ * 2. In the assembly code, we use D0-D31 registers. So VFPv3-D32 is used. In VFPv3-D16, there will be failure
@ */
#ifdef ENABLE_NE10_FIR_FLOAT_NEON
.text
.syntax unified
@/**
@ * @details
@ * This function operates on floating-point data types.
@ * There are no restrictions on numTaps and blockSize.
@ *
@ * The order of the coefficients in *coeffs should be
@ * bN, bN-1, bN-2, .....b1, b0
@ *
@ * <b>Cycle Count:</b>
@ *
@ * <code>45 + 8 * numTaps + 12.25 * blockSize + 4.375 * numTaps * blockSize</code>
@ *
@ * when the block size > 32, the tap is > 4, you could get
@ * maximized improvement
@ *
@ * @param[in] *S points to struct parameter
@ * @param[in] *pSrc points to the input buffer
@ * @param[out] *pDst points to the output buffer
@ * @param[in] blockSize block size of filter
@ */
.align 4
.global ne10_fir_float_neon
.extern ne10_qMaskTable32
.thumb
.thumb_func
ne10_fir_float_neon:
PUSH {r4-r12,lr} @push r12: to keep stack 8 bytes aligned
VPUSH {q4}
@/*ARM Registers*/
pStateStruct .req R0
pSrc .req R1
pDst .req R2
blockSize .req R3
pState .req R4 @/* State pointer */
pCoeffs .req R5 @/* Coefficient pointer */
pStateCurnt .req R6 @/* Points to the current sample of the state */
pX .req R7 @/* Temporary pointers for state buffer */
pB .req R8 @/* Temporary pointers for coefficient buffer */
numTaps .req R9 @/* Length of the filter */
tapCnt .req R10 @ /* Loop counter */
Count .req R11 @ /* Loop counter */
pTemp .req R11
pMask .req R14 @ /* Mask Table */
mask .req R12
@/*NEON variale Declaration*/
qInp .qn Q0.F32
dInp_0 .dn D0.F32
dInp_1 .dn D1.F32
qCoeff .qn Q1.F32
dCoeff_0 .dn D2.F32
dCoeff_1 .dn D3.F32
qZero .qn Q2.F32
qMask .qn Q3.U32
dMask_0 .dn D6.U32
dMask_1 .dn D7.U32
dOut_0 .dn D6.F32
dOut_1 .dn D7.F32
qAcc0 .qn Q8.F32
dAcc0_0 .dn D16.F32
dAcc0_1 .dn D17.F32
qTemp .qn Q9.F32
dTemp_0 .dn D18.F32
dTemp_1 .dn D19.F32
qTemp1 .qn Q10.F32
dTemp1_0 .dn D20.F32
dTemp1_1 .dn D21.F32
qTemp2 .qn Q11.F32
qTemp3 .qn Q12.F32
qMask1 .qn Q4.U32
dMask1_0 .dn D8.U32
dMask1_1 .dn D9.U32
qMaskTmp .qn Q14.U32
dMaskTmp_0 .dn D28.U32
dMaskTmp_1 .dn D29.U32
qAcc1 .qn Q3.F32
qAcc2 .qn Q13.F32
qAcc3 .qn Q15.F32
LDRH numTaps,[pStateStruct],#4
LDR pState,[pStateStruct],#4
LDR pCoeffs,[pStateStruct],#4
@/* S->state buffer contains previous frame (numTaps - 1) samples */
@/* pStateCurnt points to the location where the new input data should be written */
@/*pStateCurnt = &(S->state[(numTaps - 1u)])@*/
SUB mask,numTaps,#1
#ifdef __PIC__
@/* position-independent access of LDR pMask,=ne10_qMaskTable32 */
LDR pTemp,.L_PIC0_GOT_OFFSET
LDR pMask,.L_GOT_ne10_qMaskTable32
.L_PIC0:
ADD pTemp,pTemp,pc
LDR pMask,[pTemp,pMask]
#else
LDR pMask,=ne10_qMaskTable32
#endif
AND tapCnt,numTaps,#3
ADD pStateCurnt,pState,mask,LSL #2
AND mask,blockSize,#3
@/* Apply loop unrolling and compute 4 output values simultaneously.
@* The variables acc0 ... acc3 hold output values that are being computed:
@*
@* acc0 = b[numTaps-1] * x[n-numTaps-1] + b[numTaps-2] * x[n-numTaps-2] + b[numTaps-3] * x[n-numTaps-3] +...+ b[0] * x[0]
@* acc1 = b[numTaps-1] * x[n-numTaps] + b[numTaps-2] * x[n-numTaps-1] + b[numTaps-3] * x[n-numTaps-2] +...+ b[0] * x[1]
@* acc2 = b[numTaps-1] * x[n-numTaps+1] + b[numTaps-2] * x[n-numTaps] + b[numTaps-3] * x[n-numTaps-1] +...+ b[0] * x[2]
@* acc3 = b[numTaps-1] * x[n-numTaps+2] + b[numTaps-2] * x[n-numTaps+1] + b[numTaps-3] * x[n-numTaps] +...+ b[0] * x[3]
@*/
@/*If numTaps,blockSize are not multiples of 4, Get the appropriate Masks*/
ADD pTemp,pMask,tapCnt,LSL #4
VEOR qZero,qZero
ADD pX,pMask,mask,LSL #4
VLD1 {dMaskTmp_0,dMaskTmp_1},[pTemp]
VLD1 {dMask1_0,dMask1_1},[pX]
@/* Copy blockCnt number of new input samples into the state buffer */
SUBS blockSize,#4
BLT firEndOuterLoop
@/* Compute 4 outputs at a time*/
firOuterLoop:
VLD1 {dTemp_0,dTemp_1},[pSrc]!
MOV pX,pState
MOV pB,pCoeffs
@/* Read the first four samples from the state buffer:
@* x[n-numTaps], x[n-numTaps-1], x[n-numTaps-2],x[n-numTaps-3] */
VST1 {dTemp_0,dTemp_1},[pStateCurnt]!
@/* Zero the Accumulators*/
VEOR qAcc0,qAcc0
VLD1 {dInp_0,dInp_1},[pX]!
@//* Read the first four coefficients b[numTaps] to b[numTaps-3] */
VLD1 {dCoeff_0,dCoeff_1},[pB]!
@/* Loop unrolling. Process 4 taps at a time. */
SUBS tapCnt,numTaps,#4
VLD1 {dTemp_0,dTemp_1},[pX]!
BLT firEndInnerLoop
firInnerLoop:
VEXT qTemp1,qInp,qTemp,#1
@/* acc0 += b[numTaps] * x[n-numTaps-1]+ b[numTaps] * x[n-numTaps-2] +
@* b[numTaps] * x[n-numTaps-3] + b[numTaps] * x[n-numTaps-4]*/
VMLA qAcc0,qInp,dCoeff_0[0]
@/* acc1 += b[numTaps-1] * x[n-numTaps-2]+ b[numTaps-1] * x[n-numTaps-3] +
@b[numTaps-1] * x[n-numTaps-4] +*b[numTaps-1] * x[n-numTaps-5]*/
VMUL qAcc1,qTemp1,dCoeff_0[1]
VEXT qTemp2,qInp,qTemp,#2
@/* acc2 += b[numTaps-2] * x[n-numTaps-3]+ b[numTaps-2] * x[n-numTaps-4] +
@b[numTaps-2] * x[n-numTaps-5] + *b[numTaps-2] * x[n-numTaps-6]*/
VMUL qAcc2,qTemp2,dCoeff_1[0]
VADD qAcc0, qAcc0, qAcc1
VEXT qTemp3,qInp,qTemp,#3
@/* acc3 += b[numTaps-3] * x[n-numTaps-4]+ b[numTaps-3] * x[n-numTaps-5] +
@b[numTaps-3] * x[n-numTaps-6] +*b[numTaps-3] * x[n-numTaps-7] */
VMUL qAcc3,qTemp3,dCoeff_1[1]
VADD qAcc0, qAcc0, qAcc2
VMOV qInp,qTemp
VLD1 {dTemp_0,dTemp_1},[pX]!
VADD qAcc0, qAcc0, qAcc3
SUBS tapCnt,#4
@/* Read the b[numTaps-4] to b[numTaps-7] coefficients */
VLD1 {dCoeff_0,dCoeff_1},[pB]!
BGE firInnerLoop
firEndInnerLoop:
ADDS tapCnt, tapCnt, #4
BEQ firStoreOutput
@/* If the filter length is not a multiple of 4, compute the remaining filter taps */
@/*Select only the remaining filter Taps*/
VMOV qMask,qMaskTmp
VBSL qMask,qCoeff,qZero
VEXT qTemp1,qInp,qTemp,#1
VMLA qAcc0,qInp,dOut_0[0]
VEXT qTemp2,qInp,qTemp,#2
VMLA qAcc0,qTemp1,dOut_0[1]
VMLA qAcc0,qTemp2,dOut_1[0]
firStoreOutput:
@/* Advance the state pointer by 4 to process the next group of 4 samples */
ADD pState,#16
@/* The results in the 4 accumulators are in 2.30 format. Convert to 1.31
@ * Then store the 4 outputs in the destination buffer. */
SUBS blockSize,#4
VST1 {dAcc0_0,dAcc0_1},[pDst]!
BGE firOuterLoop
firEndOuterLoop:
@/*Handle BlockSize Not a Multiple of 4*/
ADDS blockSize,#4
BEQ firCopyData
@/*Copy the Remaining BlockSize Number of Input Sample to state Buffer*/
VMOV qMask,qMask1
VLD1 {dTemp1_0,dTemp1_1},[pStateCurnt]
VLD1 {dTemp_0,dTemp_1},[pSrc]
ADD pSrc,pSrc,blockSize,LSL #2
MOV pX,pState
MOV pB,pCoeffs
VBSL qMask,qTemp,qTemp1
VST1 {dMask_0,dMask_1},[pStateCurnt]
VLD1 {dInp_0,dInp_1},[pX]!
ADD pStateCurnt,pStateCurnt,blockSize, LSL #2
@/* Zero the Accumulators*/
VEOR qAcc0,qAcc0
VLD1 {dCoeff_0,dCoeff_1},[pB]!
SUBS tapCnt,numTaps,#4
VLD1 {dTemp_0,dTemp_1},[pX]!
BLT firEndInnerLoop1
firInnerLoop1:
VEXT qTemp1,qInp,qTemp,#1
VMLA qAcc0,qInp,dCoeff_0[0]
VEXT qTemp2,qInp,qTemp,#2
VMLA qAcc0,qTemp1,dCoeff_0[1]
VEXT qTemp3,qInp,qTemp,#3
VMLA qAcc0,qTemp2,dCoeff_1[0]
VMOV qInp,qTemp
VMLA qAcc0,qTemp3,dCoeff_1[1]
VLD1 {dCoeff_0,dCoeff_1},[pB]!
SUBS tapCnt,#4
VLD1 {dTemp_0,dTemp_1},[pX]!
BGE firInnerLoop1
firEndInnerLoop1:
VMOV qMask,qMaskTmp
VBSL qMask,qCoeff,qZero
VEXT qTemp1,qInp,qTemp,#1
VMLA qAcc0,qInp,dOut_0[0]
VEXT qTemp2,qInp,qTemp,#2
VMLA qAcc0,qTemp1,dOut_0[1]
VMLA qAcc0,qTemp2,dOut_1[0]
VMOV qMask,qMask1
VLD1 {dTemp_0,dTemp_1},[pDst]
@/* If the blockSize is not a multiple of 4, Mask the unwanted Output */
VBSL qMask,qAcc0,qTemp
VST1 {dMask_0,dMask_1},[pDst]
ADD pDst,pDst,blockSize,LSL #2
ADD pState,pState,blockSize,LSL #2
firCopyData:
@/* Processing is complete. Now shift the data in the state buffer down by
@** blockSize samples. This prepares the state buffer for the next function
@** call. */
@/* Points to the start of the state buffer */
SUB numTaps,numTaps,#1
AND mask,numTaps,#3
LDR pStateCurnt,[pStateStruct,#-8]
ADD pTemp,pMask,mask,LSL #4
VLD1 {dInp_0,dInp_1},[pState]!
VLD1 {dMask_0,dMask_1},[pTemp]
@/* copy data */
SUBS Count,numTaps,#4
BLT firEnd
firCopyLoop:
VST1 {dInp_0,dInp_1},[pStateCurnt]!
SUBS Count,#4
VLD1 {dInp_0,dInp_1},[pState]!
BGE firCopyLoop
firEnd:
VLD1 {dTemp_0,dTemp_1},[pStateCurnt]
VBSL qMask,qInp,qTemp
VST1 {dOut_0,dOut_1},[pStateCurnt]
ADD pStateCurnt,pStateCurnt,mask, LSL #2
@/*Return From Function*/
VPOP {q4}
POP {r4-r12,pc}
@/*ARM Registers*/
.unreq pStateStruct
.unreq pSrc
.unreq pDst
.unreq blockSize
.unreq pState
.unreq pCoeffs
.unreq pStateCurnt
.unreq pX
.unreq pB
.unreq numTaps
.unreq tapCnt
.unreq Count
.unreq pTemp
.unreq pMask
.unreq mask
@/*NEON variale Declaration*/
.unreq qInp
.unreq dInp_0
.unreq dInp_1
.unreq qCoeff
.unreq dCoeff_0
.unreq dCoeff_1
.unreq qZero
.unreq qMask
.unreq dMask_0
.unreq dMask_1
.unreq dOut_0
.unreq dOut_1
.unreq qAcc0
.unreq dAcc0_0
.unreq dAcc0_1
.unreq qTemp
.unreq dTemp_0
.unreq dTemp_1
.unreq qTemp1
.unreq dTemp1_0
.unreq dTemp1_1
.unreq qTemp2
.unreq qTemp3
.unreq qMask1
.unreq dMask1_0
.unreq dMask1_1
.unreq qMaskTmp
.unreq dMaskTmp_0
.unreq dMaskTmp_1
.unreq qAcc1
.unreq qAcc2
.unreq qAcc3
#endif
@/* ENABLE_NE10_FIR_FLOAT_NEON */
@/**
@ * @details
@ * This function operates on floating-point data types.
@ * There are no restrictions on numTaps and blockSize.
@ *
@ * The order of the coefficients in *coeffs should be
@ * bN, bN-1, bN-2, .....b1, b0
@ *
@ * <b>Cycle Count:</b>
@ *
@ * <code> Co + C1 * numTaps + C3 * blockSize * decimation Factor + c4 * numTaps * blockSize</code>
@ *
@ * when the block size > 32, the tap > 4, you could get
@ * maximized improvement
@ *
@ * @param[in] *S points to struct parameter
@ * @param[in] *pSrc points to the input buffer
@ * @param[out] *pDst points to the output buffer
@ * @param[in] blockSize block size of filter
@ */
#ifdef ENABLE_NE10_FIR_DECIMATE_FLOAT_NEON
.align 4
.global ne10_fir_decimate_float_neon
.extern ne10_qMaskTable32
.extern ne10_divLookUpTable
.thumb
.thumb_func
ne10_fir_decimate_float_neon:
PUSH {r4-r12,lr} @push r12: to keep stack 8 bytes aligned
VPUSH {d8-d9}
@/*ARM Registers*/
pStateStruct .req R0
pSrc .req R1
pDst .req R2
blockSize .req R3
pState .req R4 @/* State pointer */
pCoeffs .req R5 @/* Coefficient pointer */
decimationFact .req R6
outBlockSize .req R7
pX .req R6 @/* Temporary pointers for state buffer */
pB .req R8 @/* Temporary pointers for coefficient buffer */
numTaps .req R9 @/* Length of the filter */
tapCnt .req R10 @ /* Loop counter */
Count .req R11 @ /* Loop counter */
pTemp .req R11
blkCnt .req R11
pMask .req R14 @ /* Mask Table */
mask .req R12
Offset .req R12
@/*NEON variale Declaration*/
qInp0 .qn Q0.F32
dInp0_0 .dn D0.F32
dInp0_1 .dn D1.F32
qCoeff .qn Q1.F32
dCoeff_0 .dn D2.F32
dCoeff_1 .dn D3.F32
qZero .qn Q2.F32
qMask .qn Q3.U32
qMaskF32 .qn Q3.F32
dMask_0 .dn D6.U32
dMask_1 .dn D7.U32
dOut_0 .dn D6.F32
dOut_1 .dn D7.F32
qInp3 .qn Q4.F32
dInp3_0 .dn D8.F32
dInp3_1 .dn D9.F32
qAcc0 .qn Q8.F32
dAcc0_0 .dn D16.F32
dAcc0_1 .dn D17.F32
qTemp .qn Q9.F32
dTemp_0 .dn D18.F32
dTemp_1 .dn D19.F32
qInp1 .qn Q9.F32
dInp1_0 .dn D18.F32
dInp1_1 .dn D19.F32
qAcc1 .qn Q10.F32
dAcc1_0 .dn D20.F32
dAcc1_1 .dn D21.F32
qAcc2 .qn Q11.F32
dAcc2_0 .dn D22.F32
dAcc2_1 .dn D23.F32
qAcc3 .qn Q12.F32
dAcc3_0 .dn D24.F32
dAcc3_1 .dn D25.F32
qMask1 .qn Q13.U32
dMask1_0 .dn D26.U32
dMask1_1 .dn D27.U32
qMaskTmp .qn Q14.U32
dMaskTmp_0 .dn D28.U32
dMaskTmp_1 .dn D29.U32
qInp2 .qn Q15.F32
dInp2_0 .dn D30.F32
dInp2_1 .dn D31.F32
LDRB decimationFact,[pStateStruct],#2
LDRH numTaps,[pStateStruct],#2
LDR pCoeffs,[pStateStruct],#4
LDR pState,[pStateStruct],#4
@//outBlockSize = blockSize / S->M
#ifdef __PIC__
@/* position-independent access of LDR pMask,=ne10_divLookUpTable */
LDR pTemp,.L_PIC1_GOT_OFFSET
LDR pMask,.L_GOT_ne10_divLookUpTable
.L_PIC1:
ADD pTemp,pTemp,pc
LDR pMask,[pTemp,pMask]
#else
LDR pMask,=ne10_divLookUpTable
#endif
SUBS mask,decimationFact,#1
ADD pMask,pMask,mask,LSL #2
LDR mask,[pMask]
@//MOV pX,#0
SMULWB outBlockSize,blockSize,mask
CMP outBlockSize,#0
IT LT
RSBLT outBlockSize,#0
@/* S->state buffer contains previous frame (numTaps - 1) samples */
@/* pStateCurnt points to the location where the new input data should be written */
@//pStateCurnt = S->state + (numTaps - 1u)@
@/* Copy Blocksize number of new input samples into the state buffer */
#ifdef __PIC__
@/* position-independent access of LDR pMask,=ne10_qMaskTable32 */
LDR pTemp,.L_PIC2_GOT_OFFSET
LDR pMask,.L_GOT_ne10_qMaskTable32
.L_PIC2:
ADD pTemp,pTemp,pc
LDR pMask,[pTemp,pMask]
#else
LDR pMask,=ne10_qMaskTable32
#endif
SUB tapCnt,numTaps,#1
AND mask,blockSize,#3
ADD pB,pState,tapCnt,LSL #2
ADD mask,pMask,mask,LSL #4
VLD1 {dTemp_0,dTemp_1},[pSrc]!
VLD1 {dMask1_0,dMask1_1},[mask]
SUBS Count,blockSize,#4
LSL Offset,decimationFact, #2
VMOV qMask,qMask1
BLT firDecimateEndCopy
firDecimateCopyLoop:
VST1 {dTemp_0,dTemp_1},[pB]!
SUBS Count,#4
VLD1 {dTemp_0,dTemp_1},[pSrc]!
BGE firDecimateCopyLoop
firDecimateEndCopy:
VLD1 {dCoeff_0,dCoeff_1},[pB]
VBSL qMask,qTemp,qCoeff
VST1 {dMask_0,dMask_1},[pB]
ADD pB,pB,tapCnt,LSL #2
@// Load Mask Value
AND blkCnt,outBlockSize,#3
ADD blkCnt,pMask,blkCnt,LSL #4
VLD1 {dMask1_0,dMask1_1},[blkCnt]
@/*Load Mask Table Values*/
AND tapCnt,numTaps,#3
ADD pTemp,pMask,tapCnt,LSL #4
VEOR qZero,qZero,qZero
VLD1 {dMaskTmp_0,dMaskTmp_1},[pTemp]
@/*Handle 4 output samples at a time */
SUBS blkCnt,outBlockSize,#4
BLT firDecimateEndOuterLoop
@//blkCnt = outBlockSize>>2@
firDecimateOuterLoop:
@/* Set accumulator to zero */
VEOR qAcc0,qAcc0,qAcc0
VEOR qAcc1,qAcc1,qAcc1
VEOR qAcc2,qAcc2,qAcc2
VEOR qAcc3,qAcc3,qAcc3
@/* Initialize state pointer */
MOV pX,pState
@/* Initialize coeff pointer */
MOV pB,pCoeffs
SUBS tapCnt,numTaps,#4
VLD1 {dCoeff_0,dCoeff_1},[pB]!
VLD1 {dInp0_0,dInp0_1},[pX],Offset
VLD1 {dInp1_0,dInp1_1},[pX],Offset
VLD1 {dInp2_0,dInp2_1},[pX],Offset
VLD1 {dInp3_0,dInp3_1},[pX],Offset
SUB pX,pX,Offset, LSL #2
ADD pX,pX,#16
BLT firDecimateEndInnerLoop
firDecimateInnerLoop:
VMLA qAcc0,qCoeff,qInp0
VMLA qAcc1,qCoeff,qInp1
VMLA qAcc2,qCoeff,qInp2
VMLA qAcc3,qCoeff,qInp3
VLD1 {dCoeff_0,dCoeff_1},[pB]!
VLD1 {dInp0_0,dInp0_1},[pX],Offset
VLD1 {dInp1_0,dInp1_1},[pX],Offset
VLD1 {dInp2_0,dInp2_1},[pX],Offset
VLD1 {dInp3_0,dInp3_1},[pX],Offset
SUB pX,pX,Offset, LSL #2
ADD pX,pX,#16
SUBS tapCnt,#4
BGE firDecimateInnerLoop
firDecimateEndInnerLoop:
@/* If the filter length is not a multiple of 4, compute the remaining filter taps */
VMOV qMask,qMaskTmp
VBSL qMask,qCoeff,qZero
VMLA qAcc0,qMaskF32,qInp0
VMLA qAcc1,qMaskF32,qInp1
VMLA qAcc2,qMaskF32,qInp2
VMLA qAcc3,qMaskF32,qInp3
VADD dAcc0_0,dAcc0_0,dAcc0_1
VADD dAcc1_0,dAcc1_0,dAcc1_1
VADD dAcc2_0,dAcc2_0,dAcc2_1
VADD dAcc3_0,dAcc3_0,dAcc3_1
VPADD dAcc0_0,dAcc0_0,dAcc1_0
VPADD dAcc0_1,dAcc2_0,dAcc3_0
ADD pState,pState,Offset,LSL #2
VST1 {dAcc0_0,dAcc0_1},[pDst]!
SUBS blkCnt,#4
BGE firDecimateOuterLoop
firDecimateEndOuterLoop:
@/*Handle BlockSize Not a Multiple of 4*/
ADDS blkCnt,#4
BEQ firDecimateCopyData
@/* Set accumulator to zero */
VEOR qAcc0,qAcc0,qAcc0
VEOR qAcc1,qAcc1,qAcc1
VEOR qAcc2,qAcc2,qAcc2
VEOR qAcc3,qAcc3,qAcc3
@/* Initialize state pointer */
MOV pX,pState
@/* Initialize coeff pointer */
MOV pB,pCoeffs
SUBS tapCnt,numTaps,#4
VLD1 {dCoeff_0,dCoeff_1},[pB]!
VLD1 {dInp0_0,dInp0_1},[pX],Offset
VLD1 {dInp1_0,dInp1_1},[pX],Offset
VLD1 {dInp2_0,dInp2_1},[pX],Offset
VLD1 {dInp3_0,dInp3_1},[pX],Offset
SUB pX,pX,Offset, LSL #2
ADD pX,pX,#16
BLT firDecimateEndInnerLoop1
firDecimateInnerLoop1:
VMLA qAcc0,qCoeff,qInp0
VMLA qAcc1,qCoeff,qInp1
VMLA qAcc2,qCoeff,qInp2
VMLA qAcc3,qCoeff,qInp3
VLD1 {dCoeff_0,dCoeff_1},[pB]!
VLD1 {dInp0_0,dInp0_1},[pX],Offset
VLD1 {dInp1_0,dInp1_1},[pX],Offset
VLD1 {dInp2_0,dInp2_1},[pX],Offset
VLD1 {dInp3_0,dInp3_1},[pX],Offset
SUB pX,pX,Offset, LSL #2
ADD pX,pX,#16
SUBS tapCnt,#4
BGE firDecimateInnerLoop1
firDecimateEndInnerLoop1:
@/* If the filter length is not a multiple of 4, compute the remaining filter taps */
VMOV qMask,qMaskTmp
VBSL qMask,qCoeff,qZero
VMLA qAcc0,qMaskF32,qInp0
VMLA qAcc1,qMaskF32,qInp1
VMLA qAcc2,qMaskF32,qInp2
VMLA qAcc3,qMaskF32,qInp3
VADD dAcc0_0,dAcc0_0,dAcc0_1
VADD dAcc1_0,dAcc1_0,dAcc1_1
VADD dAcc2_0,dAcc2_0,dAcc2_1
VADD dAcc3_0,dAcc3_0,dAcc3_1
MUL Offset,Offset,blkCnt
VPADD dAcc0_0,dAcc0_0,dAcc1_0
VPADD dAcc0_1,dAcc2_0,dAcc3_0
ADD pState,pState,Offset
VMOV qMask,qMask1
VLD1 {dTemp_0,dTemp_1},[pDst]
VBSL qMask,qAcc0,qTemp
VST1 {dMask_0,dMask_1},[pDst]
ADD pDst,pDst,blkCnt,LSL #2
firDecimateCopyData:
@/* Processing is complete. Now shift the data in the state buffer down by
@** blockSize samples. This prepares the state buffer for the next function
@** call. */
@/* Points to the start of the state buffer */
SUB numTaps,numTaps,#1
AND mask,numTaps,#3
LDR pX,[pStateStruct,#-4]
ADD pTemp,pMask,mask,LSL #4
VLD1 {dInp0_0,dInp0_1},[pState]!
VLD1 {dMask_0,dMask_1},[pTemp]
@/* copy data */
SUBS Count,numTaps,#4
BLT firDecimateEnd
firDecimateCopyLoop1:
VST1 {dInp0_0,dInp0_1},[pX]!
SUBS Count,#4
VLD1 {dInp0_0,dInp0_1},[pState]!
BGE firDecimateCopyLoop1
firDecimateEnd:
VLD1 {dTemp_0,dTemp_1},[pX]
VBSL qMask,qInp0,qTemp
VST1 {dOut_0,dOut_1},[pX]
ADD pX,pX,mask, LSL #2
@// Return From Function
VPOP {d8-d9}
POP {r4-r12,pc}
@/*ARM Registers*/
.unreq pStateStruct
.unreq pSrc
.unreq pDst
.unreq blockSize
.unreq pState
.unreq pCoeffs
.unreq decimationFact
.unreq outBlockSize
.unreq pX
.unreq pB
.unreq numTaps
.unreq tapCnt
.unreq Count
.unreq pTemp
.unreq blkCnt
.unreq pMask
.unreq mask
.unreq Offset
@/*NEON variale Declaration*/
.unreq qInp0
.unreq dInp0_0
.unreq dInp0_1
.unreq qCoeff
.unreq dCoeff_0
.unreq dCoeff_1
.unreq qZero
.unreq qMask
.unreq qMaskF32
.unreq dMask_0
.unreq dMask_1
.unreq dOut_0
.unreq dOut_1
.unreq qInp3
.unreq dInp3_0
.unreq dInp3_1
.unreq qAcc0
.unreq dAcc0_0
.unreq dAcc0_1
.unreq qTemp
.unreq dTemp_0
.unreq dTemp_1
.unreq qInp1
.unreq dInp1_0
.unreq dInp1_1
.unreq qAcc1
.unreq dAcc1_0
.unreq dAcc1_1
.unreq qAcc2
.unreq dAcc2_0
.unreq dAcc2_1
.unreq qAcc3
.unreq dAcc3_0
.unreq dAcc3_1
.unreq qMask1
.unreq dMask1_0
.unreq dMask1_1
.unreq qMaskTmp
.unreq dMaskTmp_0
.unreq dMaskTmp_1
.unreq qInp2
.unreq dInp2_0
.unreq dInp2_1
#endif
@/* ENABLE_NE10_FIR_DECIMATE_FLOAT_NEON */
@/**
@ * @details
@ * This function operates on floating-point data types.
@ * There are no restrictions on numTaps and blockSize.
@ *
@ * The order of the coefficients in *coeffs should be
@ * bN, bN-1, bN-2, .....b1, b0
@ *
@ * <b>Cycle Count:</b>
@ *
@ * when the S->tapnumTaps/S->L is big , you could get
@ * maximized improvement
@ *
@ * <code> C0 + C2 * blockSize + C3 * blockSize * interpolateFactor + C4 * numTaps * blockSize * interpolateFactor </code>
@ *
@ * @param[in] *S points to struct parameter
@ * @param[in] *pSrc points to the input buffer
@ * @param[out] *pDst points to the output buffer
@ * @param[in] blockSize block size of filter
@ */
#ifdef ENABLE_NE10_FIR_INTERPOLATE_FLOAT_NEON
.align 4
.global ne10_fir_interpolate_float_neon
.extern ne10_qMaskTable32
.thumb
.thumb_func
ne10_fir_interpolate_float_neon:
PUSH {r4-r12,lr} @push r12: to keep stack 8 bytes aligned
@/*ARM Registers*/
pStateStruct .req R0
pSrc .req R1
pDst .req R2
blockSize .req R3
pState .req R4 @/* State pointer */
pB .req R5 @/* Temporary pointers for coefficient buffer */
pCoeffs .req R5 @/* Coefficient pointer */
pStateCurnt .req R5 @/* Points to the current sample of the state */
pX .req R6 @/* Temporary pointers for state buffer */
interpolationFact .req R7
intFact .req R8
phaseLen .req R9
Offset .req R10
Count .req R11 @ /* Loop counter */
pTemp .req R11
mask .req R12
pMask .req R14 @ /* Mask Table */
index .req R14
@/*NEON variale Declaration*/
qInp .qn Q0.F32
dInp_0 .dn D0.F32
dInp_1 .dn D1.F32
qCoeff0 .qn Q1.F32
dCoeff0_0 .dn D2.F32
dCoeff0_1 .dn D3.F32
qZero .qn Q2.F32
qMask .qn Q3.U32
dMask_0 .dn D6.U32
dMask_1 .dn D7.U32
dOut_0 .dn D6.F32
dOut_1 .dn D7.F32
qAcc0 .qn Q8.F32
dAcc0_0 .dn D16.F32
dAcc0_1 .dn D17.F32
qTemp .qn Q9.F32
dTemp_0 .dn D18.F32
dTemp_1 .dn D19.F32
qCoeff1 .qn Q10.F32
dCoeff1_0 .dn D20.F32
dCoeff1_1 .dn D21.F32
qCoeff2 .qn Q11.F32
dCoeff2_0 .dn D22.F32
dCoeff2_1 .dn D23.F32
qCoeff3 .qn Q12.F32
dCoeff3_0 .dn D24.F32
dCoeff3_1 .dn D25.F32
qMask1 .qn Q13.F32
dMask1_0 .dn D26.F32
dMask1_1 .dn D27.F32
qMaskTemp .qn Q14.U32
dMaskTemp_0 .dn D28.U32
dMaskTemp_1 .dn D29.U32
LDRB interpolationFact,[pStateStruct],#2
LDRH phaseLen,[pStateStruct],#2
LDR pCoeffs,[pStateStruct],#4
LDR pState,[pStateStruct],#4
LSL Offset,interpolationFact, #2
@/* S->state buffer contains previous frame (phaseLen - 1) samples */
@/* pStateCurnt points to the location where the new input data should be written */
AND phaseLen,#3
#ifdef __PIC__
@/* position-independent access of LDR pMask,=ne10_qMaskTable32 */
LDR pTemp,.L_PIC3_GOT_OFFSET
LDR pMask,.L_GOT_ne10_qMaskTable32
.L_PIC3:
ADD pTemp,pTemp,pc
LDR pMask,[pTemp,pMask]
#else