How to get struct-type?

[zaoqi]

(struct-type-of v) → (or/c struct-type? #f)
Returns #f if (struct? v) is #f

[shhyou]

How about struct-info?

https://docs.racket-lang.org/reference/inspectors.html#%28def._%28%28quote._~23~25kernel%29._struct-info%29%29

[zaoqi]

@shhyou

> (struct s (v))
> (struct-info (s 0))
#f
#t
> 

[bennn]

Right, but you need a more powerful inspector:

#lang racket/base

(struct s (v) #:inspector (make-inspector))
(struct-info (s 0))
;; #<struct-type:s>
;; #f

The page @shhyou linked to explains inspectors:
https://docs.racket-lang.org/reference/inspectors.html

[zaoqi]

@bennn How do I change a defined structure?

[bennn]

I'm not sure what you mean.

Do you want to get the struct type of a struct that's defined in another file & doesn't use #:inspector ? I'm not sure how to do that. If you could:

1. save (current-inspector)
2. set (current-inspector (make-inspector))
3. evaluate the struct definitions

then it'd be possible to use the saved inspector with struct-type. But I really don't know how to do step 3.

[jackfirth]

If you're using a #:transparent struct instead of an opaque one, you don't need a more powerful inspector:

> (struct s (v) #:transparent)
> (struct-info (s 0))
#<struct-type:s>
#f

If your struct isn't transparent, you probably shouldn't be reflecting over it with struct-type unless you're making something like a debugger or other program instrumentation tool. But if you are, using a more powerful inspector is a reasonable approach.

[zaoqi]

I'm implementing a DSL that needs to compare the two struct types.

[zaoqi]

@bennn

> (current-inspector (make-inspector))
> (struct x (a))
> (x 0)
#<x>
> (struct-info (x 0))
#f
#t
> 

[mflatt]

@zaoqi Here's how to do steps 1 and 4 in @bennn's suggestion:

> (define insp (current-inspector))
> (current-inspector (make-inspector))
> (struct x (a))
> (struct-info (x 0))
#f
#t
> (parameterize ([current-inspector insp])
     (struct-info (x 0)))
#<struct-type:x>
#f

[shhyou]

@zaoqi Why not just use #:transparent for your structs?

[shhyou]

Or perhaps provide your own struct to the user in the library

[zaoqi]

@shhyou Can I redifine struct?

[shhyou]

Something like this (simply shadows the struct binding from #lang)

; my-lib.rkt
#lang racket
(provide (rename-out [my-struct struct]))
(define-syntax my-struct
  (syntax-rules ()
    [(_ x ...) (struct x ... #:transparent)]))

#lang racket
(require "my-lib.rkt")
(struct x ())
(struct-info (x))

[zaoqi]

@shhyou

(define (struct-type-eq? x y)
  (let-values ([(tx _x) (struct-info x)] [(ty _y) (struct-info y)])
    (equal? tx ty)))

Can I define it like this?