meson: use disabler feature to convert configuration errors to warnings

po/meson.build

@@ -1,6 +1,10 @@
 # SPDX-License-Identifier: LGPL-2.1+
 
 i18n = import('i18n')
-i18n.gettext(meson.project_name(),
-             preset : 'glib',
-             data_dirs : '.')
+if find_program('xgettext', required : false).found()
+        i18n.gettext(meson.project_name(),
+                     preset : 'glib',
+                     data_dirs : '.')
+else
+        warning('Can not do gettext because xgettext is not installed.')
+endif

src/basic/meson.build

@@ -288,17 +288,23 @@ basic_gcrypt_sources = files(
         'gcrypt-util.c',
         'gcrypt-util.h')
 
-libbasic = static_library(
-        'basic',
-        basic_sources,
-        include_directories : includes,
-        dependencies : [versiondep,
-                        threads,
-                        libcap,
-                        libselinux,
-                        libm],
-        c_args : ['-fvisibility=default'],
-        install : false)
+if gperf.found()
+        libbasic = static_library(
+                'basic',
+                basic_sources,
+                include_directories : includes,
+                dependencies : [versiondep,
+                                threads,
+                                libcap,
+                                libselinux,
+                                libm],
+                c_args : ['-fvisibility=default'],
+                install : false)
+        have_libbasic = true
+else
+        libbasic = disabler()
+        have_libbasic = false
+endif
 
 # A convenience library that is separate from libbasic to avoid
 # unnecessary linking to libgcrypt.

src/journal-remote/meson.build

@@ -22,16 +22,20 @@ if conf.get('HAVE_MICROHTTPD') == 1
 '''.split())
 endif
 
-libsystemd_journal_remote = static_library(
-        'systemd-journal-remote',
-        libsystemd_journal_remote_sources,
-        include_directories : includes,
-        dependencies : [threads,
-                        libmicrohttpd,
-                        libgnutls,
-                        libxz,
-                        liblz4],
-        install : false)
+if gperf.found()
+        libsystemd_journal_remote = static_library(
+                'systemd-journal-remote',
+                libsystemd_journal_remote_sources,
+                include_directories : includes,
+                dependencies : [threads,
+                                libmicrohttpd,
+                                libgnutls,
+                                libxz,
+                                liblz4],
+                install : false)
+else
+        libsystemd_journal_remote = disabler()
+endif
 
 systemd_journal_remote_sources = files('''
         journal-remote-main.c

src/libsystemd/meson.build

@@ -1,5 +1,13 @@
 # SPDX-License-Identifier: LGPL-2.1+
 
+# Used to determine if components with libsystemd dependencies are built
+if have_libbasic
+        have_libsystemd = true
+else
+        have_libsystemd = false
+        warning('libsystemd will not be built')
+endif
+
 id128_sources = files('''
         sd-id128/id128-util.c
         sd-id128/id128-util.h

src/login/meson.build

@@ -44,11 +44,15 @@ if conf.get('HAVE_ACL') == 1
         liblogind_core_sources += logind_acl_c
 endif
 
-liblogind_core = static_library(
-        'logind-core',
-        liblogind_core_sources,
-        include_directories : includes,
-        dependencies : [libacl])
+if gperf.found()
+        liblogind_core = static_library(
+                'logind-core',
+                liblogind_core_sources,
+                include_directories : includes,
+                dependencies : [libacl])
+else
+        liblogind_core = disabler()
+endif
 
 loginctl_sources = files('''
         loginctl.c

src/nspawn/meson.build

@@ -32,13 +32,17 @@ nspawn_gperf_c = custom_target(
 
 libnspawn_core_sources += [nspawn_gperf_c]
 
-libnspawn_core = static_library(
-        'nspawn-core',
-        libnspawn_core_sources,
-        include_directories : includes,
-        dependencies : [libacl,
-                        libseccomp,
-                        libselinux])
+if gperf.found() and libcap.found()
+        libnspawn_core = static_library(
+                'nspawn-core',
+                libnspawn_core_sources,
+                include_directories : includes,
+                dependencies : [libacl,
+                                libseccomp,
+                                libselinux])
+else
+        libnspawn_core = disabler()
+endif
 
 systemd_nspawn_sources = files('nspawn.c')
 

src/resolve/meson.build

@@ -132,11 +132,16 @@ resolved_dnssd_gperf_c = custom_target(
         output : 'resolved-dnssd-gperf.c',
         command : [gperf, '@INPUT@', '--output-file', '@OUTPUT@'])
 
-libsystemd_resolve_core = static_library(
-        'systemd-resolve-core',
-        basic_dns_sources,
-        dns_type_headers,
-        include_directories : includes)
+if gperf.found()
+        libsystemd_resolve_core = static_library(
+                'systemd-resolve-core',
+                basic_dns_sources,
+                dns_type_headers,
+                include_directories : includes)
+else
+        libsystemd_resolve_core = disabler()
+endif
+
 
 systemd_resolved_sources += [resolved_gperf_c, resolved_dnssd_gperf_c]
 

src/shared/meson.build

@@ -1,5 +1,13 @@
 # SPDX-License-Identifier: LGPL-2.1+
 
+# Used to determine if components with libshared dependencies are built
+if gperf.found() and libcap.found() and libmount.found()
+        have_libshared = true
+else
+        have_libshared = false
+        warning('libshared will not be built')
+endif
+
 shared_sources = files('''
         acl-util.h
         acpi-fpdt.c

src/udev/meson.build

@@ -1,5 +1,13 @@
 # SPDX-License-Identifier: LGPL-2.1+
 
+# Used to determine if components with libudev dependencies are built
+if have_libshared
+        have_libudev = true
+else
+        have_libudev = false
+        warning('libudev will not be built')
+endif
+
 udevadm_sources = files('''
         udevadm.c
         udevadm.h