-
Notifications
You must be signed in to change notification settings - Fork 168
/
proper_erlang_abstract_code.erl
3115 lines (2753 loc) · 103 KB
/
proper_erlang_abstract_code.erl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
%%% This file is part of PropEr.
%%%
%%% PropEr is free software: you can redistribute it and/or modify
%%% it under the terms of the GNU General Public License as published by
%%% the Free Software Foundation, either version 3 of the License, or
%%% (at your option) any later version.
%%%
%%% PropEr is distributed in the hope that it will be useful,
%%% but WITHOUT ANY WARRANTY; without even the implied warranty of
%%% MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
%%% GNU General Public License for more details.
%%%
%%% You should have received a copy of the GNU General Public License
%%% along with PropEr. If not, see <http://www.gnu.org/licenses/>.
%%%
%%% Alternatively, you may use this file under the terms of the Apache
%%% License, Version 2.0 (the "License"); you may not use this file
%%% except in compliance with the License. You may obtain a copy of
%%% the License at <http://www.apache.org/licenses/LICENSE-2.0>
%%%
%%% Unless required by applicable law or agreed to in writing, software
%%% distributed under the License is distributed on an "AS IS" BASIS,
%%% WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
%%% See the License for the specific language governing permissions and
%%% limitations under the License.
%%%
%%% If you wish to allow use of your version of this file only under
%%% the terms of the Apache License, you should delete the provisions
%%% above and replace them with the notice and other provisions
%%% required by the Apache License; see
%%% <http://www.apache.org/licenses/LICENSE-2.0>. If you do not delete
%%% the provisions above, a recipient may use your version of this
%%% file under the terms of either the GNU General Public License or
%%% the Apache License.
%%%
%%% @doc PropEr generator of abstract code
%%%
%%% <p>This module is a PropEr generator for abstract code. It
%%% generates guards, expressions, programs (modules), and terms. It
%%% does not generate macros or other attributes than `function',
%%% `record', `spec', and `type'. The generated programs (guards,
%%% expressions) can be used for testing the Compiler or other modules
%%% traversing programs as abstract forms. Typical examples of the
%%% latter are <code>erl_eval</code>, <code>erl_pp</code>,
%%% <code>erl_prettypr</code> (Syntax Tools), and parse transforms.
%%% Created modules should compile without errors, but will most likely
%%% crash immediately when invoked.</p>
%%%
%%% <p>This is an example how to test the Compiler:</p>
%%%
%%% ```
%%% test() ->
%%% ?FORALL(Abstr, proper_erlang_abstract_code:module(),
%%% ?WHENFAIL(
%%% begin
%%% io:format("~ts\n", [[erl_pp:form(F) || F <- Abstr]]),
%%% compile(Abstr, [report_errors])
%%% end,
%%% case compile(Abstr, []) of
%%% {error, _Es, _Ws} -> false;
%%% _ -> true
%%% end)).
%%%
%%% compile(Abstr, Opts) ->
%%% compile:noenv_forms(Abstr, Opts).
%%% '''
-module(proper_erlang_abstract_code).
-export([module/0, module/1, guard/0, guard/1, expr/0, expr/1]).
-export([term/0, term/1]).
%-compile(export_all). -compile(nowarn_export_all).
%-define(debug, true).
-ifdef(debug).
-define(DEBUG(F, As), io:format(F, As)).
-else.
-define(DEBUG(F, AS), ok).
-endif.
-include("proper_internal.hrl").
-type char_fun() :: fun(() -> proper_types:type()).
%%% A function that generates characters. The default function
%%% chooses from <code>$a..$z | $A..$Z</code>.
-type atom_fun() :: fun(() -> proper_types:type()).
%%% A function that generates atoms. The default function chooses
%%% from 100 common English words.
-type weight() :: non_neg_integer().
-type limit() :: non_neg_integer().
-type option() ::
{'variables', [atom()]} |
{'weight', {Key :: atom(), Weight :: weight()}} |
{'function', [{FunctionName :: atom(), Arity :: arity()}]} |
{'types', [{TypeName :: atom(), NumOfParams :: arity()}]} |
{'records', [{RecordName:: atom(), [FieldName :: atom()]}]} |
{'limit', [{Name :: atom(), Limit :: limit()}]} |
{'char', char_fun()} |
{'atom', atom_fun()} |
{'set_all_weights', weight()}.
%%% See description below.
-type fa() :: {atom(), arity()}. % function+arity
-type ta() :: {atom(), arity()}. % type+arity
-type rec() :: {RecordName :: atom(), [FieldName :: atom()]}.
-record(gen_state,
{
size = 0 :: proper_gen:size(),
result_type = 'program' :: 'program' | 'guard' | 'expr' | 'term',
functions = [] :: [fa()],
functions_and_auto_imported = [] :: [{weight(), fa()}],
expr_bifs = [] :: [fa()],
guard_bifs = [] :: [fa()],
named_funs = [] :: [fa()],
records = [] :: [rec()],
guard_records = [] :: [rec()],
types = [] :: [ta()],
predef_types = [] :: [ta()],
module :: module(),
options = [] :: [option()],
weights = #{} :: #{Key :: atom() => Weight :: weight()},
limits = #{} :: #{Key :: atom() => Limit :: limit()},
variables = ordsets:new() :: ordsets:ordset(atom()),
simple_char = fun default_simple_char/0 :: char_fun(),
atom = fun default_atom/0 :: atom_fun(),
resize = 'false' :: boolean()
}).
-record(post_state,
{
context = 'expr' :: 'expr' | 'type' | 'record' | 'pattern',
vars = ordsets:new() :: ordsets:ordset(atom()),
vindex = 0 :: non_neg_integer(),
forbidden = ordsets:new() :: ordsets:ordset(atom()),
known_functions = [] :: [fa()],
atom = fun default_atom/0 :: atom_fun()
}).
-define(DEFAULT_SMALL_WEIGHT_PROGRAM, 50). % Needs to be quite high.
-define(DEFAULT_SMALL_WEIGHT_TERM, 50).
-define(MAX_CALL_ARGS, 2).
-define(MAX_FUNCTION_CLAUSES, 2).
-define(MAX_QUALIFIERS, 2).
-define(MAX_IF_CLAUSES, 2).
-define(MAX_CATCH_CLAUSES, 2).
-define(MAX_CLAUSES, 2).
-define(MAX_BODY, 2).
-define(MAX_GUARD, 2).
-define(MAX_GUARD_TESTS, 2).
-define(MAX_MAP, 2).
-define(MAX_TYPE_SPECIFIER, 2).
-define(MAX_RECORD_FIELDS, 3).
-define(MAX_TUPLE, 2).
-define(MAX_BIN_ELEMENTS, 2).
-define(MAX_FUNCTION_TYPES, 2).
-define(MAX_FUNCTION_CONSTRAINTS, 2).
-define(MAX_UNION_TYPES, 4).
-define(MAX_TUPLE_TYPES, 2).
-define(MAX_LIST, 4).
-define(MAX_STRING, 4).
%%% "div 2" is just a suggestion.
-define(RESIZE(S), S#gen_state{size = S#gen_state.size div 2}).
%%% @doc Returns abstract code of a term that can be handled by
%%% <code>erl_parse:normalise/0</code>.
%%% No pid() or port().
-spec term() -> proper_types:type().
term() ->
term([]).
%%% @doc Same as {@link term/0}, but accepts a list of options.
%%% === Options ===
%%%
%%% Many options are the same as the ones for {@link module/1}.
%%% <ul>
%%% <li><code>{atom, {@link atom_fun()}}</code> - A atom generating
%%% function to replace the default.</li>
%%% <li><code>{char, {@link char_fun()}}</code> - A character generating
%%% function to replace the default. The function is used when
%%% generating strings and characters.</li>
%%% <li><code>{limit, [{Name, Limit}]}</code> - Set the limit of
%%% <code>Name</code> to <code>Limit</code>. The limit names are:
%%% <ul>
%%% <li><code>bin_elements</code> - Number of segments of a bitstring.</li>
%%% <li><code>list</code> - Number of elements of a plain list.</li>
%%% <li><code>map</code> - Number of associations of a map.</li>
%%% <li><code>string</code> - Number of characters of a string.</li>
%%% <li><code>tuple</code> - Number of elements of a tuple.</li>
%%% </ul>
%%% </li>
%%% <li><code>{resize, boolean()}</code> - Use <code>?SIZED</code>
%%% to limit the size of the generated abstract code. With this
%%% option set to <code>false</code> (the default) big code
%%% may be generated among the first instances.</li>
%%% <li><code>{set_all_weights, Weight}</code> - Set the weight of
%%% all keys to <code>Weight</code>.</li>
%%% <li><code>{weight, {Key, Weight}}</code> - Set the weight of
%%% <code>Key</code> to weight <code>Weight</code>. A weight of zero
%%% means that a construct is not generated. Higher weights means that
%%% a construct i generated relatively often. Groups of weight keys
%%% follow. Notice that the weight of a key is relative to other
%%% keys of the same group. The weight of <code>small</code> needs
%%% to quite high to avoid generating too deeply nested abstract
%%% code.</li> <ul>
%%% <li>Atomic expressions (<code>small</code>): <code>atom, boolean,
%%% integer, string, char, float, nil</code></li>
%%% <li>Compound terms: <code>small, bitstring, list, tuple,
%%% map, 'fun'</code></li>
%%% <li>Map expressions (<code>map</code>): <code>build_map</code></li>
%%% <li>List expressions (<code>list</code>): <code>plain_list,
%%% cons</code></li>
%%% <li>Bitstrings (<code>bitstring</code>): <code>bits, bytes</code></li>
%%% <li>Function expressions (<code>'fun'</code>):
%%% <code>ext_mfa</code></li>
%%% </ul>
%%% </ul>
-spec term(Options :: [option()]) -> proper_types:type().
term(Opts) ->
PreOpts = [{set_all_weights, 0}],
Tags = [compound, small, bitstring, list, tuple, map, 'fun',
atom, boolean, integer, string, char, float, nil,
bits, bytes,
plain_list, cons,
build_map,
ext_mfa],
WOpts = ([{weight, {small, ?DEFAULT_SMALL_WEIGHT_TERM}}]
++ [{weight, {T, 1}} || T <- Tags]),
BadOpts = [Opt ||
{weight, {T, _}} = Opt <- Opts,
not lists:member(T, Tags)],
case BadOpts =:= [] andalso options(PreOpts ++ WOpts ++ Opts) of
false ->
erlang:error(badarg);
S0 ->
S1 = S0#gen_state{result_type = term},
S = eval_dependencies(S1),
?LET(E,
?SIZED(Size, compound(S#gen_state{size = Size})),
begin
#gen_state{functions = Funs, atom = AtomGen} = S,
[Term] = post_process([E], Funs, AtomGen, []),
Term
end)
end.
%%% @doc Returns abstract code of a module.
%%% The module has type declarations, functions, function specifications,
%%% and record declarations.
-spec module() -> proper_types:type().
module() ->
module([]).
%%% @doc Same as {@link module/0}, but accepts a list of options.
%%% === Options ===
%%%
%%% <ul>
%%% <li><code>{atom, {@link atom_fun()}}</code> - A atom generating
%%% function to replace the default.</li>
%%% <li><code>{char, {@link char_fun()}}</code> - A character generating
%%% function to replace the default. The function is used when
%%% generating strings and characters.</li>
%%% <li><code>{functions, [{Name, Arity}]}</code> - A list of FAs to
%%% be used as names of generated functions. The default is a small
%%% number of functions with a small number of arguments.</li>
%%% <li><code>{limit, [{Name, Limit}]}</code> - Set the limit of
%%% <code>Name</code> to <code>Limit</code>. The limit names are:
%%% <ul>
%%% <li><code>bin_elements</code> - Number of segments of a bitstring.</li>
%%% <li><code>list</code> - Number of elements of a plain list.</li>
%%% <li><code>map</code> - Number of associations of a map.</li>
%%% <li><code>string</code> - Number of characters of a string.</li>
%%% <li><code>tuple</code> - Number of elements of a tuple.</li>
%%% <li><code>body</code> - Number of clauses of a body.</li>
%%% <li><code>call_args</code> - Number of arguments of function call.</li>
%%% <li><code>catch_clauses</code> - Number of clauses of the
%%% <code>catch</code> part of a <code>try/catch</code>.</li>
%%% <li><code>clauses</code> - Number of clauses of <code>case</code>,
%%% the <code>of</code> part of <code>try/catch</code>, and
%%% <code>receive</code>.</li>
%%% <li><code>function_clauses</code> - Number of clauses of
%%% a function.</li>
%%% <li><code>function_constraints</code> - Number of constraints of
%%% a function specification.</li>
%%% <li><code>function_constraints</code> - Number of constraints of
%%% a function specification.</li>
%%% <li><code>function_types</code> - Number of types of
%%% an overloaded function specification.</li>
%%% <li><code>guard</code> - Number of guards of a clause.</li>
%%% <li><code>guard_tests</code> - Number of guard tests of a guard.</li>
%%% <li><code>if_clauses</code> - Number of clauses of
%%% <code>if</code>.</li>
%%% <li><code>tuple_types</code> - Number of types (elements)
%%% of tuple types.</li>
%%% <li><code>qualifiers</code> - Number of qualifiers
%%% of comprehensions.</li>
%%% <li><code>record_fields</code> - Number of fields of record
%%% declarations.</li>
%%% <li><code>tsl</code> - Number of elements of
%%% type specifier lists (of segments of bit syntax expressions).</li>
%%% <li><code>union_types</code> - Number of types of type
%%% union.s</li>
%%% </ul>
%%% </li>
%%% <li><code>{records, [{Name, [Field]}]}</code> - A list
%%% of record names with field names to be used as names of
%%% generated records. The default is a small number of records
%%% with a small number of fields.</li>
%%% <li><code>{types, [{Name, NumOfParameters}]}</code> - A list
%%% of TAs to be used as names of generated types. The default
%%% is a small number of types.</li>
%%% <li><code>{resize, boolean()}</code> - Use <code>?SIZED</code>
%%% to limit the size of the generated abstract code. With this
%%% option set to <code>false</code> (the default) big code
%%% may be generated among the first instances.</li>
%%% <li><code>{set_all_weights, Weight}</code> - Set the weight of
%%% all keys to <code>Weight</code>.</li>
%%% <li><code>{weight, {Key, Weight}}</code> - Set the weight of
%%% <code>Key</code> to weight <code>Weight</code>. A weight of zero
%%% means that a construct is not generated. Higher weights means that
%%% a construct i generated relatively often. Groups of weight keys
%%% follow. Notice that the weight of a key is relative to other
%%% keys of the same group. Also notice that some keys occur in
%%% more than one group, which makes it all more complicated. The
%%% weight of <code>small</code> needs to be quite high to avoid
%%% generating too deeply nested abstract code.</li>
%%% <ul>
%%% <li>Declarations: <code>record_decl, type_decl, function_decl,
%%% function_spec</code> (<code>type_decl</code> and
%%% <code>function_spec</code> are off by default)</li>
%%% <li>Atomic expressions (<code>small</code>): <code>atom, boolean,
%%% integer, string, char, float, nil, pat_var, var</code></li>
%%% <li>Compound expressions: <code>small, bitstring, list, tuple,
%%% map, match, binop, unop, record, 'case', block, 'if', 'fun',
%%% 'receive', 'try', 'catch', try_of, termcall, varcall, localcall,
%%% extcall</code> (<code>termcall</code> is off by default)</li>
%%% <li>Map expressions (<code>map</code>): <code>build_map,
%%% update_map</code></li>
%%% <li>List expressions (<code>list</code>): <code>plain_list, cons,
%%% lc</code></li>
%%% <li>Qualifiers (of <code>lc</code>): <code>lc_gen, blc_gen,
%%% lc_any_filter, lc_guard_filter</code></li>
%%% <li>Bitstrings (<code>bitstring</code>): <code>bits, blc,
%%% literal_bits</code></li>
%%% <li>Try after (<code>'try', try_of</code>): <code>no_try_after,
%%% try_after</code></li>
%%% <li>Catch clause exception types (<code>'catch'</code>):
%%% <code>no_eclass, any_eclass, lit_eclass, var_eclass,
%%% bad_eclass</code></li>
%%% <li>Receive timouts (<code>'receive'</code>): <code>
%%% lit_timeout, inf_timeout, var_timeout</code></li>
%%% <li>Function expressions (<code>'fun'</code>): <code>
%%% lambda, rec_lambda, local_mfa, ext_mfa, any_mfa</code></li>
%%% <li>Guards: <code>no_guard, yes_guard</code></li>
%%% <li>Guard test: <code>small, tuple, map, cons, plain_list, bits,
%%% binop, unop, record, guard_call, remote_guard_call</code></li>
%%% <li>Pattern: <code>small, match, tuple, cons, plain_list, bits,
%%% unop, binop, record, map_pattern, string_prefix</code></li>
%%% <li>Pattern variables (<code>pat_var</code>):
%%% <code>fresh_var, bound_var</code></li>
%%% <li>Record field initialization (the <code>_ = V</code> syntax):
%%% <code>yes_multi_field_init, no_multi_field_init</code></li>
%%% <li>String prefix (<code>string_prefix</code>): <code>
%%% nil, string, string_prefix_list</code></li>
%%% <li>Types: <code>annotated_type, atom, bitstring, 'fun',
%%% integer_range_type, nil, map, predefined_type, record,
%%% remote_type, singleton_integer_type, tuple, type_union,
%%% type_variable, user_defined_type</code></li>
%%% <li>Function specifications: <code>yes_constrained_function_type,
%%% no_constrained_function_type</code></li>
%%% <li>Overloaded function specifications: <code>
%%% no_overloaded, yes_overloaded</code></li>
%%% <li>Singleton integer type (<code>singleton_integer_type</code>):
%%% <code>integer, char, unop, binop</code></li>
%%% </ul>
%%% </ul>
-spec module(Options :: [option()]) -> proper_types:type().
module(Opts) when is_list(Opts) ->
case options(Opts) of
false ->
erlang:error(badarg);
State0 ->
TopTags = [record_decl, type_decl, function_decl, function_spec],
TagWeights = get_weights(TopTags, State0),
?DEBUG(" TagWeights ~p\n", [TagWeights]),
State = set_up(State0),
FormsL = [form(TW, TagWeights, State) || TW <- TagWeights],
Fs = ([{attribute, anno(), module, State#gen_state.module}]
++ lists:append(FormsL)),
#gen_state{functions = Funs, atom = AtomGen} = State,
true = length(Funs) > 0,
?SUCHTHAT(T,
?LET(P,
Fs,
post_process(P, Funs, AtomGen, [])),
ok_by_the_linter(forms, T))
end.
%%% @doc Returns abstract code of a guard. A guard is a sequence
%%% of guard tests.
-spec guard() -> proper_types:type().
guard() ->
guard([]).
%%% @doc Same as {@link guard/0}, but accepts a list of options. See
%%% {@link module/1} for a description of the options.
-spec guard(Options :: [option()]) -> proper_types:type().
guard(Opts) when is_list(Opts) ->
case options(Opts) of
false ->
erlang:error(badarg);
State0 ->
State1 = State0#gen_state{result_type = guard},
State = set_up(State1),
?LET(G,
?SIZED(Size, a_guard(State#gen_state{size = Size})),
begin
#gen_state{functions = Funs,
atom = AtomGen,
variables = Vars} = State,
[Guard] = post_process([G], Funs, AtomGen, Vars),
Guard
end)
end.
%%% @doc Returns abstract code of an expression.
-spec expr() -> proper_types:type().
expr() ->
expr([]).
%%% @doc Same as {@link expr/0}, but accepts a list of options. See
%%% {@link module/1} for a description of the options.
-spec expr(Options :: list()) -> proper_types:type().
expr(Opts) when is_list(Opts) ->
case options(Opts) of
false ->
erlang:error(badarg);
State0 ->
State1 = State0#gen_state{result_type = expr,
functions = []},
State2 = set_up(State1),
?SUCHTHAT(Expr,
?LET(E1,
?SIZED(Size,
begin
State = State2#gen_state{size = Size},
abstract_expr(State)
end),
begin
#gen_state{functions = Funs,
atom = AtomGen,
variables = Vars} = State2,
[E2] = post_process([E1], Funs, AtomGen, Vars),
E2
end),
ok_by_the_linter(expr, Expr))
end.
set_up(S0) ->
#gen_state{functions = Fs, records = Rs, types = Ts} = S0,
GRs = guard_records(Rs),
case {Fs, Rs, Ts} of
{[], [], []} ->
erlang:error(nothing_to_work_with);
_ ->
%% Give local functions higher weight.
AutoImported = auto_imported(),
FW = case length(Fs) of
0 ->
0; % not used
NumFs ->
max(1, round(length(AutoImported) / NumFs))
end,
FAWs = ([{FW, FA} || FA <- Fs]
++ [{1, FA} || FA <- AutoImported]),
S1 = S0#gen_state{functions_and_auto_imported = FAWs,
expr_bifs = guard_bifs() ++ expr_ops(),
guard_bifs = guard_bifs() ++ guard_ops(),
guard_records = GRs},
State = eval_dependencies(S1),
?DEBUG(" records: ~p\n", [State#gen_state.records]),
?DEBUG(" types: ~p\n", [State#gen_state.types]),
?DEBUG(" functions: ~p\n", [State#gen_state.functions]),
?DEBUG(" weights: ~p\n", [State#gen_state.weights]),
?DEBUG(" limits: ~p\n", [State#gen_state.limits]),
?DEBUG(" resize: ~p\n", [State#gen_state.resize]),
State
end.
%%% The fields of the chosen record are initiated with guard
%%% expressions, which means that the record can occur in a guard
%%% expression.
guard_records([]) ->
[];
guard_records([R | _]) ->
[R].
form({_Tag, 0}, _, _State) ->
[];
form({type_decl, _}, _, State) ->
TypeNames = State#gen_state.types,
Exports = [{attribute, anno(), export_type, TypeNames}],
Decls = [type_decl(State, TN) || TN <- TypeNames],
Exports ++ Decls;
form({record_decl, _}, _, State) ->
RecordNames = State#gen_state.records,
State = State#gen_state{records = RecordNames},
State1 = exclude_tags([fresh_var], State),
State2 = State1#gen_state{records = []},
declare_recs(RecordNames, State2);
form({function_decl, _}, TagWeights, State) ->
FunctionNames = State#gen_state.functions,
Exports = [{attribute, anno(), export, FunctionNames}],
State = State#gen_state{functions = FunctionNames},
{function_spec, SpecW} = lists:keyfind(function_spec, 1, TagWeights),
Decls = [begin
FD = function_decl(State, FN),
case SpecW of
0 ->
[FD];
_ ->
[function_spec(State, FN), FD]
end
end ||
FN <- FunctionNames],
Exports ++ lists:append(Decls);
form({function_spec, _}, _, _State) ->
[].
declare_recs([], _) ->
[];
declare_recs([Rec|Recs], S0) ->
S0_1 = exclude_tags([record], S0),
R = record_decl(S0_1, Rec),
S = S0#gen_state{records = [Rec|S0#gen_state.records]},
[R | declare_recs1(Recs, S)].
declare_recs1([], _S) ->
[];
declare_recs1([Rec|Recs], S0) ->
R = record_decl(S0, Rec),
S = S0#gen_state{records = [Rec|S0#gen_state.records]},
[R | declare_recs1(Recs, S)].
record_decl(S0, {RecName, Fs}=R) ->
?SIZED(Size,
begin
S = S0#gen_state{size = Size},
{'attribute', anno(), 'record',
{RecName, field_decls(S, R, Fs)}}
end).
field_decls(S, R, Fs) ->
[field_decl(S, R, F) || F <- Fs].
field_decl(S0, R, F) ->
S = case rec_init_guard_expr(S0, R) of
true ->
exclude_tags([complex_field_init], S0);
false ->
S0
end,
?LET(Field,
wunion([field_no_type, field_yes_type], S, ?FUNCTION_NAME),
set_field_name(Field, F)).
rec_init_guard_expr(S, R) ->
lists:member(R, S#gen_state.guard_records).
set_field_name({'typed_record_field', Field, AbstractType}, F) ->
{'typed_record_field', set_field_name(Field, F), AbstractType};
set_field_name({'record_field', A, field_name}, F) ->
{'record_field', A, lit_atom(F)};
set_field_name({'record_field', A, field_name, AbstractExpr}, F) ->
{'record_field', A, lit_atom(F), AbstractExpr}.
field_yes_type(S) ->
{'typed_record_field', field_no_type(S), abstract_type(S)}.
field_no_type(S) ->
wunion([field_no_init, field_yes_init], S, ?FUNCTION_NAME).
field_no_init(_S) ->
{'record_field', anno(), field_name()}.
field_yes_init(S) ->
{'record_field',
anno(),
field_name(),
case get_weight(complex_field_init, S) of
0 ->
guard_test(S);
1 ->
abstract_expr(S)
end}.
field_name() ->
field_name.
type_decl(S0, {TypeName, N}) ->
?SIZED(Size,
begin
S = S0#gen_state{size = Size},
Params = list_of_gen2(N, type_parameter()),
{'attribute', anno(), type_attr(),
%% Not affected by weight of 'variable'.
{TypeName, abstract_type(S), Params}}
end).
type_parameter() ->
a_variable(type_parameter).
type_attr() ->
proper_types:oneof(['type', 'opaque']).
function_spec(S0, {F, N}) ->
?SIZED(Size,
begin
S = S0#gen_state{size = Size},
{'attribute', anno(), spec_attr(),
{{F, N}, function_type_list(S, N)}}
end).
spec_attr() ->
'spec'.
%% oneof(['callback', 'spec']).
function_decl(S0, {F, N}) ->
?SIZED(Size,
begin
S = S0#gen_state{size = Size},
{'function', anno(), F, N, function_clause_seq(S, N)}
end).
abstract_expr(S) ->
compound(S).
compound(#gen_state{size = 0}=S) ->
wunion([small], S, ?FUNCTION_NAME); % assume weight(small) > 0
compound(S) ->
Tags = [small, bitstring, list, tuple, map, match, binop, unop,
record, 'case', block, 'if', 'fun', 'receive', 'try',
'catch', try_of, termcall, varcall, localcall, extcall],
wunion(Tags, resize(S), ?FUNCTION_NAME).
a_map(S, abstract_type) ->
map_type(S);
a_map(S, Where) ->
wunion([build_map, update_map], S, Where).
a_list(S, Where) ->
wunion([plain_list, cons, lc], S, Where).
%%% Assume 'plain' means 'proper' (see eqc:eqc_erlang_program).
plain_list(S, T) ->
?LET(L,
list_of_gen(T, get_limit(list, S)),
lists:foldr(fun(E, A) ->
{'cons', anno(), E, A}
end, nil(), L)).
cons(_S, T) ->
{'cons', anno(), T, T}.
nil(_S, abstract_type) ->
empty_list_type();
nil(_S, _Where) ->
nil().
nil() ->
{'nil', anno()}.
update_record(S, T) ->
?LET({RecName, Fields},
known_record(S),
{'record',
anno(),
abstract_expr(S),
RecName,
record_field_seq(S, T, Fields, update)}).
'catch'(S) ->
{'catch', anno(), abstract_expr(S)}.
termcall(_S, T) ->
{'tuple', anno(), [T, T]}.
varcall(S, T) ->
{'call', anno(), T, args(S)}.
localcall(S) ->
?LET({F, N},
local_function_or_auto_imported(S),
{'call', anno(), F, n_args(S, N)}).
extcall(S) ->
proper_types:weighted_union(
[{1, ?LAZY(any_extcall(S))},
{1, ?LAZY(known_extcall(S))}]).
any_extcall(S) ->
N = random_n_args(S),
{'call', anno(), remote_function(S), n_args(S, N)}.
known_extcall(S) ->
?LET({F, N},
expr_bif(S),
{'call', anno(),
{'remote', anno(), lit_atom('erlang'), lit_atom(F)},
n_args(S, N)}).
expr_bif(S) ->
proper_types:oneof(S#gen_state.expr_bifs).
n_args(S, N) ->
list_of_gen2(N, abstract_expr(S)).
args(S) ->
N = random_n_args(S),
list_of_gen2(N, abstract_expr(S)).
local_function_or_auto_imported(S) ->
?LET({F, N},
proper_types:weighted_union(S#gen_state.functions_and_auto_imported),
case lists:member({F, N}, S#gen_state.named_funs) of
true ->
{a_variable(F), N};
false ->
{lit_atom(F), N}
end).
remote_function(S) ->
{'remote', anno(), abstract_expr(S), abstract_expr(S)}.
lc(S) ->
{'lc', anno(), template(S), qualifier_seq(S)}.
blc(S) ->
LiteralW = get_weight(literal_bits, S),
wunion1(
[{1, ?LAZY({'bc', anno(), template(S), qualifier_seq(S)})},
{LiteralW, ?LAZY(literal_bc(S))}
]).
literal_bc(S) ->
%% The weight of `literal_bits' is not zero.
SBC = set_tag_weights([{in_literal_bc, 1}], S),
{'bc', anno(), bits(SBC, compound), qualifier_seq(SBC)}.
template(S) ->
abstract_expr(S).
qualifier_seq(S) ->
non_empty_list_of_gen(qualifier(S), get_limit(qualifiers, S)).
qualifier(S) ->
Tags = [lc_gen, blc_gen, lc_any_filter, lc_guard_filter],
wunion(Tags, S, ?FUNCTION_NAME).
lc_gen(S) ->
{'generate', anno(), pattern(S), abstract_expr(S)}.
blc_gen(S) ->
LiteralW = get_weight(literal_bits, S),
WildBitsW = wild_bits_weight(S),
?LET({Pattern, Expr},
{bits(S, pattern),
wunion1(
[{WildBitsW, ?LAZY(abstract_expr(S))},
{LiteralW, ?LAZY(bits(S, compound))}
])},
{'b_generate', anno(), Pattern, Expr}).
lc_any_filter(S) ->
abstract_expr(S).
lc_guard_filter(S) ->
guard_test(S).
block(S) ->
{'block', anno(), body(S)}.
'if'(S) ->
{'if', anno(), if_clause_seq(S)}.
if_clause_seq(S) ->
non_empty_list_of_gen(if_clause(S), get_limit(if_clauses, S)).
if_clause(S) ->
{'clause', anno(), [], if_guard_seq(S), body(S)}.
if_guard_seq(S) ->
list_of_gen(a_guard(S), get_limit(guard, S)).
'case'(S) ->
{'case', anno(), abstract_expr(S), clause_seq(S)}.
'try'(S) ->
NESeq = non_empty_catch_clause_seq(S),
Seq = catch_clause_seq(S),
?LET(After,
wunion([no_try_after, try_after], S, ?FUNCTION_NAME),
case After of
[] ->
{'try', anno(), body(S), [], NESeq, After};
_ ->
{'try', anno(), body(S), [], Seq, After}
end).
try_of(S) ->
NESeq = non_empty_catch_clause_seq(S),
Seq = catch_clause_seq(S),
?LET(After,
wunion([no_try_after, try_after], S, ?FUNCTION_NAME),
case After of
[] ->
{'try', anno(), body(S), clause_seq(S), NESeq, After};
_ ->
{'try', anno(), body(S), clause_seq(S), Seq, After}
end).
no_try_after(_S) ->
[].
try_after(S) ->
body(S).
catch_clause_seq(S) ->
list_of_gen(catch_clause(S), get_limit(catch_clauses, S)).
non_empty_catch_clause_seq(S) ->
non_empty_list_of_gen(catch_clause(S), get_limit(catch_clauses, S)).
catch_clause(S) ->
Tags = [no_eclass, any_eclass, lit_eclass, var_eclass, bad_eclass],
?LET({EClass, St},
{wunion(Tags, S, ?FUNCTION_NAME), stacktrace_variable(S)},
{'clause', anno(),
[{'tuple', anno(), [EClass, pattern(S), St]}],
clause_guard_seq(S),
body(S)}).
no_eclass(_S) ->
a_variable('_').
any_eclass(_S) ->
a_variable('_').
lit_eclass(_S) ->
proper_types:oneof([lit_atom('exit'),
lit_atom('error'),
lit_atom('throw')]).
var_eclass(S) ->
var(S). % atom is fallback
bad_eclass(_S) ->
lit_atom(bad_eclass).
stacktrace_variable(S) ->
%% weight(fresh_var) = 0 results in an anonymous variable.
fresh_var(S).
'receive'(S) ->
Ws = sum_weights([lit_timeout, inf_timeout, var_timeout], S),
AfterWs = min(Ws, 1),
proper_types:weighted_union(
[{1, ?LAZY(receive_no_after(S))},
{AfterWs, ?LAZY(receive_yes_after(S))}
]).
receive_no_after(S) ->
{'receive', anno(), clause_seq(S)}.
receive_yes_after(S) ->
?LET(Timeout,
wunion([lit_timeout, inf_timeout, var_timeout], S, ?FUNCTION_NAME),
{'receive', anno(), receive_after_clause_seq(S), Timeout, body(S)}).
receive_after_clause_seq(S) ->
list_of_gen(clause(S), get_limit(clauses, S)).
clause_seq(S) ->
non_empty_list_of_gen(clause(S), get_limit(clauses, S)).
lit_timeout(S) ->
an_integer(S).
inf_timeout(_S) ->
lit_atom('infinity').
var_timeout(S) ->
abstract_expr(S).
'fun'(S, abstract_type) ->
fun_type(S);
'fun'(S, Where) ->
Tags = [lambda, rec_lambda, local_mfa, ext_mfa, any_mfa],
wunion(Tags, S, Where).
lambda(S) ->
?LET({_F, N},
proper_types:oneof(S#gen_state.named_funs),
{'fun', anno(), {'clauses', function_clause_seq(S, N)}}).
rec_lambda(S) ->
?LET({F, N},
proper_types:oneof(S#gen_state.named_funs),
begin
FNW = {1, {F, N}}, % too low?
Functions = [FNW | S#gen_state.functions_and_auto_imported],
S1 = S#gen_state{functions_and_auto_imported = Functions},
{'named_fun', anno(), F, function_clause_seq(S1, N)}
end).
function_clause_seq(S, N) ->
NCl = random_n_clauses(S),
list_of_gen2(NCl, function_clause(S, N)).
random_n_clauses(S) ->
uniform(get_limit(function_clauses, S)).
function_clause(S, N) ->
{'clause', anno(), pattern_seq(S, N), clause_guard_seq(S), body(S)}.
local_mfa(S) ->
?LET({F, N},
local_function(S),
{'fun', anno(), {'function', F, N}}).
ext_mfa(S) ->
LW =
case
(S#gen_state.result_type =:= term orelse
get_weight(function_decl, S) > 0)
of
true ->
1;
false ->
0
end,
wunion1(
[{LW, ?LAZY(?LET({F, N},
local_function(S),
{'fun', anno(),
{'function', lit_atom(S#gen_state.module),
lit_atom(F),
lit_integer(N)}}))},
{1, ?LAZY({'fun', anno(),
{'function', any_module(S),
any_function(),
lit_integer(proper_types:arity())}})}
]).
any_mfa(S) ->
?SUCHTHAT(Fun_MFA,
?LET({M, F, A},
{var_or_atom(S), var_or_atom(S), var_or_arity(S)},
{'fun', anno(), {'function', M, F, A}}),
begin
{'fun', _, {'function', M, F, A}} = Fun_MFA,
is_var(M) orelse is_var(F) orelse is_var(A)
end).
var_or_atom(S) ->
var(S). % atom is fallback
var_or_arity(_S) ->
proper_types:oneof([a_variable(bound_var_or_an_arity),
lit_integer(proper_types:arity())]).
is_var({'var', _, _}) -> true;
is_var(_) -> false.