forked from gudtech/x12-schema
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Sequence.pm
168 lines (129 loc) · 5.6 KB
/
Sequence.pm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
package X12::Schema::Sequence;
use Moose;
use namespace::autoclean;
use Carp 'croak';
with 'X12::Schema::Sequencable';
has children => (isa => 'ArrayRef[X12::Schema::Sequencable]', is => 'ro', required => 1);
has _cooked_begin => (isa => 'ArrayRef[HashRef]', is => 'bare');
has _cooked_nofollow => (isa => 'ArrayRef[HashRef]', is => 'bare');
has _cooked_empty => (isa => 'ArrayRef[Bool]', is => 'bare');
# DIVERSITY: These loop rules are much looser than prescribed by X12.6
# DIVERSITY: may need to handle UN/EDIFACT's explicit nesting indicators
sub encode {
my ($self, $sink, $obj) = @_;
die "Sequence ".$self->name." can only encode a HASH" unless $obj && ref($obj) eq 'HASH' && !blessed($obj);
my %tmp = %$obj; # we will remove things as they are processed
my @output;
for my $elem (@{ $self->children }) {
my $passed = delete $tmp{ $elem->name };
if (!defined($elem->max_use) || $elem->max_use > 1) {
$passed ||= [];
die "Replicated segment or loop ".$elem->name." must encode an ARRAY" unless ref($passed) eq 'ARRAY' && !blessed($passed);
die "Segment or loop ".$elem->name." is required" if $elem->required && !@$passed;
die "Segment or loop ".$elem->name." is limited to ".$elem->max_use." uses" if $elem->max_use && @$passed > $elem->max_use;
$elem->encode($sink, $_) for @$passed;
}
else {
die "Segment or loop ".$elem->name." is required" if $elem->required && !defined($passed);
$elem->encode($sink, $passed) if defined($passed);
}
}
die "Unused children passed to ".$self->name.": ".join(', ',sort keys %tmp) if %tmp;
}
sub decode {
my ($self, $src, $exit_cont) = @_;
my $kids = $self->{children};
my @internal_cont;
my %data;
$internal_cont[ @$kids ] = $exit_cont;
for my $i ( reverse 0 .. $#$kids ) {
$internal_cont[$i] = $self->{_cooked_empty}[$i] ?
{ %{ $self->{_cooked_begin}[$i] }, %{ $internal_cont[$i+1] } } :
$self->{_cooked_begin}[$i];
}
for my $i ( 0 .. $#$kids ) {
my $kid = $kids->[$i];
printf "Looking for %s at %d (%s)\n", join('|', sort keys %{ $kid->_initial_tags }), $src->segment_counter+1, $src->peek_code
if $src->trace > 0;
if ($src->peek_code && !$internal_cont[$i]{$src->peek_code}) {
$src->get;
die "Unexpected segment at ".$src->segment_counter."\n";
}
if (defined($kid->max_use) && $kid->max_use == 1) {
if ($kid->_initial_tags->{ $src->peek_code }) {
$data{ $kid->name } = $kid->decode( $src, $internal_cont[$i+1] );
} elsif ($kid->required) {
die $kid->name." is required at ".($src->segment_counter+1)."\n";
}
}
else {
my @accum;
while ($kid->_initial_tags->{ $src->peek_code }) {
if (defined($kid->max_use) && @accum >= $kid->max_use) {
die $kid->name." exceeds ".$kid->max_use." occurrences at ".($src->segment_counter+1)."\n";
}
push @accum, $kid->decode( $src, $internal_cont[$i] ); # deliberately $i - we'll loop back
}
if ($kid->required && !@accum) {
die $kid->name." is required at ".($src->segment_counter+1)."\n";
}
$data{$kid->name} = \@accum;
}
}
return \%data;
}
sub BUILD {
my ($self) = @_;
my $elems = $self->children;
my (@begin, @nofollow, @empty);
# Correct the values for min/max
for my $child (@$elems) {
push @begin, $child->_initial_tags;
push @nofollow, $child->_ambiguous_end_tags;
push @empty, $child->_can_be_empty;
my $desc = "Child " . $child->name . " of " . $self->name;
if (!defined($child->max_use) || $child->max_use > 1) {
croak "$desc can be empty, so it may not be repeated unambiguously"
if $empty[-1];
croak "$desc is ambiguous when followed by itself"
if grep { exists $nofollow[-1]{$_} } keys %{ $begin[-1] };
$nofollow[-1] = { %{ $nofollow[-1] }, %{ $begin[-1] } };
}
if (!$child->required) {
croak "$desc can already be empty, so it may not be optional" if $empty[-1];
$nofollow[-1] = { %{ $nofollow[-1] }, %{ $begin[-1] } };
$empty[-1] = 1;
}
}
$self->{_cooked_empty} = \@empty;
$self->{_cooked_nofollow} = \@nofollow;
$self->{_cooked_begin} = \@begin;
# get initial
my %initial;
my $can_be_empty = 1;
for my $childix ( 0 .. $#$elems ) {
%initial = (%initial, %{ $begin[$childix] });
unless ($empty[$childix]) {
$can_be_empty = 0;
last;
}
}
# check for composition errors
my %excluded_from_continuation;
for my $ix ( 0 .. $#$elems ) {
my $herename = $elems->[$ix]->name;
my ($conflict) = grep { exists $excluded_from_continuation{$_} } keys %{ $begin[$ix] };
if ($conflict) {
croak sprintf "In %s, %s can start with tag %s which makes the end of %s ambiguous",
$self->name, $herename, $conflict, $excluded_from_continuation{$conflict};
}
%excluded_from_continuation = () unless $empty[$ix];
for my $exclude (keys %{ $nofollow[$ix] }) {
$excluded_from_continuation{$exclude} = $herename;
}
}
$self->_can_be_empty($can_be_empty);
$self->_ambiguous_end_tags(\%excluded_from_continuation);
$self->_initial_tags(\%initial);
}
__PACKAGE__->meta->make_immutable;