-
Notifications
You must be signed in to change notification settings - Fork 3.9k
/
rabbit_mqtt_processor.erl
2753 lines (2597 loc) · 122 KB
/
rabbit_mqtt_processor.erl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
%% This Source Code Form is subject to the terms of the Mozilla Public
%% License, v. 2.0. If a copy of the MPL was not distributed with this
%% file, You can obtain one at https://mozilla.org/MPL/2.0/.
%%
%% Copyright (c) 2007-2023 VMware, Inc. or its affiliates. All rights reserved.
%%
-module(rabbit_mqtt_processor).
-feature(maybe_expr, enable).
-export([info/2, init/4, process_packet/2,
terminate/3, handle_pre_hibernate/0,
handle_ra_event/2, handle_down/2, handle_queue_event/2,
proto_version_tuple/1, throttle/2, format_status/1,
remove_duplicate_client_id_connections/2,
remove_duplicate_client_id_connections/3,
update_trace/2, send_disconnect/2]).
-ifdef(TEST).
-export([get_vhost_username/1, get_vhost/3, get_vhost_from_user_mapping/2]).
-endif.
-export_type([state/0,
send_fun/0]).
-import(rabbit_mqtt_util, [mqtt_to_amqp/1,
amqp_to_mqtt/1,
ip_address_to_binary/1]).
-include_lib("kernel/include/logger.hrl").
-include_lib("rabbit_common/include/rabbit.hrl").
-include_lib("rabbit_common/include/rabbit_framing.hrl").
-include_lib("rabbit/include/amqqueue.hrl").
-include("rabbit_mqtt.hrl").
-include("rabbit_mqtt_packet.hrl").
-define(MAX_PERMISSION_CACHE_SIZE, 12).
-define(CONSUMER_TAG, <<"mqtt">>).
-define(QUEUE_TTL_KEY, <<"x-expires">>).
-define(AMQP_091_SHORT_STR_MAX_SIZE, 255).
-type send_fun() :: fun((iodata()) -> ok).
-type session_expiry_interval() :: non_neg_integer() | infinity.
-type subscriptions() :: #{topic_filter() => #mqtt_subscription_opts{}}.
-type topic_aliases() :: {Inbound :: #{topic() => pos_integer()},
Outbound :: #{topic() => pos_integer()}}.
-record(auth_state,
{user :: #user{},
authz_ctx :: #{binary() := binary()}
}).
-record(cfg,
{socket :: rabbit_net:socket(),
proto_ver :: protocol_version_atom(),
clean_start :: boolean(),
session_expiry_interval_secs :: session_expiry_interval(),
will_msg :: option(mqtt_msg()),
exchange :: rabbit_exchange:name(),
%% Set if client has at least one subscription with QoS 1.
queue_qos1 :: option(rabbit_amqqueue:name()),
%% Did the client ever sent us a PUBLISH packet?
published = false :: boolean(),
ssl_login_name :: none | binary(),
retainer_pid :: pid(),
delivery_flow :: flow | noflow,
trace_state :: rabbit_trace:state(),
prefetch :: non_neg_integer(),
vhost :: rabbit_types:vhost(),
client_id :: client_id(),
%% User Property set in the CONNECT packet.
user_prop :: user_property(),
conn_name :: option(binary()),
ip_addr :: inet:ip_address(),
port :: inet:port_number(),
peer_ip_addr :: inet:ip_address(),
peer_port :: inet:port_number(),
connected_at = os:system_time(millisecond) :: pos_integer(),
send_fun :: send_fun(),
%% Maximum MQTT packet size in bytes for packets sent from server to client.
max_packet_size_outbound :: max_packet_size(),
topic_alias_maximum_outbound :: non_neg_integer()
}).
-record(state,
{cfg :: #cfg{},
queue_states = rabbit_queue_type:init() :: rabbit_queue_type:state(),
%% Packet IDs published to queues but not yet confirmed.
unacked_client_pubs = rabbit_mqtt_confirms:init() :: rabbit_mqtt_confirms:state(),
%% Packet IDs published to MQTT subscribers but not yet acknowledged.
unacked_server_pubs = #{} :: #{packet_id() => QueueMsgId :: non_neg_integer()},
%% Packet ID of next PUBLISH packet (with QoS > 0) sent from server to client.
%% (Not to be confused with packet IDs sent from client to server which can be the
%% same IDs because client and server assign IDs independently of each other.)
packet_id = 1 :: packet_id(),
%% "A Session cannot have more than one Non‑shared Subscription with the same Topic Filter,
%% so the Topic Filter can be used as a key to identify the subscription within that Session."
%% [v5 4.8.1]
subscriptions = #{} :: subscriptions(),
auth_state = #auth_state{},
ra_register_state :: option(registered | {pending, reference()}),
%% quorum queues and streams whose soft limit has been exceeded
queues_soft_limit_exceeded = sets:new([{version, 2}]) :: sets:set(),
qos0_messages_dropped = 0 :: non_neg_integer(),
topic_aliases = {#{}, #{}} :: topic_aliases()
}).
-opaque state() :: #state{}.
%% NB: If init/4 returns an error, it must clean up itself because terminate/3 will not be called.
-spec init(ConnectPacket :: mqtt_packet(),
RawSocket :: rabbit_net:socket(),
ConnectionName :: binary(),
SendFun :: send_fun()) ->
{ok, state()} | {error, {socket_ends, any()} | reason_code()}.
init(#mqtt_packet{fixed = #mqtt_packet_fixed{type = ?CONNECT},
variable = ConnectPacket},
Socket, ConnName, SendFun) ->
%% Check whether peer closed the connection.
%% For example, this can happen when connection was blocked because of resource
%% alarm and client therefore disconnected due to client side CONNACK timeout.
case rabbit_net:socket_ends(Socket, inbound) of
{ok, SocketEnds} ->
process_connect(ConnectPacket, Socket, ConnName, SendFun, SocketEnds);
{error, Reason} ->
{error, {socket_ends, Reason}}
end.
process_connect(
#mqtt_packet_connect{
username = Username0,
password = Password0,
proto_ver = ProtoVer,
clean_start = CleanStart,
client_id = ClientId0,
keep_alive = KeepaliveSecs,
props = ConnectProps,
will_props = WillProps} = Packet,
Socket, ConnName0, SendFun, {PeerIp, PeerPort, Ip, Port}) ->
?LOG_DEBUG("Received a CONNECT, client ID: ~s, username: ~s, clean start: ~s, "
"protocol version: ~p, keepalive: ~p, property names: ~p",
[ClientId0, Username0, CleanStart, ProtoVer, KeepaliveSecs, maps:keys(ConnectProps)]),
SslLoginName = ssl_login_name(Socket),
Flow = case rabbit_misc:get_env(rabbit, mirroring_flow_control, true) of
true -> flow;
false -> noflow
end,
MaxPacketSize = maps:get('Maximum-Packet-Size', ConnectProps, ?MAX_PACKET_SIZE),
TopicAliasMax = persistent_term:get(?PERSISTENT_TERM_TOPIC_ALIAS_MAXIMUM),
TopicAliasMaxOutbound = min(maps:get('Topic-Alias-Maximum', ConnectProps, 0), TopicAliasMax),
{ok, MaxSessionExpiry} = application:get_env(?APP_NAME, max_session_expiry_interval_seconds),
SessionExpiry =
case {ProtoVer, CleanStart} of
{5, _} ->
%% "If the Session Expiry Interval is absent the value 0 is used."
case maps:get('Session-Expiry-Interval', ConnectProps, 0) of
?UINT_MAX ->
%% "If the Session Expiry Interval is 0xFFFFFFFF (UINT_MAX),
%% the Session does not expire."
MaxSessionExpiry;
Seconds ->
min(Seconds, MaxSessionExpiry)
end;
{_, _CleanSession = true} ->
%% "Setting Clean Start to 1 and a Session Expiry Interval of 0, is equivalent
%% to setting CleanSession to 1 in the MQTT Specification Version 3.1.1."
0;
{_, _CleanSession = false} ->
%% The following sentence of the MQTT 5 spec 3.1.2.11.2 is wrong:
%% "Setting Clean Start to 0 and no Session Expiry Interval, is equivalent to
%% setting CleanSession to 0 in the MQTT Specification Version 3.1.1."
%% Correct is:
%% "CleanStart=0 and SessionExpiry=0xFFFFFFFF (UINT_MAX) for MQTT 5.0 would
%% provide the same as CleanSession=0 for 3.1.1."
%% see https://issues.oasis-open.org/projects/MQTT/issues/MQTT-538
%% Therefore, we use the maximum allowed session expiry interval.
MaxSessionExpiry
end,
Result0 =
maybe
ok ?= check_protocol_version(ProtoVer),
ok ?= check_extended_auth(ConnectProps),
{ok, ClientId} ?= ensure_client_id(ClientId0, CleanStart, ProtoVer),
{ok, {Username1, Password}} ?= check_credentials(Username0, Password0, SslLoginName, PeerIp),
{VHostPickedUsing, {VHost, Username2}} = get_vhost(Username1, SslLoginName, Port),
?LOG_DEBUG("MQTT connection ~s picked vhost using ~s", [ConnName0, VHostPickedUsing]),
ok ?= check_vhost_exists(VHost, Username2, PeerIp),
ok ?= check_vhost_alive(VHost),
ok ?= check_vhost_connection_limit(VHost),
{ok, User = #user{username = Username}} ?= check_user_login(VHost, Username2, Password,
ClientId, PeerIp, ConnName0),
ok ?= check_user_connection_limit(Username),
{ok, AuthzCtx} ?= check_vhost_access(VHost, User, ClientId, PeerIp),
ok ?= check_user_loopback(Username, PeerIp),
rabbit_core_metrics:auth_attempt_succeeded(PeerIp, Username, mqtt),
{ok, RaRegisterState} ?= register_client_id(VHost, ClientId, CleanStart, WillProps),
{ok, WillMsg} ?= make_will_msg(Packet),
{TraceState, ConnName} = init_trace(VHost, ConnName0),
ok = rabbit_mqtt_keepalive:start(KeepaliveSecs, Socket),
S = #state{
cfg = #cfg{socket = Socket,
proto_ver = proto_integer_to_atom(ProtoVer),
clean_start = CleanStart,
session_expiry_interval_secs = SessionExpiry,
ssl_login_name = SslLoginName,
delivery_flow = Flow,
trace_state = TraceState,
prefetch = prefetch(ConnectProps),
conn_name = ConnName,
ip_addr = Ip,
port = Port,
peer_ip_addr = PeerIp,
peer_port = PeerPort,
send_fun = SendFun,
exchange = rabbit_misc:r(VHost, exchange, rabbit_mqtt_util:env(exchange)),
retainer_pid = rabbit_mqtt_retainer_sup:start_child_for_vhost(VHost),
vhost = VHost,
client_id = ClientId,
user_prop = maps:get('User-Property', ConnectProps, []),
will_msg = WillMsg,
max_packet_size_outbound = MaxPacketSize,
topic_alias_maximum_outbound = TopicAliasMaxOutbound},
auth_state = #auth_state{
user = User,
authz_ctx = AuthzCtx},
ra_register_state = RaRegisterState},
ok ?= clear_will_msg(S),
{ok, S}
end,
Result = case Result0 of
{ok, State0 = #state{}} ->
process_connect(State0);
{error, _} = Err0 ->
Err0
end,
case Result of
{ok, SessPresent, State = #state{}} ->
Props0 = #{'Maximum-QoS' => ?QOS_1,
'Topic-Alias-Maximum' => TopicAliasMax,
'Maximum-Packet-Size' => persistent_term:get(
?PERSISTENT_TERM_MAX_PACKET_SIZE_AUTHENTICATED),
'Shared-Subscription-Available' => 0,
'Session-Expiry-Interval' => case SessionExpiry of
infinity -> ?UINT_MAX;
Secs -> Secs
end},
Props = case {ClientId0, ProtoVer} of
{<<>>, 5} ->
%% "If the Client connects using a zero length Client Identifier, the Server
%% MUST respond with a CONNACK containing an Assigned Client Identifier."
maps:put('Assigned-Client-Identifier', State#state.cfg#cfg.client_id, Props0);
_ ->
Props0
end,
send_conn_ack(?RC_SUCCESS, SessPresent, ProtoVer, SendFun, MaxPacketSize, Props),
{ok, State};
{error, ConnectReasonCode} = Err
when is_integer(ConnectReasonCode) ->
%% If a server sends a CONNACK packet containing a non-zero return
%% code it MUST set Session Present to 0 [MQTT-3.2.2-4].
SessPresent = false,
send_conn_ack(ConnectReasonCode, SessPresent, ProtoVer, SendFun, MaxPacketSize, #{}),
Err
end.
-spec prefetch(ConnectProperties :: properties()) -> pos_integer().
prefetch(Props) ->
%% "If the Receive Maximum value is absent then its value defaults to 65,535" [v5 3.1.2.11.3]
ReceiveMax = maps:get('Receive-Maximum', Props, ?TWO_BYTE_INTEGER_MAX),
%% "The Server might choose to send fewer than Receive Maximum messages to the Client
%% without receiving acknowledgement, even if it has more than this number of messages
%% available to send." [v5 3.3.4]
min(rabbit_mqtt_util:env(prefetch), ReceiveMax).
-spec send_conn_ack(reason_code(), boolean(), protocol_version(), send_fun(),
max_packet_size(), properties()) -> ok.
send_conn_ack(ConnectReasonCode, SessPresent, ProtoVer, SendFun, MaxPacketSize, Props) ->
Code = case ProtoVer of
5 -> ConnectReasonCode;
_ -> connect_reason_code_to_return_code(ConnectReasonCode)
end,
Packet = #mqtt_packet{fixed = #mqtt_packet_fixed{type = ?CONNACK},
variable = #mqtt_packet_connack{
session_present = SessPresent,
code = Code,
props = Props}},
_ = send(Packet, ProtoVer, SendFun, MaxPacketSize),
ok.
%% "Connect Reason Code" used in v5:
%% https://docs.oasis-open.org/mqtt/mqtt/v5.0/os/mqtt-v5.0-os.html#_Toc3901079
%% "Connect Return Code" used in v3 and v4:
%% http://docs.oasis-open.org/mqtt/mqtt/v3.1.1/os/mqtt-v3.1.1-os.html#_Toc385349257
-spec connect_reason_code_to_return_code(reason_code()) ->
connect_return_code().
connect_reason_code_to_return_code(?RC_SUCCESS) ->
?CONNACK_ACCEPT;
connect_reason_code_to_return_code(?RC_UNSUPPORTED_PROTOCOL_VERSION) ->
?CONNACK_UNACCEPTABLE_PROTO_VER;
connect_reason_code_to_return_code(?RC_CLIENT_IDENTIFIER_NOT_VALID) ->
?CONNACK_ID_REJECTED;
connect_reason_code_to_return_code(?RC_BAD_USER_NAME_OR_PASSWORD) ->
?CONNACK_BAD_CREDENTIALS;
connect_reason_code_to_return_code(RC) when RC =:= ?RC_NOT_AUTHORIZED orelse
RC =:= ?RC_QUOTA_EXCEEDED ->
?CONNACK_NOT_AUTHORIZED;
connect_reason_code_to_return_code(_) ->
%% Everything else gets mapped to the most generic Connect Return Code.
?CONNACK_SERVER_UNAVAILABLE.
process_connect(State0) ->
maybe
{ok, QoS0SessPresent, State1} ?= handle_clean_start_qos0(State0),
{ok, SessPresent, State2} ?= handle_clean_start_qos1(QoS0SessPresent, State1),
{ok, State} ?= init_subscriptions(SessPresent, State2),
rabbit_networking:register_non_amqp_connection(self()),
self() ! connection_created,
{ok, SessPresent, State}
else
{error, _} = Error ->
unregister_client(State0),
Error
end.
-spec process_packet(mqtt_packet(), state()) ->
{ok, state()} |
{stop, {disconnect, {client_initiated, SendWill :: boolean()} | server_initiated}, state()} |
{error, Reason :: term(), state()}.
process_packet(Packet = #mqtt_packet{fixed = #mqtt_packet_fixed{type = Type}},
State = #state{auth_state = #auth_state{}})
when Type =/= ?CONNECT ->
process_request(Type, Packet, State).
-spec process_request(packet_type(), mqtt_packet(), state()) ->
{ok, state()} |
{stop, {disconnect, {client_initiated, SendWill :: boolean()} | server_initiated}, state()} |
{error, Reason :: term(), state()}.
process_request(?PUBACK,
#mqtt_packet{variable = #mqtt_packet_puback{packet_id = PacketId,
reason_code = ReasonCode}},
#state{unacked_server_pubs = U0,
queue_states = QStates0,
cfg = #cfg{queue_qos1 = QName}} = State) ->
case maps:take(PacketId, U0) of
{QMsgId, U} ->
SettleOp = case is_success(ReasonCode) of
true ->
complete;
false ->
%% 'discard' instead of 'requeue' due to v5 spec:
%% "If PUBACK or PUBREC is received containing a Reason Code of 0x80
%% or greater the corresponding PUBLISH packet is treated as
%% acknowledged, and MUST NOT be retransmitted [MQTT-4.4.0-2]."
discard
end,
case rabbit_queue_type:settle(QName, SettleOp, ?CONSUMER_TAG, [QMsgId], QStates0) of
{ok, QStates, Actions} ->
message_acknowledged(QName, State),
{ok, handle_queue_actions(Actions, State#state{unacked_server_pubs = U,
queue_states = QStates})};
{protocol_error, _ErrorType, _Reason, _ReasonArgs} = Err ->
{error, Err, State}
end;
error ->
{ok, State}
end;
process_request(?PUBLISH,
#mqtt_packet{fixed = #mqtt_packet_fixed{qos = ?QOS_2}},
State = #state{cfg = #cfg{proto_ver = ?MQTT_PROTO_V5,
client_id = ClientId}}) ->
%% MQTT 5 spec 3.3.1.2 QoS
%% "If the Server included a Maximum QoS in its CONNACK response
%% to a Client and it receives a PUBLISH packet with a QoS greater than this
%% then it uses DISCONNECT with Reason Code 0x9B (QoS not supported)."
?LOG_WARNING("Received a PUBLISH with QoS2. Disconnecting MQTT client ~ts", [ClientId]),
send_disconnect(?RC_QOS_NOT_SUPPORTED, State),
{stop, {disconnect, server_initiated}, State};
process_request(?PUBLISH,
#mqtt_packet{
fixed = #mqtt_packet_fixed{qos = Qos,
retain = Retain,
dup = Dup},
variable = Variable = #mqtt_packet_publish{packet_id = PacketId},
payload = Payload},
State0 = #state{unacked_client_pubs = U,
cfg = #cfg{proto_ver = ProtoVer}}) ->
case process_topic_alias_inbound(Variable, State0) of
{ok, Topic, Props, State1} ->
EffectiveQos = maybe_downgrade_qos(Qos),
rabbit_global_counters:messages_received(ProtoVer, 1),
State = maybe_increment_publisher(State1),
Msg = #mqtt_msg{retain = Retain,
qos = EffectiveQos,
topic = Topic,
dup = Dup,
packet_id = PacketId,
payload = Payload,
props = Props},
case EffectiveQos of
?QOS_0 ->
publish_to_queues_with_checks(Msg, State);
?QOS_1 ->
rabbit_global_counters:messages_received_confirm(ProtoVer, 1),
case rabbit_mqtt_confirms:contains(PacketId, U) of
false ->
publish_to_queues_with_checks(Msg, State);
true ->
%% Client re-sent this PUBLISH packet.
%% We already sent this message to target queues awaiting confirmations.
%% Hence, we ignore this re-send.
{ok, State}
end
end;
{error, ReasonCode} ->
send_disconnect(ReasonCode, State0),
{stop, {disconnect, server_initiated}, State0}
end;
process_request(?SUBSCRIBE,
#mqtt_packet{
variable = #mqtt_packet_subscribe{
packet_id = SubscribePktId,
subscriptions = Subscriptions},
payload = undefined},
#state{cfg = #cfg{proto_ver = ProtoVer}} = State0) ->
?LOG_DEBUG("Received a SUBSCRIBE with subscription(s) ~p", [Subscriptions]),
{ResultRev, RetainedRev, State1} =
lists:foldl(
fun(_Subscription, {[{error, _} = E | _] = L, R, S}) ->
%% Once a subscription failed, mark all following subscriptions
%% as failed instead of creating bindings because we are going
%% to close the client connection anyway.
{[E | L], R, S};
(#mqtt_subscription{topic_filter = TopicFilter,
options = Opts0 = #mqtt_subscription_opts{
qos = Qos0,
retain_handling = Rh}},
{L0, R0, S0}) ->
QoS = maybe_downgrade_qos(Qos0),
Opts = Opts0#mqtt_subscription_opts{qos = QoS},
L = [QoS | L0],
R1 = [{TopicFilter, QoS} | R0],
case S0#state.subscriptions of
#{TopicFilter := Opts} ->
R = if Rh =:= 0 -> R1;
Rh > 0 -> R0
end,
{L, R, S0};
_ ->
maybe
{ok, Q} ?= ensure_queue(QoS, S0),
QName = amqqueue:get_name(Q),
BindingArgs = binding_args_for_proto_ver(ProtoVer, TopicFilter, Opts),
ok ?= add_subscription(TopicFilter, BindingArgs, QName, S0),
ok ?= maybe_delete_old_subscription(TopicFilter, Opts, S0),
Subs = maps:put(TopicFilter, Opts, S0#state.subscriptions),
S1 = S0#state{subscriptions = Subs},
maybe_increment_consumer(S0, S1),
R = if Rh < 2 -> R1;
Rh =:= 2 -> R0
end,
case self_consumes(Q) of
false ->
case consume(Q, QoS, S1) of
{ok, S2} ->
{L, R, S2};
{error, _} = E1 ->
{[E1 | L0], R, S1}
end;
true ->
{L, R, S1}
end
else
{error, _} = E2 -> {[E2 | L0], R0, S0}
end
end
end, {[], [], State0}, Subscriptions),
ReasonCodesRev = subscribe_result_to_reason_codes(ResultRev, ProtoVer),
Reply = #mqtt_packet{fixed = #mqtt_packet_fixed{type = ?SUBACK},
variable = #mqtt_packet_suback{
packet_id = SubscribePktId,
reason_codes = lists:reverse(ReasonCodesRev)}},
_ = send(Reply, State1),
case hd(ResultRev) of
{error, _} ->
{error, subscribe_error, State1};
_ ->
State = send_retained_messages(lists:reverse(RetainedRev), State1),
{ok, State}
end;
process_request(?UNSUBSCRIBE,
#mqtt_packet{variable = #mqtt_packet_unsubscribe{packet_id = PacketId,
topic_filters = TopicFilters},
payload = undefined},
State0) ->
?LOG_DEBUG("Received an UNSUBSCRIBE for topic filter(s) ~p", [TopicFilters]),
{ReasonCodes, State} =
lists:foldl(
fun(TopicFilter, {L, #state{subscriptions = Subs0,
cfg = #cfg{proto_ver = ProtoVer}} = S0}) ->
case maps:take(TopicFilter, Subs0) of
{Opts, Subs} ->
BindingArgs = binding_args_for_proto_ver(ProtoVer, TopicFilter, Opts),
case delete_subscription(
TopicFilter, BindingArgs, Opts#mqtt_subscription_opts.qos, S0) of
ok ->
S = S0#state{subscriptions = Subs},
maybe_decrement_consumer(S0, S),
{[?RC_SUCCESS | L], S};
{error, access_refused} ->
{[?RC_NOT_AUTHORIZED | L], S0};
{error, _} ->
{[?RC_UNSPECIFIED_ERROR | L], S0}
end;
error ->
{[?RC_NO_SUBSCRIPTION_EXISTED | L], S0}
end
end, {[], State0}, TopicFilters),
Reply = #mqtt_packet{fixed = #mqtt_packet_fixed{type = ?UNSUBACK},
variable = #mqtt_packet_unsuback{
packet_id = PacketId,
reason_codes = lists:reverse(ReasonCodes)}},
_ = send(Reply, State),
{ok, State};
process_request(?PINGREQ, #mqtt_packet{}, State = #state{cfg = #cfg{client_id = ClientId}}) ->
?LOG_DEBUG("Received a PINGREQ from client ID ~s", [ClientId]),
Reply = #mqtt_packet{fixed = #mqtt_packet_fixed{type = ?PINGRESP}},
_ = send(Reply, State),
?LOG_DEBUG("Sent a PINGRESP to client ID ~s", [ClientId]),
{ok, State};
process_request(?DISCONNECT,
#mqtt_packet{variable = #mqtt_packet_disconnect{reason_code = Rc,
props = Props}},
#state{cfg = #cfg{session_expiry_interval_secs = CurrentSEI} = Cfg} = State0) ->
?LOG_DEBUG("Received a DISCONNECT with reason code ~b and properties ~p", [Rc, Props]),
RequestedSEI = case maps:find('Session-Expiry-Interval', Props) of
{ok, ?UINT_MAX} ->
%% "If the Session Expiry Interval is 0xFFFFFFFF (UINT_MAX),
%% the Session does not expire."
infinity;
{ok, Secs} ->
Secs;
error ->
%% "If the Session Expiry Interval is absent, the Session
%% Expiry Interval in the CONNECT packet is used."
CurrentSEI
end,
State =
case CurrentSEI of
RequestedSEI ->
State0;
0 when RequestedSEI > 0 ->
%% "If the Session Expiry Interval in the CONNECT packet was zero, then it is a Protocol
%% Error to set a non-zero Session Expiry Interval in the DISCONNECT packet sent by the
%% Client. If such a non-zero Session Expiry Interval is received by the Server, it does
%% not treat it as a valid DISCONNECT packet. The Server uses DISCONNECT with Reason
%% Code 0x82 (Protocol Error) as described in section 4.13."
%% The last sentence does not make sense because the client already closed the network
%% connection after it sent us the DISCONNECT. Hence, we do not reply with another
%% DISCONNECT.
?LOG_WARNING("MQTT protocol error: Ignoring requested Session Expiry "
"Interval ~p in DISCONNECT because it was 0 in CONNECT.",
[RequestedSEI]),
State0;
_ ->
%% "The session expiry interval can be modified at disconnect."
{ok, MaxSEI} = application:get_env(?APP_NAME, max_session_expiry_interval_seconds),
NewSEI = min(RequestedSEI, MaxSEI),
lists:foreach(fun(QName) ->
update_session_expiry_interval(QName, NewSEI)
end, existing_queue_names(State0)),
State0#state{cfg = Cfg#cfg{session_expiry_interval_secs = NewSEI}}
end,
%% "If the Network Connection is closed without the Client first sending a DISCONNECT packet with Reason
%% Code 0x00 (Normal disconnection) [...] the Will Message is published." [v5 3.14]
SendWill = Rc > ?RC_NORMAL_DISCONNECTION,
{stop, {disconnect, {client_initiated, SendWill}}, State}.
-spec maybe_update_session_expiry_interval(amqqueue:amqqueue(), session_expiry_interval()) -> ok.
maybe_update_session_expiry_interval(Queue, Expiry) ->
OldExpiry = case rabbit_misc:table_lookup(amqqueue:get_arguments(Queue), ?QUEUE_TTL_KEY) of
undefined ->
infinity;
{long, Millis} ->
Millis div 1000
end,
case OldExpiry of
Expiry ->
ok;
_ ->
update_session_expiry_interval(amqqueue:get_name(Queue), Expiry)
end.
-spec update_session_expiry_interval(rabbit_amqqueue:name(), session_expiry_interval()) -> ok.
update_session_expiry_interval(QName, Expiry) ->
Fun = fun(Q) ->
Args0 = amqqueue:get_arguments(Q),
Args = if Expiry =:= infinity ->
proplists:delete(?QUEUE_TTL_KEY, Args0);
true ->
rabbit_misc:set_table_value(
Args0, ?QUEUE_TTL_KEY, long, timer:seconds(Expiry))
end,
amqqueue:set_arguments(Q, Args)
end,
case rabbit_amqqueue:update(QName, Fun) of
not_found ->
ok;
Q ->
ok = rabbit_queue_type:policy_changed(Q) % respects queue args
end.
check_protocol_version(V)
when V =:= 3 orelse V =:= 4 ->
ok;
check_protocol_version(5) ->
case rabbit_feature_flags:is_enabled(mqtt_v5) of
true ->
ok;
false ->
?LOG_ERROR("Rejecting MQTT 5.0 connection because feature flag mqtt_v5 is disabled"),
{error, ?RC_UNSUPPORTED_PROTOCOL_VERSION}
end.
check_extended_auth(#{'Authentication-Method' := Method}) ->
%% In future, we could support SASL via rabbit_auth_mechanism
%% as done by rabbit_reader and rabbit_stream_reader.
?LOG_ERROR("Extended authentication (method ~p) is not supported", [Method]),
{error, ?RC_BAD_AUTHENTICATION_METHOD};
check_extended_auth(_) ->
ok.
check_credentials(Username, Password, SslLoginName, PeerIp) ->
case creds(Username, Password, SslLoginName) of
nocreds ->
auth_attempt_failed(PeerIp, <<>>),
?LOG_ERROR("MQTT login failed: no credentials provided"),
{error, ?RC_BAD_USER_NAME_OR_PASSWORD};
{invalid_creds, {undefined, Pass}} when is_binary(Pass) ->
auth_attempt_failed(PeerIp, <<>>),
?LOG_ERROR("MQTT login failed: no username is provided"),
{error, ?RC_BAD_USER_NAME_OR_PASSWORD};
{invalid_creds, {User, undefined}} when is_binary(User) ->
auth_attempt_failed(PeerIp, User),
?LOG_ERROR("MQTT login failed for user '~p': no password provided", [User]),
{error, ?RC_BAD_USER_NAME_OR_PASSWORD};
{UserBin, PassBin} ->
{ok, {UserBin, PassBin}}
end.
-spec ensure_client_id(client_id(), boolean(), protocol_version()) ->
{ok, client_id()} | {error, reason_code()}.
ensure_client_id(<<>>, _CleanStart = false, ProtoVer)
when ProtoVer < 5 ->
?LOG_ERROR("MQTT client ID must be provided for non-clean session in MQTT v~b", [ProtoVer]),
{error, ?RC_CLIENT_IDENTIFIER_NOT_VALID};
ensure_client_id(<<>>, _, _) ->
{ok, rabbit_data_coercion:to_binary(
rabbit_misc:base64url(
rabbit_guid:gen_secure()))};
ensure_client_id(ClientId, _, _)
when is_binary(ClientId) ->
{ok, ClientId}.
-spec register_client_id(rabbit_types:vhost(), client_id(), boolean(), properties()) ->
{ok, RaRegisterState :: undefined | {pending, reference()}} |
{error, ConnectErrorCode :: pos_integer()}.
register_client_id(VHost, ClientId, CleanStart, WillProps)
when is_binary(VHost), is_binary(ClientId) ->
%% Always register client ID in pg.
PgGroup = {VHost, ClientId},
ok = pg:join(persistent_term:get(?PG_SCOPE), PgGroup, self()),
case rabbit_mqtt_ff:track_client_id_in_ra() of
true ->
case collector_register(ClientId) of
{ok, Corr} ->
%% Ra node takes care of removing duplicate client ID connections.
{ok, {pending, Corr}};
{error, _} = Err ->
%% e.g. this node was removed from the MQTT cluster members
?LOG_ERROR("MQTT connection failed to register client ID ~s in vhost ~s in Ra: ~p",
[ClientId, VHost, Err]),
{error, ?RC_IMPLEMENTATION_SPECIFIC_ERROR}
end;
false ->
%% "If a Network Connection uses a Client Identifier of an existing Network Connection to
%% the Server, the Will Message for the exiting connection is sent unless the new
%% connection specifies Clean Start of 0 and the Will Delay is greater than zero."
%% [v5 3.1.3.2.2]
Args = case {CleanStart, WillProps} of
{false, #{'Will-Delay-Interval' := I}} when I > 0 ->
[PgGroup, self(), false];
_ ->
[PgGroup, self()]
end,
ok = erpc:multicast([node() | nodes()],
?MODULE,
remove_duplicate_client_id_connections,
Args),
{ok, undefined}
end.
%% Once feature flag mqtt_v5 becomes required, the caller should always pass SendWill to this
%% function (remove_duplicate_client_id_connections/2) so that we can delete this function.
-spec remove_duplicate_client_id_connections(
{rabbit_types:vhost(), client_id()}, pid()) -> ok.
remove_duplicate_client_id_connections(PgGroup, PidToKeep) ->
remove_duplicate_client_id_connections(PgGroup, PidToKeep, true).
-spec remove_duplicate_client_id_connections(
{rabbit_types:vhost(), client_id()}, pid(), boolean()) -> ok.
remove_duplicate_client_id_connections(PgGroup, PidToKeep, SendWill) ->
try persistent_term:get(?PG_SCOPE) of
PgScope ->
Pids = pg:get_local_members(PgScope, PgGroup),
lists:foreach(fun(Pid) ->
gen_server:cast(Pid, {duplicate_id, SendWill})
end, Pids -- [PidToKeep])
catch _:badarg ->
%% MQTT supervision tree on this node not fully started
ok
end.
-spec init_trace(rabbit_types:vhost(), binary()) ->
{rabbit_trace:state(), undefined | binary()}.
init_trace(VHost, ConnName0) ->
TraceState = rabbit_trace:init(VHost),
ConnName = case rabbit_trace:enabled(TraceState) of
true ->
ConnName0;
false ->
%% Tracing does not need connection name.
%% Use less memmory by setting to undefined.
undefined
end,
{TraceState, ConnName}.
-spec update_trace(binary(), state()) -> state().
update_trace(ConnName0, State = #state{cfg = Cfg0 = #cfg{vhost = VHost}}) ->
{TraceState, ConnName} = init_trace(VHost, ConnName0),
Cfg = Cfg0#cfg{trace_state = TraceState,
conn_name = ConnName},
State#state{cfg = Cfg}.
-spec self_consumes(amqqueue:amqqueue()) -> boolean().
self_consumes(Queue) ->
case amqqueue:get_type(Queue) of
?QUEUE_TYPE_QOS_0 ->
false;
_ ->
lists:any(fun(Consumer) ->
element(1, Consumer) =:= self()
end, rabbit_amqqueue:consumers(Queue))
end.
handle_clean_start_qos0(State) ->
handle_clean_start(false, ?QOS_0, State).
handle_clean_start_qos1(QoS0SessPresent, State) ->
handle_clean_start(QoS0SessPresent, ?QOS_1, State).
handle_clean_start(_, QoS, State = #state{cfg = #cfg{clean_start = true}}) ->
%% "If the Server accepts a connection with CleanSession set to 1, the Server
%% MUST set Session Present to 0 in the CONNACK packet [MQTT-3.2.2-1].
SessPresent = false,
case get_queue(QoS, State) of
{error, _} ->
{ok, SessPresent, State};
{ok, Q0} ->
QName = amqqueue:get_name(Q0),
case delete_queue(QName, State) of
ok ->
{ok, SessPresent, State};
{error, access_refused} ->
{error, ?RC_NOT_AUTHORIZED}
end
end;
handle_clean_start(SessPresent, QoS,
State0 = #state{cfg = #cfg{clean_start = false,
session_expiry_interval_secs = Expiry}}) ->
case get_queue(QoS, State0) of
{error, _} ->
%% Queue will be created later when client subscribes.
{ok, SessPresent, State0};
{ok, Q} ->
case consume(Q, QoS, State0) of
{ok, State} ->
maybe_update_session_expiry_interval(Q, Expiry),
{ok, _SessionPresent = true, State};
{error, access_refused} ->
{error, ?RC_NOT_AUTHORIZED};
{error, _Reason} ->
{error, ?RC_IMPLEMENTATION_SPECIFIC_ERROR}
end
end.
-spec get_queue(qos(), state()) ->
{ok, amqqueue:amqqueue()} |
{error, not_found | {resource_locked, amqqueue:amqqueue()}}.
get_queue(QoS, State) ->
QName = queue_name(QoS, State),
case rabbit_amqqueue:lookup(QName) of
{ok, Q} = Ok ->
try rabbit_amqqueue:check_exclusive_access(Q, self()) of
ok ->
Ok
catch
exit:#amqp_error{name = resource_locked} ->
%% This can happen when same client ID re-connects
%% while its old connection is not yet closed.
{error, {resource_locked, Q}}
end;
{error, not_found} = Err ->
Err
end.
-spec subscribe_result_to_reason_codes(nonempty_list(qos() | {error, term()}),
protocol_version_atom()) ->
nonempty_list(reason_code()).
subscribe_result_to_reason_codes(SubscribeResult, ProtoVer) ->
lists:map(fun(QoS) when is_integer(QoS) ->
QoS;
({error, Reason}) when ProtoVer =:= ?MQTT_PROTO_V5 ->
case Reason of
access_refused -> ?RC_NOT_AUTHORIZED;
queue_limit_exceeded -> ?RC_QUOTA_EXCEEDED;
_ -> ?RC_UNSPECIFIED_ERROR
end;
({error, _}) ->
?RC_UNSPECIFIED_ERROR
end, SubscribeResult).
-spec queue_name(qos(), state()) -> rabbit_amqqueue:name().
queue_name(?QOS_1, #state{cfg = #cfg{queue_qos1 = #resource{kind = queue} = Name}}) ->
Name;
queue_name(QoS, #state{cfg = #cfg{client_id = ClientId,
vhost = VHost}}) ->
QNameBin = rabbit_mqtt_util:queue_name_bin(ClientId, QoS),
rabbit_misc:r(VHost, queue, QNameBin).
%% Returns names of queues that exist in the database.
-spec existing_queue_names(state()) -> [rabbit_amqqueue:name()].
existing_queue_names(State) ->
QNames = [queue_name(QoS, State) || QoS <- [?QOS_0, ?QOS_1]],
lists:filter(fun rabbit_amqqueue:exists/1, QNames).
%% To save memory, we only store the queue_qos1 value in process state if there is a QoS 1 subscription.
%% We store it in the process state such that we don't have to build the binary on every PUBACK we receive.
maybe_set_queue_qos1(?QOS_1, State = #state{cfg = Cfg = #cfg{queue_qos1 = undefined}}) ->
State#state{cfg = Cfg#cfg{queue_qos1 = queue_name(?QOS_1, State)}};
maybe_set_queue_qos1(_, State) ->
State.
-spec init_subscriptions(boolean(), state()) ->
{ok, state()} | {error, reason_code()}.
init_subscriptions(_SessionPresent = _SubscriptionsPresent = true,
State = #state{cfg = #cfg{proto_ver = ProtoVer}}) ->
maybe
{ok, SubsQos0} ?= init_subscriptions0(?QOS_0, State),
{ok, SubsQos1} ?= init_subscriptions0(?QOS_1, State),
Subs = maps:merge(SubsQos0, SubsQos1),
rabbit_global_counters:consumer_created(ProtoVer),
%% Cache subscriptions in process state to avoid future mnesia:match_object/3 queries.
{ok, State#state{subscriptions = Subs}}
end;
init_subscriptions(_, State) ->
{ok, State}.
-spec init_subscriptions0(qos(), state()) ->
{ok, subscriptions()} | {error, reason_code()}.
init_subscriptions0(QoS, State0 = #state{cfg = #cfg{proto_ver = ProtoVer,
exchange = Exchange}}) ->
Bindings =
rabbit_binding:list_for_source_and_destination(
Exchange,
queue_name(QoS, State0),
%% Querying table rabbit_route is catastrophic for CPU usage.
%% Querying table rabbit_reverse_route is acceptable because
%% the source exchange is always the same in the MQTT plugin whereas
%% the destination queue is different for each MQTT client and
%% rabbit_reverse_route is sorted by destination queue.
_Reverse = true),
try
Subs = lists:foldl(
fun(#binding{key = Key,
args = Args = []},
Acc) ->
Opts = #mqtt_subscription_opts{qos = QoS},
TopicFilter = amqp_to_mqtt(Key),
case ProtoVer of
?MQTT_PROTO_V5 ->
%% session upgrade
NewBindingArgs = binding_args_for_proto_ver(ProtoVer, TopicFilter, Opts),
ok = recreate_subscription(TopicFilter, Args, NewBindingArgs, QoS, State0);
_ ->
ok
end,
maps:put(TopicFilter, Opts, Acc);
(#binding{key = Key,
args = Args},
Acc) ->
Opts0 = #mqtt_subscription_opts{} = lists:keyfind(mqtt_subscription_opts, 1, Args),
TopicFilter = amqp_to_mqtt(Key),
Opts = case ProtoVer of
?MQTT_PROTO_V5 ->
Opts0;
_ ->
%% session downgrade
ok = recreate_subscription(TopicFilter, Args, [], QoS, State0),
#mqtt_subscription_opts{qos = QoS}
end,
maps:put(TopicFilter, Opts, Acc)
end, #{}, Bindings),
{ok, Subs}
catch throw:{error, Reason} ->
Rc = case Reason of
access_refused -> ?RC_NOT_AUTHORIZED;
_Other -> ?RC_IMPLEMENTATION_SPECIFIC_ERROR
end,
{error, Rc}
end.
recreate_subscription(TopicFilter, OldBindingArgs, NewBindingArgs, Qos, State) ->
case add_subscription(TopicFilter, NewBindingArgs, Qos, State) of
ok ->
case delete_subscription(TopicFilter, OldBindingArgs, Qos, State) of
ok ->
ok;
{error, _} = Err ->
throw(Err)
end;
{error, _} = Err ->
throw(Err)
end.
-spec hand_off_to_retainer(pid(), topic(), mqtt_msg()) -> ok.
hand_off_to_retainer(RetainerPid, Topic0, Msg = #mqtt_msg{payload = Payload}) ->
Topic = amqp_to_mqtt(Topic0),
if Payload =:= <<>> ->
rabbit_mqtt_retainer:clear(RetainerPid, Topic);
true ->
rabbit_mqtt_retainer:retain(RetainerPid, Topic, Msg)
end.
-spec send_retained_messages([{topic_filter(), qos()}], state()) -> state().
send_retained_messages(Subscriptions, State) ->
lists:foldl(fun({TopicFilter, Qos}, S) ->
send_retained_message(TopicFilter, Qos, S)
end, State, Subscriptions).
-spec send_retained_message(topic_filter(), qos(), state()) -> state().
send_retained_message(TopicFilter0, SubscribeQos,
State0 = #state{packet_id = PacketId0,
cfg = #cfg{retainer_pid = RPid}}) ->
TopicFilter = amqp_to_mqtt(TopicFilter0),
case rabbit_mqtt_retainer:fetch(RPid, TopicFilter) of
undefined ->
State0;
#mqtt_msg{qos = MsgQos,
retain = Retain,
payload = Payload,
props = Props0} ->
Qos = effective_qos(MsgQos, SubscribeQos),
%% Wildcards are currently not supported when fetching retained
%% messages. Therefore, TopicFilter must must be a topic name.
{Topic, Props, State1} = process_topic_alias_outbound(TopicFilter, Props0, State0),
{PacketId, State} = case Qos of
?QOS_0 ->
{undefined, State1};
?QOS_1 ->
{PacketId0,
State1#state{packet_id = increment_packet_id(PacketId0)}}
end,
Packet = #mqtt_packet{
fixed = #mqtt_packet_fixed{
type = ?PUBLISH,
qos = Qos,
dup = false,
retain = Retain
},
variable = #mqtt_packet_publish{
packet_id = PacketId,
topic_name = Topic,
props = Props
},
payload = Payload},
_ = send(Packet, State),
State
end.
clear_will_msg(#state{cfg = #cfg{vhost = Vhost,
client_id = ClientId}} = State) ->
QNameBin = rabbit_mqtt_util:queue_name_bin(ClientId, will),
QName = #resource{virtual_host = Vhost, kind = queue, name = QNameBin},