-
Notifications
You must be signed in to change notification settings - Fork 0
/
oblitterated.asm
2444 lines (2107 loc) · 71 KB
/
oblitterated.asm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
; OBLITTERATED
; an unlikely max headroom incident
;
; Vector-06c demo
; svo 2022 for cafeparty
.project oblitterated.rom
.tape v06c-rom
.org 100h
TILTSPEED equ 421 ;128 ; 3*255
TILT1 equ 0 ; band tilt 0 = most horizontal
TILT2 equ 4
TILT3 equ 8
BAND_THICC equ 5 ; normal band base thickness
BAND_STEP equ 32 ; band period
BAND_N equ 8 ; number of bands
; нормальное сообщение
MSG_TIME equ 100
; первертствие
GREET_TIME equ 40
di
; ---
start:
xra a
out 10h
lxi sp, 100h
mvi a, 0C3h
sta 0
lxi h, Restart
shld 1
mvi a, 0C9h
sta 38h
Restart:
lxi sp,100h
call ay_noise
ei \ hlt
lxi h, colors_nil + 15
call colorset
call Cls
call bsszero
; сбросить LFSR
lxi h, 65535
shld rnd16+1
call ay_noise
; создает таски и устанавливает начальный контекст гигачада (изначально он выключен)
lxi h, song_1
call gigachad_init
; начальная фаза -- мельтешня и выползающая харя
call sequence_next
; первое сообщение
lxi h, msg_sequence
shld msgptr
call SetPixelModeOR
mvi a, 080h ; select plane $8000
sta line_bitplane_1
sta line_bitplane_2
lxi h, ((224 + TILT1) << 8)|0
shld line_x0
lxi h, ((255 - TILT1) << 8)|255
shld line_x1
call draw_bands
mvi a, 0a0h ; select plane $a000
sta line_bitplane_1
sta line_bitplane_2
lxi h, ((224 + TILT2) << 8)|0 ; y | x
shld line_x0
lxi h, ((255 - TILT2) << 8)|255
shld line_x1
call draw_bands
mvi a, 0c0h ; select plane $c000
sta line_bitplane_1
sta line_bitplane_2
lxi h, ((224 + TILT3) << 8)|0
shld line_x0
lxi h, ((255 - TILT3) << 8)|255
shld line_x1
call draw_bands
; initial phase for up/down cosine
mvi a, 128
sta faddi
lxi h, $0000
shld tiltphase
; убрать дефолтную мадженту
call cyclecolors
foreva_lup
; typical: line 282 (30 lines free)
; worst: line 305 (7 lines free)
ei
hlt
lxi h, framecnt
inr m
mov a, m
call cyclecolors
call rnd16
lxi h, faddi ; update arg
inr m
call cosm ; e = cos(m)
; invert direction: vertical stripes ping-pong
mvi d, 0
lxi h, updownctr
inr m
lxi h, fasign
mov a, m
jnz $+4
cma
mov m, a
ora a
jp no_negate_here
; negate increment
mov a, e
cma
;inr a
mov e, a
mvi d, $ff
no_negate_here
lhld facum ; facum += cos(arg)
dad d
shld facum
lda frame_scroll
sta frame_scroll_prev
; SELFMOD: 3 bytes
; phase 0: rnd flicker: lda rnd16+1
; phase 1: fast flicker mov a, l \ cma \ nop
; others: slow pan mov a, h \ nop \ nop
modesw1 nop
nop
nop
sta frame_scroll ; frame_scroll = trunc(facum)
; calculate tilt, a number 0..2
lhld tiltphase
lxi d, TILTSPEED
dad d
shld tiltphase
mov a, h
; select tilt angle based on integral part of tiltphase
sui 64
jc pal_idx_0 ; 0..63
sui 64
jc pal_idx_1 ; 64..127
sui 64
jc pal_idx_2 ; 128..192
pal_idx_1 ; 192..255
lxi h, colors_2+15
jmp setcolors
pal_idx_2
lxi h, colors_3+15
jmp setcolors
pal_idx_0
lxi h, colors_1+15
jmp setcolors
setcolors:
call colorset
lda frame_scroll
out 3
;;;;;;;
;mvi a, 15
;out 2
modesw2: ; переход на главную процедуру секвенции
call 0
; музон
call gigachad_frame
;mvi a, 0
;out 2
;;;;;;
jmp foreva_lup
sequence_next:
lxi h, seq_index
sequence_next_L0:
mvi d, 0
mov e, m ; de = static_cast<int>(seq_index)
inr m \ inr m \ inr m \ inr m ; seq_index++
lxi h, sequence ; hl = &sequence[0]
dad d ; hl = &sequence[current].setup
mov e, m
inx h
mov d, m ; de = sequence[current].setup
inx h ; hl = &sequence[current].main
mov a, d
ora e
jnz sequence_index_L1 ; if sequence[current].setup == 0
; end of sequence, loop back to 0
lxi h, seq_index
mvi m, 0 ; сбросили индекс на 0 и повторяем
jmp sequence_next_L0
sequence_index_L1:
; hl = &sequence[current].main
; de = sequence[current].setup
push h
lxi b, sequence_index_L2
push b ; адрес возврата из setup
xchg
pchl ; вызов процедуры setup
sequence_index_L2:
pop h
mov e, m
inx h
mov d, m ; de = sequence[seq_index].main
; осталось прописать адрес main в главный переход
xchg
shld modesw2 + 1
ret
; main sequence of the "animation"
sequence
dw phase0_setup_mus, phase0_main ; begin with fast flicker
dw phase0_setup, phase0_main
dw phase0_setup, phase0_main
dw phase0_setup, phase0_main
dw phase0_setup, phase0_main
dw phase0_setup, phase0_main
dw phase0_setup, phase0_main
dw phaseN1_setup, phaseN1_main ; TAPE ERROR appears
dw phase0_setup, phase0_main ; flicker again
dw phase0_setup, phase0_main ; flicker again
dw phase0_setup, phase0_main ; flicker again
dw phase1_setup, phase1_main ; face appears
dw phase2_setup, phase2_main ; full max flickers
dw phase5_setup, phase5_main ; main part with messages
dw phase6_setup_noise, phase6_main ; max disappears (loud noise)
dw phase0_setup_noise, phase0_main ; empty flicker (moderate noise)
dw phase0_setup, phase0_main
dw phase0_setup, phase0_main
dw phase0_setup, phase0_main
; end titles...
dw phase7_setup_mus, phase7_main ; end titles show up
dw phase8_setup, phase8_main ; end titles hold
dw phase8_setup, phase8_main
dw phase9_setup, phase9_main ; end titles hold and wipe off
dw phase0_setup_loudnoise, phase0_main
dw phase0_setup_noise, phase0_main
dw phase0_setup, phase0_main ; empty flicker and repeat
dw phaseA_setup, phaseA_main ; logo display
dw Restart, Restart
dw 0, 0
; сообщения двойной ширины (128, 16 стобцов)
msgptr dw msg_sequence
msg_sequence dw msg_hello1, msg_hello2, msg_hello1, msg_hello2
dw msg_what_a_strange_place, msg_what_a_strange_place
dw msg_i_have_to_blit_myself, msg_i_have_to_blit_myself
dw msg_as_fast_as_i_can, msg_as_fast_as_i_can
dw msg_just_to_stay_where_i_am
dw msg_just_to_stay_where_i_am
dw msg_null
dw msg_null
dw msg_i_am_fully
dw msg_i_am_fully
dw msg_oblitterated, msg_oblitterated
dw msg_oblitterated, msg_oblitterated
dw msg_oblitterated, msg_oblitterated
dw 0, 0
greetz_sequence
dw msg_null, msg_null, ;msg_null, msg_null
dw msg_null, msg_null, ;msg_null, msg_null
dw msg_gr_errorsoft ;, msg_gr_errorsoft
dw msg_null, msg_null, ;msg_null, msg_null
dw msg_gr_frog ;, msg_gr_frog
dw msg_null, msg_null, ;msg_null, msg_null
dw msg_gr_ivagor ;, msg_gr_ivagor
dw msg_null, msg_null, ;msg_null, msg_null
dw msg_gr_kansoft ;, msg_gr_kansoft
dw msg_null, msg_null, ;msg_null, msg_null
dw msg_gr_lafromm ;, msg_gr_lafromm
dw msg_null, msg_null, ;msg_null, msg_null
dw msg_gr_manwe ;, msg_gr_zx
dw msg_null, msg_null, ;msg_null, msg_null
dw msg_gr_metamorpho;, msg_gr_metamorpho
dw msg_null, msg_null, ;msg_null, msg_null
dw msg_gr_nzeemin ;, msg_gr_nzeemin
dw msg_null, msg_null, ;msg_null, msg_null
dw msg_gr_tnt23 ;, msg_gr_tnt23
dw msg_null, msg_null, ;msg_null, msg_null
dw msg_gr_else ;, msg_gr_else
dw msg_null, msg_null, ;msg_null, msg_null
dw msg_gr_orgaz ;, msg_gr_orgaz
dw msg_null, msg_null, ;msg_null, msg_null
dw msg_gr_rts ;, msg_gr_rts
dw msg_null, msg_null, ;msg_null, msg_null
dw msg_null, msg_null, ;msg_null, msg_null
dw msg_null, msg_null, ;msg_null, msg_null
dw 0, 0
bss_start equ $
ctr8i db 0
ctr8j db 0
frame_scroll db 0
frame_scroll_prev db 0
pal_idx db 0
frameskip db 0
framecnt db 0
faddi db 0 ; cos arg
facum db 0, 0 ; scroll accumulator
fasign db 0
updownctr db 0
tiltphase dw 0
ph1_height db 0
seq_index db 0
phase2_ctr db 0
phase0_ctr db 0
var_ctr16 dw 0
msg_timer db 0
mainseq_active db 0 ; главная последовательность в процессе
bss_length equ $-bss_start
; e = cos(m)
LOGOXY equ $04c1+0e000h
lda rnd16+1
phaseN1_setup:
mvi a, $7c ; "mov a, h"
sta modesw1
lxi h, 0
shld modesw1+1
mvi a, 130
sta phase0_ctr
ret
phaseN1_main:
lxi h, msg_tape_error1
shld blit_src1+1
lxi h, msg_tape_error2
shld blit_src2+1
lxi h, $0620+0e000h ; -- top / right corner
shld blit_xy
mvi a, 18/2 ; text tag height
sta blit_height
;mvi a, 64/8/8 ; text tag width (1)
;sta blit_width
lxi h, blit_line_c1 + (4 - 1) * blit_linej_sz
shld blit_widthj
call blit
lxi h, phase0_ctr
dcr m
rnz
jmp sequence_next
;; ----------------------------------------------
;; phase0: полная мельтешня без переднего плана
;; ----------------------------------------------
phase0_setup_loudnoise:
call gigachad_disable
call ay_noise_louder
jmp phase0_setup
phase0_setup_noise:
call gigachad_disable
call ay_noise
jmp phase0_setup
phase0_setup_stfu:
call gigachad_disable
call ay_stfu
jmp phase0_setup
phase0_setup_mus:
;;; START INTRO SONG
lxi h, song_1
call gigachad_init
call gigachad_enable
call gigachad_precharge
phase0_setup:
; modesw1 = "lda rnd16+1"
mvi a, $3a ; lda
sta modesw1
lxi h, rnd16 + 1
shld modesw1 + 1
xra a
sta frame_scroll
sta frame_scroll_prev
mvi a, 60
sta phase0_ctr
ret
phase0_main:
lxi h, phase0_ctr
dcr m
rnz
lda seq_index
push psw
call bsszero
pop psw
sta seq_index
jmp sequence_next
;; ----------------------------------------------
;; phase1: мельтешня быстрая, но не случайная, снизу выплывает харя
;; ----------------------------------------------
phase1_setup:
; modesw = "mov a, l \ cma" = 7d, 2f
lxi h, $7d2f; $2f7d
shld modesw1
xra a
sta modesw1+2
sta ph1_height
ret
phase1_main:
lxi h, ph1_height
inr m
mov a, m
ora a ;; так получается обалденский эффект
rar
inr a
mov c, a
ral
mov b, a
lxi h, LOGOXY-122/2
mov l, a
sub b
shld wipe_xy
shld blit_xy
mov a, c
;cpi (122)/2 ;; это если полностью, но выходит затянуто
cpi 60/2 ;; а так вполне себе шустро
jc phase1_L1
; завершаем фазу 1
; перед следующей фазой надо тщательно затереть остатки мельтешни.
; они через строку, поэтому два раза
mvi a, 80
sta wipe_height
mvi a, 128/8/8
sta wipe_width
call wipe
lhld wipe_xy
inr l
shld wipe_xy
call wipe
jmp sequence_next
phase1_L1
;
sta varblit_clip_h
;
sta wipe_height
sta blit_height
mvi a, 128/8/8 ;= 2
sta wipe_width
call wipe
lxi d, varmax_top_a
lxi h, varmax_top_b
lda wipe_xy
mov c, a
jmp varblit
;; ----------------------------------------------
;; phase1: переход между влетом и статической картинкой, мерцание?
;; ----------------------------------------------
phase2_setup:
mvi a, 16
sta phase2_ctr
;call gigachad_enable
;;; START MAIN SONG
lxi h, song_0
call gigachad_init
jmp gigachad_enable
;ret
phase2_main:
lxi h, phase2_ctr
mov a, m
dcr m
jz sequence_next
; редко -- выводим голову
ani 3
jz blit_full_head
; часто - все стираем: TODO померить как мы успеваем, но смотрится зашибись
mvi a, 80
sta wipe_height
mvi a, 192/8/8 ;128/8/8
sta wipe_width
call wipe
lhld wipe_xy
inr l
shld wipe_xy
jmp wipe
;ret
;; ----------------------------------------------
phase3_setup:
mvi a, $7c ; "mov a, h"
sta modesw1
lxi h, 0
shld modesw1+1
ret
; то же самое, что phase5, но только голова без текста
phase3_main:
jmp blit_full_head
; ret
;;
;; Основная фаза с полной головой и текстом
;;
phase5_setup:
mvi a, $7c ; "mov a, h"
sta modesw1
lxi h, 0
shld modesw1+1
mvi a, 1
sta mainseq_active
lxi h, $e0f0 ; a bogus last message position so that it's wiped safely
shld blit_banner_p3+1
mvi a, MSG_TIME
sta msg_seq_time
call msg_sequence_next
jmp gigachad_enable
;ret
; основная фаза: рисуем все
phase5_main:
; для ускорения рисуем черепушку отдельно, она уже плечей
call blit_full_head
call msg_sequence_frame
jz p5_L1 ; новое сообщение -> пропускаем рисование, а то кадр
blit_banner:
blit_banner_p1: lxi h, msg_tape_error1
shld blit_src1+1
blit_banner_p2: lxi h, msg_tape_error2
shld blit_src2+1
blit_banner_p3: lxi h, $16f0+0e000h ; -- top / right corner
; all messages are 2x wide
shld blit_xy
mvi a, 18/2 ; text tag height
sta blit_height
lxi h, blit_line_c1 + (4 - 2) * blit_linej_sz
shld blit_widthj
call blit
p5_L1:
lda mainseq_active
ora a
cz sequence_next
ret
blit_full_head
blit_head:
mvi c, LOGOXY & 255
lxi d, varmax_top_a
lxi h, varmax_top_b
call varblit ; return @ line 201
; и плечи пошире
blit_torso:
mvi c, $47
lxi d, varmax_bottom_a
lxi h, varmax_bottom_b
jmp varblit
;; ----------------------------------------------
;; phase6: смываем харю
;; ----------------------------------------------
;; ----------------------------------------------
;; phase1: мельтешня быстрая, но не случайная, снизу выплывает харя
;; ----------------------------------------------
phase6_setup_noise:
call gigachad_disable
call ay_stfu
call ay_noise_louder
phase6_setup:
; modesw = "mov a, l \ cma" = 7d, 2f
lxi h, $7d2f; $2f7d
shld modesw1
xra a
sta modesw1+2
mvi a, 122/2
sta ph1_height
; голову затереть черезстрочно, а то она ярковата для исчезающей
lxi h, LOGOXY
shld wipe_xy
mvi a, 122/2 ; head height
sta wipe_height
mvi a, 128/8/8
sta wipe_width
call wipe
; и верх затереть совсем для расползания классного
lxi h, LOGOXY
inr l
shld wipe_xy
mvi a, 30
sta wipe_height
call wipe
; плечи надо затереть совсем, а то фигня выходит
lxi h, $0447+0e000h
shld wipe_xy
mvi a, 72/2 ; 72 lines
sta wipe_height
mvi a, 192/8/8 ; 192 pixels wide torso
sta wipe_width
call wipe
lxi h, $0448+0e000h
shld wipe_xy
call wipe
jmp wipe_banner2
;ret
phase6_main:
;jmp $
lxi h, ph1_height
dcr m ;\ dcr m
mov a, m
ora a ;; так получается обалденский эффект
rar
inr a
mov c, a
ral
mov b, a
lxi h, LOGOXY-122/2
mov l, a
sub b
shld wipe_xy
shld blit_xy
mov a, c
ora a ;; а так вполне себе шустро
jz $+6
jp phase6_L1
; завершаем фазу
; перед следующей фазой надо тщательно затереть остатки мельтешни.
; они через строку, поэтому два раза
mvi a, 128
sta wipe_height
mvi a, 128/8/8
sta wipe_width
call wipe
lhld wipe_xy
inr l
shld wipe_xy
call wipe
jmp sequence_next
phase6_L1
; остаток точно совпадает с phase1_L1
jmp phase1_L1
; sta wipe_height
; sta blit_height
; mvi a, 128/8/8 ; 2
; sta wipe_width
;
; lxi h, blit_line_c1 + (4 - 2) * blit_linej_sz
; shld blit_widthj
;
; lxi h, hello_jpg
; shld blit_src1+1
; lxi h, hello_jpg2
; shld blit_src2+1
; call wipe ; можно вообще не вызывать, но тогда грязновато
; jmp blit
; ;ret
; end titles, kinda sorta
phase7_setup_mus:
call gigachad_enable
phase7_setup:
mvi a, $7c ; "mov a, h"
sta modesw1
lxi h, 0
shld modesw1+1
mvi a, 255
sta phase0_ctr
; инициализация гритзов
lxi h, $e0f0 ; a bogus last message position so that it's wiped safely
shld blit_banner_p3+1
lxi h, greetz_sequence ; 29a
shld msgptr
mvi a, GREET_TIME
sta msg_seq_time
mvi a, 1
sta mainseq_active
call msg_sequence_next
ret
phase7_main:
titleout_xy equ $0020+0e000h
title_xy_1 equ titleout_xy + 12*256 + 14 * 8 ; oblitterated
title_xy_2 equ titleout_xy + 8 * 256 + 10 * 8 ; an unlikely max headroom incident
title_xy_3 equ titleout_xy + 12 * 256 + 3 * 8 ; svo 2022
title_xy_4 equ titleout_xy + 8 * 256 ; music by firestarter
text_height equ 18/2
text_width equ 1
text_dwidth equ 2
mvi a, text_height
sta blit_height
;mvi a, text_width
; greetz
call msg_sequence_frame
; 8-column messages
lxi h, blit_line_c1 + (4 - text_width) * blit_linej_sz
shld blit_widthj
lxi h, msg_no_longer_inv1
shld blit_src1+1
lxi h, msg_no_longer_inv2
shld blit_src2+1
lxi h, title_xy_1 + 2 * 8
shld blit_xy
call blit
lxi h, msg_svo2022
shld blit_src1+1
shld blit_src2+1
lxi h, title_xy_3
shld blit_xy
call blit
; double-width texts
lxi h, blit_line_c1 + (4 - text_dwidth) * blit_linej_sz
shld blit_widthj
lxi h, msg_an_unlikely_max_headroom_incident
shld blit_src1+1
shld blit_src2+1
lxi h, title_xy_2
shld blit_xy
call blit
lxi h, msg_music_by_firestarter_a
shld blit_src1+1
lxi h, msg_music_by_firestarter_b
shld blit_src2+1
lxi h, title_xy_4
shld blit_xy
call blit
lxi h, msg_oblitterated
shld blit_src1+1
shld blit_src2+1
lxi h, title_xy_1
shld blit_xy
call blit
; blit greetz
lhld blit_banner_p1+1
shld blit_src1+1
lhld blit_banner_p2+1
shld blit_src2+1
lhld blit_banner_p3+1
shld blit_xy
call blit
; cafeparty logo
mvi a, 0 ; disable interlace
sta varblit_ilace
lxi h, adj_for_scroll_exact
shld varblit_adj_vec
mvi c, $5c
lxi d, cafe_bw
lxi h, cafe_bw
call varblit
lxi h, adj_for_scroll
shld varblit_adj_vec
; эта фаза завершается когда заканчиваются тексты
;lxi h, phase0_ctr
;dcr m
;rnz
lda mainseq_active
ora a
rnz
jmp sequence_next
phase8_setup: ret
phase8_main: jmp phase7_main
phase9_setup:
; wipe
lxi h, titleout_xy + 8*256 + 16*8
shld wipe_xy
mvi a, text_height * 9
sta wipe_height
mvi a, 2
sta wipe_width
call wipe
lxi h, titleout_xy + 8*256 + 16*8 + 1
shld wipe_xy
;mvi a, $55
;sta wipe_bitmap
jmp wipe
;ret
phase9_main:
jmp sequence_next
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; PHASE A: final logo display
;; hold for 1 minute = 3000 frames
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
endlogo_y equ $90
phaseA_setup:
call gigachad_disable
call ay_stfu
lxi h, 3000
shld var_ctr16
jmp Cls
phaseA_main:
; hijack the main loop because it's the end anyway
ei
hlt
lxi h, colors_logo+15
call colorset
lda frame_scroll
out 3
lxi h, adj_for_scroll_exact
shld varblit_adj_vec
; cafeparty logo
mvi a, 0
sta varblit_ilace ; disable interlace
mvi a, $c0
sta varblit_plane ; set plane = $c0
mvi c, endlogo_y
lxi d, cafe_c0
lxi h, cafe_c0
call varblit
mvi a, 0 ; disable interlace
sta varblit_ilace
mvi a, $e0
sta varblit_plane ; set plane = $e0
mvi c, endlogo_y
lxi d, cafe_e0
lxi h, cafe_e0
call varblit
lxi h, adj_for_scroll
shld varblit_adj_vec
lhld var_ctr16
lxi b, -1
dad b
mov a, h
ora l
jz sequence_next
shld var_ctr16
jmp phaseA_main
wipe_banner2ex: lhld blit_banner_p3+1
call adj_for_scroll
mvi d, 18
mov b, h
xra a
wb2ex_L1: mov m, a \ inr h \ mov m, a \ inr h
mov m, a \ inr h \ mov m, a \ inr h
mov m, a \ inr h \ mov m, a \ inr h
mov m, a \ inr h \ mov m, a \ inr h
mov m, a \ inr h \ mov m, a \ inr h
mov m, a \ inr h \ mov m, a \ inr h
mov m, a \ inr h \ mov m, a \ inr h
mov m, a \ inr h \ mov m, a; \ inr h
dcr d
rz
dcr l
mov h, b
jmp wb2ex_L1
wipe_banner2ez:
lxi h, 0
dad sp
shld wb2ez_sp + 1
lhld blit_banner_p3+1
call adj_for_scroll
mvi d, 16 ; columns
lxi b, 0
inr l
wb2ez_L1: sphl
push b
push b
push b
push b
push b
push b
push b
push b
push b
inr h
dcr d
jnz wb2ez_L1
wb2ez_sp: lxi sp, 0
ret
; wipe the (double) banner message in its jumpy position
wipe_banner2:
mvi a, 9 \ sta wipe_height
mvi a, 2 \ sta wipe_width
lhld blit_banner_p3+1
mvi a, -8 \ add h \ mov h, a
push h
shld wipe_xy
call wipe
pop h
inr l
shld wipe_xy
jmp wipe
; ret