rt#91153

lib/Type/Utils.pm

@@ -47,6 +47,8 @@ sub extends
 		{
 			$caller->add_type( $lib->get_type($_) )
 				for sort $lib->meta->type_names;
+			$caller->add_coercion( $lib->get_coercion($_) )
+				for sort $lib->meta->coercion_names;
 		}
 		elsif ($lib->isa('MooseX::Types::Base'))
 		{

t/library-inheritance.t

@@ -0,0 +1,120 @@
+=pod
+
+=encoding utf-8
+
+=head1 PURPOSE
+
+Checks that it's possible to extend existing type libraries.
+
+=head1 AUTHOR
+
+Toby Inkster E<lt>tobyink@cpan.orgE<gt>.
+
+=head1 COPYRIGHT AND LICENCE
+
+This software is copyright (c) 2013 by Toby Inkster.
+
+This is free software; you can redistribute it and/or modify it under
+the same terms as the Perl 5 programming language system itself.
+
+=cut
+
+use strict;
+use warnings;
+use lib qw( . ./t ../inc ./inc );
+use utf8;
+
+use Test::More;
+use Test::Requires { Encode => 0 };
+use Test::TypeTiny;
+
+BEGIN {
+	package Local::Types;
+	use Type::Library -base;
+	use Type::Utils -all;
+	extends 'Types::Standard';
+	declare "Foo", as "Str";
+	$INC{'Local/Types.pm'} = __FILE__;
+};
+
+use Local::Types -all;
+use Type::Utils;
+
+my $chars          = "Café Paris|Garçon";
+my $bytes_utf8     = Encode::encode("utf-8",      $chars);
+my $bytes_western  = Encode::encode("iso-8859-1", $chars);
+
+is(length($chars),         17, 'length $chars == 17');
+is(length($bytes_utf8),    19, 'length $bytes_utf8 == 19');
+is(length($bytes_western), 17, 'length $bytes_western == 17');
+
+my $SplitSpace = (ArrayRef[Str]) + (Split[qr/\s/]);
+my $SplitPipe  = (ArrayRef[Foo]) + (Split[qr/\|/]);
+
+ok($SplitSpace->can_be_inlined, '$SplitSpace can be inlined');
+ok($SplitPipe->can_be_inlined, '$SplitPipe can be inlined');
+
+is_deeply(
+	$SplitSpace->coerce($chars),
+	[ "Café", "Paris|Garçon" ],
+	'$SplitSpace->coerce($chars)',
+);
+
+is_deeply(
+	$SplitSpace->coerce($bytes_utf8),
+	[ map Encode::encode("utf-8", $_), "Café", "Paris|Garçon" ],
+	'$SplitSpace->coerce($bytes_utf8)',
+);
+
+is_deeply(
+	$SplitSpace->coerce($bytes_western),
+	[ map Encode::encode("iso-8859-1", $_), "Café", "Paris|Garçon" ],
+	'$SplitSpace->coerce($bytes_western)',
+);
+
+should_pass($SplitSpace->coerce($chars), ArrayRef[Str]);
+should_pass($SplitSpace->coerce($bytes_utf8), ArrayRef[Str]);
+should_pass($SplitSpace->coerce($bytes_western), ArrayRef[Str]);
+
+is_deeply(
+	my $arr_chars = $SplitPipe->coerce($chars),
+	[ "Café Paris", "Garçon" ],
+	'$SplitPipe->coerce($chars)',
+);
+
+is_deeply(
+	my $arr_bytes_utf8 = $SplitPipe->coerce($bytes_utf8),
+	[ map Encode::encode("utf-8", $_), "Café Paris", "Garçon" ],
+	'$SplitPipe->coerce($bytes_utf8)',
+);
+
+is_deeply(
+	my $arr_bytes_western = $SplitPipe->coerce($bytes_western),
+	[ map Encode::encode("iso-8859-1", $_), "Café Paris", "Garçon" ],
+	'$SplitPipe->coerce($bytes_western)',
+);
+
+my $JoinPipe = Foo + Join["|"];
+
+is(
+	$_ = $JoinPipe->coerce($arr_chars),
+	$chars,
+	'$JoinPipe->coerce($arr_chars)',
+);
+should_pass($_, Str);
+
+is(
+	$_ = $JoinPipe->coerce($arr_bytes_utf8),
+	$bytes_utf8,
+	'$JoinPipe->coerce($arr_bytes_utf8)',
+);
+should_pass($_, Str);
+
+is(
+	$_ = $JoinPipe->coerce($arr_bytes_western),
+	$bytes_western,
+	'$JoinPipe->coerce($arr_bytes_western)',
+);
+should_pass($_, Str);
+
+done_testing;