-
Notifications
You must be signed in to change notification settings - Fork 8
/
Slash.pm
1940 lines (1566 loc) · 55.7 KB
/
Slash.pm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
# This code is a part of Slash, and is released under the GPL.
# Copyright 1997-2005 by Open Source Technology Group. See README
# and COPYING for more information, or see http://slashcode.com/.
# $Id$
package Slash;
# BENDER: It's time to kick some shiny metal ass!
=head1 NAME
Slash - the BEAST
=head1 SYNOPSIS
use Slash; # figure the rest out ;-)
=head1 DESCRIPTION
Slash is the code that runs Slashdot.
=head1 FUNCTIONS
=cut
use strict; # ha ha ha ha ha!
use Symbol 'gensym';
use Slash::Constants ':people';
use Slash::DB;
use Slash::Display;
use Slash::Utility;
use Fcntl;
use File::Spec::Functions;
use Time::Local;
use Time::HiRes;
use base 'Exporter';
use vars qw($VERSION @EXPORT);
$VERSION = '2.005000'; # v2.5.0
# note: those last two lines of functions will be moved elsewhere
@EXPORT = qw(
constrain_score
getData
gensym
dispComment displayStory displayThread dispStory
getOlderStories getOlderDays moderatorCommentLog printComments
);
# this is the worst damned warning ever, so SHUT UP ALREADY!
$SIG{__WARN__} = sub { warn @_ unless $_[0] =~ /Use of uninitialized value/ };
# BENDER: Fry, of all the friends I've had ... you're the first.
########################################################
# Behold, the beast that is threaded comments
sub selectComments {
my($discussion, $cid, $options) = @_;
my $slashdb = getCurrentDB();
my $reader = getObject('Slash::DB', { db_type => 'reader' });
my $constants = getCurrentStatic();
my $user = getCurrentUser();
my $form = getCurrentForm();
my($min, $max) = ($constants->{comment_minscore},
$constants->{comment_maxscore});
my $num_scores = $max - $min + 1;
my $comments; # One bigass hashref full of comments
for my $x (0..$num_scores-1) {
$comments->{0}{totals}[$x] = 0;
}
my $y = 0;
for my $x ($min..$max) {
$comments->{0}{total_keys}{$x} = $y;
$y++;
}
# When we pull comment text from the DB, we only want to cache it if
# there's a good chance we'll use it again.
my $cache_read_only = 0;
$cache_read_only = 1 if $discussion->{type} eq 'archived';
$cache_read_only = 1 if timeCalc($discussion->{ts}, '%s') <
time - 3600 * $constants->{comment_cache_max_hours};
my $thisComment;
my $gcfu_opt = {
cache_read_only => $cache_read_only,
one_cid_only => $options->{one_cid_only},
};
if ($options->{force_read_from_master}) {
$thisComment = $slashdb->getCommentsForUser($discussion->{id}, $cid, $gcfu_opt);
} else {
$thisComment = $reader->getCommentsForUser($discussion->{id}, $cid, $gcfu_opt);
}
if (!$thisComment) {
_print_cchp($discussion);
return ( {}, 0 );
}
my $max_uid = $reader->countUsers({ max => 1 });
my $reasons = $reader->getReasons();
# We first loop through the comments and assign bonuses and
# and such.
for my $C (@$thisComment) {
# By setting pid to zero, we remove the threaded
# relationship between the comments. Don't ignore threads
# in forums, or when viewing a single comment (cid > 0)
$C->{pid} = 0 if $user->{commentsort} > 3
&& $cid == 0
&& $user->{mode} ne 'parents'; # Ignore Threads
# I think instead we want something like this... (not this
# precisely, it munges up other things).
# I'm still looking into how to get parent links and
# children to show up properly in flat mode. - Jamie 2002/07/30
# $user->{state}{noreparent} = 1 if $user->{commentsort} > 3;
$C->{points} = _get_points($C, $user, $min, $max, $max_uid, $reasons);
# Let us fill the hash range for hitparade
$comments->{0}{totals}[$comments->{0}{total_keys}{$C->{points}}]++;
}
# If we are sorting by highest score we resort to figure in bonuses
if ($user->{commentsort} == 3) {
@$thisComment = sort {
$b->{points} <=> $a->{points} || $a->{cid} <=> $b->{cid}
} @$thisComment;
} elsif ($user->{commentsort} == 1 || $user->{commentsort} == 5) {
@$thisComment = sort {
$b->{cid} <=> $a->{cid}
} @$thisComment;
} else {
@$thisComment = sort {
$a->{cid} <=> $b->{cid}
} @$thisComment;
}
# This loop mainly takes apart the array and builds
# a hash with the comments in it. Each comment is
# is in the index of the hash (based on its cid).
for my $C (@$thisComment) {
# So we save information. This will only have data if we have
# happened through this cid while it was a pid for another
# comments. -Brian
my $tmpkids = $comments->{$C->{cid}}{kids};
my $tmpvkids = $comments->{$C->{cid}}{visiblekids};
# We save a copy of the comment in the root of the hash
# which we will use later to find it via its cid
$comments->{$C->{cid}} = $C;
# Kids is what displayThread will actually use.
$comments->{$C->{cid}}{kids} = $tmpkids;
$comments->{$C->{cid}}{visiblekids} = $tmpvkids;
# The comment pushes itself onto it own kids structure
# which should make it the first -Brian
push @{$comments->{$C->{pid}}{kids}}, $C->{cid};
# The next line deals with hitparade -Brian
#$comments->{0}{totals}[$C->{points} - $min]++; # invert minscore
# This deals with what will appear.
$comments->{$C->{pid}}{visiblekids}++
if $C->{points} >= (defined $user->{threshold} ? $user->{threshold} : $min);
# Can't mod in a discussion that you've posted in.
# Just a point rule -Brian
$user->{points} = 0 if $C->{uid} == $user->{uid}; # Mod/Post Rule
}
my $count = @$thisComment;
# Cascade comment point totals down to the lowest score, so
# (2, 1, 3, 5, 4, 2, 1) becomes (18, 16, 15, 12, 7, 3, 1).
# We do a bit of a weird thing here, returning this data in
# the fields for a fake comment with "cid 0"...
for my $x (reverse(0..$num_scores-2)) {
$comments->{0}{totals}[$x] += $comments->{0}{totals}[$x + 1];
}
# get the total visible kids for each comment --Pater
countTotalVisibleKids($comments);
_print_cchp($discussion, $count, $comments->{0}{totals});
reparentComments($comments, $reader);
return($comments, $count);
}
sub constrain_score {
my ($score) = @_;
my $constants = getCurrentStatic();
my ($min, $max) = ($constants->{comment_minscore}, $constants->{comment_maxscore});
$score = $min if $score < $min;
$score = $max if $score > $max;
return $score;
}
sub _get_points {
my($C, $user, $min, $max, $max_uid, $reasons) = @_;
my $hr = {
score_start => constrain_score($C->{pointsorig} + $C->{tweak_orig}),
moderations => constrain_score($C->{points} + $C->{tweak}) - constrain_score($C->{pointsorig} + $C->{tweak_orig}),
};
my $points = $hr->{score_start};
# User can setup to give points based on size.
# my $len = length($C->{comment});
my $len = $C->{len};
if ($len) {
# comments.len should always be > 0, because Slash doesn't
# accept zero-length comments. If it is = 0, something is
# wrong; don't apply these score modifiers. (What is
# likely is that the admin hasn't properly updated the
# comments table with this new column. - Jamie 2003/03/20)
if ($user->{clbig} && $user->{clbig_bonus} && $len > $user->{clbig}) {
$hr->{clbig} = $user->{clbig_bonus};
}
if ($user->{clsmall} && $user->{clsmall_bonus} && $len < $user->{clsmall}) {
$hr->{clsmall} = $user->{clsmall_bonus};
}
}
# If the user is AC and we give AC's a penalty/bonus
if ($user->{people_bonus_anonymous} && isAnon($C->{uid})) {
$hr->{people_bonus_anonymous} =
$user->{people_bonus_anonymous};
}
# If you don't trust new users
if ($user->{new_user_bonus} && $user->{new_user_percent}
&& 100 - 100*$C->{uid}/$max_uid < $user->{new_user_percent}) {
$hr->{new_user_bonus} = $user->{new_user_bonus};
}
# Adjust reasons. Do we need a reason?
# Are you threatening me?
my $reason_name = $reasons->{$C->{reason}}{name};
if ($user->{"reason_alter_$reason_name"}) {
$hr->{reason_bonus} =
$user->{"reason_alter_$reason_name"};
}
# Keep your friends close but your enemies closer.
# Or ignore them, we don't care.
if ($user->{uid} != $C->{uid}) {
if ($user->{people}{FRIEND()}{$C->{uid}}) {
$hr->{people_bonus_friend} =
$user->{people_bonus_friend};
}
if ($user->{people}{FOE()}{$C->{uid}}) {
$hr->{people_bonus_foe} =
$user->{people_bonus_foe}
}
if ($user->{people}{FREAK()}{$C->{uid}}) {
$hr->{people_bonus_freak} =
$user->{people_bonus_freak}
}
if ($user->{people}{FAN()}{$C->{uid}}) {
$hr->{people_bonus_fan} =
$user->{people_bonus_fan}
}
if ($user->{people}{FOF()}{$C->{uid}}) {
$hr->{people_bonus_fof} =
$user->{people_bonus_fof}
}
if ($user->{people}{EOF()}{$C->{uid}}) {
$hr->{people_bonus_eof} =
$user->{people_bonus_eof}
}
}
# Karma bonus time
if ($user->{karma_bonus} && $C->{karma_bonus} eq 'yes') {
$hr->{karma_bonus} =
$user->{karma_bonus};
}
# And, the poster-was-a-subscriber bonus
if ($user->{subscriber_bonus} && $C->{subscriber_bonus} eq 'yes') {
$hr->{subscriber_bonus} =
$user->{subscriber_bonus};
}
for my $key (grep !/^score_/, keys %$hr) { $points += $hr->{$key} }
$points = $max if $points > $max;
$points = $min if $points < $min;
$hr->{score_end} = $points;
if (wantarray) {
for my $key (grep !/^score_/, keys %$hr) {
my $val = $hr->{$key} + 0;
$hr->{$key} = "+$val" if $val > 0;
}
return ($points, $hr);
} else {
return $points;
}
}
sub _print_cchp {
my($discussion, $count, $hp_ar) = @_;
return unless $discussion->{stoid};
my $form = getCurrentForm();
return unless $form->{ssi} eq 'yes' && $form->{cchp};
my $file_suffix = $form->{cchp};
$count ||= 0;
$hp_ar ||= [ ];
my $constants = getCurrentStatic();
my($min, $max) = ($constants->{comment_minscore},
$constants->{comment_maxscore});
my $num_scores = $max - $min + 1;
push @$hp_ar, 0 while scalar(@$hp_ar) < $num_scores;
my $hp_str = join(",", @$hp_ar);
# If these totals are wanted, print them to the file, so
# the freshenup.pl task (or whatever) can update without
# having to redo the work we just did. Make sure the
# file exists first (if a malicious web user is able to
# pass in a cchp value without having created a file that
# we can write to, it will be ignored).
my $filename = File::Spec->catfile($constants->{logdir},
"cchp.$file_suffix");
if (!-e $filename || !-w _
|| ((stat _)[2] & 0007)) {
warn "_print_cchp not trying to open '$filename': "
. "missing, unwriteable or insecure\n";
} else {
if (!sysopen(my $fh, $filename,
O_WRONLY # file must already exist
)) {
warn "_print_cchp cannot open '$filename', $!\n";
} else {
$count ||= 0;
$hp_str ||= '0';
print $fh "count $count, hitparade $hp_str\n";
close $fh;
}
}
}
########################################################
sub reparentComments {
my($comments, $reader) = @_;
my $constants = getCurrentStatic();
my $user = getCurrentUser();
my $form = getCurrentForm();
my $depth = $constants->{max_depth} || 7;
return if $user->{state}{noreparent} || (!$depth && !$user->{reparent});
# adjust depth for root pid or cid
if (my $cid = $form->{cid} || $form->{pid}) {
while ($cid && (my($pid) = $reader->getComment($cid, 'pid'))) {
$depth++;
$cid = $pid;
}
}
# You know, we do assume comments are linear -Brian
for my $x (sort { $a <=> $b } keys %$comments) {
next if $x == 0; # exclude the fake "cid 0" comment
my $pid = $comments->{$x}{pid};
my $reparent;
# do threshold reparenting thing
if ($user->{reparent} && $comments->{$x}{points} >= $user->{threshold}) {
my $tmppid = $pid;
while ($tmppid && $comments->{$tmppid}{points} < $user->{threshold}) {
$tmppid = $comments->{$tmppid}{pid};
$reparent = 1;
}
if ($reparent && $tmppid >= ($form->{cid} || $form->{pid})) {
$pid = $tmppid;
} else {
$reparent = 0;
}
}
if ($depth && !$reparent) { # don't reparent again!
# set depth of this comment based on parent's depth
$comments->{$x}{depth} = ($pid ? $comments->{$pid}{depth} : 0) + 1;
# go back each pid until we find one with depth less than $depth
while ($pid && $comments->{$pid}{depth} >= $depth) {
$pid = $comments->{$pid}{pid};
$reparent = 1;
}
}
if ($reparent) {
# remove child from old parent
if ($pid >= ($form->{cid} || $form->{pid})) {
@{$comments->{$comments->{$x}{pid}}{kids}} =
grep { $_ != $x }
@{$comments->{$comments->{$x}{pid}}{kids}}
}
# add child to new parent
$comments->{$x}{pid} = $pid;
push @{$comments->{$pid}{kids}}, $x;
}
}
}
# I wonder if much of this logic should be moved out to the theme.
# This logic can then be placed at the theme level and would eventually
# become what is put into $comment->{no_moderation}. As it is, a lot
# of the functionality of the moderation engine is intrinsically linked
# with how things behave on Slashdot. - Cliff 6/6/01
# I rearranged the order of these tests (check anon first for speed)
# and pulled some of the tests from dispComment/_hard_dispComment
# back here as well, just to have it all in one place. - Jamie 2001/08/17
# And now it becomes a function of its own - Jamie 2002/02/26
sub _can_mod {
my($comment) = @_;
my $user = getCurrentUser();
my $constants = getCurrentStatic();
# set time_unixepoch to current time if we aren't passed a
# comment this is the case for the check for the moderate button
# on the article page
$comment->{time_unixepoch} = time unless $comment;
$comment->{time_unixepoch} = timeCalc($comment->{date}, "%s", 0)
unless $comment->{time_unixepoch};
my $retval =
!$user->{is_anon}
&& $constants->{allow_moderation}
&& !$comment->{no_moderation}
&& ( (
$user->{points} > 0
&& $user->{willing}
&& $comment->{uid} != $user->{uid}
&& $comment->{lastmod} != $user->{uid}
&& $comment->{ipid} ne $user->{ipid}
&& (!$constants->{mod_same_subnet_forbid}
|| $comment->{subnetid} ne $user->{subnetid} )
&& (!$user->{state}{discussion_archived}
|| $constants->{comments_moddable_archived})
&& ($comment->{time_unixepoch} >= time() - 3600*
($constants->{comments_moddable_hours}
|| 24*$constants->{archive_delay}))
) || (
$constants->{authors_unlimited}
&& $user->{seclev} >= $constants->{authors_unlimited}
) || (
$user->{acl}{modpoints_always}
) );
return $retval;
}
#========================================================================
=head2 printComments(SID [, PID, CID])
Prints all that comment stuff.
=over 4
=item Parameters
=over 4
=item SID
The story ID to print comments for.
=item PID
The parent ID of the comments to print.
=item CID
The comment ID to print.
=back
=item Return value
None.
=item Dependencies
The 'printCommentsMain', 'printCommNoArchive',
and 'printCommComments' template blocks.
=back
=cut
sub printComments {
my($discussion, $pid, $cid, $options) = @_;
my $user = getCurrentUser();
my $slashdb = getCurrentDB();
my $constants = getCurrentStatic();
my $form = getCurrentForm();
if (!$discussion || !$discussion->{id}) {
print getData('no_such_sid', {}, '');
return 0;
}
# Couple of rules on how to treat the discussion depending on how mode is set -Brian
$discussion->{type} = isDiscussionOpen($discussion);
$pid ||= 0;
$cid ||= 0;
my $cidorpid = $cid || $pid;
my $lvl = 0;
# Get the Comments
my $sco = { force_read_from_master => $options->{force_read_from_master} || 0 };
$sco->{one_cid_only} = 1 if $cidorpid && (
$user->{mode} eq 'nocomment'
|| ( $user->{mode} eq 'flat' && $user->{commentsort} > 3 )
|| $options->{just_submitted}
);
# For now, until we are able to pull hitparade into discussions so we can
# read it here, don't use the one_cid_only optimization feature.
$sco->{one_cid_only} = 0;
my($comments, $count) = selectComments($discussion, $cidorpid, $sco);
if ($cidorpid && !exists($comments->{$cidorpid})) {
# No such comment in this discussion.
my $d = getData('no_such_comment', {
sid => $discussion->{id},
cid => $cid,
}, '');
print $d;
return 0;
}
# Should I index or just display normally?
my $cc = 0;
$cc = $comments->{$cidorpid}{visiblekids}
if $comments->{$cidorpid}
&& $comments->{$cidorpid}{visiblekids};
$lvl++ if $user->{mode} ne 'flat'
&& $user->{mode} ne 'archive'
&& $user->{mode} ne 'metamod'
&& $cc > $user->{commentspill}
&& ( $user->{commentlimit} > $cc ||
$user->{commentlimit} > $user->{commentspill} );
if ($discussion->{type} eq 'archived'
|| ($discussion->{is_future} && !$constants->{subscribe_future_post})
|| ($discussion->{commentstatus} && $discussion->{commentstatus} ne 'enabled')
) {
# This was named "comment_read_only" but that's not very
# descriptive; let's call it what it is... -Jamie 2002/02/26
if ($discussion->{type} eq 'archived') {
$user->{state}{discussion_archived} = 1;
}
if ($discussion->{is_future} && !$constants->{subscribe_future_post}) {
$user->{state}{discussion_future_nopost} = 1;
}
slashDisplay('printCommNoArchive', { discussion => $discussion });
}
slashDisplay('printCommentsMain', {
comments => $comments,
title => $discussion->{title},
'link' => $discussion->{url},
count => $count,
sid => $discussion->{id},
cid => $cid,
pid => $pid,
lvl => $lvl,
});
return if $user->{state}{nocomment} || $user->{mode} eq 'nocomment';
# stats for clampe
if ($constants->{clampe_stats} && $ENV{SCRIPT_NAME}) {
my $fname = catfile('clampe', $user->{ipid});
my $comlog = "UID: $user->{uid} #Comments: $count";
doClampeLog($fname, [$comlog]);
}
my($comment, $next, $previous);
if ($cid) {
my($next, $previous);
$comment = $comments->{$cid};
if (my $sibs = $comments->{$comment->{pid}}{kids}) {
for (my $x = 0; $x < @$sibs; $x++) {
($next, $previous) = ($sibs->[$x+1], $sibs->[$x-1])
if $sibs->[$x] == $cid;
}
}
$next = $comments->{$next} if $next;
$previous = $comments->{$previous} if $previous;
}
# Flat and theaded mode don't index, even on large stories, so they
# need to use more, smaller pages. if $cid is 0, then we get the
# totalviskids for the story --Pater
my $total = ($user->{mode} eq 'flat' || $user->{mode} eq 'nested') ? $comments->{$cidorpid}{totalvisiblekids} : $cc;
my $lcp = linkCommentPages($discussion->{id}, $pid, $cid, $total);
my $comment_html = slashDisplay('printCommComments', {
can_moderate => _can_mod($comment),
comment => $comment,
comments => $comments,
'next' => $next,
previous => $previous,
sid => $discussion->{id},
cid => $cid,
pid => $pid,
cc => $cc,
lcp => $lcp,
lvl => $lvl,
}, { Return => 1 });
# We have to get the comment text we need (later we'll search/replace
# them into the text).
my $comment_text = { };
# Should we read/write the parsed comments to/from memcached?
# This will be possible only if some particular prefs of this user
# are set to the standard values. If this is possible, then for
# almost every comment, we can pull fully rendered text directly
# from memcached and not have to touch the DB.
# Currently, the only user prefs that affect comment rendering at
# this level are whether domaintags are the default, and whether
# maxcommentsize is the default.
my $mcd = $slashdb->getMCD();
$mcd = undef if
$form->{mode} eq 'archive'
|| $user->{domaintags} != 2
|| $user->{maxcommentsize} != $constants->{default_maxcommentsize};
# loop here, pull what cids we can
my $cids_needed_ar = $user->{state}{cids} || [ ];
my($mcd_debug, $mcdkey, $mcdkeylen);
if ($mcd) {
# MemCached key prefix "ctp" means "comment_text, parsed".
# Prepend our site key prefix to try to avoid collisions
# with other sites that may be using the same servers.
$mcdkey = "$slashdb->{_mcd_keyprefix}:ctp:";
$mcdkeylen = length($mcdkey);
if ($constants->{memcached_debug}) {
$mcd_debug = { start_time => Time::HiRes::time };
}
}
$mcd_debug->{total} = scalar @$cids_needed_ar if $mcd_debug;
if ($mcd) {
if ($mcd && $constants->{memcached_debug} && $constants->{memcached_debug} > 2) {
print STDERR scalar(gmtime) . " printComments memcached mcdkey '$mcdkey'\n";
}
my @keys_try =
map { "$mcdkey$_" }
grep { $_ != $form->{cid} }
@$cids_needed_ar;
$comment_text = $mcd->get_multi(@keys_try);
my @old_keys = keys %$comment_text;
if ($mcd && $constants->{memcached_debug} && $constants->{memcached_debug} > 1) {
print STDERR scalar(gmtime) . " printComments memcached got keys '@old_keys' tried for '@keys_try'\n"
}
$mcd_debug->{hits} = scalar @old_keys if $mcd_debug;
for my $old_key (@old_keys) {
my $new_key = substr($old_key, $mcdkeylen);
$comment_text->{$new_key} = delete $comment_text->{$old_key};
}
@$cids_needed_ar = grep { !exists $comment_text->{$_} } @$cids_needed_ar;
}
if ($mcd && $constants->{memcached_debug} && $constants->{memcached_debug} > 1) {
print STDERR scalar(gmtime) . " printComments memcached mcd '$mcd' con '$constants->{memcached}' mcd '$mcd' dt '$user->{domaintags}' mcs '$user->{maxcommentsize}' still needed: '@$cids_needed_ar'\n";
}
# Now we get fresh with the comment text. We take all of the cids
# that we have found and we then speed through the text replacing
# the tags that were there to hold them.
my $more_comment_text = $slashdb->getCommentText($cids_needed_ar) || {}
if @$cids_needed_ar;
if ($mcd && $constants->{memcached_debug} && $constants->{memcached_debug} > 1) {
print STDERR scalar(gmtime) . " more_comment_text keys: '" . join(" ", sort keys %$more_comment_text) . "'\n";
}
for my $cid (keys %$more_comment_text) {
if ($form->{mode} ne 'archive'
&& $comments->{$cid}{len} > $user->{maxcommentsize}
&& $form->{cid} ne $cid)
{
# We remove the domain tags so that strip_html will not
# consider </a blah> to be a non-approved tag. We'll
# add them back at the last step. In-between, we chop
# the comment down to size, then massage it to make sure
# we still have good HTML after the chop.
$more_comment_text->{$cid} =~ s{</a[^>]+>}{</a>}gi;
my $text = chopEntity($more_comment_text->{$cid},
$user->{maxcommentsize});
$text = strip_html($text);
$text = balanceTags($text);
$more_comment_text->{$cid} = addDomainTags($text);
}
# Now write the new data into our hashref and write it out to
# memcached if appropriate. For these purposes, if we were
# cleared to read from memcached, the data we just got is also
# valid to write to memcached.
$comment_text->{$cid} = parseDomainTags($more_comment_text->{$cid},
$comments->{$cid}{fakeemail});
# If the comment should have noFollow on its links, apply
# them here.
my $karma_bonus = $comments->{$cid}{karma_bonus};
if (!$karma_bonus || $karma_bonus eq 'no') {
$comment_text->{$cid} = noFollow($comment_text->{$cid});
}
if ($mcd && $form->{cid} ne $cid) {
my $exptime = $constants->{memcached_exptime_comtext};
$exptime = 86400 if !defined($exptime);
my $retval = $mcd->set("$mcdkey$cid", $comment_text->{$cid}, $exptime);
if ($mcd && $constants->{memcached_debug} && $constants->{memcached_debug} > 1) {
my $exp_at = $exptime ? scalar(gmtime(time + $exptime)) : "never";
print STDERR scalar(gmtime) . " printComments memcached writing '$mcdkey$cid' length " . length($comment_text->{$cid}) . " retval=$retval expire: $exp_at\n";
}
}
}
if ($mcd && $constants->{memcached_debug} && $constants->{memcached_debug} > 1) {
print STDERR scalar(gmtime) . " comment_text keys: '" . join(" ", sort keys %$comment_text) . "'\n";
}
if ($mcd_debug) {
$mcd_debug->{hits} ||= 0;
printf STDERR scalar(gmtime) . " printComments memcached"
. " tried=" . ($mcd ? 1 : 0) . " total_cids=%d hits=%d misses=%d elapsed=%6.4f\n",
$mcd_debug->{total} , $mcd_debug->{hits},
$mcd_debug->{total} - $mcd_debug->{hits},
Time::HiRes::time - $mcd_debug->{start_time};
}
# OK we have all the comment data in our hashref, so the search/replace
# on the nearly-fully-rendered page will work now.
$comment_html =~ s|<SLASH type="COMMENT-TEXT">(\d+)</SLASH>|$comment_text->{$1}|g;
print $comment_html;
}
#========================================================================
=head2 moderatorCommentLog(TYPE, ID)
Prints a table detailing the history of moderation of a particular
comment and/or the reasons why a comment is scored like it is.
(The template name is modCommentLog and this shows info about not
just moderation but modifiers; this function should probably be
renamed the same.)
=over 4
=item Parameters
=over 4
=item TYPE
String describing type of the ID data: cid, uid, cuid, ipid, subnetid,
bipid or bsubnetid.
=item ID
Cid or IPID.
=back
=item Return value
The HTML.
=item Dependencies
The 'modCommentLog' template block.
=back
=cut
sub moderatorCommentLog {
my($type, $value, $options) = @_;
$options ||= {};
my $title = $options->{title};
my $slashdb = getCurrentDB();
my $constants = getCurrentStatic();
my $user = getCurrentUser();
# If the user doesn't want even to see the numeric score of
# a comment, they certainly don't want to see all this detail.
return "" if $user->{noscores};
my $seclev = $user->{seclev};
my $mod_admin = $seclev >= $constants->{modviewseclev} ? 1 : 0;
my $asc_desc = $type eq 'cid' ? 'ASC' : 'DESC';
my $limit = $type eq 'cid' ? 0 : 100;
my $both_mods = (($type =~ /ipid/) || ($type =~ /subnetid/) || ($type =~ /global/)) ? 1 : 0;
my $skip_ip_disp = 0;
if ($type =~ /^b(ip|subnet)id$/) {
$skip_ip_disp = 1;
} elsif ($type =~ /^(ip|subnet)id$/) {
$skip_ip_disp = 2;
}
my $gmcl_opts = {};
$gmcl_opts->{hours_back} = $options->{hours_back} if $options->{hours_back};
$gmcl_opts->{order_col} = "reason" if $type eq "cid";
my $mods = $slashdb->getModeratorCommentLog($asc_desc, $limit,
$type, $value, $gmcl_opts);
my $timestamp_hr = exists $options->{hr_hours_back}
? $slashdb->getTime({ add_secs => -3600 * $options->{hr_hours_back} })
: "";
if (!$mod_admin) {
# Eliminate inactive moderations from the list.
$mods = [ grep { $_->{active} } @$mods ];
}
my($reasons, @return, @reasonHist);
my $reasonTotal = 0;
$reasons = $slashdb->getReasons();
# Note: Before 2001/01/27 or so, the only things being displayed
# in this template were moderations, and if there were none,
# we could short-circuit here if @$mods was empty. But now,
# the template handles that decision.
my $seen_mods = {};
for my $mod (@$mods) {
$seen_mods->{$mod->{id}}++;
vislenify($mod); # add $mod->{ipid_vis}
#$mod->{ts} = substr($mod->{ts}, 5, -3);
$mod->{nickname2} = $slashdb->getUser($mod->{uid2},
'nickname') if $both_mods; # need to get 2nd nick
next unless $mod->{active};
$reasonHist[$mod->{reason}]++;
$reasonTotal++;
}
my $listed_reason = 0;
if ($type eq 'cid') {
my $val_q = $slashdb->sqlQuote($value);
$listed_reason = $slashdb->sqlSelect("reason", "comments", "cid=$val_q");
}
my @reasonsTop = _getTopModReasons($reasonTotal, $listed_reason, \@reasonHist);
my $show_cid = ($type eq 'cid') ? 0 : 1;
my $show_modder = $mod_admin ? 1 : 0;
my $mod_to_from = ($type eq 'uid') ? 'to' : 'from';
my $modifier_hr = { };
my $reason = 0;
if ($type eq 'cid') {
my $cid_q = $slashdb->sqlQuote($value);
my($min, $max) = ($constants->{comment_minscore},
$constants->{comment_maxscore});
my $max_uid = $slashdb->countUsers({ max => 1 });
my $select = "cid, uid, karma_bonus, reason, points, pointsorig, tweak, tweak_orig";
if ($constants->{plugin}{Subscribe} && $constants->{subscribe}) {
$select .= ", subscriber_bonus";
}
my $comment = $slashdb->sqlSelectHashref(
$select,
"comments",
"cid=$cid_q");
$comment->{comment} = $slashdb->sqlSelect(
"comment",
"comment_text",
"cid=$cid_q");
$reason = $comment->{reason};
my $user = getCurrentUser();
my $points;
($points, $modifier_hr) = _get_points($comment, $user, $min, $max, $max_uid, $reasons);
}
my $this_user;
$this_user = $slashdb->getUser($value) if $type eq "uid";
my $cur_uid;
$cur_uid = $value if $type eq "uid" || $type eq "cuid";
my $mod_ids = [keys %$seen_mods];
my $mods_to_m2s;
if ($constants->{show_m2s_with_mods} && $options->{show_m2s}) {
$mods_to_m2s = $slashdb->getMetamodsForMods($mod_ids, $constants->{m2_limit_with_mods});
}
# Do the work to determine which moderations share the same m2s
if ($type eq "cid"
&& $constants->{show_m2s_with_mods}
&& $constants->{m2_multicount}
&& $options->{show_m2s}){
foreach my $m (@$mods){
my $key = '';
foreach my $m2 (@{$mods_to_m2s->{$m->{id}}}) {
$key .= "$m2->{uid} $m2->{val},";
}
$m->{m2_identity} = $key;
}
@$mods = sort {
$a->{reason} <=> $b->{reason}
||
$b->{active} <=> $a->{active}
||
$a->{m2_identity} cmp $b->{m2_identity}
} @$mods;
}
my $data = {
type => $type,
mod_admin => $mod_admin,
mods => $mods,
reasonTotal => $reasonTotal,
reasonHist => \@reasonHist,
reasonsTop => \@reasonsTop,
reasons => $reasons,
reason => $reason,
modifier_hr => $modifier_hr,
show_cid => $show_cid,
show_modder => $show_modder,
mod_to_from => $mod_to_from,
both_mods => $both_mods,
timestamp_hr => $timestamp_hr,
skip_ip_disp => $skip_ip_disp,
this_user => $this_user,
title => $title,
mods_to_m2s => $mods_to_m2s,
show_m2s => $options->{show_m2s},
cur_uid => $cur_uid,
value => $value,
need_m2_form => $options->{need_m2_form},
need_m2_button => $options->{need_m2_button},
meta_mod_only => $options->{meta_mod_only},
};
slashDisplay('modCommentLog', $data, { Return => 1, Nocomm => 1 });
}
# Takes a reason histogram, a list of counts of each reason mod.
# So $reasonHist[1] is the number of Offtopic moderations (at
# least if Offtopic is still reason 1). Returns a list of hashrefs,
# the top 3 mods performed and their percentages, rounded to the
# nearest 10%, sorted largest to smallest.
sub _getTopModReasons{
my($reasonTotal, $listed_reason, $reasonHist_ar) = @_;
return ( ) unless $reasonTotal;
my $top_needed = 3;
my @reasonsTop = ( );
# Algorithm by MJD in Perl Quiz of the Week #7
# http://perl.plover.com/qotw/r/solution/007
my @p = map { $_*10/$reasonTotal } @$reasonHist_ar;
my @r = map { int($_+0.5) } @p;
my @e = map { $p[$_] - $r[$_] } (0..$#r);
my $total_error = 0;
for (@e) { $total_error += $_ }
# Round total_error to int, to avoid float rounding error
my $sign = $total_error < 0 ? -1 : 1;
$total_error *= $sign;
$total_error = int($total_error+0.5);
if ($total_error) {
for (0..$#r) {
next unless $e[$_] * $sign > 0;
$r[$_] += $sign;
$total_error--;
last if $total_error <= 0;
}
}
# This part I added, so if it breaks, don't blame MJD :) JRM
my %reasonRound = map { ($_, $r[$_]*10) } (0..$#r);
my @rr_keys = sort { $a <=> $b } keys %reasonRound;
my $min = (sort { $b <=> $a } values %reasonRound)[$top_needed-1];
for my $key (0..$#r) {
$reasonRound{$key} = 0 if $reasonRound{$key} < $min;
}
my $have = 0;
for my $key (0..$#r) {
++$have if $reasonRound{$key} > $min;
}
for my $key (0..$#r) {
if ($reasonRound{$key} == $min) {
if ($have >= $top_needed) {
$reasonRound{$key} = 0;