feat(igor-bom): publish igor-bom (#464)

* feat(igor-bom): publish igor-bom

build.gradle

@@ -29,11 +29,13 @@ buildscript {
 }
 
 allprojects {
-    group = "com.netflix.spinnaker.igor"
-    apply plugin: 'spinnaker.base-project'
-    if (Boolean.valueOf(enablePublishing)) {
-      apply plugin: 'spinnaker.project'
-    }
+  group = "com.netflix.spinnaker.igor"
+  apply plugin: 'spinnaker.base-project'
+  if (Boolean.valueOf(enablePublishing)) {
+    apply plugin: 'spinnaker.project'
+  }
+
+  if (name != "igor-bom") {
     apply plugin: 'java-library'
     apply plugin: 'groovy'
 
@@ -51,6 +53,7 @@ allprojects {
         jvmArgs '-agentlib:jdwp=transport=dt_socket,server=y,suspend=n,address=8188'
       }
     }
+  }
 }
 
 defaultTasks 'run'

igor-bom/igor-bom.gradle

@@ -0,0 +1,52 @@
+/*
+ * Copyright 2019 Netflix, Inc.
+ *
+ * Licensed under the Apache License, Version 2.0 (the "License");
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *    http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ */
+
+apply plugin: "java-platform"
+apply plugin: "maven-publish"
+
+// without this building the pom fails when using the Nebula publishing plugin
+configurations {
+  create("compileOnly")
+}
+
+javaPlatform {
+  allowDependencies()
+}
+
+
+if (Boolean.valueOf(enablePublishing)) {
+  publishing {
+    publications {
+      nebula(MavenPublication) {
+        from components.javaPlatform
+      }
+    }
+  }
+}
+
+dependencies {
+  api(platform("com.netflix.spinnaker.kork:kork-bom:$korkVersion"))
+
+  constraints {
+    api("com.netflix.spinnaker.fiat:fiat-api:$fiatVersion")
+    api("com.netflix.spinnaker.fiat:fiat-core:$fiatVersion")
+
+    rootProject
+      .subprojects
+      .findAll { it != project }
+      .each { api(project(it.path)) }
+  }
+}

settings.gradle

@@ -16,7 +16,7 @@
 
 rootProject.name='igor'
 
-include 'igor-web'
+include 'igor-web', 'igor-bom'
 
 def setBuildFile(project) {
     project.buildFileName = "${project.name}.gradle"