common: Create options for applications, other fixes

This creates a new option `ghaf.programs.<name>`, which allows us to
configure applications across targets and whether they run inside a VM
or not.

This also fixes Chromium border glitch, and Element border colour
(SP-4645 & SP-4644).

Signed-off-by: Humaid Alqasimi <humaid.alqassimi@tii.ae>

lib/launcher.nix

@@ -9,8 +9,6 @@ _: {
           then old.postInstall
           else "";
       in {
-        desktopItems = null;
-        desktopItem = null;
         postInstall = pInst + "rm -rf \"$out/share/applications\"";
       }))
     pkgs;

modules/common/default.nix

@@ -16,5 +16,6 @@
     ./virtualization/docker.nix
     ./systemd
     ./services
+    ./programs
   ];
 }

modules/common/programs/chromium.nix

@@ -0,0 +1,23 @@
+# Copyright 2024 TII (SSRC) and the Ghaf contributors
+# SPDX-License-Identifier: Apache-2.0
+{
+  config,
+  lib,
+  ...
+}: let
+  cfg = config.ghaf.programs.chromium;
+in {
+  options.ghaf.programs.chromium = {
+    enable = lib.mkEnableOption "Enable Chromium program settings";
+    useZathuraVM = lib.mkEnableOption "Open PDFs in Zathura VM";
+  };
+  config = lib.mkIf cfg.enable {
+    programs.chromium.enable = true;
+
+    # Fix border glitch when going maximised->minimised.
+    programs.chromium.initialPrefs.browser.custom_chrome_frame = false;
+
+    # Don't use pdf.js, open externally.
+    programs.chromium.extraOpts."AlwaysOpenPdfExternally" = true;
+  };
+}

modules/common/programs/default.nix

@@ -0,0 +1,8 @@
+# Copyright 2024 TII (SSRC) and the Ghaf contributors
+# SPDX-License-Identifier: Apache-2.0
+{
+  imports = [
+    ./zathura.nix
+    ./chromium.nix
+  ];
+}

modules/common/programs/zathura.nix

@@ -0,0 +1,19 @@
+# Copyright 2024 TII (SSRC) and the Ghaf contributors
+# SPDX-License-Identifier: Apache-2.0
+{
+  config,
+  lib,
+  ...
+}: let
+  cfg = config.ghaf.programs.zathura;
+in {
+  options.ghaf.programs.zathura = {
+    enable = lib.mkEnableOption "Enable Zathura program settings";
+  };
+  config = lib.mkIf cfg.enable {
+    # Use regular clipboard instead of primary clipboard.
+    environment.etc."zathurarc".text = ''
+      set selection-clipboard clipboard
+    '';
+  };
+}

modules/desktop/graphics/demo-apps.nix

@@ -62,12 +62,5 @@ in {
         path = "${pkgs.appflowy}/bin/appflowy";
         icon = "${pkgs.appflowy}/opt/data/flutter_assets/assets/images/flowy_logo.svg";
       };
-    environment.systemPackages =
-      lib.optional cfg.chromium pkgs.chromium
-      ++ lib.optional cfg.element-desktop pkgs.element-desktop
-      ++ lib.optional cfg.firefox pkgs.firefox
-      ++ lib.optional cfg.gala-app pkgs.gala-app
-      ++ lib.optional cfg.zathura pkgs.zathura
-      ++ lib.optional (cfg.appflowy && pkgs.stdenv.isx86_64) pkgs.appflowy;
   };
 }

modules/desktop/graphics/labwc.nix

@@ -71,6 +71,10 @@ in {
           identifier = "org.pwmt.zathura";
           colour = "#122263";
         }
+        {
+          identifier = "Element";
+          colour = "#337aff";
+        }
       ];
       description = "List of applications and their frame colours";
     };

targets/lenovo-x1/appvms/chromium.nix

@@ -60,9 +60,8 @@ in {
       ];
       microvm.devices = [];
 
-      # Disable chromium built-in PDF viewer to make it execute xdg-open
-      programs.chromium.enable = true;
-      programs.chromium.extraOpts."AlwaysOpenPdfExternally" = true;
+      ghaf.programs.chromium.enable = true;
+
       # Set default PDF XDG handler
       xdg.mime.defaultApplications."application/pdf" = "ghaf-pdf.desktop";
     }

targets/lenovo-x1/appvms/zathura.nix

@@ -10,11 +10,7 @@
   extraModules = [
     {
       time.timeZone = "Asia/Dubai";
-
-      # Use regular clipboard instead of primary clipboard.
-      environment.etc."zathurarc".text = ''
-        set selection-clipboard clipboard
-      '';
+      ghaf.programs.zathura.enable = true;
     }
   ];
   borderColor = "#122263";