add dep-versions app

changelog.md

@@ -1,6 +1,8 @@
 # Unreleased
 
 * Allow envs to be excluded from being exposed as `devShells` for specific systems.
+* Add an app, `dep-versions`, that prints all components' direct dependencies and their actual version in an
+  environment.
 
 # 0.6.0
 

lib/default.nix

@@ -39,6 +39,8 @@ let
   asFunction = f:
   if isFunction f then f else _: f;
 
+  concatMapAttrsToList = f: a: concatLists (mapAttrsToList f a);
+
   unwords = concatStringsSep " ";
 
   unlines = concatStringsSep "\n";
@@ -126,6 +128,7 @@ in {
   normalizeOverrides
   overridesFor
   asFunction
+  concatMapAttrsToList
   unwords
   unlines
   unlinesMap

lib/dep-versions.nix

@@ -0,0 +1,49 @@
+{config, lib, util, env}:
+with lib;
+let
+
+  console = import ./console.nix { inherit lib; };
+  inherit (console) s indent;
+  inherit (s) colors;
+
+  pkgs = config.pkgs;
+
+  ghc = config.envs.${env}.ghc.ghc;
+
+  dep' = name: version: let
+    desc = if version == null then colors.magenta name else "${colors.magenta name} ${colors.cyan version}";
+    pkg = ghc.${name};
+    actual =
+      if pkg == null
+      then "[boot package or unknown]"
+      else "${colors.green "->"} ${colors.red pkg.version}";
+  in ["${desc} ${actual}"];
+
+  dep = d:
+  if isAttrs d
+  then dep' d.name d.version
+  else let
+    result = builtins.split "^([[:graph:]]+) (.*)$" d;
+    parts = head (drop 1 result);
+    name = head parts;
+    version = head (drop 1 parts);
+  in
+  if length result == 3
+  then dep' name version
+  else dep' d null;
+
+  componentDeps = name: conf: let
+    head = colors.yellow name;
+  in [head] ++ indent (concatMap dep conf.dependencies);
+
+  packageDeps = name: conf: let
+    head = colors.blue name;
+  in [head] ++ indent (util.concatMapAttrsToList componentDeps conf.internal.componentsSet);
+
+  packagesDeps =
+    pkgs.writeText "dep-versions" (util.unlines (util.concatMapAttrsToList packageDeps config.packages));
+
+in pkgs.writeScript "print-dep-versions" ''
+  #!${pkgs.zsh}/bin/zsh
+  echo -e "$(cat ${packagesDeps})"
+''

lib/doc/default.nix

@@ -141,6 +141,7 @@ let
         (opt "hackage" "Hackage" mod-hackage)
         (text tags)
         (text cross)
+        (text misc)
       ];
     }
   ];

lib/doc/prose.nix

@@ -1030,4 +1030,34 @@ in {
 
   '';
 
+  misc = ''
+  ## Miscellaneous tools {#misc}
+
+  ### Show overrides {#show-overrides}
+
+  ```
+  nix run .#show-overrides
+  ```
+
+  Prints all environments' overrides.
+
+  ### Show config {#show-config}
+
+  ```
+  nix run .#show-config
+  ```
+
+  Prints the project's entire configuration.
+
+  ### Show dependency versions {#dep-versions}
+
+  ```
+  nix run .#dep-versions
+  nix run .#env.ghc96.dep-versions
+  ```
+
+  Prints all components' dependencies and their actual versions in the dev environment, or the named environment in the
+  second variant.
+  '';
+
 }

modules/output.nix

@@ -15,6 +15,8 @@ let
 
   showOverrides = import ../lib/show-overrides.nix { inherit config lib util; };
 
+  depVersions = env: import ../lib/dep-versions.nix { inherit config lib util env; };
+
   # TODO use the json method and print in cli
   show-config = util.paramApp {
     name = "show-config";
@@ -25,7 +27,9 @@ let
   app = program: { type = "app"; program = "${program}"; };
 
   envApps = env: {
-    ${env.name} = mapAttrs (_: command: app "${(envCommand { inherit env command; }).path}") config.commands;
+    ${env.name} = mapAttrs (_: command: app "${(envCommand { inherit env command; }).path}") config.commands // {
+      dep-versions = app "${depVersions env.name}";
+    };
   };
 
   commandApps = mapAttrs (_: c: app "${c.path}");
@@ -136,6 +140,7 @@ in {
         gen-overrides = app "${genOverrides}";
         gen = app "${genAll}";
         show-overrides = app "${showOverrides}";
+        dep-versions = app "${depVersions "dev"}";
       };
 
     };

test/default.nix

@@ -21,6 +21,7 @@ let
     overrides = test "overrides";
     subdir = test "subdir";
     local-prelude = test "local-prelude";
+    dep-versions = test "dep-versions";
   };
 
   testA = n: t: "${n} ${t}";

test/dep-versions/root/dep/lib/Dep.hs

@@ -0,0 +1 @@
+module Dep where

test/dep-versions/root/flake.nix

@@ -0,0 +1,35 @@
+{
+  description = "hix test project";
+
+  inputs.hix.url = "path:HIX";
+
+  outputs = { hix, ... }:
+  hix.lib.flake {
+    main = "root";
+    packages = {
+
+      dep = {
+        src = ./dep;
+        cabal = {
+          dependencies = ["aeson >= 2" "extra ^>= 1.7"];
+        };
+        library = {
+          enable = true;
+          dependencies = ["uuid == 1.3" "vector >= 0.11 && < 0.13"];
+        };
+      };
+
+      root = {
+        src = ./.;
+
+        library = {
+          enable = true;
+          dependencies = [{ name = "aeson"; version = "^>= 2.1"; } "array"];
+        };
+
+      };
+
+    };
+
+  };
+}

test/dep-versions/root/lib/Root.hs

@@ -0,0 +1 @@
+module Root where

test/dep-versions/test.nix

@@ -0,0 +1,19 @@
+{ pkgs }: {
+  test = builtins.toFile "dep-versions-test" ''
+    cd ./root
+    nix flake update
+
+    target='dep
+  library
+    aeson >= 2 -> 2.1.2.1
+    extra ^>= 1.7 -> 1.7.14
+    uuid == 1.3 -> 1.3.15
+    vector >= 0.11 && < 0.13 -> 0.13.0.0
+root
+  library
+    aeson ^>= 2.1 -> 2.1.2.1
+    array [boot package or unknown]'
+
+    check 'nix run .#dep-versions' $target 'Output is wrong'
+  '';
+}