-
Notifications
You must be signed in to change notification settings - Fork 8
/
zISAMFile.prw
1808 lines (1369 loc) · 44.1 KB
/
zISAMFile.prw
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
/* -------------------------------------------------------------------------------------------
Copyright 2015-2019 Júlio Wittwer ( siga0984@gmail.com | http://siga0984.wordpress.com/ )
É permitido, gratuitamente, a qualquer pessoa que obtenha uma cópia deste software
e dos arquivos de documentação associados (o "Software"), para negociar o Software
sem restrições, incluindo, sem limitação, os direitos de uso, cópia, modificação, fusão,
publicação, distribuição, sublicenciamento e/ou venda de cópias do Software,
SEM RESTRIÇÕES OU LIMITAÇÕES.
O SOFTWARE É FORNECIDO "TAL COMO ESTÁ", SEM GARANTIA DE QUALQUER TIPO, EXPRESSA OU IMPLÍCITA,
INCLUINDO MAS NÃO SE LIMITANDO A GARANTIAS DE COMERCIALIZAÇÃO, ADEQUAÇÃO A UMA FINALIDADE
ESPECÍFICA E NÃO INFRACÇÃO. EM NENHUM CASO OS AUTORES OU TITULARES DE DIREITOS AUTORAIS
SERÃO RESPONSÁVEIS POR QUALQUER REIVINDICAÇÃO, DANOS OU OUTRA RESPONSABILIDADE, SEJA
EM AÇÃO DE CONTRATO OU QUALQUER OUTRA FORMA, PROVENIENTE, FORA OU RELACIONADO AO SOFTWARE.
*** USE A VONTADE, POR SUA CONTA E RISCO ***
Permission is hereby granted, free of charge, to any person obtaining a copy of this software
and associated documentation files (the "Software"), to deal in the Software without
restriction, including without limitation the rights to use, copy, modify, merge, publish,
distribute, sublicense, and/or sell copies of the Software, and to permit persons to whom
the Software is furnished to do so, WITHOUT RESTRICTIONS OR LIMITATIONS.
THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR IMPLIED,
INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS FOR A PARTICULAR
PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE
FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT
OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE.
***USE AS YOU WISH , AT YOUR OWN RISK ***
------------------------------------------------------------------------------------------- */
#include 'Protheus.ch'
#include "zLibDateTime.ch"
#include "zLibZCompare.ch"
/* ======================================================================================
Classe ZISAMFILE
Autor Julio Wittwer
Data 01/2019
Descrição A Classe ZISAMFILE serve de base para implementação de tabeas ISAM
através de herança. Atualmente é herdada pelas classes ZDBFFILE e ZMEMFILE\
Ela serve para unificar os métodos comuns de processamento e lógica de acesso a
registros em tabela ISAM
====================================================================================== */
CLASS ZISAMFILE FROM LONGNAMECLASS
DATA cError // Descrição do último erro
DATA lVerbose // Modo Verbose (echo em console ligado)
DATA bFilter // Codeblock de filtro
DATA nIndexOrd // Ordem de indice atual
DATA aIndexes // Array com objetos de indice
DATA oCurrentIndex // Objeto do indice atual
DATA nRecno // Número do registro (RECNO) atualmnete posicionado
DATA nLastRec // Ultimo registro do arquivo - Total de registros
DATA aStruct // Array com a estrutura do DBF
DATA nFldCount // Quantidade de campos do arquivo
DATA lBOF // Flag de inicio de arquivo
DATA lEOF // Flag de final de arquivo
DATA lOpened // Indica se o arquivo está aberto
DATA lCanWrite // Arquivo aberto para gravacao
DATA aGetRecord // Array com todas as colunas do registro atual
DATA aPutRecord // Array com campos para update
DATA oISAMLogger // Objeto de log
DATA oFileDef // Definição extendida do arquivo
METHOD New() // *** O Construtor nao pode ser chamado diretamente ***
METHOD GoTo(nRec) // Posiciona em um registro informado.
METHOD GoTop() // Posiciona no RECNO 1 da tabela
METHOD GoBottom() // Posiciona em LASTREC da tabela
METHOD Skip() // Navegação de registros ISAM
METHOD SetFilter() // Permite setar um filtro para os dados
METHOD ClearFilter() // Limpa o filtro
METHOD BOF() // Retorna .T. caso tenha se tentado navegar antes do primeiro registro
METHOD EOF() // Retorna .T, caso o final de arquivo tenha sido atingido
METHOD Lastrec() // Retorna o total de registros / numero do ultimo registro da tabela
METHOD RecCount() // Retorna o total de registros / numero do ultimo registro da tabela
METHOD GetStruct() // Retorna CLONE da estrutura de dados da tabela
METHOD FCount() // Retorna o numero de campo / colunas da tabela
METHOD FieldName( nPos ) // Recupera o nome da coluna informada
METHOD FieldPos( cField ) // Retorna a posicao de um campo na estrutura da tabela ( ID da Coluna )
METHOD FieldType( nPos ) // Recupera o tipo da coluna informada
METHOD SetOrder() // Seta um indice / ordem ativa
METHOD IndexOrd() // Retorna a ordem ativa
METHOD IndexKey() // Retorna a expressao de indice ativa
METHOD IndexValue() // Retorna o valor da chave de indice do registro atual
METHOD Seek(cKeyExpr) // Realiza uma busca usando o indice ativo
METHOD CreateIndex() // Cria um Indice ( em memoria ) para a tabela
METHOD ClearIndex() // Fecha todos os indices
METHOD Search() // Busca um registro que atenda os criterios informados
METHOD CreateFrom() // Cria tabela a partir da estrutura do objeto ou alias informado
METHOD AppendFrom() // Apenda dados do objeto ou alias informado na tabela atual
METHOD Export() // Exporta o arquivo para um outro formato
METHOD Import() // Importa dados de arquivo externo em outro formato ( SDF,CSV,JSON )
METHOD GetErrorStr() // Retorna apenas a descrição do último erro ocorrido
METHOD SetVerbose() // Liga ou desliga o modo "verbose" da classe
METHOD IsVerbose() // Consulta ao modo verbose
METHOD SetFileDef() // Guarda o objeto da definição do arquivo
// ========================= Metodos de uso interno da classe
METHOD _ResetError() // Limpa a ultima ocorrencia de erro
METHOD _SetError() // Seta uma nova ocorrencia de erro
METHOD _InitVars() // Inicializa propriedades
METHOD _CheckFilter() // Verifica se o registro atual está contemplado no filtro
METHOD _SkipNext() // Le o proximo registro da tabela
METHOD _SkipPrev() // Le o registro anterior da tabela
METHOD _ClearRecord() // Limpa o conteudo do registro em memoria
METHOD _BuildFieldBlock(cFieldExpr) // Cria codeblock com expressao de campos
METHOD _ExportSDF() // Exporta dados para arquivo SDF
METHOD _ExportCSV() // Exporta dados para arquivo CSV
METHOD _ExportJSON() // Exporta dados para arquivo JSON
METHOD _ExportXML() // Exporta dados para arquivo XML
METHOD _ImportSDF() // Importa dados de arquivo SDF
METHOD _ImportCSV() // Importa dados de arquivo CSV
METHOD _ImportJSON() // Importa dados de arquivo JSON
ENDCLASS
// ----------------------------------------
METHOD New(oParent) CLASS ZISAMFILE
::oISAMLogger := ZLOGGER():New("ZISAMFILE")
::oISAMLogger:Write("NEW","IsamFile based on "+GetClassName(oParent))
Return
// ----------------------------------------
// Retorna .T. caso a ultima movimentação de registro
// tentou ir antes do primeiro registro
METHOD BOF() CLASS ZISAMFILE
Return ::lBOF
// ----------------------------------------\
// Retorna .T. caso a tabela esteja em EOF
METHOD EOF() CLASS ZISAMFILE
Return ::lEOF
// ----------------------------------------------------------
// Posiciona diretamente em um regsitro
METHOD GoTo(nRec) CLASS ZISAMFILE
// Verifica se o registro é válido
// Se não for, vai para EOF
::oISAMLogger:Write("GoTo","Record "+cValToChar(nRec))
If nRec > ::nLastRec .or. nRec < 1
::lEOF := .T.
::_ClearRecord()
Return
Endif
// ----------------------------------------
// Atualiza o numero do registro atual
::nRecno := nRec
// Traz o registro atual para a memória
::_ReadRecord()
Return
// ----------------------------------------------------------
// Movimenta a tabela para o primeiro registro
// Release 20190105 : Contempla uso de indice
METHOD GoTop() CLASS ZISAMFILE
::oISAMLogger:Write("GoToP")
IF ::nLastRec == 0
// Nao há registros
::lBOF := .T.
::lEOF := .T.
::nRecno := 0
::_ClearRecord()
Return
Endif
If ::nIndexOrd > 0
// Se tem indice ativo, pergunta pro indice
// quanl é o primeiro registro da ordem
::nRecno := ::oCurrentIndex:GetFirstRec()
Else
// Ordem fisica
// Atualiza para o primeiro registtro
::nRecno := 1
Endif
// Traz o registro atual para a memória
::_ReadRecord()
If ( !::_CheckFilter() )
// Nao passou na verificacao do filtro
// busca o proximo registro que atenda
::_SkipNext()
Endif
Return
// ----------------------------------------------------------
// Movimenta a tabela para o último registro
METHOD GoBottom() CLASS ZISAMFILE
::oISAMLogger:Write("GoBottom")
IF ::nLastRec == 0
// Nao há registros
::lBOF := .T.
::lEOF := .T.
::nRecno := 0
::_ClearRecord()
Return
Endif
If ::nIndexOrd > 0
// Se tem indice ativo, pergunta pro indice
// quanl é o primeiro registro da ordem
::nRecno := ::oCurrentIndex:GetLastRec()
Else
// Ordem fisica
// Atualiza o RECNO para o ultimo registro
::nRecno := ::nLastRec
Endif
// Traz o registro atual para a memória
::_ReadRecord()
If ( !::_CheckFilter() )
// Nao passou na verificacao do filtro
// busca nos registros anteriores o primeiro que atende
::_SkipPrev()
Endif
Return
// ----------------------------------------------------------
// Avança ou retrocede o ponteiro de registro
// No caso de DBSkip(0), apenas faz refresh do registro atual
// Default = 1 ( Próximo Registro )
METHOD Skip( nQtd ) CLASS ZISAMFILE
Local lForward := .T.
::oISAMLogger:Write("Skip")
If nQtd == NIL
nQtd := 1
ElseIF nQtd < 0
lForward := .F.
Endif
// Quantidade de registros para mover o ponteiro
// Se for negativa, remove o sinal
nQtd := abs(nQtd)
While nQtd > 0
If lForward
IF ::_SkipNext()
nQtd--
Else
// Bateu EOF()
::_ClearRecord()
Return
Endif
Else
IF ::_SkipPrev()
nQtd--
Else
// Bateu BOF()
Return
Endif
Endif
Enddo
// Traz o registro atual para a memória
::_ReadRecord()
Return
// ----------------------------------------------------------
// Permite setar um filtro para a navegação de dados
// Todos os campos devem estar em letras maiusculas
METHOD SetFilter( cFilter ) CLASS ZISAMFILE
Local cFilterBlk
::oISAMLogger:Write("SetFilter",cFilter)
// retorna string com codebloc para expressao de campos
cFilterBlk := ::_BuildFieldBlock(cFilter)
// Monta efetivamente o codeblock
::bFilter := &(cFilterBlk)
Return .T.
// ----------------------------------------------------------
// Limpa a expressao de filtro atual
METHOD ClearFilter() CLASS ZISAMFILE
::oISAMLogger:Write("ClearFilter")
::bFilter := NIL
Return
// ----------------------------------------------------------
// Retorna o numero do ultimo registro da tabela
METHOD Lastrec() CLASS ZISAMFILE
Return ::nLastRec
// ----------------------------------------------------------
// Colocado apenas por compatibilidade
//
METHOD Reccount() CLASS ZISAMFILE
Return ::nLastRec
// ----------------------------------------------------------
// Retorna um clone do Array da estrutura da tabela
METHOD GetStruct() CLASS ZISAMFILE
Return aClone( ::aStruct )
// ----------------------------------------------------------
// Retorna o numero de campo / colunas da tabela
METHOD FCount() CLASS ZISAMFILE
Return ::nFldCount
// ----------------------------------------------------------
// Recupera o nome de um campo da tabela
// a partir da posicao do campo na estrutura
METHOD FieldName(nPos) CLASS ZISAMFILE
If nPos > 0 .and. nPos <= ::nFldCount
Return ::aStruct[nPos][1]
Endif
Return NIL
// ----------------------------------------------------------
// Recupera o numero do campo na estrutura da tabela
// a partir do nome do campo
METHOD FieldPos( cField ) CLASS ZISAMFILE
Return ASCAN( ::aStruct , {|x| x[1] = cField })
// ----------------------------------------------------------
// Recupera o tipo do campo na estrutura da tabela
// a partir da posicao do campo na estrutura
METHOD FieldType(nPos) CLASS ZISAMFILE
If nPos > 0 .and. nPos <= ::nFldCount
Return ::aStruct[nPos][2]
Endif
Return NIL
// ----------------------------------------
// Permite trocar a ordedm atual usando
// um indice aberto
METHOD SetOrder(nOrd) CLASS ZISAMFILE
::oISAMLogger:Write("SetOrder","Order: "+cValToChar(nOrd))
If nOrd < 0 .OR. nOrd > len( ::aIndexes )
UserException("DbSetOrder - Invalid Order "+cValToChar(nOrd))
Endif
::nIndexOrd := nOrd
If ::nIndexOrd > 0
::oCurrentIndex := ::aIndexes[::nIndexOrd]
Else
::oCurrentIndex := NIL
Endif
Return
// ----------------------------------------
// Retorna o numero da ordem do indce ativo
METHOD IndexOrd() CLASS ZISAMFILE
Return ::nIndexOrd
// ----------------------------------------
// Retorna a expressao da chave de indice atual
// Caso nao haja indice ativo, retorna ""
METHOD IndexKey() CLASS ZISAMFILE
IF ::nIndexOrd > 0
Return ::oCurrentIndex:GetIndexExpr()
Endif
Return ""
// ----------------------------------------
// Retorna o numero da ordem do indce ativo
METHOD IndexValue() CLASS ZISAMFILE
IF ::nIndexOrd > 0
Return ::oCurrentIndex:GetIndexValue()
Endif
Return NIL
// ----------------------------------------
// Retorna o numero da ordem do indce ativo
METHOD Seek(cKeyExpr) CLASS ZISAMFILE
Local nRecFound := 0
::oISAMLogger:Write("Seek","Key: "+cKeyExpr)
IF ::nIndexOrd <= 0
UserException("DBSeek Failed - No active Index")
Endif
nRecFound := ::oCurrentIndex:IndexSeek(cKeyExpr)
If nRecFound > 0
// NAo precisa resincronizar o indice
// Eu já fiz a busca pelo indice
::nRecno := nRecFound
::_ReadRecord()
Return .T.
Endif
// Nao achou nada, vai para EOF
::lEOF := .T.
::_ClearRecord()
Return .F.
// ----------------------------------------
// *** METODO DE USO INTERNO ***
// Cria uma instancia de um indice em memoria
// Acrescenta na lista de indices
// Torna o indice ativo e posiciona no primeiro
// registro da nova ordem
METHOD CreateIndex(cIndexExpr) CLASS ZISAMFILE
Local oMemIndex
Local nLastIndex
::oISAMLogger:Write("CreateIndex","Expression: "+cIndexExpr)
// Cria o objeto do indice passando a instancia
// do arquivo DBF atual
oMemIndex := ZMEMINDEX():New(self)
// Cria o indice com a expressao informada
oMemIndex:CreateIndex(cIndexExpr)
// Acrescenta o indice criado na tabela
aadd(::aIndexes,oMemIndex)
// E torna este indice atual
nLastIndex := len(::aIndexes)
::SetOrder( nLastIndex )
// Posiciona no primeiro registro da nova ordem
::GoTop()
Return
// ----------------------------------------
// Fecha todos os indices
METHOD ClearIndex() CLASS ZISAMFILE
Local nI
::oISAMLogger:Write("ClearIndex")
For nI := 1 to len(::aIndexes)
::oCurrentIndex := ::aIndexes[nI]
::oCurrentIndex:Close()
FreeObj(::oCurrentIndex)
Next
Return
// ----------------------------------------------------------
// Cria um arquivo de dados na instancia atual usando a estrutura
// do objeto de arquivo de dados informado como parametro
// Pode ser infomado um Alias / WorkArea
// Caso lAppend seja .T., a tabela é aberta em modo exclusivo e para gravação
// e os dados são importados
METHOD CreateFrom( _oDBF , lAppend ) CLASS ZISAMFILE
Local lFromAlias := .F.
Local cAlias := ""
Local aStruct := {}
::oISAMLogger:Write("CreateFrom")
If lAppend = NIL ; lAppend := .F. ; Endif
If valtype(_oDBF) == 'C'
// Se a origem é caractere, só pode ser um ALIAS
lFromAlias := .T.
cAlias := alltrim(upper(_oDBF))
If Select(cAlias) < 1
UserException("Alias does not exist - "+cAlias)
Endif
aStruct := (cAlias)->(DbStruct())
Else
aStruct := _oDBF:GetStruct()
Endif
If !::Create(aStruct)
Return .F.
Endif
IF lAppend
// Dados serão apendados na criação
// Abre para escrita exclusiva
If !::Open(.T.,.T.)
Return .F.
Endif
// Apenda os dados
IF !::AppendFrom(_oDBF)
Return .F.
Endif
// E posiciona no primeiro registro
::GoTop()
Endif
Return .T.
// ----------------------------------------------------------
// Apena os dados da tabela informada na atual
// Origem = _oDBF
// Destino = self
METHOD AppendFrom( _oDBF , lAll, lRest , cFor , cWhile ) CLASS ZISAMFILE
Local aFromTo := {}
Local aFrom := {}
Local nI, nPos, cField
Local lFromAlias := .F.
Local cAlias := ""
::oISAMLogger:Write("AppendFrom")
DEFAULT lAll := .T.
DEFAULT lRest := .F.
DEFAULT cFor := ''
DEFAULT cWhile := ''
// Primeiro, a tabela tem qye estar aberta
IF !::lOpened
UserException("AppendFrom Failed - Table not opened")
Return .F.
Endif
IF !::lCanWrite
UserException("AppendFrom Failed - Table opened for READ ONLY")
Return .F.
Endif
If valtype(_oDBF) == 'C'
// Se a origem é caractere, só pode ser um ALIAS
lFromAlias := .T.
cAlias := alltrim(upper(_oDBF))
If Select(cAlias) < 1
UserException("Alias does not exist - "+cAlias)
Endif
aFrom := (cAlias)->(DbStruct())
Else
aFrom := _oDBF:GetStruct()
Endif
// Determina match de campos da origem no destino
For nI := 1 to len(aFrom)
cField := aFrom[nI][1]
nPos := ::FieldPos(cField)
If nPos > 0
aadd( aFromTo , { nI , nPos })
Endif
Next
IF lFromAlias
// Dados de origem a partir de uma WorkArea
If lAll
// Se é para importar tudo, pega desde o primeiro registro
(cAlias)->(DbGoTop())
Endif
While !(cAlias)->(EOF())
// Insere um novo registro na tabela atual
::Insert()
// Preenche os campos com os valores da origem
For nI := 1 to len(aFromTo)
::FieldPut( aFromTo[nI][2] , (cAlias)->(FieldGet(aFromTo[nI][1])) )
Next
// Atualiza os valores
::Update()
// Vai para o procimo registro
(cAlias)->(DbSkip())
Enddo
Else
If lAll
// Se é para importar tudo, pega desde o primeiro registro
_oDBF:GoTop()
Endif
While !_oDBF:EOF()
// Insere um novo registro na tabela atual
::Insert()
// Preenche os campos com os valores da origem
For nI := 1 to len(aFromTo)
::FieldPut( aFromTo[nI][2] , _oDBF:FieldGet(aFromTo[nI][1]) )
Next
// Atualiza os valores
::Update()
// Vai para o procimo registro
_oDBF:Skip()
Enddo
Endif
Return .T.
// ----------------------------------------------------------
// Exporta o arquivo para um outro formato
// cFormat = Formato a exportar
// SDF
// CSV
// JSON
// XML
// cFileOut = Arquivo de saída
METHOD Export( cFormat, cFileOut , bBlock ) CLASS ZISAMFILE
::oISAMLogger:Write("Export")
// Primeiro, a tabela tem qye estar aberta
IF !::lOpened
UserException("ZISAMFILE:EXPORT() Failed - Table not opened")
Return .F.
Endif
cFormat := alltrim(Upper(cFormat))
If cFormat == "SDF"
lOk := ::_ExportSDF(cFileOut)
ElseIf cFormat == "CSV"
lOk := ::_ExportCSV(cFileOut)
ElseIf cFormat == "JSON"
lOk := ::_ExportJSON(cFileOut)
ElseIf cFormat == "XML"
lOk := ::_ExportXML(cFileOut)
Else
UserException("Export() ERROR - Formato ["+cFormat+"] não suportado. ")
Endif
Return lOk
// ----------------------------------------------------------
// Recebe a definicao extendida da tabela
// Com isso eu já tenho a estrutura
METHOD SetFileDef(oDef) CLASS ZISAMFILE
::oISAMLogger:Write("SetFileDef")
IF ::lOpened
UserException("SetFileDef Failed - Table already opened")
Return .F.
Endif
// Recebe a definição do arquivo
::oFileDef := oDef
Return .T.
// ----------------------------------------------------------
// Formato SDF
// Texto sem delimitador , Campos colocados na ordem da estrutura
// CRLF como separador de linhas
// Campo MEMO não é exportado
METHOD _ExportSDF( cFileOut ) CLASS ZISAMFILE
Local nHOut
Local nPos
Local cBuffer := ''
Local cRow
Local cTipo,nTam,nDec
::oISAMLogger:Write("_ExportSDF")
nHOut := fCreate(cFileOut)
If nHOut == -1
::_SetError("Output SDF File Create Error - FERROR "+cValToChar(Ferror()))
Return .F.
Endif
::GoTop()
While !::Eof()
// Monta uma linha de dados
cRow := ""
For nPos := 1 TO ::nFldCount
cTipo := ::aStruct[nPos][2]
nTam := ::aStruct[nPos][3]
nDec := ::aStruct[nPos][4]
IF cTipo = 'M'
Loop
Endif
If cTipo = 'C'
cRow += ::FieldGet(nPos)
ElseIf cTipo = 'N'
cRow += Str(::FieldGet(nPos),nTam,nDec)
ElseIf cTipo = 'D'
cRow += DTOS(::FieldGet(nPos))
ElseIf cTipo = 'L'
cRow += IIF(::FieldGet(nPos),'T','F')
Endif
Next
cRow += CRLF
cBuffer += cRow
If len(cBuffer) > 32000
// A cada 32 mil bytes grava em disco
fWrite(nHOut,cBuffer)
cBuffer := ''
Endif
::Skip()
Enddo
// Grava flag de EOF
cBuffer += Chr(26)
// Grava resto do buffer que falta
fWrite(nHOut,cBuffer)
cBuffer := ''
fClose(nHOut)
Return
// ----------------------------------------------------------
// Formato CSV
// Strings entre aspas duplas, campos colocados na ordem da estrutura
// Virgula como separador de campos, CRLF separador de linhas
// Gera o CSV com Header
// Campo MEMO não é exportado
METHOD _ExportCSV( cFileOut ) CLASS ZISAMFILE
Local nHOut
Local nPos
Local cBuffer := ''
Local cRow
Local cTipo,nTam,nDec
::oISAMLogger:Write("_ExportCSV")
nHOut := fCreate(cFileOut)
If nHOut == -1
::_SetError("Output CSV File Create Error - FERROR "+cValToChar(Ferror()))
Return .F.
Endif
// Primeira linha é o "header" com o nome dos campos
For nPos := 1 TO ::nFldCount
If ::aStruct[nPos][2] == 'M'
Loop
Endif
If nPos > 1
cBuffer += ','
Endif
cBuffer += '"'+Alltrim(::aStruct[nPos][1])+'"'
Next
cBuffer += CRLF
::GoTop()
While !::Eof()
// Monta uma linha de dados
cRow := ""
For nPos := 1 TO ::nFldCount
cTipo := ::aStruct[nPos][2]
nTam := ::aStruct[nPos][3]
nDec := ::aStruct[nPos][4]
IF cTipo = 'M'
Loop
Endif
If nPos > 1
cRow += ","
Endif
If cTipo = 'C'
// Dobra aspas duplas caso exista dentro do conteudo
cRow += '"' + StrTran(rTrim(::FieldGet(nPos)),'"','""') + '"'
ElseIf cTipo = 'N'
// Numero trimado
cRow += cValToChar(::FieldGet(nPos))
ElseIf cTipo = 'D'
// Data em formato AAAAMMDD entre aspas
cRow += '"'+Alltrim(DTOS(::FieldGet(nPos)))+'"'
ElseIf cTipo = 'L'
// Boooleano true ou false
cRow += IIF(::FieldGet(nPos),'true','false')
Endif
Next
cRow += CRLF
cBuffer += cRow
If len(cBuffer) > 32000
// A cada 32 mil bytes grava em disco
fWrite(nHOut,cBuffer)
cBuffer := ''
Endif
::Skip()
Enddo
// Grava resto do buffer que falta
If len(cBuffer) > 0
fWrite(nHOut,cBuffer)
cBuffer := ''
Endif
fClose(nHOut)
Return .T.
// ----------------------------------------------------------
// Formato JSON - Exporta estrutura e dados
// Objeto com 2 propriedades
// header : Array de Arrays, 4 colunas, estrutura da tabela
// data : Array de Arrays, cada linha é um registro da tabela,
// campos na ordem da estrutura
// -- Campo Memo não é exportado
/* {
"header": [
["cCampo", "cTipo", nTam, nDec], ...
],
"data": [
["José", 14, true], ...
] }
*/
METHOD _ExportJSON( cFileOut ) CLASS ZISAMFILE
Local nHOut
Local nPos
Local cBuffer := ''
Local lFirst := .T.
Local cRow
Local cTipo,nTam,nDec
::oISAMLogger:Write("_ExportJSON")
nHOut := fCreate(cFileOut)
If nHOut == -1
::_SetError("Output JSON File Create Error - FERROR "+cValToChar(Ferror()))
Return .F.
Endif
cBuffer += '{' + CRLF
cBuffer += '"header": [' + CRLF
For nPos := 1 to len(::aStruct)
If ::aStruct[nPos][2] == 'M'
LOOP
Endif
If nPos = 1
cBuffer += "["
Else
cBuffer += '],'+CRLF+'['
Endif
cBuffer += '"'+Alltrim(::aStruct[nPos][1])+'","'+;
::aStruct[nPos][2]+'",'+;
cValToChar(::aStruct[nPos][3])+','+;
cValToChar(::aStruct[nPos][4])
Next
cBuffer += ']'+CRLF
cBuffer += ']' + CRLF
cBuffer += ',' + CRLF
cBuffer += '"data": [' + CRLF
::GoTop()
While !::Eof()
// Monta uma linha de dados
if lFirst
cRow := "["
lFirst := .F.
Else
cRow := "],"+CRLF+"["
Endif
For nPos := 1 TO ::nFldCount
cTipo := ::aStruct[nPos][2]
nTam := ::aStruct[nPos][3]
nDec := ::aStruct[nPos][4]
IF cTipo = 'M'
Loop
Endif
If nPos > 1
cRow += ","
Endif
If cTipo = 'C'
// Usa Escape sequence de conteudo
// para astas duplas. --
cRow += '"' + StrTran(rTrim(::FieldGet(nPos)),'"','\"') + '"'
ElseIf cTipo = 'N'
// Numero trimado
cRow += cValToChar(::FieldGet(nPos))
ElseIf cTipo = 'D'
// Data em formato AAAAMMDD como string
cRow += '"'+Alltrim(DTOS(::FieldGet(nPos)))+'"'
ElseIf cTipo = 'L'
// Boooleano = true ou false
cRow += IIF(::FieldGet(nPos),'true','false')
Endif
Next
cBuffer += cRow
If len(cBuffer) > 32000
// A cada 32 mil bytes grava em disco
fWrite(nHOut,cBuffer)
cBuffer := ''
Endif
::Skip()
Enddo
// Termina o JSON
cBuffer += ']' + CRLF
cBuffer += ']' + CRLF
cBuffer += '}' + CRLF