webfortune: init

Signed-off-by: Sumner Evans <me@sumnerevans.com>

flake.nix

@@ -3,9 +3,14 @@
   inputs = {
     nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
     flake-utils.url = "github:numtide/flake-utils";
+    webfortune = {
+      url = "github:sumnerevans/webfortune";
+      inputs.nixpkgs.follows = "nixpkgs";
+      inputs.flake-utils.follows = "flake-utils";
+    };
   };
 
-  outputs = { self, nixpkgs, flake-utils }@inputs: {
+  outputs = inputs@{ self, nixpkgs, flake-utils, webfortune }: {
     nixosConfigurations = {
       tatooine = nixpkgs.lib.nixosSystem {
         system = "x86_64-linux";

host-configurations/morak.nix

@@ -1,4 +1,10 @@
-{ config, lib, pkgs, modulesPath, ... }: with lib; {
+{ config, lib, pkgs, modulesPath, inputs, ... }: with lib; let
+  quotesfile = pkgs.fetchurl {
+    url = "https://raw.githubusercontent.com/sumnerevans/home-manager-config/master/modules/email/quotes";
+    hash = "sha256-79oQM/7QyVRDXV+BBz6qfhp7n6dakaNgJAMvnbqGPx0=";
+  };
+in
+{
   imports = [ (modulesPath + "/profiles/qemu-guest.nix") ];
 
   boot = {
@@ -124,6 +130,14 @@
   services.backup.healthcheckId = "6c9caf62-4f7b-4ef7-82ac-d858d3bcbcb5";
   services.backup.healthcheckPruneId = "f90ed04a-2596-49d0-a89d-764780a27fc6";
 
+  # Webfortune
+  services.webfortune = {
+    enable = true;
+    inherit quotesfile;
+    sourceUrl = "https://github.com/sumnerevans/home-manager-config/blob/master/modules/email/quotes";
+    virtualHost = "fortune.sumnerevans.com";
+  };
+
   # Add a backup service for the actual config.
   services.backup.backups.syncthing-pictures-tmp-data = {
     path = "/mnt/syncthing-pictures-tmp";

host-configurations/tatooine.nix

@@ -1,4 +1,4 @@
-{ modulesPath, ... }: {
+{ modulesPath, pkgs, ... }: {
   imports = [ (modulesPath + "/profiles/qemu-guest.nix") ];
 
   boot.initrd.availableKernelModules = [ "ahci" "xhci_pci" "virtio_pci" "sd_mod" "sr_mod" ];

modules/services/default.nix

@@ -18,6 +18,7 @@
     ./restic.nix
     ./sshd.nix
     ./syncthing.nix
+    ./webfortune.nix
     ./xandikos.nix
   ];
 

modules/services/webfortune.nix

@@ -0,0 +1,58 @@
+{ config, inputs, lib, pkgs, ... }:
+with lib;
+let
+  cfg = config.services.webfortune;
+in
+{
+  options = {
+    services.webfortune = {
+      enable = mkEnableOption "webfortune";
+      quotesfile = mkOption {
+        type = types.path;
+        description = "Path to the quotesfile";
+      };
+      sourceUrl = mkOption {
+        type = types.str;
+        description = "URL to the quotesfile";
+      };
+      virtualHost = mkOption {
+        type = types.str;
+        description = "The virtual host to use";
+      };
+      listenAddr = mkOption {
+        type = types.str;
+        default = "0.0.0.0:8477";
+        description = "Address to listen on";
+      };
+    };
+  };
+
+  config = mkIf cfg.enable {
+    services.nginx = {
+      enable = true;
+      virtualHosts.${cfg.virtualHost} = {
+        addSSL = true;
+        enableACME = true;
+        locations."/" = {
+          recommendedProxySettings = true;
+          proxyPass = "http://${cfg.listenAddr}";
+        };
+      };
+    };
+
+    systemd.services.webfortune = {
+      description = "webfortune";
+      after = [ "network.target" ];
+      wantedBy = [ "multi-user.target" ];
+      environment = {
+        QUOTESFILE = cfg.quotesfile;
+        QUOTESFILE_SOURCE_URL = cfg.sourceUrl;
+        LISTEN_ADDR = cfg.listenAddr;
+      };
+      serviceConfig = {
+        ExecStart = "${inputs.webfortune.packages.${pkgs.system}.webfortune}/bin/webfortune";
+        Restart = "always";
+      };
+    };
+  };
+}