/
frame.pl
1053 lines (973 loc) · 39.2 KB
/
frame.pl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
:- module(frame, [
%% Give a class frame for a given class.
class_frame/3,
% Various class/document queries
all_documents/2,
all_classes/2,
class_properties/3,
class_property_frame/4,
%% Fill a given class frame with data.
fill_class_frame/4,
document_filled_frame/3,
all_document_instances/2,
all_document_iris/2,
% Get an object as described by a frame.
% (should this be exported?)
% document_object/4,
% As JSON-LD
document_jsonld/3,
% As JSON-LD with a context
document_jsonld/4,
% As JSON-LD with a context and depth parameter
document_jsonld/5,
class_frame_jsonld/3,
object_edges/3,
delete_object/2,
update_object/2,
update_object/3,
document_filled_class_frame_jsonld/4,
object_instance_graph/3
]).
/** <module> Frames
*
* Frame code for generating either objects based on ontology information
* or descriptors of the object type - or the combination of the two
* coupled together.
*
* * * * * * * * * * * * * COPYRIGHT NOTICE * * * * * * * * * * * * * * *
* *
* This file is part of TerminusDB. *
* *
* TerminusDB is free software: you can redistribute it and/or modify *
* it under the terms of the GNU General Public License as published by *
* the Free Software Foundation, under version 3 of the License. *
* *
* *
* TerminusDB is distributed in the hope that it will be useful, *
* but WITHOUT ANY WARRANTY; without even the implied warranty of *
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the *
* GNU General Public License for more details. *
* *
* You should have received a copy of the GNU General Public License *
* along with TerminusDB. If not, see <https://www.gnu.org/licenses/>. *
* *
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * */
:- use_module(utils).
:- use_module(base_type).
:- use_module(triplestore).
:- use_module(validate_schema, except([document/2])).
:- use_module(validate_instance).
:- use_module(inference).
:- use_module(database).
:- use_module(schema, []).
:- use_module(types).
:- use_module(frame_types).
:- use_module(jsonld).
:- use_module(prefixes).
:- use_module(expansions).
:- use_module(library(apply)).
:- use_module(library(yall)).
:- use_module(library(apply_macros)).
class_record(Database,Class,[class=Class|L]) :-
maybe_meta(Class,Database,L).
property_record(Database,Property,L) :-
maybe_meta(Property,Database,L).
all_documents(Database,AER) :-
unique_solutions(E,schema:document(E,Database),AE),
maplist(class_record(Database),AE,AER).
all_classes(Database,ACR) :-
unique_solutions(C,class(C,Database),AC),
maplist(class_record(Database),AC,ACR).
/**
* get_label(Document,Database,Label) is semidet.
*/
get_label(Document,Database,Label) :-
database_instance(Database,Collection),
database_instance(Database,Instance),
global_prefix_expand(rdfs:label,LabelProp),
xrdf(Collection,Instance,Document,LabelProp,literal(lang(_,Label))),
!.
get_label(Document,Database,Label) :-
database_instance(Database,Collection),
database_instance(Database,Instance),
global_prefix_expand(rdfs:label,LabelProp),
xrdf(Collection,Instance,Document,LabelProp,literal(type(_,Label))),
!.
get_some_label(E,Database,L) :-
( get_label(E,Database,L)
-> true
; L=E).
/**
* all_document_instances(Database,Ae) is semidet.
*
* Returns a list of URI=[type=Class,label=Label] elements, where
* Class is an document class and Label is a string.
*/
all_document_instances(Database,AE) :-
database_instance(Database,Instance),
unique_solutions(E=[type=C,label=L],
( xrdf(Database,Instance,
E,rdf:type,C),
schema_util:document(C,Database),
get_some_label(E,Database,L)),
AE).
all_document_iris(Database, IRIs) :-
database_instance(Database, Instance),
findall(IRI,
( xrdf(Database,Instance,
IRI,rdf:type,C),
schema_util:document(C, Database)
),
IRIs).
add_most_specific_property(Database,P,PList,Rp) :-
% write('P: '),writeq(P),nl,
member(Q,PList), % write('Q: '),writeq(Q),nl,
( subsumptionPropertiesOf(P,Q,Database)
*-> select(Q,PList,PListp), Rp=[P|PListp] % ,write('P < Q'),nl
; subsumptionPropertiesOf(Q,P,Database)
*-> Rp=PList % ,write('Q < P'), nl
; Rp=[P|PList]),
% Hail mary - makes me so uncomfortable.
!.
add_most_specific_property(_Database,P,PList,[P|PList]).
most_specific_properties(Database,Properties,SpecificProperties) :-
foldl(add_most_specific_property(Database),Properties,[],SpecificProperties).
class_properties(Class, Database, PropertiesPrime) :-
( schema:document(Class,Database)
-> DocumentProperties=['http://www.w3.org/2000/01/rdf-schema#label',
'http://www.w3.org/2000/01/rdf-schema#comment']
; DocumentProperties=[]),
( setof(Super,schema:subsumptionOf(Class,Super,Database),Classes),
setof(P,
S^(member(S,Classes),
validate_schema:domain(P,S,Database)),
Properties)
-> most_specific_properties(Database,Properties,MSProperties),
append(MSProperties,DocumentProperties,PropertiesWithAbstract),
database_schema(Database,Schema),
exclude({Schema,Database}/[X]>>(
xrdf(Database,
Schema,
X,tcs:tag,tcs:abstract)),
PropertiesWithAbstract,
PropertiesPrime)
; PropertiesPrime=DocumentProperties).
%:- rdf_meta has_formula(r,o).
has_formula(Class,Database) :-
( subClassOf(Class,_,Database)
; intersectionOf(Class,_,Database)
; unionOf(Class,_,Database)
; disjointUnionOf(Class,_,Database)
; oneOfList(Class,_,Database)
).
% restriction_type(+Class:uri, -Restriction:restriction_formula, +Database:database is nondet.
%
% Get the restriction formula for a restriction class.
%
%:- rdf_meta restriction_type(r,t,?).
restriction_type(CR,restriction([uri=CR,property=OP,someValuesFrom=C]),Database) :-
database_schema(Database,Schema),
xrdf(Database,Schema,CR,owl:onProperty,OP),
xrdf(Database,Schema,CR,owl:someValuesFrom,C).
restriction_type(CR,restriction([uri=CR,property=OP,allValuesFrom=C]),Database) :-
database_schema(Database,Schema),
xrdf(Database,Schema,CR,owl:onProperty,OP),
xrdf(Database,Schema,CR,owl:allValuesFrom,C).
restriction_type(CR,restriction([uri=CR,property=OP,minCardinality=N]),Database) :-
database_schema(Database,Schema),
xrdf(Database,Schema,CR,owl:onProperty,OP),
xrdf(Database,Schema,CR,owl:minCardinality,literal(type(_Type, CardStr))),
(number(CardStr)-> CardStr=N ; atom_number(CardStr,N)).
restriction_type(CR,restriction([uri=CR,property=OP,maxCardinality=N]),Database) :-
database_schema(Database,Schema),
xrdf(Database,Schema,CR,owl:onProperty,OP),
xrdf(Database,Schema,CR,owl:maxCardinality,literal(type(_Type, CardStr))),
(number(CardStr)-> CardStr=N ; atom_number(CardStr,N)).
restriction_type(CR,restriction([uri=CR,property=OP,cardinality=N]),Database) :-
database_schema(Database,Schema),
xrdf(Database,Schema,CR,owl:onProperty,OP),
xrdf(Database,Schema,CR,owl:cardinality,literal(type(_Type, CardStr))),
(number(CardStr)-> CardStr=N ; atom_number(CardStr,N)).
restriction_type(CR,restriction([uri=CR,property=OP,minQualifiedCardinality=N,onClass=C]), Database) :-
database_schema(Database,Schema),
xrdf(Database,Schema,CR,owl:onProperty,OP),
xrdf(Database,Schema,CR,owl:minQualifiedCardinality,literal(type(_Type, CardStr))),
xrdf(Database,Schema,CR,owl:onClass,C),
(number(CardStr)-> CardStr=N ; atom_number(CardStr,N)).
restriction_type(CR,restriction([uri=CR,property=OP,maxQualifiedCardinality=N,onClass=C]), Database) :-
database_schema(Database,Schema),
xrdf(Database,Schema,CR,owl:onProperty,OP),
xrdf(Database,Schema,CR,owl:maxQualifiedCardinality,literal(type(_Type,CardStr))),
xrdf(Database,Schema,CR,owl:onClass,C),
(number(CardStr)-> CardStr=N ; atom_number(CardStr,N)).
restriction_type(CR,restriction([uri=CR,property=OP,qualifiedCardinality=N,onClass=C]), Database) :-
database_schema(Database,Schema),
xrdf(Database,Schema,CR,owl:onProperty,OP),
xrdf(Database,Schema,CR,owl:qualifiedCardinality,literal(type(_Type,CardStr))),
xrdf(Database,Schema,CR,owl:onClass,C),
(number(CardStr)-> CardStr=N ; atom_number(CardStr,N)).
restriction_type(CR,restriction([uri=CR,property=OP,hasValue=V]), Database) :-
database_schema(Database,Schema),
xrdf(Database,Schema,CR,owl:onProperty,OP),
xrdf(Database,Schema,CR,owl:hasValue,V).
% ignore modeline
% is_class_formula(+Formula:any) is semidet.
%
% True if Formula is a class formula
is_class_formula(Class<Superclasses) :-
is_uri(Class),
exclude(is_class_formula,Superclasses,[]).
is_class_formula(Class=and(Sols)) :-
is_uri(Class),
exclude(is_class_formula,Sols,[]).
is_class_formula(Class=or(Sols)) :-
is_uri(Class),
exclude(is_class_formula,Sols,[]).
is_class_formula(Class=xor(Sols)) :-
is_uri(Class),
exclude(is_class_formula,Sols,[]).
is_class_formula(Class=oneOf(OneList)) :-
is_uri(Class),
exclude(is_uri,OneList,[]).
is_class_formula(restriction(Restriction)) :-
is_property_restriction(Restriction).
is_class_formula(class(Class)) :-
is_uri(Class).
:- multifile error:has_type/2.
error:has_type(class_formula,X) :-
is_class_formula(X).
/*
* class_assertion(+Database:database +Class:uri, -Formula:class_formula) is nondet.
*
* Get one solution of the OWL class assertions
*
* @param Database A graph object identifying the current schema graph.
* @param Class Atom URI identifier of rfds or owl Class.
* @param Formula Term describing the class relationships.
*
* TODO: Formula should be a type
*/
%:- rdf_meta class_assertion(o,r,t).
class_assertion(Database, Class, (Class<Solns)) :-
%class(Class),
setof(Sol, Y^(subClassOf(Class,Y,Database),
class_formula(Y, Database, Sol)),
Solns).
class_assertion(Database, Class, (Class=and(Solns))) :-
%class(Class,Database),
setof(Sol,Y^(intersectionOf(Class,Y,Database),
class_formula(Y,Database,Sol)),
Solns).
class_assertion(Database,Class,(Class=or(Solns))) :-
%class(Class,Database),
setof(Sol,Y^(unionOf(Class,Y,Database),
class_formula(Y,Database,Sol)),
Solns).
class_assertion(Database,Class,(Class=xor(Solns))) :-
%class(Class,Database),
setof(Sol,Y^(disjointUnionOf(Class,Y,Database),
class_formula(Y,Database,Sol)),
Solns).
class_assertion(Database,Class,(Class=oneOf(OneList))) :-
oneOfList(Class,OneList,Database).
class_assertion(Database,Class,RType) :-
restriction(Class,Database),
restriction_type(Class,RType,Database).
class_assertion(Database,Class,class(Class)) :-
immediateClass(Class,Database),
\+ restriction(Class,Database),
\+ has_formula(Class,Database).
/*
* class_formula(+Class:uri, +Database:database -Formula:class_formula) is semidet.
*
* Create a formula describing the manner in which the class is
* defined.
*
* @param Database A graph idntifying the current schema graph.
* @param Class Atom URI identifier of rfds or owl Class.
* @param Formula Term describing the class relationships.
*/
class_formula(Class,Database,F) :-
setof(Sol,class_assertion(Database,Class,Sol), Solns),
( [F]=Solns
-> true
; F=(Class=and(Solns))
).
maybe_label(C,Database,[label=L]) :-
label(C,L,Database), !.
maybe_label(_,_,[]).
maybe_comment(C,Database,[comment=Comment]) :-
comment(C,Comment,Database), !.
maybe_comment(_,_,[]).
maybe_tcs_tag(C,Database,[tcstag=DC]) :-
tcs_tag(C,DC,Database), !.
maybe_tcs_tag(_,_,[]).
maybe_meta(C,Database,LCD) :-
maybe_label(C,Database,Label),
maybe_comment(C,Database,Comment),
maybe_tcs_tag(C,Database,DCOGTag),
append(Label, Comment, LC),
append(LC,DCOGTag,LCD).
decorate_elements([],_Database,[]).
decorate_elements([Elt|Rest],Database,[MLC|Restp]) :-
class_record(Database,Elt,MLC),
decorate_elements(Rest,Database,Restp).
/**
* property_restriction(+Property:uri,+Database:databasePR:property_restriction) is det.
*
* Obtains a property restriction which is intrinsic to the property rather than
* a result of a restriction class.
*/
property_restriction(P,Database,R) :-
( functionalProperty(P,Database)
-> R=[uri=P,property=P,cardinality=1]
; R=true
).
/**
* classes_below(+Class:uri, +Database, -Below:list(uri)) is det.
*
* Get all classes below us in the subsumption hierarchy,
* excluding owl:Nothing or abstract classes.
*/
classes_below(Class,Database,BelowList) :-
unique_solutions(Below,schema:subsumptionOf(Below,Class,Database),Classes),
exclude([X]>>(X='http://www.w3.org/2002/07/owl#Nothing'), Classes, ClassesNoBottom),
database_schema(Database,Schema),
exclude({Database, Schema}/[X]>>(
xrdf(Database, Schema,
X,tcs:tag,tcs:abstract)),
ClassesNoBottom,
BelowList).
simplify_restriction_list(T,R,S) :-
( R = [S]
-> true
; R = []
-> S=true
; S=[type=T,
operands=R]).
/**
* normalise_restriction(+Restriction:property_restriction,-N:property_restriction) is det.
*
* Disjunctive normal form for restriction.
*/
normalise_restriction([type=sub, operands=Results],N) :-
!,
maplist([X,Y]>>normalise_restriction(X,Y),Results,Normalised),
exclude([X]>>(X=true),Normalised,Result),
debug(normalise,'normalise_restriction sub: ~p',[Result]),
( exclude([F]>>(F=[type=T|_], member(T,[and,sub])), Result, [])
-> foldl([F,R,O]>>(F=[type=_,operands=Fs], append(Fs,R,O)),Result,[],Acc)
; Acc=Result),
simplify_restriction_list(sub,Acc,N).
normalise_restriction([type=and, operands=Results],N) :-
!,
maplist([X,Y]>>normalise_restriction(X,Y),Results,Normalised),
exclude([X]>>(X=true),Normalised,Result),
debug(normalise,'normalise_restriction and: ~p',[Result]),
( exclude([F]>>(F=[type=T|_], member(T,[and,sub])), Result, [])
-> foldl([F,R,O]>>(F=[type=_,operands=Fs], append(Fs,R,O)),Result,[],Acc)
; Acc=Result),
simplify_restriction_list(and,Acc,N).
normalise_restriction([type=or, operands=Results],N) :-
!,
maplist([X,Y]>>(normalise_restriction(X,Y)),Results,Normalised),
simplify_restriction_list(or,Normalised,N).
normalise_restriction([type=xor, operands=Results],N) :-
!,
maplist([X,Y]>>normalise_restriction(X,Y),Results,Normalised),
exclude([X]>>(X=true),Normalised,Result),
simplify_restriction_list(xor,Result,N).
normalise_restriction([uri=U|Res],[uri=U|Res]) :-
!.
normalise_restriction(true,true) :-
!.
/*
* restriction_formula(+Formula:class_formula,+Database:database
* -RestrictionFormula:property_restriction) is det.
*
* Calculate the formula of restrictions for a class.
*/
restriction_formula(_<L,Database,S) :-
!,
maplist({Database}/[C,F]>>(restriction_formula(C,Database,F)),
L,R),
simplify_restriction_list(sub,R,S).
restriction_formula(_=or(L),Database,S) :-
!,
maplist({Database}/[C,F]>>(restriction_formula(C,Database,F)),
L,R),
simplify_restriction_list(or,R,S).
restriction_formula(_=and(L),Database,S) :-
!,
maplist({Database}/[C,F]>>(restriction_formula(C,Database,F)),
L,R),
simplify_restriction_list(and,R,S).
restriction_formula(_=xor(L),Database,S) :-
!,
maplist({Database}/[C,F]>>(restriction_formula(C,Database,F)),
L,R),
simplify_restriction_list(xor,R,S).
restriction_formula(class(_),_,true) :-
!.
restriction_formula(restriction(L),_,L) :-
!.
restriction_formula(_=oneOf(_),_,true) :-
!.
/**
* select_restriction(+P:uri,+R:property_restriction,+Database:database-S:property_restriction) is det.
*/
select_restriction(P,[type=or,operands=Operands],G,Restriction) :-
!,
convlist({P,G}/[R,S]>>select_restriction(P,R,G,S), Operands, NewOperands),
simplify_restriction_list(or,NewOperands,Restriction).
select_restriction(P,[type=sub,operands=Operands],G,Restriction) :-
!,
convlist({P,G}/[R,S]>>select_restriction(P,R,G,S), Operands, NewOperands),
simplify_restriction_list(sub,NewOperands,Restriction).
select_restriction(P,[type=and,operands=Operands],G,Restriction) :-
!,
convlist({P,G}/[R,S]>>select_restriction(P,R,G,S), Operands, NewOperands),
simplify_restriction_list(and,NewOperands,Restriction).
select_restriction(P,[type=xor,operands=Operands],G,Restriction) :-
!,
convlist({P,G}/[R,S]>>select_restriction(P,R,G,S), Operands, NewOperands),
simplify_restriction_list(xor,NewOperands,Restriction).
select_restriction(P,[uri=U,property=Q|R],G,[uri=U,property=P|R]) :-
subsumptionPropertiesOf(P,Q,G),
!.
select_restriction(_,[uri=_,property=_|_],_,true) :-
!. % \+ subsumptionPropertiesOf(P,Q,Database).
select_restriction(_,true,_,true).
/**
* calculate_property_restriction(+Property:uri,+Restriction_Formula:property_restriction,
* +Database:database-Restriction:property_restriction) is det.
*
* Calculate the full restriction on a given property, from the formula and
* constraints directly on the property.
*/
calculate_property_restriction(Property,Restriction_Formula,Database,Restriction) :-
select_restriction(Property,Restriction_Formula,Database,CalculatedRestriction),
property_restriction(Property,Database,PropRestriction),
normalise_restriction([type=and,operands=[PropRestriction,CalculatedRestriction]],
Restriction).
/**
* apply_restriction(+Class:uri,+Property:uri,+Database:database
* +RestrictionFormula:property_restriction,Frame) is semidet.
*
*
*/
%:- rdf_meta apply_restriction(r,r,o,o,t).
apply_restriction(Class,Property,Database,Restriction_Formula,
[type=datatypeProperty,
property=Property,
domain=Class,
restriction=Restriction,
range=Range
|RecordRemainder]) :-
% Checking for pseudo_properties, which denote annotations and other opaque linking
% we don't want to generate a frame here at all.
annotationProperty(Property,Database),
!,
mostSpecificRange(Property,Range,Database),
property_record(Database,Property,RecordRemainder),
calculate_property_restriction(Property,Restriction_Formula,Database,Restriction).
apply_restriction(Class,Property,Database,Restriction_Formula,
[type=datatypeProperty,
property=Property,
domain=Class,
restriction=Restriction,
range=Range
|RecordRemainder]) :-
mostSpecificRange(Property,Range,Database),
datatype(Range,Database),
% We only just found out that we've no alternatives now after testing data type..
!,
property_record(Database,Property,RecordRemainder),
calculate_property_restriction(Property,Restriction_Formula,Database,Restriction).
apply_restriction(Class,Property,Database,Restriction_Formula,
[type=objectProperty,
property=Property,
domain=Class,
range=Range,
restriction=Restriction,
frame=[type=document,class=Range|RTail]
|RecordRemainder]) :-
mostSpecificRange(Property,Range,Database),
class(Range,Database),
schema:document(Range,Database),
% We are a document frame.
!,
property_record(Database,Property,RecordRemainder),
maybe_label(Range,Database,RLabel),
maybe_comment(Range,Database,RComment),
append(RLabel, RComment, RTail),
calculate_property_restriction(Property,Restriction_Formula,Database,Restriction).
apply_restriction(Class,Property,Database,Restriction_Formula,
[type=objectProperty,
property=Property,
domain=Class,
range=Range,
restriction=Restriction,
frame=Frame
|RecordRemainder]) :-
mostSpecificRange(Property,Range,Database),
class(Range,Database),
oneOfList(Range,OneList,Database),
% We are an document frame.
!,
Frame = [type=oneOf, elements=DecoratedOneList],
decorate_elements(OneList,Database,DecoratedOneList),
property_record(Database,Property,RecordRemainder),
% These always come together as a triplet, so should probably be one thing.
calculate_property_restriction(Property,Restriction_Formula,Database,Restriction).
apply_restriction(Class,Property,Database,Restriction_Formula,
[type=objectProperty,
property=Property,
domain=Class,
range=Range,
frame=Frame,
restriction=Restriction
|RecordRemainder]) :-
mostSpecificRange(Property,Range,Database),
class(Range,Database),
% Object property but not an document
!,
property_record(Database,Property,RecordRemainder),
calculate_property_restriction(Property,Restriction_Formula,Database,Restriction),
classes_below(Range,Database,Below),
( [NextClass] = Below
% singleton choice of class class should just be rendered.
-> class_frame_aux(NextClass,Database,Frame)
% We can't decide from here...
; convlist({Database}/[C,F]>>(class_frame_aux(C,Database,F)),Below,Frames),
Frame=[type=class_choice,operands=Frames]
).
/*
* calculate_frame(+Class:uri,+Properties:list(uri),
* +Restriction_Formula:property_restriction, Database:database -Frame) is det.
*
* Calculate the application of the restriction formula to the properties.
333 */
calculate_frame(Class,Properties,Restriction_Formula,Database,Frames) :-
maplist({Class,Database,Restriction_Formula}/[Property,Property_Frame]
>>(apply_restriction(Class,Property,Database,Restriction_Formula,Property_Frame)),
Properties, Frames).
/*
* We can't actually check types here because tabling doesn't work with
* attributed variables.
*
* class_frame_aux(+Class:uri,Database:databaseOutputFrame:frame) is semidet.
* Generate the frame associated with a given class.
*
* Fails if the class doesn't exist.
*/
%:- if(current_prolog_flag(optimise,true)).
%:- table class_frame/3.
%:- endif.
class_frame(Class,Database,Frame) :-
class_frame_aux(Class,Database,Frame).
class_frame_aux(Class, Database, Frame) :-
( class_formula(Class,Database,Formula)
-> restriction_formula(Formula,Database,RestrictionFormula),
class_properties(Class,Database,Properties),
* format('Class: ~q~n Formula: ~q~n Properties ~q~n',[Class,Formula,Properties]),
debug(restriction,'Restriction: ~p',[RestrictionFormula]),
calculate_frame(Class,Properties,RestrictionFormula,Database,Frame)
; Frame = [type=failure, message='No Class Formula!', class=Class]).
/**
* fill_class_frame(+Elt,+Database,-Frame,-Filled) is det.
*
* Fill a class frame with values to recreate the LDO structure.
*
* NOTE: This should probably be upgraded to JSON-LD using dictionaries.
*/
fill_class_frame(_,_,[],[]) :- !.
fill_class_frame(Elt,Database,[[type=objectProperty|P]|Rest], Frames) :-
% object property
!,
member(property=Prop, P),
select(frame=Frame,P,Pp),
Prefix=[type=objectProperty,domainValue=Elt|Pp],
( setof([frame=FilledFrame],
V^(inferredEdge(Elt, Prop, V, Database),
fill_class_frame(V,Database,Frame,FilledFrame)),
FrameSuffixes)
-> maplist(append(Prefix),FrameSuffixes,PrefixFrames),
fill_class_frame(Elt,Database,Rest,F),
append(PrefixFrames,F,Frames)
; fill_class_frame(Elt,Database,Rest,Frames)).
fill_class_frame(Elt,Database,[[type=datatypeProperty|P]|Rest],Frames) :-
% datatype property
!,
member(property=Prop, P),
Prefix = [type=datatypeProperty,domainValue=Elt|P],
( setof([rangeValue=V], inferredEdge(Elt, Prop, V, Database), Vs)
-> maplist(append(Prefix),Vs,PrefixFrames),
fill_class_frame(Elt,Database,Rest,F),
append(PrefixFrames,F,Frames)
; fill_class_frame(Elt,Database,Rest,Frames)).
fill_class_frame(Elt,Database,[[type=restriction|_]|Rest],Frames) :-
% a bare restriction (restricts nothing)
!,
fill_class_frame(Elt,Database,Rest,Frames).
fill_class_frame(Elt,Database,[type=class_choice,operands=Fs],Fsp_Filtered) :-
% A class choice (the choice has already been made...)
!,
%format('Elt: ~q~n', [Elt]),
instanceClass(Elt,Class,Database),
%format('Class: ~q~n', [Class]),
maplist({Elt,Database}/[Fin,Fout]>>(fill_class_frame(Elt,Database,Fin,Fout)),Fs,Fsp),
%format('Fsp: ~q~n', [Fsp]),
include({Class}/[Frame]>>(
forall(member(Prop_Frame,Frame),
member(domain=Class, Prop_Frame))
), Fsp, Filtered),
debug(frame,'fill_class_frame/4 choice Filtered: ~q~n', [Filtered]),
Filtered = [Fsp_Filtered].
fill_class_frame(Elt,Database,C,[type=Type,frames=Fsp]) :-
member(type=Type, C),
member(operands=Fs, C),
% An operand
!,
maplist({Elt,Database}/[Fin,Fout]>>(fill_class_frame(Elt,Database,Fin,Fout)),Fs,Fsp).
fill_class_frame(Elt,_,F,DocumentFrame) :-
member(type=Type, F),
member(Type,[oneOf,document]),
% Just need one type
!,
append(F,[domainValue=Elt],DocumentFrame).
fill_class_frame(Elt,DB,F,_) :-
format(atom(M), 'Unable to process frame for frame filling rendering the predicate semi-deterministic. Results from: ~q~n', [fill_class_frame(Elt,DB,F,_)]),
throw(error(M)).
choose_property(Database,Property,[type=and,operands=R], Result) :-
member(F,R),
!,
choose_property(Database,Property,F,Result).
choose_property(Database,Property,[type=or,operands=R], Result) :-
member(F,R),
!,
choose_property(Database,Property,F,Result).
choose_property(Database,Property,[type=xor,operands=R], Result) :-
member(F,R),
!,
choose_property(Database,Property,F,Result).
choose_property(Database,P,[R|Rest], [R|Result]) :-
member(property=Q,R),
!,
% Can this be correct?
subsumptionPropertiesOf(P,Q,Database), !,
choose_property(Database,P,Rest,Result).
choose_property(Database,P,[R|FrameRest], Result) :-
\+ (member(property=Q,R), subsumptionPropertiesOf(P,Q,Database)),
choose_property(Database,P,FrameRest,Result), !.
choose_property(_Database,_P,[], []) :- !.
% Property Frame
class_property_frame(Class, Property, Database, PropertyFrame) :-
class_frame(Class, Database, Frame),
choose_property(Database,Property,Frame,PropertyFrame).
% get filled frame for document
document_filled_frame(Document,Database,Filled) :-
instanceClass(Document,Class,Database),
class_frame(Class,Database,Frame),
fill_class_frame(Document,Database,Frame,Filled).
/*
* realiser(+Document:uri,+Frame:frame,+Database:database+Depth:number,-Realiser:any) is det.
*
* Synthesise the concrete representative of the schema class,
* showing inhabitation unfolding documents up to a depth of Depth.
*
* Does not actually appear to be det!
*/
realiser(Elt,Frame,Database,Depth,['@type'=Class,
'@id'=Elt
|Realisers]) :-
instanceClass(Elt,Class,Database),
realise_frame(Elt,Frame,Database,Depth,Realisers).
/*
* realise_frame(Elt,Frame,Database,Depth,Quasi_JSONLD) is det.
*
* Traverse frame synthesising realisers.
*/
realise_frame(_,[],_,_,[]) :-
!.
realise_frame(Elt,[[type=objectProperty|P]|Rest],Database,Depth,Realisers) :-
!, % no turning back if we are an object property
member(property=Prop, P),
select(frame=Frame,P,_FrameLessP),
( setof(New_Realiser,
V^(inferredEdge(Elt, Prop, V, Database),
( schema:document(V,Database)
-> ( Depth =< 1
-> New_Realiser=[V]
; New_Depth is Depth-1,
document_object(V,Database,New_Depth,Object),
Object = [_Type,_Id|New_Realiser])
; realiser(V,Frame,Database,Depth,New_Realiser))),
RealiserValues)
-> ( RealiserValues = [Val]
-> Realisers = [Prop=Val|RealiserTail]
; Realisers = [Prop=RealiserValues|RealiserTail]
),
realise_frame(Elt,Rest,Database,Depth,RealiserTail)
; realise_frame(Elt,Rest,Database,Depth,Realisers)
).
realise_frame(Elt,[[type=datatypeProperty|P]|Rest],Database,Depth,Realisers) :-
!, % no turning back if we are a datatype property
member(property=Prop, P),
( setof(V,
inferredEdge(Elt, Prop, V, Database),
RealiserValues)
-> ( RealiserValues = [Val]
-> Realisers = [Prop=Val|RealiserTail]
; Realisers = [Prop=RealiserValues|RealiserTail]
),
realise_frame(Elt,Rest,Database,Depth,RealiserTail)
; realise_frame(Elt,Rest,Database,Depth,Realisers)
).
realise_frame(Elt,[[type=restriction|_R]|Rest],Database,Depth,Realisers) :-
% We are a bare restriction, not applied to any property
!,
realise_frame(Elt,Rest,Database,Depth,Realisers).
realise_frame(Elt,[[type=class_choice,operands=_]|Rest],Database,Depth,[Realiser|Realisers]) :-
% We are a bare class_choice, not applied to any property
!,
document_object(Elt,Database,Depth,Realiser),
realise_frame(Elt,Rest,Database,Depth,Realisers).
realise_frame(Elt,Frame,Database,Depth,Realisers) :-
% We should be able to assume correctness of operator here...
% member(type=Type, Frame),
member(operands=Fs, Frame),
!, % We're an operator, so stick with it
maplist({Elt,Database,Depth}/[TheFrame,New_Realiser]
>>(realiser(Elt,TheFrame,Database,Depth,New_Realiser)),Fs,Realisers).
realise_frame(_Elt,F,_Database,_Depth,[]) :-
memberchk(type=oneOf, F),
!.
realise_frame(Elt, Frame, Database, Depth, New_Realiser) :-
memberchk(type=document, Frame),
( Depth =< 1
-> New_Realiser=[]
; New_Depth is Depth-1,
document_object(Elt,Database,New_Depth,Object),
Object = [_Type,_Id|New_Realiser]).
/*
* realise_triples(Elt,Frame,Database,Realiser) is det.
*
* The triple realiser must be kept in complete lock step with the definition above.
* This makes me wonder if we shouldn't keep the method fused or derived!
*
* It may be desirable to have a depth parameter here as well?
*/
realise_triples(_,[],_,[]) :-
!.
realise_triples(Elt,[[type=objectProperty|P]|Rest],Database,[(C,G,Elt,RDFType,Type)|Realiser]) :-
!, % no turning back if we are an object property
database_name(Database,C),
database_instance(Database,G),
RDFType = 'http://www.w3.org/1999/02/22-rdf-syntax-ns#type',
xrdf(Database,G,Elt,RDFType,Type),
member(property=Prop, P),
select(frame=Frame,P,_FrameLessP),
( setof(New_Realiser,
V^(inferredEdge(Elt, Prop, V, Database),
( schema:document(V,Database)
-> New_Realiser=[(C,G,Elt,Prop,V)]
; realise_triples(V,Frame,Database,Below),
New_Realiser=[(C,G,Elt,Prop,V)|Below])),
RealiserLists)
-> append(RealiserLists,Realisers_on_P),
realise_triples(Elt,Rest,Database,Realiser_Tail),
append(Realisers_on_P, Realiser_Tail, Realiser)
; realise_triples(Elt,Rest,Database,Realiser)
).
realise_triples(Elt,[[type=datatypeProperty|P]|Rest],Database,[(C,G,Elt,RDFType,Type)|Realiser]) :-
!, % no turning back if we are a datatype property
database_name(Database,C),
database_instance(Database,G),
RDFType = 'http://www.w3.org/1999/02/22-rdf-syntax-ns#type',
xrdf(Database,G,Elt,RDFType,Type),
member(property=Prop, P),
( setof((C,G,Elt,Prop,V),
inferredEdge(Elt, Prop, V, Database),
Realisers_on_P)
-> realise_triples(Elt,Rest,Database,Realiser_Tail),
append(Realisers_on_P,Realiser_Tail,Realiser)
; realise_triples(Elt,Rest,Database,Realiser)
).
realise_triples(Elt,[[type=restriction|_R]|Rest],Database,Realiser) :-
% We are a bare restriction, not applied to any property
!,
realise_triples(Elt,Rest,Database,Realiser).
realise_triples(Elt,[[type=class_choice,operands=_]|Rest],Database,Realiser) :-
% We are a bare class choice, not applied to any property
!,
object_edges(Elt,Database,Edges),
realise_triples(Elt,Rest,Database,Realiser_Tail),
append(Edges,Realiser_Tail,Realiser).
realise_triples(Elt,Frame,Database,Realisers) :-
% We should be able to assume correctness of operator here...
% member(type=Type, Frame),
member(operands=Fs, Frame),
!, % We're an operator, so stick with it
maplist({Elt,Database}/[TheFrame,New_Realiser]
>>(realise_triples(Elt,TheFrame,Database,New_Realiser)),Fs,Realiser_List),
append(Realiser_List,Realisers).
realise_triples(_Elt,F,_Database,[]) :-
member(type=Type, F),
member(Type,[oneOf,document]),
% is a one-of or document (don't backtrack over member)
!.
/*
* document_object(+Document:uri,+Database:database+Depth,-Realiser) is semidet.
*
* Gets the realiser for the frame associated with the class of
* Document
*/
document_object(Document,Database,Depth,Realiser) :-
most_specific_type(Document,Class,Database),
class_frame(Class,Database,Frame),
realiser(Document,Frame,Database,Depth,Realiser).
/*
* document_jsonld(+Document:uri,+Ctx:any,+Database:database-Realiser) is semidet.
*
* Gets the realiser for the frame associated with the class of
* Document in a JSON_LD format using a supplied context.
*/
document_jsonld(Document,Ctx,Database,JSON_LD) :-
document_object(Document, Database, 1, Realiser),
term_jsonld(Realiser, JSON_Ex),
database_name(Database, Name),
get_collection_jsonld_context(Name,Ctx_Database),
merge_dictionaries(Ctx,Ctx_Database,Ctx_Total),
compress(JSON_Ex,Ctx_Total,JSON_LD).
/*
* document_jsonld(+Document:uri,+Ctx:any,+Database:database+Depth,-Realiser) is semidet.
*
* Gets the realiser for the frame associated with the class of
* Document in a JSON-LD format using a supplied context and unfolding
* up to depth Depth
*/
document_jsonld(Document,Ctx,Database,Depth,JSON_LD) :-
document_object(Document, Database, Depth, Realiser),
term_jsonld(Realiser, JSON_Ex),
database_name(Database, Name),
get_collection_jsonld_context(Name,Ctx_Database),
merge_dictionaries(Ctx,Ctx_Database,Ctx_Total),
compress(JSON_Ex,Ctx_Total,JSON_LD).
/*
* document_jsonld(+Document:uri,+Database:database-Realiser) is semidet.
*
* Gets the realiser for the frame associated with the class of
* Document in a JSON_LD format.
*/
document_jsonld(Document,Database,JSON_LD) :-
document_jsonld(Document,_{},Database,JSON_LD).
/*
* class_frame_jsonld(Class,Database,JSON_Frame) is det.
*
*/
class_frame_jsonld(Class,Database,JSON_Frame) :-
class_frame(Class,Database,Frame),
term_jsonld(Frame,JSON_LD),
database_name(Database, Name),
get_collection_jsonld_context(Name,Ctx),
compress(JSON_LD,Ctx,JSON_Frame).
/*
* object_edges(URI,Database,Edges) is det.
*
* Is there any way to make this so that everyting is derived from
* the same source?
*/
object_edges(URI,Database,Edges) :-
( most_specific_type(URI,Class,Database),
class_frame(Class,Database,Frame),
realise_triples(URI,Frame,Database,Unsorted),
sort(Unsorted,Edges)
-> true
% There is no type in the database, so it doesn't exist...
; Edges=[]).
/*
* object_references(URI,Database,Edges) is det.
*
* Get the set of references to a given object.
*/
object_references(URI,Database,Edges) :-
database_name(Database,C),
database_instance(Database,G),
% TBD: much more efficient to represent edges as e.g. e(C,G,Elt,Prop,URI)
findall((C,G,Elt,Prop,URI),
inferredEdge(Elt, Prop, URI, Database),
Edges).
/*
* object_instance_graph(JSON_or_URI,Database,I) is det.
*/
object_instance_graph(URI,Database,I) :-
atom(URI),
!,
database_instance(Database,Instance),
member(I,Instance),
% Defo exists here.
( xrdf(Database,[I],URI,rdf:type,_)
-> true).
object_instance_graph(JSON,Database,I) :-
is_dict(JSON),
get_dict('@id', JSON, URI),
object_instance_graph(URI,Database,I).
/*
* delete_object(URI,Database) is det.
*
*/
delete_object(URI,Database) :-
get_collection_jsonld_context(Database,Ctx),
prefix_expand(URI,Ctx,URI_Ex),
object_edges(URI_Ex,Database,Object_Edges),
object_references(URI_Ex,Database,References),
append(Object_Edges,References,Edges),
database_name(Database,DB_Name),
maplist({DB_Name,Database}/[(DB_Name,[G],X,Y,Z)]>>delete(Database,G,X,Y,Z), Edges).
/*
* update_object(Obj:dict,Database) is det.
*