-
Notifications
You must be signed in to change notification settings - Fork 1
/
clock.asm
573 lines (478 loc) · 7.98 KB
/
clock.asm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
; VDC Clock Demo
; Version 1
;
; Copyright (c) 2020 Samuel A. Falvo II
; This software is licensed under MPLv2 terms.
;
; This code implements a simple clock. It is a vehicle by
; which I may learn to invoke CP/M system calls; but, also,
; by which I may also develop Z80 code for working with my
; VDC-II core.
;
; This program is the first Z80 code I've written in maybe
; 30 years. Forgive any style demerits; it's been a while.
defc RVS = 40h
defc BLACK = 00h
defc RED = 09h
defc YELLOW = 0Ch
defc PAUSED_FLAG = RED
include "ue.asm"
include "log.asm"
include "bdos.asm"
include "vdc.asm"
AppInitialize:
; Initialize our custom keyboard handler.
ld hl,ClockKbdHandler
ld (kbdHandler),hl
; Clear the screen.
ld hl,0
ld (r0),hl ; left
ld (r1),hl ; top
ld l,80
ld (r2),hl ; right
ld l,30
ld (r3),hl ; bottom
ld l,20h
ld (r4),hl ; Fill screen with spaces
call VdcDrawTextSlab
; Print our title bar.
ld hl,33 ; Left edge of title text
ld (r0),hl
ld l,h ; Top edge
ld (r1),hl
ld hl,helloMsg ; Text to print in title bar
ld (r2),hl
ld hl,helloLen
ld (r3),hl
call VdcPrintRawText
; Color the title bar.
ld hl,0
ld (r0),hl ; left
ld (r1),hl ; top
ld l,80
ld (r2),hl ; right
ld l,1
ld (r3),hl ; bottom
ld l,46h
ld (r4),hl ; Make titlebar cyan, reverse video
call VdcDrawAttrSlab
; Color the rest of the screen.
ld hl,0
ld (r0),hl ; left
inc hl
ld (r1),hl ; top
ld l,80
ld (r2),hl ; right
ld l,30
ld (r3),hl ; bottom
ld l,06h
ld (r4),hl ; Make everything cyan
call VdcDrawAttrSlab
; Set paused flag and reset the clock to 00:00:00.
ld a,PAUSED_FLAG
ld (paused),a
xor a
ld (h0),a
ld (h1),a
ld (m0),a
ld (m1),a
ld (s0),a
ld (s1),a
ld hl,0
ld (vdcVSHandler),hl
; Draw clock
call _RedrawPaused
call _RedrawClock
; Show the user we're now running by printing our banner.
; Return to the User Environment's event loop once we've
; finished.
ld de,helloMsg
jp BdosPrintString
.helloMsg
defm "VDC Clock Demo"
defc helloLen = ASMPC - helloMsg
defm 13,10
defm "Press Q to exit.",13,10
defm "$"
ClockKbdHandler:
cp 'q'
jr z,doQuit
cp 'Q'
jr z,doQuit
cp 'p'
jr z,TogglePause
cp 'P'
jr z,TogglePause
push af
ld de,keyPressedMsg
call BdosPrintString
pop af
ld e,a
call BdosConsoleOut
ld de,crMsg
jp BdosPrintString
.doQuit jp ueReturn
keyPressedMsg:
defm "You just pressed this key: $"
crMsg: defm " ",13,"$"
TogglePause:
ld a,(paused)
xor a,PAUSED_FLAG
ld (paused),a
jr z,notpaused
ld hl,0
ld (vdcVSHandler),hl
jp _RedrawPaused
notpaused:
ld hl,ClockVSYNCHandler
ld (vdcVSHandler),hl
jp _RedrawPaused
; Approximately 60 times a second, this procedure should be called by the UE event loop.
; It's triggered off the VGA's vertical sync pulse.
;
; Unfortunately, the asynchronous nature of the UE's event loop and probably my lack-luster
; programming skills means that we miss a lot of VSYNCs in the process. So, after carefully
; observing program behavior, it looks like we need to respond after only 16-ish frames that
; we can actually see, ignoring the remainder that fly by unnoticed.
;
; Note that the 16 frames limit is calibrated against *my* RC2014, which uses a Z80 processor
; running at 7.3728MHz. If you're running a Z180, Z280, Z380, or Rabbit processor of some
; kind, you'll need to customize this calibration for your hardware.
ClockVSYNCHandler:
ld a,(frames)
inc a
cp 17 ; In a perfect world, this would be 60. But, ...
jr z,bumpS0
ld (frames),a
ret
bumpS0:
xor a
ld (frames),a
ld a,(s0)
inc a
cp 10
jr z,bumpS1
ld (s0),a
jp _RedrawClock
bumpS1:
xor a
ld (s0),a
ld a,(s1)
inc a
cp 6
jr z,bumpM0
ld (s1),a
jp _RedrawClock
bumpM0:
xor a
ld (s1),a
ld a,(m0)
inc a
cp 10
jr z,bumpM1
ld (m0),a
jp _RedrawClock
bumpM1:
xor a
ld (m0),a
ld a,(m1)
inc a
cp 6
jr z,bumpH0
ld (m1),a
jp _RedrawClock
bumpH0:
xor a
ld (m1),a
ld a,(h0)
inc a
cp 10
jr z,bumpH1
ld (h0),a
jp _RedrawClock
bumpH1:
xor a
ld (h0),a
ld a,(h1)
inc a
cp 10
jr z,rollOver
ld (h1),a
jp _RedrawClock
rollOver:
xor a
ld (h1),a
jp _RedrawClock
_RedrawPaused:
ld hl,32
ld (r0),hl
ld hl,12
ld (r1),hl
ld hl,pausedMsg
ld (r2),hl
ld hl,pausedLen
ld (r3),hl
call VdcPrintRawText
ld hl,32
ld (r0),hl
ld de,pausedLen
add hl,de
ld (r2),hl
ld hl,12
ld (r1),hl
inc hl
ld (r3),hl
ld a,(paused)
ld (r4),a
jp VdcDrawAttrSlab
.pausedMsg
defm " P A U S E D "
defc pausedLen = ASMPC - pausedMsg
_RedrawClock:
ld hl,2
ld (digitT),hl
dec hl
dec hl
ld (digitL),hl
ld a,(h1)
call dodig
ld a,(h0)
call dodig
call docolon
ld a,(m1)
call dodig
ld a,(m0)
call dodig
ld a,(s1)
or a,30H
ld (secondsBuf+2),a
ld a,(s0)
or a,30H
ld (secondsBuf+3),a
ld hl,(digitL)
inc hl
inc hl
ld (r0),hl
ld hl,10
ld (r1),hl
ld hl,secondsBuf
ld (r2),hl
ld hl,4
ld (r3),hl
call VdcPrintRawText
ld hl,(digitL)
inc hl
inc hl
ld (r0),hl
inc hl
inc hl
inc hl
inc hl
ld (r2),hl
ld hl,10
ld (r1),hl
inc hl
ld (r3),hl
ld a,YELLOW
ld (r4),a
jp VdcDrawAttrSlab
.secondsBuf
defm ": XX"
.dodig and a,0Fh
ld e,a
ld d,0
ld hl,segtab
add hl,de
ld a,(hl)
ld (digitState),a
call _DrawLED
ld hl,(digitL)
ld de,14
add hl,de
ld (digitL),hl
ret
.docolon
ld hl,(digitL)
ld (r0),hl
inc hl
inc hl
ld (r2),hl
ld hl,(digitT)
inc hl
inc hl
ld (r1),hl
ld de,5
add hl,de
ld (r3),hl
ld a,YELLOW | RVS
ld (r4),a
call VdcDrawAttrSlab
ld hl,(digitT)
inc hl
inc hl
inc hl
ld (r1),hl
inc hl
inc hl
inc hl
ld (r3),hl
ld a,BLACK
ld (r4),a
call VdcDrawAttrSlab
ld hl,(digitL)
inc hl
inc hl
inc hl
inc hl
ld (digitL),hl
ret
.segtab defb @00111111 ; 0 0gfedcba
defb @00000110 ; 1
defb @01011011 ; 2
defb @01001111 ; 3
defb @01100110 ; 4
defb @01101101 ; 5
defb @01111101 ; 6
defb @00000111 ; 7
defb @01111111 ; 8
defb @01101111 ; 9
_DrawLED:
call _DrawA
call _DrawB
call _DrawC
call _DrawD
call _DrawE
call _DrawF
jp _DrawG
_DrawA:
call lfrt1
call topbot0
ld a,(digitState) ; R4 = attribute to draw with
bit 0,a
.drawseg
jr nz,drawa0
xor a
jr drawa1
.drawa0 ld a,YELLOW | RVS
.drawa1 ld (r4),a
jp VdcDrawAttrSlab
_DrawB:
call lfrt2
call topbot1
ld a,(digitState)
bit 1,a
jr drawseg
_DrawC:
call lfrt2
call topbot3
ld a,(digitState)
bit 2,a
jr drawseg
_DrawD:
call lfrt1
call topbot4
ld a,(digitState)
bit 3,a
jr drawseg
_DrawE:
call lfrt0
call topbot3
ld a,(digitState)
bit 4,a
jr drawseg
_DrawF:
call lfrt0
call topbot1
ld a,(digitState)
bit 5,a
jr drawseg
_DrawG:
call lfrt1
call topbot2
ld a,(digitState)
bit 6,a
jr drawseg
; 7 segment LEDs can be broken up into three horizontal columns (left, middle, and right),
; and 5 rows. Each lfrtX procedure configures the left and right edges to use for the
; three columns. Correspondingly, the topbotX procedures do the same for the different
; rows.
.lfrt0
ld hl,(digitL) ; R0 = left edge of segment
ld (r0),hl
inc hl ; R2 = right edge
inc hl
ld (r2),hl
ret
.lfrt1
ld hl,(digitL) ; R0 = left edge of segment
inc hl
inc hl
ld (r0),hl
ld de,8 ; R2 = right edge of segment
add hl,de
ld (r2),hl
ret
.lfrt2
ld hl,(digitL) ; R0 = left edge of segment
ld de,10
add hl,de
ld (r0),hl
inc hl ; R2 = right edge
inc hl
ld (r2),hl
ret
.topbot0
ld hl,(digitT) ; R1 = top edge of segment
ld (r1),hl
inc hl
ld (r3),hl ; R3 = bottom edge of segment
ret
.topbot1
ld hl,(digitT) ; R1 = top edge of segment
inc hl
ld (r1),hl
inc hl
inc hl
inc hl
ld (r3),hl ; R3 = bottom edge of segment
ret
.topbot2
ld hl,(digitT) ; R1 = top edge of segment
ld de,4
add hl,de
ld (r1),hl
inc hl
ld (r3),hl ; R3 = bottom edge of segment
ret
.topbot3
ld hl,(digitT) ; R1 = top edge of segment
ld de,5
add hl,de
ld (r1),hl
inc hl
inc hl
inc hl
ld (r3),hl ; R3 = bottom edge of segment
ret
.topbot4
ld hl,(digitT) ; R1 = top edge of segment
ld de,8
add hl,de
ld (r1),hl
inc hl
ld (r3),hl ; R3 = bottom edge of segment
ret
.digitState
defb 0
.digitL
defw 0
.digitT
defw 0
.paused defb 0
.h0 defb 0
.m0 defb 0
.s0 defb 0
.h1 defb 0
.m1 defb 0
.s1 defb 0
.frames defb 0