-
Notifications
You must be signed in to change notification settings - Fork 730
/
Rest.sc
72 lines (66 loc) · 1.32 KB
/
Rest.sc
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
Rest {
var <>dur = 1;
*new { |dur(1)|
^super.newCopyArgs(dur)
}
// for use by Pfunc and Pfuncn
*processRest { |inval|
inval.put(\isRest, true);
^1
}
processRest { |inval|
inval.put(\isRest, true);
^dur.value(inval)
}
// for use e.g. in ListPatterns
*embedInStream { |inval|
^this.processRest(inval).yield; // the actual return value is the next inval
}
embedInStream { |inval|
^this.processRest(inval).yield;
}
*asStream {
^Routine({ |inval|
loop {
inval = this.embedInStream(inval);
}
})
}
asStream {
^Routine({ |inval|
loop {
inval = this.embedInStream(inval);
}
})
}
*isRest { ^true }
isRest { ^true }
value { ^dur }
storeOn { |stream| stream << "Rest(" << dur << ")" }
}
+ Object {
processRest { ^this }
}
+ Collection {
processRest { |inval|
^this.collect(_.processRest(inval))
}
}
+ Event {
processRest { ^this }
}
+ SimpleNumber {
// Some patterns call .delta on the eventstream's yield value
// since a SimpleNumber is a valid rest, it must answer 'delta' with itself
delta {}
// but Ppar and several other patterns do "put(\delta, ...)"
// so they need to convert the simplenumber into a real rest event
asEvent { ^Event.silent(this) }
}
+ Event {
asEvent {}
}
+ Nil {
// Ppar etc. need stream.next(event).asEvent to be nil when the stream ends
asEvent {}
}