-
Notifications
You must be signed in to change notification settings - Fork 42
/
hlmanager.vim
192 lines (161 loc) · 4.53 KB
/
hlmanager.vim
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
" Util:
function! s:define_type_checker() "{{{1
" dynamically define s:is_Number(v) etc..
let types = {
\ "Number": 0,
\ "String": 1,
\ "Funcref": 2,
\ "List": 3,
\ "Dictionary": 4,
\ "Float": 5,
\ }
for [type, number] in items(types)
let s = ''
let s .= 'function! s:is_' . type . '(v)' . "\n"
let s .= ' return type(a:v) is ' . number . "\n"
let s .= 'endfunction' . "\n"
execute s
endfor
endfunction
"}}}
call s:define_type_checker()
unlet! s:define_type_checker
let s:SCREEN = (has('gui_running')
\ || (has('termtruecolor') && &guicolors == 1)
\ || (has('nvim') && has('termguicolors') && &termguicolors == 1))
\ ? 'gui' : 'cterm'
" Main:
let s:hlmgr = {}
function! s:hlmgr.new(prefix) "{{{1
let R = deepcopy(self)
call R.init(a:prefix)
return R
endfunction
function! s:hlmgr.init(prefix) "{{{1
let self._colors = {}
let self._specs = {}
let self.prefix = a:prefix
return self
endfunction
function! s:hlmgr.register_auto(spec) "{{{1
if s:is_String(a:spec)
return a:spec
endif
if s:is_Dictionary(a:spec)
let spec = string(a:spec[s:SCREEN])
let name = get(self._specs, spec, '')
if !empty(name)
" If color is already defined for spec provided.
" return that color
return name
endif
endif
return self.register(self.color_next(), a:spec)
endfunction
function! s:hlmgr.register(name, spec) "{{{1
call self.define(a:name, a:spec)
let self._colors[a:name] = a:spec
" This might overwrite existing spec but its OK since _specs is simple color
" re-using mechanizm for performance.
let self._specs[string(a:spec[s:SCREEN])] = a:name
return a:name
endfunction
function! s:hlmgr.define(name, color) "{{{1
let command = printf('highlight %s %s', a:name, self.hl_defstr(a:color))
silent execute command
endfunction
function! s:hlmgr.refresh() "{{{1
for [name, color] in items(self._colors)
call self.define(name, color)
endfor
endfunction
function! s:hlmgr.color_next() "{{{1
return printf(self.prefix . '%05d', len(self._colors))
endfunction
function! s:hlmgr.reset() "{{{1
call self.clear()
call self.init(self.prefix)
endfunction
function! s:hlmgr.spec_for(color) "{{{1
return get(self._colors, a:color, '')
endfunction
function! s:hlmgr.parse(spec, ...) "{{{1
" return dictionary from string
" 'guifg=#25292c guibg=#afb0ae' => {'gui': ['#afb0ae', '#25292c']}
let R = {}
if empty(a:spec)
return R
endif
let screens = empty(a:000) ? [s:SCREEN] : ['gui', 'cterm' ]
for screen in screens
let R[screen] = ['','']
for def in split(a:spec)
let [key,val] = split(def, '=')
if key ==# screen . 'bg' | let R[screen][0] = val
elseif key ==# screen . 'fg' | let R[screen][1] = val
elseif key ==# screen | call add(R[screen], val)
endif
endfor
endfor
return R
endfunction
function! s:hlmgr.parse_full(spec) "{{{1
return self.parse(a:spec, 1)
endfunction
function! s:hlmgr.capture(hlname) "{{{1
let hlname = a:hlname
if empty(hlID(hlname))
" if hl not exists, return empty string
return ''
endif
redir => HL_SAVE
execute 'silent! highlight ' . hlname
redir END
if !empty(matchstr(HL_SAVE, 'xxx cleared$'))
return ''
endif
" follow highlight link
let link = matchstr(HL_SAVE, 'xxx links to \zs.*')
if !empty(link)
return self.capture(link)
endif
return matchstr(HL_SAVE, 'xxx \zs.*')
endfunction
function! s:hlmgr.clear() "{{{1
for color in self.colors()
silent execute 'highlight clear' color
endfor
endfunction
function! s:hlmgr.colors() "{{{1
return keys(self._colors)
endfunction
function! s:hlmgr.hl_defstr(color) "{{{1
" return 'guibg=DarkGreen gui=bold' (Type: String)
let color = a:color[s:SCREEN]
let R = []
"[NOTE] empty() is not appropriate, cterm color is specified with number
for [idx, s] in [[ 0, 'bg' ], [ 1, 'fg' ] ,[ 2, ''] ]
let c = get(color, idx, -1)
if (s:is_String(c) && empty(c)) || (s:is_Number(c) && c ==# -1)
continue
endif
call add(R, printf('%s%s=%s', s:SCREEN, s, color[idx]))
endfor
return join(R)
endfunction
function! s:hlmgr.convert(hlname) "{{{1
return self.parse(self.capture(a:hlname))
endfunction
function! s:hlmgr.convert_full(hlname) "{{{1
return self.parse_full(self.capture(a:hlname))
endfunction
function! s:hlmgr.dump() "{{{1
return PP(self)
endfunction
"}}}
" API:
function! choosewin#hlmanager#new(prefix) "{{{1
return s:hlmgr.new(a:prefix)
endfunction
"}}}
" vim: foldmethod=marker