Move twirl plumbing into twirl.gradle.

build.gradle

@@ -1,5 +1,3 @@
-import play.japi.twirl.compiler.TwirlCompiler
-
 buildscript {
   repositories {
     maven { url "https://plugins.gradle.org/m2/" }
@@ -10,29 +8,22 @@ buildscript {
     classpath 'com.github.jengelman.gradle.plugins:shadow:2.0.2'
     classpath "com.netflix.nebula:nebula-release-plugin:6.3.3"
     classpath "gradle.plugin.com.palantir.gradle.docker:gradle-docker:0.19.2"
-    classpath 'org.scala-lang:scala-library:2.12.5'
-    classpath 'org.scala-lang.modules:scala-parser-combinators_2.12:1.1.0'
-    classpath 'com.typesafe.play:twirl-compiler_2.12:1.3.13'
-    classpath 'com.typesafe.play:twirl-api_2.12:1.3.13'
   }
 }
 
 apply plugin: "scala"
 apply plugin: "io.ratpack.ratpack-java"
 apply plugin: "nebula.release"
 apply plugin: "com.palantir.docker"
+apply plugin: 'com.github.johnrengelman.shadow'
+apply from: "gradle/twirl.gradle"
 
 mainClassName = "io.sdkman.site.SiteMain"
-apply plugin: 'com.github.johnrengelman.shadow'
 
 repositories {
   jcenter()
 }
 
-configurations {
-  generatedCompile
-}
-
 dependencies {
   compile 'org.scala-lang:scala-library:2.12.4'
   compile ratpack.dependency("guice")
@@ -48,20 +39,6 @@ dependencies {
   testCompile 'org.jvnet.mock-javamail:mock-javamail:1.9'
 }
 
-def gensrcDir = "$buildDir/gensrc/scala"
-
-sourceSets {
-  generated {
-    scala.srcDir gensrcDir
-    compileClasspath = configurations.generatedCompile
-  }
-  main {
-    compileClasspath += sourceSets.generated.output
-  }
-  test {
-    compileClasspath += sourceSets.generated.output
-  }
-}
 
 docker {
   name 'sdkman/sdkman-website'
@@ -70,36 +47,3 @@ docker {
   files tasks.shadowJar.outputs
   dependsOn shadowJar
 }
-
-def compileTemplate(File template, File sourceDir, File gensrcDir) {
-  TwirlCompiler.compile(
-          template,
-          file(sourceDir),
-          file(gensrcDir),
-          "play.twirl.api.HtmlFormat",
-          ["io.sdkman.repos.Candidate", "play.twirl.api.Html"],
-          new ArrayList<String>())
-}
-
-task prepareTemplates() {
-  doLast {
-    def sourceDir = file("src/main/twirl")
-    ["", "includes/"].each { folder ->
-      file("$sourceDir/$folder").listFiles().findAll { !it.directory }.each { File template ->
-        println("Compiling template: ${template.name}: $sourceDir/$folder -> $gensrcDir/")
-        compileTemplate(template, file("$sourceDir/$folder"), file(gensrcDir))
-      }
-    }
-  }
-}
-
-compileGeneratedScala {
-  dependsOn(prepareTemplates)
-  classpath = configurations.compile
-}
-
-compileScala {
-  dependsOn(compileGeneratedScala)
-  source += sourceSets.generated.scala
-}
-

gradle/twirl.gradle

@@ -0,0 +1,63 @@
+import play.japi.twirl.compiler.TwirlCompiler
+
+buildscript {
+    repositories {
+        jcenter()
+    }
+    dependencies {
+        classpath 'org.scala-lang:scala-library:2.12.5'
+        classpath 'org.scala-lang.modules:scala-parser-combinators_2.12:1.1.0'
+        classpath 'com.typesafe.play:twirl-compiler_2.12:1.3.13'
+        classpath 'com.typesafe.play:twirl-api_2.12:1.3.13'
+    }
+}
+
+configurations {
+    generatedCompile
+}
+
+def gensrcDir = "$buildDir/gensrc/scala"
+sourceSets {
+    generated {
+        scala.srcDir gensrcDir
+        compileClasspath = configurations.generatedCompile
+    }
+    main {
+        compileClasspath += sourceSets.generated.output
+    }
+    test {
+        compileClasspath += sourceSets.generated.output
+    }
+}
+
+def compileTemplate(File template, File sourceDir, File gensrcDir) {
+    TwirlCompiler.compile(
+            template,
+            file(sourceDir),
+            file(gensrcDir),
+            "play.twirl.api.HtmlFormat",
+            ["io.sdkman.repos.Candidate", "play.twirl.api.Html"],
+            new ArrayList<String>())
+}
+
+task prepareTemplates() {
+    doLast {
+        def sourceDir = file("src/main/twirl")
+        ["", "includes/"].each { folder ->
+            file("$sourceDir/$folder").listFiles().findAll { !it.directory }.each { File template ->
+                println("Compiling template: ${template.name}: $sourceDir/$folder -> $gensrcDir/")
+                compileTemplate(template, file("$sourceDir/$folder"), file(gensrcDir))
+            }
+        }
+    }
+}
+
+compileGeneratedScala {
+  dependsOn(prepareTemplates)
+  classpath = configurations.compile
+}
+
+compileScala {
+  dependsOn(compileGeneratedScala)
+  source += sourceSets.generated.scala
+}