-
Notifications
You must be signed in to change notification settings - Fork 8
/
zBitmap.prw
1958 lines (1620 loc) · 51.6 KB
/
zBitmap.prw
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
/* -------------------------------------------------------------------------------------------
Copyright 2015-2019 Júlio Wittwer ( siga0984@gmail.com | http://siga0984.wordpress.com/ )
É permitido, gratuitamente, a qualquer pessoa que obtenha uma cópia deste software
e dos arquivos de documentação associados (o "Software"), para negociar o Software
sem restrições, incluindo, sem limitação, os direitos de uso, cópia, modificação, fusão,
publicação, distribuição, sublicenciamento e/ou venda de cópias do Software,
SEM RESTRIÇÕES OU LIMITAÇÕES.
O SOFTWARE É FORNECIDO "TAL COMO ESTÁ", SEM GARANTIA DE QUALQUER TIPO, EXPRESSA OU IMPLÍCITA,
INCLUINDO MAS NÃO SE LIMITANDO A GARANTIAS DE COMERCIALIZAÇÃO, ADEQUAÇÃO A UMA FINALIDADE
ESPECÍFICA E NÃO INFRACÇÃO. EM NENHUM CASO OS AUTORES OU TITULARES DE DIREITOS AUTORAIS
SERÃO RESPONSÁVEIS POR QUALQUER REIVINDICAÇÃO, DANOS OU OUTRA RESPONSABILIDADE, SEJA
EM AÇÃO DE CONTRATO OU QUALQUER OUTRA FORMA, PROVENIENTE, FORA OU RELACIONADO AO SOFTWARE.
*** USE A VONTADE, POR SUA CONTA E RISCO ***
Permission is hereby granted, free of charge, to any person obtaining a copy of this software
and associated documentation files (the "Software"), to deal in the Software without
restriction, including without limitation the rights to use, copy, modify, merge, publish,
distribute, sublicense, and/or sell copies of the Software, and to permit persons to whom
the Software is furnished to do so, WITHOUT RESTRICTIONS OR LIMITATIONS.
THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR IMPLIED,
INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS FOR A PARTICULAR
PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE
FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT
OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE.
***USE AS YOU WISH , AT YOUR OWN RISK ***
------------------------------------------------------------------------------------------- */
#include 'protheus.ch'
#include 'zlib.ch'
/* ===========================================================================
Classe ZBITMAP
Autor Júlio Wittwer
Data 05/2019
Leitura e edição de Bitmap monocromatico em AdvPL
Referencia do formato do arquivo
https://en.wikipedia.org/wiki/BMP_file_format
Release 20190727 Metodo LoadFromPNG()
=========================================================================== */
CLASS ZBITMAP FROM LONGNAMECLASS
DATA cFileName // Nome do arquivo de imagem
DATA nFileSize // Tamanho em bytes total do arquivo
DATA nHeight // Altura da imagem em pixels
DATA nWidth // largura da imagem em pixels
DATA nBPP // Bits por Pixel ( 1,4,8,24 )
DATA cERROR // String com ultima ocorrencia de erro da classe
DATA aMatrix // Matrix de pontos do Bitmap ( cores )
DATA aClipBoard // Area interna de transferencia
DATA aColors // Tabela de cores do Bitmap ( BGRA )
DATA cFormat // Identificador do formato do arquivo
DATA nOffSet // Offset de inico dos dados
DATA nRawData // Tamanho dos dados
DATA nRowSize // Tamanho em bytes de uma linha da imagem
DATA nHeadSize // Tamanho do Info Header
DATA nCompress // Nivel de compressao
DATA nColorPlanes // Numero de planos de cor ( 1 )
DATA nHRes // Resolucao horizontal
DATA nVRes // Resolucao vertical
DATA nColorPal // Paleta de cores
DATA nImpColors // Cores importantes
DATA nFRColor // Cor de pintural atual ( default =0 / preto )
DATA nBgColor // Cor de fundo ( default = branco )
DATA nMargin // Margem da imagem
DATA nPenSize // Grossura da "caneta" de desenho ( default=1 )
DATA lTransparent // Transparencia ( PNG Only )
METHOD New() // Cria uma imagem vazia
METHOD LoadFromFile() // Le imagem de um arquivo BMP
METHOD LoadFromPNG() // Le imagem de um arquivo PNG
METHOD GetErrorStr() // Recupera ultimo erro da classe
METHOD Clear() // Limpa a imagem ( preenche com a cor de fundo ) ou uma parte dela
METHOD SetPixel() // Seta a cor de um ponto
METHOD GetPixel() // Recupera a cor de um ponto
METHOD BgColor() // Seta ou Recupera a cor de fundo
METHOD Negative() // Inverte as cores da imagem ( = Negativo )
METHOD SaveToBMP() // Salva a imagem em disco como Bitmap
METHOD SaveToJPG() // Salva a imagem em disco como JPEG
METHOD SaveToPNG() // Salva a imagem em disco como PNG
METHOD Rectangle() // Desenha um retângulo na imagem
METHOD Line() // Desenha uma linha na imagem entre dois pontos
METHOD Circle() // Desenha um círculo
METHOD SetBPP() // Troca a resoluçao de cores
METHOD Paint() // pintura de área da imagem delimitada
METHOD FlipH() // Inverte horizontalmente uma área da imagem ou a imagem inteira
METHOD FlipV() // Inverte verticalmente uma área da imagem ou a imagem inteira
METHOD Cut() // Copia uma parte da imagem para a área interna de transferencia e limpa a área da imagem
METHOD Copy() // Copia uma parte da imagem para a área interna de transferencia
METHOD Paste() // Plota a imagem da area interna de transferencia na coordenada indicada
METHOD Resize() // Redimensiona BMP em percentual horizontal e vertical
METHOD SetTransparent()// Liga/DEsliga transparencia da cor de fundo
ENDCLASS
// Cria um objeto BMP
// Pode ser criado sem parametros, para carregar uma imagem do disco
METHOD NEW(nWidth,nHeight,nBPP) CLASS ZBITMAP
Local nL
Local nC
Local aRow
IF nWidth = NIL
::nWidth := 32
Else
::nWidth := nWidth
Endif
If nHeight = NIL
::nHeight := 32
Else
::nHeight := nHeight
Endif
If nBPP = NIL
::nBPP := 1
Else
::nBPP := nBPP
Endif
::aColors := GetColorTab(nBPP)
::cFileName := ''
::nPenSize := 1
::nFRColor := 0 // Preto
IF ::nBPP = 1
::nOffSet := 62
::nBgColor := 1 // Branco
ElseIf ::nBPP = 4
::nOffSet := 118
::nBgColor := 15 // Branco
ElseIf ::nBPP = 8
::nOffSet := 1078
::nBgColor := 255 // Branco
ElseIf ::nBPP = 24
::nOffSet := 54
::nBgColor := RGB(256,256,256)-1 // branco
Endif
aRow := {}
// Inicializa matrix com a cor de fundo
::aMatrix := {}
For nC := 1 to ::nWidth
aadd(aRow,::nBgColor)
Next
For nL := 1 to ::nHeight
aadd(::aMatrix,aClone(aRow))
Next
::nHeadSize := 40
::nColorPlanes := 1
::nCompress := 0
::nHRes := 0
::nVRes := 0
::nColorPal := 0
::nImpColors := 0
// Tamanho calculado de cada linha em bytes
::nRowSize := int( ( (::nBPP*::nWidth) + 31 ) / 32 ) * 4
// Tamando da area de dados da imagem
::nRawData := ::nRowSize * ::nHeight
// Tamanho final da imagem
::nFileSize := ::nRawData + ::nOffSet
// Transprencia ( PNG )
// Por hora define que a cor de fundo será transparente
::lTransparent := .F.
Return self
// Carrega uma imagem BMP do disco
METHOD LOADFROMFILE(cFile) CLASS ZBITMAP
Local nH
Local cBuffer := ''
Local cBinSize
Local nBmpSize
Local nL , nC, nI
Local nByte
Local nReadOffset
Local aRow := {}
Local cBits
Local lTopDown := .F.
Local nPos, nCor, nRed, nGreen,nBlue,nAlpha
::cFileName := cFile
nH := Fopen(cFile)
If nH < 0
UserException("Fopen error ("+cValToChar(Ferror())+")")
Endif
::nFileSize := fSeek(nH,0,2)
fSeek(nH,0)
If ::nFileSize < 54
::cError := "Invalid BMP -- file too small"
Return .F.
Endif
// Aloca o Buffer e lê o arquivo intero
// para arquivos maiores que 1MB, aumentar o tamanho
// máximo de string no AdvPL -- MaxStringSize
fRead(nH,@cBuffer,::nFileSize)
fClose(nH)
::cFormat := substr(cBuffer,0,2)
If ::cFormat <> "BM"
::cError := "Unknow BMP Format ["+::cFormat+"]"
Return .F.
Endif
cBinSize := substr(cBuffer,3,4)
nBmpSize := bin2l(cBinSize)
If ::nFileSize <> nBmpSize
::cError := "BMP Incorrect Format -- File size mismatch"
Return .F.
Endif
/*
Windows BITMAPINFOHEADER[1]
Offset (hex) Offset (dec) Size (bytes) Information
0E 14 4 the size of this header (40 bytes)
12 18 4 the bitmap width in pixels (signed integer)
16 22 4 the bitmap height in pixels (signed integer)
1A 26 2 the number of color planes (must be 1)
1C 28 2 the number of bits per pixel, which is the color depth of the image. Typical values are 1, 4, 8, 16, 24 and 32.
1E 30 4 the compression method being used. See the next table for a list of possible values
22 34 4 the image size. This is the size of the raw bitmap data; a dummy 0 can be given for BI_RGB bitmaps.
26 38 4 the horizontal resolution of the image. (pixel per metre, signed integer)
2A 42 4 the vertical resolution of the image. (pixel per metre, signed integer)
2E 46 4 the number of colors in the color palette, or 0 to default to 2n
32 50 4 the number of important colors used, or 0 when every color is important; generally ignored
*/
::nOffSet := bin2l(substr(cBuffer,11,4))
::nHeadSize := bin2l(substr(cBuffer,15,4))
::nWidth := bin2l(substr(cBuffer,19,4))
::nHeight := bin2l(substr(cBuffer,23,4))
::nColorPlanes := bin2i(substr(cBuffer,27,2))
::nBPP := bin2i(substr(cBuffer,29,2))
::nCompress := bin2l(substr(cBuffer,31,4))
::nRawData := bin2l(substr(cBuffer,35,4))
::nHRes := bin2l(substr(cBuffer,39,4))
::nVRes := bin2l(substr(cBuffer,43,4))
::nColorPal := bin2l(substr(cBuffer,47,4))
::nImpColors := bin2l(substr(cBuffer,51,4))
If ::nHeight < 0
// Linhas do Bitmap "de cima pra baixo"
// Normalmente o formato padrao é "Bottom-Up" ( de baixo pra cima )
lTopDown := .T.
::nHeight := abs(::nHeight)
Endif
// Tamanho calculado de cada linha em bytes
::nRowSize := int( ( (::nBPP*::nWidth) + 31 ) / 32 ) * 4
// Tabela de cores para 4 bytes por pixel ( 16 cores )
::aColors := {}
If ::nBPP = 1
nCores := 2
ElseIF ::nBPP = 4
nCores := 16
ElseIF ::nBPP = 8
nCores := 256
ElseIF ::nBPP = 24
// Nao tem tabela de cores
nCores := 0
Else
UserException("Formato (ainda) nao suportado: "+cValToChar(::nBPP)+" BPP" )
Endif
nPos := 55
For nCor := 0 to nCores-1
nBlue := asc(substr(cBuffer,nPos,1))
nGreen := asc(substr(cBuffer,nPos+1,1))
nRed := asc(substr(cBuffer,nPos+2,1))
nAlpha := asc(substr(cBuffer,nPos+3,1))
aadd(::aColors,{nBlue,nGreen,nRed,nAlpha})
//conout("aadd(::aColors,{"+cValToChaR(nBlue)+","+cValToChaR(nGreen)+","+cValToChaR(nRed)+","+cValToChaR(nAlpha)+"})")
nPos += 4
// Conout("BGRA("+cValToChar(nCor)+") = ("+cValToChar(nBlue)+","+cValToChar(nGreen)+","+cValToChar(nRed)+","+cValToChar(nAlpha)+")")
Next
// Leitura dos dados na matriz
::aMatrix := {}
For nL := 0 to ::nHeight-1
nReadOffset := ::nOffSet + ( ::nRowSize * nL ) + 1
For nC := 0 to ::nWidth-1
nByte := asc(substr(cBuffer,nReadOffset,1))
If ::nBPP == 1
// Bitmap monocromatico
// um bit por pixel, converte para binario direto
// 0 = preto, 1 = branco
cBits := NTOBIT8(nByte)
For nI := 1 to 8
aadd(aRow,IIF(substr(cBits,nI,1)=='0',0,1))
Next
ElseIf ::nBPP == 4
// Bitmap de 16 cores
// 2 pixels por byte
cBits := NTOBIT8(nByte)
aadd(aRow, BITSTON(Substr(cBits,1,4)))
aadd(aRow, BITSTON(Substr(cBits,5,4)))
ElseIf ::nBPP == 8
// Bitmap de 256 cores
// 1 pixels por byte
aadd(aRow, nByte)
ElseIf ::nBPP == 24
// Bitmap de 256*256*256 cores
// 1 pixel a cada 3 bytes
nBlue := asc(substr(cBuffer,nReadOffset,1))
nGreen := asc(substr(cBuffer,nReadOffset+1,1))
nRed := asc(substr(cBuffer,nReadOffset+2,1))
aadd(aRow, RGB(nRed,nGreen,nBlue) )
Else
UserException("Unsupported ("+cValToChar(::nBPP)+") Bytes per Pixel")
Endif
If ::nBPP == 24
nReadOffset += 3
Else
nReadOffset += 1
Endif
Next
aSize(aRow,::nWidth)
If lTopDown
// Armazenamento de cima pra baixo
aadd(::aMatrix,aClone(aRow))
Else
// Windows BMP normalmente é armazenado de baixo pra cima
// Somente é de cima pra baixo caso a altura seja negativa
aadd(::aMatrix,NIL)
aIns(::aMatrix,1)
::aMatrix[1] := aClone(aRow)
Endif
aSize(aRow,0)
Next
Return .T.
#define PNG_WIDTH 1
#define PNG_HEIGHT 2
#define PNG_BIT_DEPHT 3
#define PNG_COLOR_TYPE 4
#define PNG_COMPRESSION 5
#define PNG_FILTER 6
#define PNG_INTERLACE 7
#define PNG_SRGB 8
#define PNG_GAMA 9
#define PNG_PIXELPERUNIT_X 10
#define PNG_PIXELPERUNIT_Y 11
#define PNG_PIXEL_UNIT 12
#define PNG_PALLETE 13
#define PNG_IMAGEDATA 14
#define PNG_HEADER chr(137)+chr(80)+chr(78)+chr(71)+chr(13)+chr(10)+chr(26)+chr(10)
METHOD LoadFromPNG(cFile) CLASS ZBITMAP
Local nH,cBuffer := ''
Local aPng := Array(14)
Local iTam , cData , nCRC // Dados do Chunk
Local cBufferOut := ''
Local nLenghtOut
Local nColSize , cRowBuffer
Local nColPos,cBits
Local nL , nC
Local aRow := {}
Local cIdat
::cFileName := cFile
nH := fopen(cFile)
IF nH == -1
::cError := "File Open Error - FERROR = "+cValToChar(Ferror())
Return .F.
Endif
// Determina o tamanho e le o arquivo inteiro
::nFileSize := fSeek(nH,0,2)
fSeek(nH,0)
fREad(nH,@cBuffer,::nFileSize)
fClose(nH)
IF !(Left(cBuffer,8) == PNG_HEADER )
::cError := "File is NOT A PNG"
Return .F.
Endif
// Corta o header fora
cBuffer := substr(cBuffer,9)
// Data Compacted Stream
cIDAT := ''
// Varre o resto do buffer
while len(cBuffer) > 0
// Tamanho dos dados do chunk
iTam := Bin4toN(left(cBuffer,4))
cBuffer := substr(cBuffer,5)
// Tipo do Chunk
cType := left(cBuffer,4)
cBuffer := substr(cBuffer,5)
If iTam > 0
cData := left(cBuffer,iTam)
cBuffer := substr(cBuffer,iTam+1)
Else
cData := ''
Endif
nCRC := Bin4toN(left(cBuffer,4))
cBuffer := substr(cBuffer,5)
nChkCRC := PNGCRC(cType+cData)
If Upper(cType) == 'IHDR'
/*
Width: 4 bytes
Height: 4 bytes
Bit depth: 1 byte
Color type: 1 byte
Compression method: 1 byte
Filter method: 1 byte
Interlace method: 1 byte
*/
aPng[PNG_WIDTH] := Bin4toN(substr(cData,1,4))
aPng[PNG_HEIGHT] := Bin4toN(substr(cData,5,4))
aPng[PNG_BIT_DEPHT] := asc(substr(cData,9,1))
aPng[PNG_COLOR_TYPE] := asc(substr(cData,10,1))
aPng[PNG_COMPRESSION] := asc(substr(cData,11,1))
aPng[PNG_FILTER] := asc(substr(cData,12,1))
aPng[PNG_INTERLACE] := asc(substr(cData,13,1))
// Por enqianto aproveita apenas comprimento e altura
// e Bit Depth ( Bits Per Pixel )
::nWidth := aPng[PNG_WIDTH]
::nHeight := aPng[PNG_HEIGHT]
IF aPng[PNG_COLOR_TYPE] = 3 // Cada pixel é um indice da paleta de cores
IF aPng[PNG_BIT_DEPHT] = 1
::nBPP := 1
::nOffSet := 62
::nBgColor := 1 // Branco
ElseIf aPng[PNG_BIT_DEPHT]= 4
::nBPP := 4
::nOffSet := 118
::nBgColor := 15 // Branco
ElseIf aPng[PNG_BIT_DEPHT] = 8
::nBPP := 8
::nOffSet := 1078
::nBgColor := 255 // Branco
Else
UserException("PNG Unsupported Bit Depth ("+cValToChar(aPng[PNG_BIT_DEPHT])+") on ColorType=3")
Endif
ElseIf aPng[PNG_COLOR_TYPE] = 2
// Cada pixel é um RGB
If aPng[PNG_BIT_DEPHT] = 8
::nBPP := 24
::nOffSet := 54
::nBgColor := RGB(256,256,256)-1 // branco
Else
UserException("PNG Unsupported Bit Depth ("+cValToChar(aPng[PNG_BIT_DEPHT])+") on ColorType=2")
Endif
ElseIf aPng[PNG_COLOR_TYPE] = 6
// Cada pixel é um RGB + alpha
If aPng[PNG_BIT_DEPHT] = 8
::nBPP := 24
::nOffSet := 54
::nBgColor := RGB(256,256,256)-1 // branco
Else
UserException("PNG Unsupported Bit Depth ("+cValToChar(aPng[PNG_BIT_DEPHT])+") on ColorType=2")
Endif
Else
UserException("PNG Unsupported Color Type "+cValToChar(aPng[PNG_COLOR_TYPE]))
Endif
ElseIF Upper(cType) == 'SRGB'
/*
0: Perceptual
1: Relative colorimetric
2: Saturation
3: Absolute colorimetric
*/
aPNG[PNG_SRGB] := asc(substr(cData,1,1))
ElseIF Upper(cType) == 'GAMA'
// The value is encoded as a 4-byte unsigned integer, representing gamma times 100000.
// For example, a gamma of 1/2.2 would be stored as 45455.
aPng[PNG_GAMA] := Bin4toN(substr(cData,1,4))
ElseIF Upper(cType) == 'PLTE'
// Paleta de cores sequencias de 3 bytes RGB
::aColors := {}
aPng[PNG_PALLETE] := {}
While len(cData) > 0
nRed := asc(substr(cData,1,1))
nGreen := asc(substr(cData,2,1))
nBlue := asc(substr(cData,3,1))
cData := substr(cData,4)
aadd( aPng[PNG_PALLETE] , {nRed,nGreen,nBlue} )
// Paleta do BITMAP : BGRA
aadd(::aColors,{nBlue,nGreen,nRed,0}) // BGRA
Enddo
ElseIF Upper(cType) == 'PHYS'
/*
Pixels per unit, X axis: 4 bytes (unsigned integer)
Pixels per unit, Y axis: 4 bytes (unsigned integer)
Unit specifier: 1 byte
*/
aPng[PNG_PIXELPERUNIT_X] := Bin4toN(substr(cData,1,4))
aPng[PNG_PIXELPERUNIT_Y] := Bin4toN(substr(cData,5,4))
aPng[PNG_PIXEL_UNIT] := asc(substr(cData,9,1))
ElseIF Upper(cType) == 'IDAT'
// Soma o stream compactado, caso haja mais que um
cIdat += cData
ElseIF Upper(cType) == 'IEND'
// Fim do arquivo
EXIT
Else
Conout("WARNING - LoadFromPNG - Ignored Chunk ["+cType+"]")
conout(hexstrdump(cData))
Endif
Enddo
IF !empty(cIdat)
cBufferOut := ''
nLenghtOut := 10*1024*1024
UnCompress( @cBufferOut , @nLenghtOut , cIdat, len(cIdat) )
nColSize := nLenghtOut / aPng[PNG_HEIGHT]
// Inicializa BMP com fundo branco
::aMatrix := {}
For nC := 1 to ::nWidth
aadd(aRow,::nBgColor)
Next
For nL := 1 to ::nHeight
aadd(::aMatrix,aClone(aRow))
Next
// Mastiga o buffer binario alimentando a matrix do Bitmap
For nL := 1 to aPng[PNG_HEIGHT]
cRowBuffer := substr(cBufferOut,1,nColSize)
cBufferOut := substr(cBufferOut,nColSize+1)
nColPos := 1
If aPng[PNG_COLOR_TYPE] == 3 .and. ::nBPP = 1
For nC := 2 to nColSize
cBits := NTOBIT8( asc(substr(cRowBuffer,nC,1)) )
While len(cBits) > 0
IF nColPos < aPng[PNG_WIDTH]
::aMatrix[nL,nColPos] := val(left(cBits,1))
Endif
nColPos++
cBits := substr(cBits,2)
Enddo
Next
ElseIf aPng[PNG_COLOR_TYPE] == 2 .and. ::nBPP = 24
// Trinca RGB
For nC := 2 to nColSize STEP 3
nRed := asc(substr(cRowBuffer,nC,1))
nGreen := asc(substr(cRowBuffer,nC+1,1))
nBlue := asc(substr(cRowBuffer,nC+2,1))
::aMatrix[nL,nColPos] := RGB(nRed,nGreen,nBlue)
nColPos++
Next
ElseIf aPng[PNG_COLOR_TYPE] == 6 .and. ::nBPP = 24
// Trinca RGB + Alpha
For nC := 2 to nColSize STEP 4
nRed := asc(substr(cRowBuffer,nC,1))
nGreen := asc(substr(cRowBuffer,nC+1,1))
nBlue := asc(substr(cRowBuffer,nC+2,1))
::aMatrix[nL,nColPos] := RGB(nRed,nGreen,nBlue)
nColPos++
Next
Else
UserException("ColorType ["+cValToChar(aPng[PNG_COLOR_TYPE])+"] BPP ["+cValToChar(::nBPP)+"] unsupported.")
Endif
Next
Endif
Return .T.
// Recupera a última informação de erro da Classe
METHOD GetErrorStr() CLASS ZBITMAP
Return ::cError
// Limpa a imagem preenchendo os pontos com
// a cor de fundo
METHOD Clear(L1,C1,L2,C2) CLASS ZBITMAP
Local nL, nC
IF pCount() == 0
// Limpa a imagem inteira
L1 := 0
C1 := 0
L2 := ::nHeight-1
C2 := ::nWidth-1
Else
// Valida coordenadas informadas para limpeza
IF L1 < 0 .or. L1 >= ::nHeight
::cError := "Invalid 1o Line -- Out Of Image Area"
Return .F.
ElseIF L2 < 0 .or. L2 >= ::nHeight
::cError := "Invalid 2o Line -- Out Of Image Area"
Return .F.
ElseIf C1 < 0 .or. C1 >= ::nWidth
::cError := "Invalid 1o Column -- Out Of Image Area"
Return .F.
ElseIf C2 < 0 .or. C2 >= ::nWidth
::cError := "Invalid 2o Column -- Out Of Image Area"
Return .F.
ElseIf L1 > L2
::cError := "Invalid Lines -- Order mismatch"
Return .F.
ElseIf C1 > C2
::cError := "Invalid Columns -- Order mismatch"
Return .F.
Endif
Endif
// Limpa a área informada
For nL := L1+1 to L2+1
For nC := C1+1 to C2+1
::aMatrix[nL][nC] := ::nBGColor
Next
Next
Return
// -------------------------------------------------
// Seta um pixel com uma cor em uma coordenada
// linha e coluna, base 0 , cor é opcional
// Diametro da caneta (Pen) opcional
METHOD SETPIXEL(nL,nC,nColor,nPen) CLASS ZBITMAP
Local nRow := nL+1
Local nCol := nC+1
If nPen = NIL
nPen := ::nPenSize
Endif
IF nColor = NIL
nColor := ::nFRColor
Endif
IF nRow < 1 .or. nRow > ::nHeight
return
ElseIF nCol < 1 .or. nCol > ::nWidth
return
Endif
::aMatrix[nRow][nCol] := nColor
IF nPen > 1
// 2x2
::aMatrix[nRow+1][nCol ] := nColor
::aMatrix[nRow ][nCol+1] := nColor
::aMatrix[nRow+1][nCol+1] := nColor
Endif
If nPen > 2
// 3x3
::aMatrix[nRow-1][nCol ] := nColor
::aMatrix[nRow+1][nCol ] := nColor
::aMatrix[nRow ][nCol-1] := nColor
::aMatrix[nRow ][nCol+1] := nColor
Endif
If nPen > 3
// 4x4
::aMatrix[nRow+2][nCol ] := nColor
::aMatrix[nRow ][nCol+2] := nColor
::aMatrix[nRow+2][nCol+2] := nColor
Endif
IF nPen > 4
// Caneta Acima de 4 ..
// Verifica limites da imagem
nHalf := nPen/2
For nRow := nL+1-nHalf TO nL+1+nHalf
If nRow > 0 .and. nRow <= ::nHeight
For nCol := nC+1-nHalf TO nC+1+nHalf
IF nCol > 0 .and. nCol <= ::nWidth
::aMatrix[nRow][nCol] := nColor
Endif
Next
Endif
Next
Endif
Return
// -------------------------------------------------
// Retorna a cor de um pixel
// linha e coluna, base 0
METHOD GETPIXEL(nRow,nCol) CLASS ZBITMAP
Return ::aMatrix[nRow+1][nCol+1]
// -------------------------------------------------
// Retorna a cor de fundo da imagem
// se informado um parametro, seta a cor de fundo
METHOD BgColor(nSet) CLASS ZBITMAP
If pCount()>0
::nBgColor := nSet
Endif
Return ::nBgColor
// --------------------------------------------------------
// Faz o "negativo" da imagem
// Recalcula as cores complementares da tabela de cores
METHOD Negative() CLASS ZBITMAP
Local nI
Local nL , nC
Local nRed := 0
Local nGreen := 0
Local nBlue := 0
If ::nBPP < 24
// Formatos menores que True Color, altera a tabela de cores
For nI := 1 to len(::aColors)
::aColors[nI][1] := 255-::aColors[nI][1]
::aColors[nI][2] := 255-::aColors[nI][2]
::aColors[nI][3] := 255-::aColors[nI][3]
Next
Else
// Imagem True Color, inverte as cores ponto a ponto
For nL := 1 to ::nHeight
For nC := 1 to ::nWidth
RGB2Dec(::aMatrix[nL][nC],@nRed,@nGreen,@nBlue)
nRed := 255 - nRed
nGreen := 255 - nGreen
nBlue := 255 - nBlue
::aMatrix[nL][nC] := RGB(nRed,nGreen,nBlue)
Next
Next
Endif
Return
// ---------------------------------------------------
// Salva o arquivo em disco
METHOD SaveToBMP(cFile) CLASS ZBITMAP
Local nH, nI, nC, nL
Local cHeader := ''
Local cHeadInfo := ''
If ::nBPP <> 1 .and. ::nBPP <> 4 .and. ::nBPP <> 8 .and. ::nBPP <> 24
UserException("Format not implemented (yet) to save")
Endif
nH := fCreate(cFile)
cHeader := "BM" // 2 bytes
cHeader += L2bin(::nFileSize) // 4 bytes
cHeader += chr(0)+chr(0) // 2 bytes
cHeader += chr(0)+chr(0) // 2 bytes
cHeader += L2bin(::nOffset) // 4 bytes
// Grava o primeiro Header
fWrite(nH,cHeader,len(cHEader)) // 14 bytes
cHeadInfo += L2bin(40) // This Header Size
cHeadInfo += L2bin(::nWidth) //
cHeadInfo += L2bin(::nHeight) //
cHeadInfo += I2Bin(::nColorPlanes) // Color planes
cHeadInfo += I2Bin(::nBPP) // Bits Per Pixel
cHeadInfo += L2bin(::nCompress) // Compression Method ( 0 = No Compression )
cHeadInfo += L2bin(::nRawData) // RAW Data Size
cHeadInfo += L2bin(::nHRes) // Resolucao Horizontal
cHeadInfo += L2bin(::nVRes) // Resolucao vertical
cHeadInfo += L2bin(::nColorPal) // Color Pallete
cHeadInfo += L2bin(::nImpColors) // Important Colors
// Até aqui o Header ocupou 54 bytes
// BMP Monocromatico
// Para o Offset 62, ainda faltam 8 bytes
// a tabela de cores tem apenas duas entradas, preto e branco
// BMP de 16 cores
// Até o offset 118 sao 64 bytes
// Tabela de Cores em BGRA - ( Blue Green Red Alpha ) 4 bytes por cor
For nI := 1 to len(::aColors)
cHeadInfo += chr(::aColors[nI][1])+chr(::aColors[nI][2])+chr(::aColors[nI][3])+chr(::aColors[nI][4])
Next
fWrite(nH,cHeadInfo,len(cHeadInfo))
// Armazena por default a imagem de baixo pra cima
If ::nBPP == 1
// Gravação de imagem monocromática
For nL := ::nHeight to 1 STEP -1
cBinRow := ''
cBitRow := ''
For nC := 1 to ::nWidth
cBitRow += chr( 48 + ::aMatrix[nL][nC])
Next
While len(cBitRow)%32 > 0
// Padding Bits to 32 ( 4 bytes )
cBitRow += '1'
Enddo
For nC := 0 to len(cBitRow)-1 STEP 8
cByteBit := Substr(cBitRow,nC+1,8)
nByte := BitsToN(cByteBit)
cBinRow += Chr(nByte)
Next
while len(cBinRow) < ::nRowSize
// Padding Bytes ( ASCII 0 )
cBinRow += Chr(0)
Enddo
// Grava os bytes da linha no arquivo
fWrite(nH,cBinRow)
Next
ElseIf ::nBPP == 4
// Gravação de imagem 16 cores
// 4 bits por cor
For nL := ::nHeight to 1 STEP -1
cBinRow := ''
cBitRow := ''
For nC := 1 to ::nWidth
cBitRow += Right(NTOBITS(::aMatrix[nL][nC]),4)
IF len(cBitRow) == 8
cBinRow += chr(BITSToN(cBitRow))
cBitRow := ''
Endif
Next
If !Empty(cBitRow)
cBitRow += '0000'
cBinRow += chr(BITSToN(cBitRow))
cBitRow := ''
Endif
while len(cBinRow) < ::nRowSize
// Padding Bytes ( ASCII 0 )
cBinRow += Chr(0)
Enddo
// Grava os bytes da linha no arquivo
fWrite(nH,cBinRow)
Next
ElseIf ::nBPP == 8
// Gravação de imagem 256 cores
// 8 bits por cor
For nL := ::nHeight to 1 STEP -1
cBinRow := ''
For nC := 1 to ::nWidth
cBinRow += chr(::aMatrix[nL][nC])
Next
while len(cBinRow) < ::nRowSize
// Padding Bytes ( ASCII 0 )
cBinRow += Chr(0)
Enddo
// Grava os bytes da linha no arquivo
fWrite(nH,cBinRow)
Next
ElseIf ::nBPP == 24
// Gravação de imagem True Color 24 bits
// 3 bytes por pixel
nTimer := seconds()
For nL := ::nHeight to 1 STEP -1
cBinRow := ''
For nC := 1 to ::nWidth
nRed := 0
nGreen := 0
nBlue := 0
RGB2Dec(::aMatrix[nL][nC],@nRed,@nGreen,@nBlue)
cBinRow += ( chr(nBlue)+chr(nGreen)+chr(nRed) )
Next
while len(cBinRow) < ::nRowSize
// Padding Bytes ( ASCII 0 )
cBinRow += Chr(0)
Enddo
// Grava os bytes da linha no arquivo
fWrite(nH,cBinRow)
Next
conout(seconds()-nTimer)
Else
// UserException("TODO")
Endif
fClose(nH)
Return .T.
// ---------------------------------------------------
// Salva a imagem em disco como PNG
// Por hora suporte apenas monocromatico
METHOD SaveToPNG(cFile) CLASS ZBITMAP
Local aPng := Array(14)
Local nH
Local nI, nL , nC
Local cBuffer , nDataSize , cData , cBits, nByte
aPng[PNG_WIDTH] := ::nWidth
aPng[PNG_HEIGHT] := ::nHeight
aPng[PNG_BIT_DEPHT] := 1
aPng[PNG_COLOR_TYPE] := 3
aPng[PNG_COMPRESSION] := 0
aPng[PNG_FILTER] := 0
aPng[PNG_INTERLACE] := 0
aPng[PNG_SRGB] := 0
aPng[PNG_GAMA] := 45455