add xUnit compatible output option

README.md

@@ -10,6 +10,8 @@ declare function string-equality-example()
 };
 ```
 
+**xray** can output test results as HTML, XML, xUnit compatible XML, and plain text, so should be simple to integrate with your favourite build/ci server.
+
 ## Getting Started
 * Clone/copy/symlink xray into the root directory of your project e.g.<br/>
 `git clone git://github.com/robwhitby/xray.git`  

src/output/html.xsl

@@ -93,7 +93,7 @@
                                             '&modules=', encode-for-uri($module-pattern), 
                                             '&tests=', encode-for-uri($test-pattern), 
                                             '&format=')"/>
-      View results as <a href="{$qs}xml">xml</a>&#160;<a href="{$qs}text">text</a>
+      View results as <a href="{$qs}xml">xml</a>&#160;|&#160;<a href="{$qs}xunit">xUnit</a>&#160;|&#160;<a href="{$qs}text">text</a>
     </p>
   </xsl:template>
 

src/output/xunit.xsl

@@ -0,0 +1,63 @@
+<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
+                xmlns:xray="http://github.com/robwhitby/xray"
+                xmlns:xdmp="http://marklogic.com/xdmp"
+                xmlns:error="http://marklogic.com/xdmp/error"
+                version="2.0"
+                exclude-result-prefixes="xray xdmp error">
+
+  <xsl:output method="xml" omit-xml-declaration="yes" indent="yes"/>
+
+  <xsl:param name="test-dir"/>
+  <xsl:param name="module-pattern"/>
+  <xsl:param name="test-pattern"/>
+
+  <xsl:template match="xray:tests">
+    <testsuites 
+        name="{$test-dir}" 
+        errors="{count(//(error:error|xray:test[@result='error']))}" 
+        failures="{count(//xray:test[@result='failed'])}" 
+        skipped="{count(//xray:test[@result='ignored'])}" 
+        tests="{count(//xray:test)}">
+      <xsl:apply-templates/>
+    </testsuites>
+  </xsl:template>
+
+  <xsl:template match="xray:module">
+    <testsuite 
+        name="{@path}"
+        classname="{@path}"
+        errors="{count((error:error|xray:test[@result='error']))}" 
+        failures="{count(xray:test[@result='failed'])}" 
+        skipped="{count(xray:test[@result='ignored'])}" 
+        tests="{count(xray:test)}">
+      <xsl:apply-templates/>
+    </testsuite>
+  </xsl:template>
+
+  <xsl:template match="xray:test">
+    <testcase 
+        name="{@name}" 
+        classname="{../@path}"
+        assertions="{count(xray:assert)}" 
+        status="{@result}">
+      <xsl:apply-templates/>
+      <xsl:if test="@result = 'ignored'">
+        <skipped/>
+      </xsl:if>
+    </testcase>
+  </xsl:template>
+
+  <xsl:template match="xray:assert[@result = 'failed']">
+    <failure type="{@test}">expected: <xsl:value-of select="xdmp:quote(xray:expected/node())"/>, actual: <xsl:value-of select="xdmp:quote(xray:actual/node())"/>
+    </failure>
+  </xsl:template>
+
+  <xsl:template match="xray:assert"/>
+
+  <xsl:template match="error:error">
+    <error message="{error:message}">
+      <xsl:copy-of select="."/>
+    </error>
+  </xsl:template>
+
+</xsl:stylesheet>

src/utils.xqy

@@ -64,7 +64,7 @@ declare function transform(
 {
   if ($format eq "text") then xdmp:set-response-content-type("text/plain") else ()
   ,
-  if ($format = ("html", "text"))
+  if ($format ne "xml")
   then 
     let $params := map:map()
     let $_ := map:put($params, "test-dir", $test-dir)