-
Notifications
You must be signed in to change notification settings - Fork 19
/
pool_logicsig.teal.tmpl
694 lines (578 loc) · 12.5 KB
/
pool_logicsig.teal.tmpl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
#pragma version 4
// Tinyman Pool LogicSig
// Documentation: https://docs.tinyman.org
// This code should be read in conjunction with validator_approval.teal.
// The validation logic is split between these two programs.
// ensure ASSET_ID_1 > ASSET_ID_2
int TMPL_ASSET_ID_1
int TMPL_ASSET_ID_2
>
assert
txn CloseRemainderTo
global ZeroAddress
==
assert
txn AssetCloseTo
global ZeroAddress
==
assert
txn RekeyTo
global ZeroAddress
==
assert
global GroupSize
int 1
>
assert
// ensure gtxn 1 is ApplicationCall to Validator App
gtxn 1 Sender
txn Sender
==
assert
gtxn 1 TypeEnum
int appl // ApplicationCall
==
assert
gtxn 1 ApplicationID
int TMPL_VALIDATOR_APP_ID
==
assert
// Bootstrap?
gtxn 1 OnCompletion
int OptIn
==
gtxn 1 NumAppArgs
int 3
==
&&
gtxna 1 ApplicationArgs 0
byte "bootstrap"
==
&&
bnz bootstrap
// The remaining operations (Mint/Burn/Swap/Redeem/Fees) must all have OnCompletion=NoOp
gtxn 1 OnCompletion
int NoOp
==
assert
// Swap?
gtxn 1 NumAppArgs
int 2
==
gtxna 1 ApplicationArgs 0
byte "swap"
==
&&
bnz swap
// The remaining operations (Mint/Burn/Redeem/Fees) must all have NumAppArgs=1
gtxn 1 NumAppArgs
int 1
==
assert
// Mint?
gtxna 1 ApplicationArgs 0
byte "mint"
==
bnz mint
// Burn?
gtxna 1 ApplicationArgs 0
byte "burn"
==
bnz burn
// Redeem?
gtxna 1 ApplicationArgs 0
byte "redeem"
==
bnz redeem
// Fees?
gtxna 1 ApplicationArgs 0
byte "fees"
==
bnz redeem_fees
err
bootstrap:
// Ensure group size is correct 4 or 5:
// 0: Pay Fees (signed by Pooler)
// 1: Call App (signed by Pool LogicSig)
// 2: Asset Creation (signed by Pool LogicSig)
// 3: Asset Optin (signed by Pool LogicSig)
// If asset 2 is an ASA:
// (4): Asset Optin (signed by Pool LogicSig)
int 5 // 5 if asset 2 is an ASA
int 4 // 4 if asset 2 is Algo
int TMPL_ASSET_ID_2
int 0 // Algo
==
select
global GroupSize
==
assert
gtxna 1 ApplicationArgs 1
btoi
int TMPL_ASSET_ID_1
==
gtxna 1 ApplicationArgs 2
btoi
int TMPL_ASSET_ID_2
==
&&
assert
// ensure sender (signer) of AssetConfig tx is same as sender of app call
gtxn 2 Sender
txn Sender
==
assert
// ensure gtxn 2 is type AssetConfig
gtxn 2 TypeEnum
int acfg
==
assert
// ensure a new asset is being created
gtxn 2 ConfigAsset
int 0
==
assert
// ensure asset total amount is max int
gtxn 2 ConfigAssetTotal
int 0
~ // inverse of 0 is max int
==
assert
// ensure decimals is 6
gtxn 2 ConfigAssetDecimals
int 6
==
assert
// ensure default frozen is false
gtxn 2 ConfigAssetDefaultFrozen
int 0
==
assert
// ensure unit name is 'TMPOOL11'
gtxn 2 ConfigAssetUnitName
byte "TMPOOL11"
==
assert
// ensure asset name begins with 'TinymanPool1.1 '
// the Validator app ensures the name ends with "{asset1_unit_name}-{asset2_unit_name}"
gtxn 2 ConfigAssetName
substring 0 15
byte "TinymanPool1.1 "
==
assert
// ensure asset url is 'https://tinyman.org'
gtxn 2 ConfigAssetURL
byte "https://tinyman.org"
==
assert
// ensure no asset manager address is set
gtxn 2 ConfigAssetManager
global ZeroAddress
==
assert
// ensure no asset reserve address is set
gtxn 2 ConfigAssetReserve
global ZeroAddress
==
assert
// ensure no asset freeze address is set
gtxn 2 ConfigAssetFreeze
global ZeroAddress
==
assert
// ensure no asset clawback address is set
gtxn 2 ConfigAssetClawback
global ZeroAddress
==
assert
// Asset 1 optin
// Ensure optin txn is signed by the same sig as this txn
gtxn 3 Sender
txn Sender
==
assert
// ensure txn type is AssetTransfer
gtxn 3 TypeEnum
int axfer
==
assert
// ensure the asset id is the same as asset 1
gtxn 3 XferAsset
int TMPL_ASSET_ID_1
==
assert
// ensure the receiver is the sender
gtxn 3 AssetReceiver
txn Sender
==
assert
// ensure the amount is 0 for Optin
gtxn 3 AssetAmount
int 0
==
assert
// if asset 2 is not 0 (Algo), it needs an optin
int TMPL_ASSET_ID_2
int 0
!=
bnz bootstrap__non_algo
gtxn 1 Fee
gtxn 2 Fee
+
gtxn 3 Fee
+
store 1 // fee_total
b check_fees
bootstrap__non_algo:
// verify 5th txn is asset 2 optin txn
gtxn 4 Sender
txn Sender
==
assert
gtxn 4 TypeEnum
int axfer
==
assert
// ensure the asset id is the same as asset 2
gtxn 4 XferAsset
int TMPL_ASSET_ID_2
==
assert
// ensure the receiver is the sender
gtxn 4 AssetReceiver
txn Sender
==
assert
// ensure the amount is 0 for Optin
gtxn 4 AssetAmount
int 0
==
assert
gtxn 1 Fee
gtxn 2 Fee
+
gtxn 3 Fee
+
gtxn 4 Fee
+
store 1 // fee_total
b check_fees
mint:
// Mint Checks:
//
// # ensure group size is 5
// global GroupSize == 5
// # ensure transaction fees are covered by txn 0
// # ensure Pool is not paying the fee
// gtxn 0 Sender != txn Sender
// gtxn 0 Receiver == txn Sender
// gtxn 0 Amount >= (gtxn 1 Fee + gtxn 4 Fee)
// # verify the receiver of the liquidity token asset is the one whose local state is updated
// gtxna 1 Accounts 1 != txn Sender
// gtxna 1 Accounts 1 == gtxn 4 AssetReceiver
// # from Pooler to Pool asset 1
// gtxn 2 Sender (Pooler) != txn Sender (Pool)
// gtxn 2 AssetReceiver (Pool) == txn Sender (Pool)
// gtxn 2 Sender (Pooler) == gtxn 3 Sender (Pooler)
// gtxn 2 XferAsset == TMPL_ASSET_ID_1
// # from Pooler to Pool asset 2
// txn Sender (Pool) == (gtxn 3 AssetReceiver or gtxn 3 Receiver) (Pool)
// gtxn 3 XferAsset == TMPL_ASSET_ID_2
// # from Pool to Pooler liquidity token
// gtxn 4 AssetReceiver (Pooler) == gtxn 2 Sender (Poooler)
// gtxn 4 Sender (Pool) == txn Sender (Pool)
// ensure group size is 5:
// 0: Pay Fees (signed by Pooler)
// 1: Call App (signed by Pool LogicSig)
// 2: Asset Transfer/Pay (signed by Pooler)
// 3: Asset Transfer/Pay (signed by Pooler)
// 4: Asset Transfer/Pay (signed by Pool LogicSig)
global GroupSize
int 5
==
assert
// verify the receiver of the asset is the one whose local state is updated
gtxna 1 Accounts 1
txn Sender
!=
assert
gtxna 1 Accounts 1
gtxn 4 AssetReceiver
==
assert
// verify txn 2 is AssetTransfer from Pooler to Pool
gtxn 2 Sender
txn Sender
!=
assert
gtxn 2 AssetReceiver
txn Sender
==
assert
gtxn 3 Sender
gtxn 2 Sender
==
assert
// ensure asset id is asset 1
gtxn 2 XferAsset
int TMPL_ASSET_ID_1
==
assert
// verify txn 3 is AssetTransfer from Pooler to Pool
gtxn 3 AssetReceiver
gtxn 3 Receiver
gtxn 3 TypeEnum
int pay
== // check if Algo
select
txn Sender
==
assert
// ensure asset id is asset 2
gtxn 3 XferAsset
int 0
gtxn 3 TypeEnum
int pay
== // check if Algo
select
int TMPL_ASSET_ID_2
==
assert
// verify txn 4 is AssetTransfer from Pool to Pooler
gtxn 4 Sender
txn Sender
==
assert
gtxn 4 AssetReceiver
gtxn 2 Sender
==
assert
gtxn 1 Fee
gtxn 4 Fee
+
store 1 // fee_total
b check_fees
burn:
// Burn Checks:
//
// # ensure group size is 5
// global GroupSize == 5
// # ensure transaction fees are covered by txn 0
// # ensure Pool is not paying the fee
// gtxn 0 Sender != txn Sender
// gtxn 0 Receiver == txn Sender
// gtxn 0 Amount >= (gtxn 1 Fee + gtxn 2 Fee gtxn 3 Fee)
// # ensure the calculated amounts are not 0
// calculated_asset1_out != 0
// calculated_asset2_out != 0
// # verify the receiver of the assets is the one whose local state is updated
// gtxna 1 Accounts 1 != txn Sender
// gtxna 1 Accounts 1 == gtxn 2 AssetReceiver
// gtxna 1 Accounts 1 == (gtxn 3 AssetReceiver or gtxn 3 Receiver)
// # from Pool to Pooler asset 1
// gtxn 2 Sender (Pooler) == txn Sender (Pool)
// gtxn 2 AssetReceiver (Pool) == gtxn 4 Sender (Pool)
// gtxn 2 XferAsset == TMPL_ASSET_ID_1
// # from Pool to Pooler asset 2
// gtxn 3 Sender (Pool) == txn Sender (Pool)
// gtxn 4 Sender (Pooler) == (gtxn 3 AssetReceiver or gtxn 3 Receiver) (Pool)
// gtxn 3 XferAsset == TMPL_ASSET_ID_2
// # from Pooler to Pool liquidity token
// gtxn 4 Sender (Pooler) != txn Sender (Pool)
// gtxn 4 AssetReceiver == txn Sender (Pool)
// ensure group size is 5:
// 0: Pay Fees (signed by Pooler)
// 1: Call App (signed by Pool LogicSig)
// 2: Asset Transfer/Pay (signed by Pool LogicSig)
// 3: Asset Transfer/Pay (signed by Pool LogicSig)
// 4: Asset Transfer/Pay (signed by Pooler)
global GroupSize
int 5
==
assert
// verify the receiver of the assets is the one whose local state is updated
gtxna 1 Accounts 1
txn Sender
!=
assert
gtxna 1 Accounts 1
gtxn 2 AssetReceiver
==
assert
gtxn 3 AssetReceiver
gtxn 3 Receiver
gtxn 3 TypeEnum
int pay
==
select
gtxna 1 Accounts 1
==
assert
// 2: AssetTransfer - from Pool to Pooler asset 1
gtxn 2 Sender
txn Sender
==
assert
gtxn 2 AssetReceiver
gtxn 4 Sender
==
assert
// ensure asset id is asset 1
gtxn 2 XferAsset
int TMPL_ASSET_ID_1
==
assert
// 3: AssetTransfer - from Pool to Pooler asset 2
gtxn 3 Sender
txn Sender
==
assert
gtxn 3 AssetReceiver
gtxn 3 Receiver
gtxn 3 TypeEnum
int pay
== // if algo
select
gtxn 4 Sender
==
assert
// ensure asset id is asset 2
gtxn 3 XferAsset
int 0
gtxn 3 TypeEnum
int pay
== // check if Algo
select
int TMPL_ASSET_ID_2
==
assert
// 4: AssetTransfer - from Pooler to Pool liquidity token
gtxn 4 Sender
txn Sender
!=
assert
gtxn 4 AssetReceiver
txn Sender
==
assert
gtxn 1 Fee
gtxn 2 Fee
+
gtxn 3 Fee
+
store 1 // fee_total
b check_fees
swap:
// ensure group size is 4:
// 0: Pay Fees (signed by Swapper)
// 1: Call App (signed by Pool LogicSig)
// 2: Asset Transfer/Pay (signed by Swapper)
// 3: Asset Transfer/Pay (signed by Pool LogicSig)
global GroupSize
int 4
==
assert
// ensure accounts[1] is not Pool
gtxna 1 Accounts 1
txn Sender
!=
assert
// ensure the sender of asset in is the one whose local state is updated
gtxn 2 Sender
gtxna 1 Accounts 1
==
assert
// ensure txn 2 sender is not the Pool
gtxn 2 Sender
txn Sender
!=
assert
// ensure txn 3 sender is the Pool
gtxn 3 Sender
txn Sender
==
assert
// ensure txn 2 receiver is Pool
gtxn 2 AssetReceiver
gtxn 2 Receiver
gtxn 2 TypeEnum
int pay
== // if Algo
select
txn Sender
==
assert
// ensure txn 3 receiver is Swapper (sender of txn 2)
gtxn 3 AssetReceiver
gtxn 3 Receiver
gtxn 3 TypeEnum
int pay
== // if Algo
select
gtxn 2 Sender
==
assert
gtxn 1 Fee
gtxn 3 Fee
+
store 1 // fee_total
b check_fees
redeem:
// ensure group size is 3:
// 0: Pay Fees (signed by Swapper)
// 1: Call App (signed by Pool LogicSig)
// 2: Asset Transfer/Pay (signed by Pool LogicSig)
global GroupSize
int 3
==
assert
// ensure accounts[1] is not Pool
gtxna 1 Accounts 1
txn Sender
!=
assert
// ensure the receiver of the asset is the one whose local state is updated
gtxn 2 AssetReceiver
gtxn 2 Receiver
gtxn 2 TypeEnum
int pay
== // if algo
select
gtxna 1 Accounts 1
==
assert
gtxn 1 Fee
gtxn 2 Fee
+
store 1 // fee_total
b check_fees
redeem_fees:
// ensure group size is 3:
// 0: Pay Fees (signed by User)
// 1: Call App (signed by Pool LogicSig)
// 2: Asset Transfer/Pay (signed by Pool LogicSig)
global GroupSize
int 3
==
assert
gtxn 1 Fee
gtxn 2 Fee
+
store 1 // fee_total
b check_fees
check_fees:
// ensure gtxn 0 amount covers all fees
// ensure Pool is not paying the fee
gtxn 0 Sender
txn Sender
!=
assert
// ensure Pool is receiving the fee
gtxn 0 Receiver
txn Sender
==
assert
gtxn 0 Amount
load 1 // fee_total
>=
return