Add a POST echo example

examples/echo_post/README.md

@@ -0,0 +1,24 @@
+Cowboy POST Echo
+================
+
+To compile this example you need rebar in your PATH.
+
+Type the following command:
+```
+$ rebar get-deps compile
+```
+
+You can then start the Erlang node with the following command:
+```
+./start.sh
+```
+
+Then point your browser to the indicated URL. You can change
+the GET parameter to check that the handler is echoing properly.
+
+Then run the following command, replacing STRING_TO_ECHO by the
+string you want to echo. Check the ```curl_post.sh``` file for details.
+
+```
+./curl_post.sh STRING_TO_ECHO
+```

examples/echo_post/curl_post.sh

@@ -0,0 +1,2 @@
+#!/bin/sh
+curl -i -d echo=$1 http://localhost:8080

examples/echo_post/rebar.config

@@ -0,0 +1,4 @@
+{deps, [
+	{cowboy, ".*",
+		{git, "git://github.com/extend/cowboy.git", "master"}}
+]}.

examples/echo_post/src/echo_post.app.src

@@ -0,0 +1,15 @@
+%% Feel free to use, reuse and abuse the code in this file.
+
+{application, echo_post, [
+	{description, "Cowboy POST echo example."},
+	{vsn, "1"},
+	{modules, []},
+	{registered, []},
+	{applications, [
+		kernel,
+		stdlib,
+		cowboy
+	]},
+	{mod, {echo_post_app, []}},
+	{env, []}
+]}.

examples/echo_post/src/echo_post.erl

@@ -0,0 +1,12 @@
+%% Feel free to use, reuse and abuse the code in this file.
+
+-module(echo_post).
+
+%% API.
+-export([start/0]).
+
+%% API.
+
+start() ->
+	ok = application:start(cowboy),
+	ok = application:start(echo_post).

examples/echo_post/src/echo_post_app.erl

@@ -0,0 +1,26 @@
+%% Feel free to use, reuse and abuse the code in this file.
+
+%% @private
+-module(echo_post_app).
+-behaviour(application).
+
+%% API.
+-export([start/2]).
+-export([stop/1]).
+
+%% API.
+
+start(_Type, _Args) ->
+	Dispatch = [
+		{'_', [
+			{[], toppage_handler, []}
+		]}
+	],
+	{ok, _} = cowboy:start_listener(http, 100,
+		cowboy_tcp_transport, [{port, 8080}],
+		cowboy_http_protocol, [{dispatch, Dispatch}]
+	),
+	echo_post_sup:start_link().
+
+stop(_State) ->
+	ok.

examples/echo_post/src/echo_post_sup.erl

@@ -0,0 +1,23 @@
+%% Feel free to use, reuse and abuse the code in this file.
+
+%% @private
+-module(echo_post_sup).
+-behaviour(supervisor).
+
+%% API.
+-export([start_link/0]).
+
+%% supervisor.
+-export([init/1]).
+
+%% API.
+
+-spec start_link() -> {ok, pid()}.
+start_link() ->
+	supervisor:start_link({local, ?MODULE}, ?MODULE, []).
+
+%% supervisor.
+
+init([]) ->
+	Procs = [],
+	{ok, {{one_for_one, 10, 10}, Procs}}.

examples/echo_post/src/toppage_handler.erl

@@ -0,0 +1,36 @@
+%% Feel free to use, reuse and abuse the code in this file.
+
+%% @doc POST echo handler.
+-module(toppage_handler).
+
+-export([init/3]).
+-export([handle/2]).
+-export([terminate/2]).
+
+init(_Transport, Req, []) ->
+	{ok, Req, undefined}.
+
+handle(Req, State) ->
+	{Method, Req2} = cowboy_http_req:method(Req),
+	{HasBody, Req3} = cowboy_http_req:has_body(Req2),
+	{ok, Req4} = maybe_echo(Method, HasBody, Req3),
+	{ok, Req4, State}.
+
+maybe_echo('POST', true, Req) ->
+	{PostVals, Req2} = cowboy_http_req:body_qs(Req),
+	Echo = proplists:get_value(<<"echo">>, PostVals),
+	echo(Echo, Req2);
+maybe_echo('POST', false, Req) ->
+	cowboy_http_req:reply(400, [], <<"Missing body.">>, Req);
+maybe_echo(_, _, Req) ->
+	%% Method not allowed.
+	cowboy_http_req:reply(405, Req).
+
+echo(undefined, Req) ->
+	cowboy_http_req:reply(400, [], <<"Missing echo parameter.">>, Req);
+echo(Echo, Req) ->
+	cowboy_http_req:reply(200,
+		[{<<"Content-Encoding">>, <<"utf-8">>}], Echo, Req).
+
+terminate(_Req, _State) ->
+	ok.

examples/echo_post/start.sh

@@ -0,0 +1,3 @@
+#!/bin/sh
+erl -pa ebin deps/*/ebin -s echo_post \
+	-eval "io:format(\"Run ./curl_post.sh STRING_TO_ECHO\")."