Make life of custom role creators easier

- accept a `List` is role body return value
- tolerate no return value from the body
- otherwise try to throw something sensible

src/Perl6/Metamodel/ParametricRoleHOW.nqp

@@ -166,8 +166,37 @@ class Perl6::Metamodel::ParametricRoleHOW
                 my $type_env;
                 my $error;
                 try {
-                    my @result := $!body_block(|@pos_args, |%named_args);
-                    $type_env := nqp::ifnull(Perl6::Metamodel::Configuration.type_env_from(@result[1]), @result[1]);
+                    my $result := $!body_block(|@pos_args, |%named_args);
+                    if nqp::isconcrete($result) {
+                        # Support for bodies returning Raku's positional
+                        my $original-result := $result;
+                        if nqp::can($result, 'FLATTENABLE_LIST') {
+                            $result := $result.FLATTENABLE_LIST();
+                        }
+                        if nqp::islist($result) && nqp::elems($result) == 2 {
+                            $type_env :=
+                                nqp::ifnull(Perl6::Metamodel::Configuration.type_env_from($result[1]), $result[1]);
+                        }
+                        else {
+                            Perl6::Metamodel::Configuration.throw_or_die(
+                                'X::Role::BodyReturn',
+                                "Role '" ~ $obj.HOW.name($obj) ~ "' body block is expected to return a list, got '"
+                                    ~ $original-result.HOW.name($original-result) ~ "' instead",
+                                :role($obj),
+                                :expected("a list of two elements"),
+                                :got( (nqp::isconcrete($original-result)
+                                        ?? "an object instance" !! "a type object")
+                                      ~ " of type " ~ $original-result.HOW.name($original-result) ))
+                        }
+                    }
+                    else {
+                        # When there is no concrete return value from the body use empty TypeEnv then.
+                        # Assuming that no Raku-generated role body would return an undefined value, especially those
+                        # that belong to the core; and assuming that the only period of time when TypeEnv is not
+                        # available on the configuration class is the early stages of the CORE.c compilation, – we can
+                        # safely skip the check for nullness. Can't we?
+                        $type_env := Perl6::Metamodel::Configuration.type_env_type().new;
+                    }
                     CATCH {
                         $error := $!;
                     }
@@ -179,8 +208,7 @@ class Perl6::Metamodel::ParametricRoleHOW
                         "Could not instantiate role '" ~ self.name($obj)
                             ~ "':\n" ~ ($exception || nqp::getmessage($error)),
                         :role($obj),
-                        :exception($error)
-                    )
+                        :exception($error) )
                 }
 
                 # Use it to build a concrete role.

src/core.c/Exception.rakumod

@@ -1850,6 +1850,17 @@ my class X::Role::Instantiation is Exception does X::Wrapper {
     }
 }
 
+my class X::Role::BodyReturn is Exception {
+    has Mu $.role is required;
+    has Str:D $.expected is required;
+    has Str:D $.got is required;
+    method message() {
+        "Bad return value of role '" ~ $!role.^name
+            ~ "' body block; expected " ~ $.expected
+            ~ " but got " ~ $.got
+    }
+}
+
 my class X::Role::Initialization is Exception {
     method message() { "Can only supply an initialization value for a role if it has a single public attribute, but this is not the case for '{$.role.^name}'" }
 }