-
Notifications
You must be signed in to change notification settings - Fork 9
/
viki.vim
3526 lines (3229 loc) · 111 KB
/
viki.vim
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
" viki.vim
" @Author: Tom Link (micathom AT gmail com?subject=vim-viki)
" @Website: http://www.vim.org/account/profile.php?user_id=4037
" @License: GPL (see http://www.gnu.org/licenses/gpl.txt)
" @Created: 2007-03-25.
" @Last Change: 2012-09-24.
" @Revision: 0.1130
exec 'runtime! autoload/viki/enc_'. substitute(&enc, '[\/<>*+&:?]', '_', 'g') .'.vim'
""" General {{{1
" This is what we consider nil, in the absence of nil in vimscript
let g:vikiDefNil = ''
" In a previous version this was used as list separator and as nil too
let g:vikiDefSep = "\n"
" In extended viki links this is considered as a reference to the current
" document. This is likely to go away.
let g:vikiSelfRef = '.'
" :doc:
" Simple Viki Names [2]: *viki-vars-simple-names*
if !exists("g:vikiUpperCharacters")
" A simple viki name is made from a series of upper and lower characters
" (i.e. CamelCase-names). These two variables define what is considered as
" upper and lower-case characters. We don't rely on the builtin
" functionality for this.
let g:vikiUpperCharacters = "A-Z" "{{{2
endif
if !exists("g:vikiLowerCharacters")
let g:vikiLowerCharacters = "a-z" "{{{2
endif
" :doc:
" Extended Viki Names [2]: *viki-vars-ext-names*
" - b:vikiExtendedNameRx, b:vikiExtendedNameSimpleRx[1]
" - b:vikiExtendedNameNameIdx, b:vikiExtendedNameDestIdx,
" b:vikiExtendedNameAnchorIdx
"
" URLs [2]: *viki-vars-urls*
" - b:vikiUrlRx, b:vikiUrlSimpleRx[1]
" - b:vikiUrlNameIdx, b:vikiUrlDestIdx, b:vikiUrlAnchorIdx
"
" NOTE: [1] The same as *Rx variables but with less groups.
" NOTE: [2] These variables are defined by |VikiSetupBuffer()|.
"
" - b:vikiAnchorRx *b:vikiAnchorRx*
" If this variable exists, the string "%{ANCHOR}" will be replaced with the
" search text. The expression has to conform to the very nomagic |/\V|
" syntax.
" Characters allowed in anchors
" Defaults to:
" [b:vikiLowerCharacters][b:vikiLowerCharacters + b:vikiUpperCharacters + '_0-9]*
if !exists('g:vikiAnchorNameRx')
let g:vikiAnchorNameRx = '' "{{{2
endif
if !exists('g:vikiUrlRestRx')
let g:vikiUrlRestRx = '['. g:vikiLowerCharacters . g:vikiUpperCharacters .'0-9?%_=&+-]*' "{{{2
endif
if !exists('g:viki#error_malformed_names')
" If true, throw an error on malformed viki names.
let g:viki#error_malformed_names = 0 "{{{2
endif
if !exists("g:vikiSpecialProtocols")
" URLs matching these protocols are handled by |VikiOpenSpecialProtocol()|.
" Can also be buffer-local.
let g:vikiSpecialProtocols = 'https\?\|ftps\?\|nntp\|mailto\|mailbox\|file' "{{{2
if exists("g:vikiSpecialProtocolsExtra")
let g:vikiSpecialProtocols .= '\|'. g:vikiSpecialProtocolsExtra
endif
endif
if !exists("g:vikiSpecialProtocolsExceptions")
" Exceptions from g:vikiSpecialProtocols
let g:vikiSpecialProtocolsExceptions = "" "{{{2
endif
if !exists("g:vikiSpecialFiles") "{{{2
" Files matching these suffixes are handled by |viki#OpenSpecialFile()|.
" Can also be buffer-local.
" :read: let g:vikiSpecialFiles = [...] "{{{2
let g:vikiSpecialFiles = [
\ '3gp',
\ 'aac',
\ 'aif',
\ 'aiff',
\ 'au',
\ 'avi',
\ 'bmp',
\ 'dia',
\ 'doc',
\ 'docx',
\ 'dvi',
\ 'eml',
\ 'eps',
\ 'gif',
\ 'htm',
\ 'html',
\ 'jpeg',
\ 'jpg',
\ 'm3u',
\ 'mhtml',
\ 'mp1',
\ 'mp2',
\ 'mp3',
\ 'mp4',
\ 'mpeg',
\ 'mpg',
\ 'odg',
\ 'ods',
\ 'odt',
\ 'ogg',
\ 'pdf',
\ 'png',
\ 'ppt',
\ 'pptx',
\ 'ps',
\ 'rtf',
\ 'voc',
\ 'wav',
\ 'wma',
\ 'wmf',
\ 'wmv',
\ 'xhtml',
\ 'xls',
\ 'xlsx',
\ 'xmind',
\ ]
if exists("g:vikiSpecialFilesExtra")
let g:vikiSpecialFiles += g:vikiSpecialFilesExtra
endif
endif
if !exists("g:vikiSpecialFilesExceptions")
" Exceptions from g:vikiSpecialFiles
let g:vikiSpecialFilesExceptions = "" "{{{2
endif
if !exists('g:viki_highlight_hyperlink_light')
let g:viki_highlight_hyperlink_light = 'term=underline cterm=underline gui=underline ctermfg=DarkBlue guifg=DarkBlue' "{{{2
endif
if !exists('g:viki_highlight_hyperlink_dark')
let g:viki_highlight_hyperlink_dark = 'term=underline cterm=underline gui=underline ctermfg=LightBlue guifg=#bfbfff' "{{{2
endif
if !exists('g:viki_highlight_inexistent_light')
let g:viki_highlight_inexistent_light = 'term=underline cterm=underline gui=underline ctermfg=DarkRed guifg=DarkRed' "{{{2
endif
if !exists('g:viki_highlight_inexistent_dark')
let g:viki_highlight_inexistent_dark = 'term=underline cterm=underline gui=underline ctermfg=Red guifg=Red' "{{{2
endif
if !exists('g:vikiPromote')
" If set to true, any files loaded by viki will become viki enabled (in
" minor mode); this was the default behaviour in earlier versions
let g:vikiPromote = 0 "{{{2
endif
if !exists("g:vikiUseParentSuffix")
" If true, use the parent document's suffix.
" If true, always append the "parent" file's suffix to the
" destination file name. I.e. if the current file is "ThisIdea.txt"
" the the viki name "OtherIdea" will refer to the file
" "OtherIdea.txt".
let g:vikiUseParentSuffix = 1 "{{{2
endif
if !exists("g:vikiAnchorMarker")
" Prefix for anchors
let g:vikiAnchorMarker = "#" "{{{2
endif
if !exists("g:vikiFreeMarker")
" If true and an explicitly marked anchor isn't found, search for the anchor
" text as such. This search will be case-insensitive. deplate won't be able
" to deal with such pseudo-references, of course.
let g:vikiFreeMarker = 0 "{{{2
endif
if !exists('g:vikiPostFindAnchor')
let g:vikiPostFindAnchor = 'norm! zz' "{{{2
endif
if !exists("g:vikiNameTypes")
" Disable certain types of viki names globally or for a single buffer.
" (experimental, doesn't fully work yet)
" List of enabled viki name types:
" s ... Simple viki name
" c ... CamelCase
" S ... simple, quoted viki name
" i ... |interviki|
" w ... Hyperwords
" f ... file-bases hyperwords
" e ... Extended viki name
" u ... URL
" x ... Directives (some commands, regions ...)
let g:vikiNameTypes = "csSeuixwf" "{{{2
endif
if !exists("g:vikiExplorer")
" Which directory explorer to use to edit directories
let g:vikiExplorer = "Sexplore" "{{{2
endif
if !exists('g:viki#cmd_no_fnameescape')
" A |regexp| matching commands for which the filename should not be
" pre-processed with |fnameescape()| when opening a file.
let g:viki#cmd_no_fnameescape = '^\(\ue\|E\)xplore\>' "{{{2
endif
if !exists("g:vikiHide")
" If hide or update: use the respective command when leaving a buffer
" If a dirty buffers gets hidden, vim usually complains. This can be
" tiresome -- depending on your editing habits. When this variable is set to
" "hide", vim won't complain. If you set it to "update", a viki buffer will
" be automatically updated before editing a different file. If you leave
" this empty (""), the default behaviour is in effect. See also |hidden|.
let g:vikiHide = '' "{{{2
endif
if !exists("g:vikiNoWrapper")
" Don't use g:vikiHide for commands matching this rx
let g:vikiNoWrapper = '\cexplore' "{{{2
endif
if !exists("g:vikiCacheInexistent")
" Cache information about a document's inexistent names
" If non-zero, save patterns for |g:vikiMarkInexistent| for later
" re-use using |tlib#cache#Filename()|. You might want to delete old
" files from the |g:tlib_cache| directory from time to time.
let g:vikiCacheInexistent = 0 "{{{2
endif
if !exists("g:vikiMapInexistent")
" If non-nil, map keys that trigger the evaluation of inexistent names
let g:vikiMapInexistent = 1 "{{{2
endif
if !exists("g:vikiMapKeys")
" Map these keys for g:vikiMapInexistent to LineQuick
let g:vikiMapKeys = "]).,;:!?\"' " "{{{2
endif
if !exists("g:vikiMapQParaKeys")
" Map these keys for g:vikiMapInexistent to ParagraphVisible
let g:vikiMapQParaKeys = "\n" "{{{2
endif
if !exists("g:vikiHCM")
" Install hooks for these conditions (requires hookcursormoved to be
" installed)
" "linechange" could cause some slowdown.
let g:vikiHCM = ['syntaxleave_oneline'] "{{{2
endif
if !exists("g:vikiMapBeforeKeys")
" Check the viki name before inserting this character
let g:vikiMapBeforeKeys = ']' "{{{2
endif
if !exists("g:vikiFamily")
" Some functions a gathered in families/classes. See vikiLatex.vim for
" an example.
" By defining this variable, family specific functions will be called for:
" - viki#{b:vikiFamily}#SetupBuffer(state)
" - viki#{b:vikiFamily}#DefineMarkup(state)
" - viki#{b:vikiFamily}#DefineHighlighting(state)
" - viki#{b:vikiFamily}#CompleteSimpleNameDef(def)
" - viki#{b:vikiFamily}#CompleteExtendedNameDef(def)
" - viki#{b:vikiFamily}#FindAnchor(anchor)
" If one of these functions is undefined for a "viki family", then the
" default one is called.
"
" Apart from the default behaviour the following families are defined:
" - latex (see |viki-latex|)
" - anyword (see |viki-anyword|)
let g:vikiFamily = "viki" "{{{2
endif
if !exists("g:vikiDirSeparator")
" The directory separator
let g:vikiDirSeparator = "/" "{{{2
endif
if !exists("g:vikiTextstylesVer")
" The version of Deplate markup.
" Defines the markup of |viki-textstyles| like emphasized or code.
let g:vikiTextstylesVer = 2 "{{{2
endif
if !exists("g:vikiHomePage")
" The default viki page (as absolute filename).
" An absolute filename that is the general viki homepage (see also
" |:VikiEdit| and |:VikiHome|).
let g:vikiHomePage = '' "{{{2
endif
if !exists("g:vikiFeedbackMin")
" How often the feedback is changed when marking inexisting links
let g:vikiFeedbackMin = &lines "{{{2
endif
if !exists("g:vikiMapLeader")
" The map leader for most viki key maps.
let g:vikiMapLeader = '<LocalLeader>v' "{{{2
endif
if !exists("g:vikiAutoMarks")
" If non-nil, anchors like #mX are turned into vim marks
let g:vikiAutoMarks = 1 "{{{2
endif
if !exists("g:VIKIBACKREFS")
" The variable that keeps back-links information
let g:VIKIBACKREFS = {} "{{{2
endif
if !exists("g:vikiBalloonLines")
" An expression that evaluates to the number of lines that should be
" included in the balloon tooltop text if &ballonexpr is set to
" viki#Balloon().
let g:vikiBalloonLines = '&lines / 3' "{{{2
endif
if !exists("g:vikiBalloon")
" If true, show some line of the target file in a balloon tooltip
" window.
let g:vikiBalloon = 1 "{{{2
endif
if !exists("g:vikiBalloonEncoding")
let g:vikiBalloonEncoding = &enc "{{{2
endif
if v:version >= 700 && !exists("g:vikiHyperWordsFiles")
" A list of files that contain special viki names
" :read: let g:vikiHyperWordsFiles = [...] "{{{2
let g:vikiHyperWordsFiles = [
\ get(split(&rtp, ','), 0).'/vikiWords.txt',
\ './.vikiWords',
\ ]
endif
if !exists("g:vikiMapFunctionality")
" Define which keys to map
" b ... go back
" c ... follow link (c-cr)
" e ... edit
" F ... find
" f ... follow link (<LocalLeader>v)
" i ... check for inexistant destinations
" I ... map keys in g:vikiMapKeys and g:vikiMapQParaKeys
" m[fb] ... map mouse (depends on f or b)
" p ... edit parent (or backlink)
" q ... quote
" tF ... tab as find
" Files ... #Files related
" let g:vikiMapFunctionality = 'mf mb tF c q e i I Files'
let g:vikiMapFunctionality = 'ALL' "{{{2
endif
if !exists("g:vikiMapFunctionalityMinor")
" Define which keys to map in minor mode (invoked via :VikiMinorMode)
let g:vikiMapFunctionalityMinor = 'f b p mf mb tF c q e' "{{{2
endif
if !exists("g:vikiFoldMethodVersion")
" :nodoc:
" Choose folding method version
" Viki supports several methods (1..7) for defining folds. If you
" find that text entry is slowed down it is probably due to the
" chosen fold method. You could try to use another method (see
" ../ftplugin/viki.vim for alternative methods) or check out this
" vim tip:
" http://vim.wikia.com/wiki/Keep_folds_closed_while_inserting_text
let g:vikiFoldMethodVersion = 8 "{{{2
endif
if !exists("g:vikiFoldBodyLevel")
" Consider fold levels bigger that this as text body, levels smaller
" than this as headings
" This variable is only used if |g:vikiFoldMethodVersion| is 1.
" If set to 0, the "b" mode in |vikiFolds| will set the body level
" depending on the headings used in the current buffer. Otherwise
" |b:vikiHeadingMaxLevel| + 1 will be used.
let g:vikiFoldBodyLevel = 6 "{{{2
endif
if !exists("g:vikiFolds")
" Define which elements should be folded:
" h :: Heading
" H :: Headings (but inverse folding)
" l :: Lists
" b :: The body has max heading level + 1. This is slightly faster
" than the other version as vim never has to scan the text; but
" the behaviour may vary depending on the sequence of headings if
" |vikiFoldBodyLevel| is set to 0.
" f :: Files regions.
" s :: ???
" This variable is only used if |g:vikiFoldMethodVersion| is 1.
let g:vikiFolds = 'hf' "{{{2
endif
if !exists("g:vikiFoldsContext") "{{{2
" Context lines for folds
let g:vikiFoldsContext = [2, 2, 2, 2]
endif
if !exists('g:viki#files_head_rx')
" If a "head" argument is passed to the #Files region, the retrieved
" lines will be preprocessed by removing text matching this
" expression.
let g:viki#files_head_rx = '^\(\*\s\+\)' "{{{2
endif
if !exists('g:viki#use_texmath')
" If true, load syntax/texmath.vim for a prettier display of
" mathematical formulas.
let g:viki#use_texmath = 1 "{{{2
endif
let g:viki#quit = 0
let s:positions = {}
let s:InterVikiRx = '^\(['. g:vikiUpperCharacters .']\+\)::\(.*\)$'
let s:hookcursormoved_oldpos = []
" let s:vikiSelfEsc = '\'
" let s:vikiEnabledID = loaded_viki .'_'. strftime('%c')
""" Commands {{{1
" Find the next viki name or URL
command! -count VikiFindNext call viki#DispatchOnFamily('Find', '', '', <count>)
" Find the previous viki name or URL
command! -count VikiFindPrev call viki#DispatchOnFamily('Find', '', 'b', <count>)
" Update the highlighting of links to inexistent files.
" VikiMarkInexistent can take a range as argument.
command! -nargs=* -range=% VikiMarkInexistent call viki#MarkInexistentInRange(<line1>, <line2>)
if exists(':VEnclose')
" Mark selected text as a quoted simple viki name, i.e., enclose it in
" [- and -].
" This command requires imaps to be installed.
command! -range VikiQuote :call VEnclose("[-", "-]", "[-", "-]")
endif
command! -narg=? VikiGoBack call viki#GoBack(<f-args>)
command! VikiJump call viki#MaybeFollowLink(0,1)
command! VikiIndex :call viki#Index()
" :display: VikiEdit[!] NAME
" Edit the wiki page called NAME. If the NAME is '*', the |viki-homepage| will
" be opened. This is a convenient way to edit any wiki page from vim's command
" line. If you call :VikiEdit! (with bang), the homepage will be opened first,
" so that the homepage's customizations (and not the current buffer's one) are
" in effect. There are a few gotchas:
"
" 1. Viki doesn't define a default directory for wiki pages. Thus a wiki page
" will be looked for in the directory of the current buffer --
" whatever this is -- and the customizations of this buffer are in
" effect. You can circumvent this problem by using |interviki|
" names or define a |viki-homepage| and call :VikiEdit! with a
" bang.
"
" 2. Viki relies on some buffer local variables to be set. As customizability
" is one viki's main design goal (although, one might want to
" discuss whether I overdid it), there are no global settings that
" would define what a valid viki name is supposed to look like. As
" a consequence, if you disabled a certain type of wiki name in the
" current buffer, you won't be able to edit a wiki page of this
" type. E.g.: If the current buffer contains a LaTeX file,
" |vikiFamily| is most likely set to "LaTeX" (see |viki-latex|).
" For the LaTeX family, e.g., CamelCase and interwiki names are
" disabled. Consequently, you can't do, e.g., >
" :VikiEdit IDEAS::WikiPage
"< Again, you can circumvent this problem by defining a
" |viki-homepage| and call :VikiEdit! with a bang.
command! -nargs=1 -bang -complete=customlist,viki#EditComplete VikiEdit :call viki#Edit(<q-args>, !empty("<bang>"))
command! -nargs=1 -bang -complete=customlist,viki#EditComplete VikiEditTab :call viki#Edit(<q-args>, !empty("<bang>"), 'tab')
command! -nargs=1 -bang -complete=customlist,viki#EditComplete VikiEditInWin1 :call viki#Edit(<q-args>, !empty("<bang>"), 1)
command! -nargs=1 -bang -complete=customlist,viki#EditComplete VikiEditInWin2 :call viki#Edit(<q-args>, !empty("<bang>"), 2)
command! -nargs=1 -bang -complete=customlist,viki#EditComplete VikiEditInWin3 :call viki#Edit(<q-args>, !empty("<bang>"), 3)
command! -nargs=1 -bang -complete=customlist,viki#EditComplete VikiEditInWin4 :call viki#Edit(<q-args>, !empty("<bang>"), 4)
" Update the current |viki-files| #Files region under the cursor.
command! VikiFilesUpdate call viki#FilesUpdate()
" Update all |viki-files| #Files regions in the current buffer.
command! VikiFilesUpdateAll call viki#FilesUpdateAll()
command! -nargs=* -bang -complete=command VikiFileExec call viki#FilesExec(<q-args>, '<bang>', 1)
" |:execute| a vim command after doing some replacements with the command
" string. For each formatted string the command is issued only once --
" i.e. you can work easily with the directories. If no special formatting
" string is contained, the preformatted filename is appended to the command.
" %{FILE} ... filename
" %{FFILE} ... preformatted filename (with '#%\ ' escaped)
" %{DIR} ... file's directory
command! -nargs=* -bang -complete=command VikiFilesExec call viki#FilesExec(<q-args>, '<bang>')
" |:execute| VikiCmd_{VIKI_COMMAND_NAME} FILENAME
command! -nargs=* -bang VikiFilesCmd call viki#FilesCmd(<q-args>, '<bang>')
" |:call| VikiCmd_{FUNCTION_NAME}(FILENAME)
command! -nargs=* -bang VikiFilesCall call viki#FilesCall(<q-args>, '<bang>')
""" Functions {{{1
" This is mostly a legacy function. Using set ft=viki should work too.
function! viki#Mode(...) "{{{3
TVarArg 'family'
" if exists('b:vikiEnabled')
" if b:vikiEnabled
" return 0
" endif
" " if b:vikiEnabled && a:state < 0
" " return 0
" " endif
" " echom "VIKI: Viki mode already set."
" endif
unlet! b:did_ftplugin
if !empty(family)
let b:vikiFamily = family
endif
set filetype=viki
endf
" Special file handlers {{{1
if !exists('g:vikiOpenFileWith_ws') && exists(':WsOpen')
function! VikiOpenAsWorkspace(file)
exec 'WsOpen '. escape(a:file, ' &!%')
exec 'lcd '. escape(fnamemodify(a:file, ':p:h'), ' &!%')
endf
let g:vikiOpenFileWith_ws = "call VikiOpenAsWorkspace('%{FILE}')"
call add(g:vikiSpecialFiles, 'ws')
endif
if type(g:vikiSpecialFiles) != 3
echoerr 'Viki: g:vikiSpecialFiles must be a list'
endif
" TAssert IsList(g:vikiSpecialFiles)
if !exists("g:vikiOpenFileWith_ANY")
if exists('g:netrw_browsex_viewer')
let g:vikiOpenFileWith_ANY = "exec 'silent !'. g:netrw_browsex_viewer .' '. shellescape('%{FILE}')" "{{{2
elseif has("win32") || has("win16") || has("win64")
let g:vikiOpenFileWith_ANY = "exec 'silent ! start \"\" '. shellescape('%{FILE}')"
elseif has("mac")
let g:vikiOpenFileWith_ANY = "exec 'silent !open '. shellescape('%{FILE}')"
elseif exists('$XDG_CURRENT_DESKTOP') && !empty($XDG_CURRENT_DESKTOP)
let g:vikiOpenFileWith_ANY = "exec 'silent !xdg-open '. shellescape('%{FILE}')"
elseif $GNOME_DESKTOP_SESSION_ID != "" || $DESKTOP_SESSION == 'gnome'
let g:vikiOpenFileWith_ANY = "exec 'silent !gnome-open '. shellescape('%{FILE}')"
elseif exists("$KDEDIR") && !empty($KDEDIR)
let g:vikiOpenFileWith_ANY = "exec 'silent !kfmclient exec '. shellescape('%{FILE}')"
endif
endif
if !exists('*VikiOpenSpecialFile')
" Handles filenames that match |vikiSpecialFiles|.
" If g:vikiOpenFileWith_{SUFFIX} is defined, it contains a command
" definition for opending files of this type. "%{FILE}" is replaced with the
" file name ("%%" = "%") and the resulting string is executed. Example: >
"
" let g:vikiOpenFileWith_html = '!firefox %{FILE}'
"
" The contents of variable g:vikiOpenFileWith_ANY will be used as fallback
" command. Under Windows, g:vikiOpenFileWith_ANY defaults to "silent !cmd /c
" start".
" All suffixes are translated to lower case.
function! VikiOpenSpecialFile(file) "{{{3
" TLogVAR a:file
let proto = tolower(fnamemodify(a:file, ':e'))
if exists('g:vikiOpenFileWith_'. proto)
let prot = g:vikiOpenFileWith_{proto}
elseif exists('g:vikiOpenFileWith_ANY')
let prot = g:vikiOpenFileWith_ANY
else
let prot = ''
endif
if prot != ''
" let openFile = viki#SubstituteArgs(prot, 'FILE', fnameescape(a:file))
let openFile = viki#SubstituteArgs(prot, 'FILE', a:file)
" TLogVAR openFile
call viki#ExecExternal(openFile)
else
throw 'Viki: Please define g:vikiOpenFileWith_'. proto .' or g:vikiOpenFileWith_ANY!'
endif
endf
endif
" Special protocol handlers {{{1
if !exists('g:vikiOpenUrlWith_mailbox')
let g:vikiOpenUrlWith_mailbox = "call VikiOpenMailbox('%{URL}')" "{{{2
function! VikiOpenMailbox(url) "{{{3
exec viki#DecomposeUrl(strpart(a:url, 10))
let idx = matchstr(args, 'number=\zs\d\+$')
if filereadable(filename)
call viki#OpenLink(filename, '', 0, 'go '.idx)
else
throw 'Viki: Can't find mailbox url: '.filename
endif
endf
endif
if !exists("g:vikiUrlFileAs")
" Possible values: special*, query, normal
let g:vikiUrlFileAs = 'special' "{{{2
endif
if !exists("g:vikiOpenUrlWith_file")
let g:vikiOpenUrlWith_file = "call VikiOpenFileUrl('%{URL}')" "{{{2
function! VikiOpenFileUrl(url) "{{{3
" TLogVAR url
if viki#IsSpecialFile(a:url)
if g:vikiUrlFileAs == 'special'
let as_special = 1
elseif g:vikiUrlFileAs == 'query'
echo a:url
let as_special = input('Treat URL as special file? (Y/n) ')
let as_special = (as_special[0] !=? 'n')
else
let as_special = 0
endif
" TLogVAR as_special
if as_special
call VikiOpenSpecialFile(a:url)
return
endif
endif
exec viki#DecomposeUrl(strpart(a:url, 7))
if filereadable(filename) || isdirectory(filename)
call viki#OpenLink(filename, anchor)
else
throw "Viki: Can't find file url: ". filename
endif
endf
endif
if !exists("g:vikiOpenUrlWith_ANY")
" let g:vikiOpenUrlWith_ANY = "exec 'silent !". g:netrw_browsex_viewer ." '. escape('%{URL}', ' &!%')"
if has("win32")
" let g:vikiOpenUrlWith_ANY = "exec 'silent !rundll32 url.dll,FileProtocolHandler '. shellescape('%{URL}')"
let g:vikiOpenUrlWith_ANY = "exec 'silent ! RunDll32.EXE URL.DLL,FileProtocolHandler '. shellescape('%{URL}', 1)"
elseif has("mac")
let g:vikiOpenUrlWith_ANY = "exec 'silent !open '. escape('%{URL}', ' &!%')"
elseif exists('$XDG_CURRENT_DESKTOP') && !empty($XDG_CURRENT_DESKTOP)
let g:vikiOpenFileWith_ANY = "exec 'silent !xdg-open '. shellescape('%{URL}')"
elseif $GNOME_DESKTOP_SESSION_ID != ""
let g:vikiOpenUrlWith_ANY = "exec 'silent !gnome-open '. shellescape('%{URL}')"
elseif $KDEDIR != ""
let g:vikiOpenUrlWith_ANY = "exec 'silent !kfmclient exec '. shellescape('%{URL}')"
endif
endif
if !exists("*VikiOpenSpecialProtocol")
" Handles filenames that match |vikiSpecialProtocols|.
" If g:vikiOpenUrlWith_{PROTOCOL} is defined, it contains a command definition
" for opending urls of this type. "%{URL}" is replaced with the url ("%%" =
" "%") and the resulting string is executed. Example: >
"
" let g:vikiOpenUrlWith_mailto = '!thunderbird -compose %{URL}'
"
" The contents of variable g:vikiOpenUrlWith_ANY will be used as fallback
" command. Under Windows, g:vikiOpenUrlWith_ANY defaults to "silent
" !rundll32 url.dll ...".
" All protocol names are translated to lower case.
function! VikiOpenSpecialProtocol(url) "{{{3
" TLogVAR a:url
" TLogVAR a:url
let proto = tolower(matchstr(a:url, '\c^[a-z]\{-}\ze:'))
let prot = 'g:vikiOpenUrlWith_'. proto
let protp = exists(prot)
if !protp
let prot = 'g:vikiOpenUrlWith_ANY'
let protp = exists(prot)
endif
if protp
exec 'let openURL = '. prot
" let url = shellescape(a:url)
let url = a:url
" TLogVAR url, a:url
let openURL = viki#SubstituteArgs(openURL, 'URL', url)
" TLogVAR openURL
call viki#ExecExternal(openURL)
else
throw 'Viki: Please define g:vikiOpenUrlWith_'. proto .' or g:vikiOpenUrlWith_ANY!'
endif
endf
endif
" Outdated: a cheap implementation of printf
function! s:sprintf1(string, arg) "{{{3
if exists('printf')
return printf(string, a:arg)
else
let rv = substitute(a:string, '\C[^%]\zs%s', escape(a:arg, '"\'), 'g')
let rv = substitute(rv, '%%', '%', 'g')
return rv
end
endf
function! viki#GetInterVikis() "{{{3
return g:vikiInterVikiNames
endf
" Get a rx that matches a simple name
function! viki#GetSimpleRx4SimpleWikiName() "{{{3
let upper = s:UpperCharacters()
let lower = s:LowerCharacters()
let simpleWikiName = '\<['.upper.']['.lower.']\+\(['.upper.']['.lower.'0-9]\+\)\+\>'
" This will mistakenly highlight words like LaTeX
" let simpleWikiName = '\<['.upper.']['.lower.']\+\(['.upper.']['.lower.'0-9]\+\)\+'
return simpleWikiName
endf
function! s:AddToRegexp(regexp, pattern) "{{{3
if a:pattern == ''
return a:regexp
elseif a:regexp == ''
return a:pattern
else
return a:regexp .'\|'. a:pattern
endif
endf
" Make all filenames use slashes
function! viki#CanonicFilename(fname) "{{{3
return substitute(simplify(a:fname), '[\/]\+', '/', 'g')
endf
" Build the rx to find viki names
function! viki#FindRx() "{{{3
let rx = s:AddToRegexp('', b:vikiSimpleNameSimpleRx)
let rx = s:AddToRegexp(rx, b:vikiExtendedNameSimpleRx)
let rx = s:AddToRegexp(rx, b:vikiUrlSimpleRx)
return rx
endf
" Wrap edit commands. Every action that creates a new buffer should use
" this function.
function! s:EditWrapper(cmd, fname) "{{{3
" TLogVAR a:cmd, a:fname
let fname = simplify(a:fname)
if g:vikiDirSeparator == '\' && fname !~ '^\w\+://'
let fname = substitute(fname, '/', '\\', 'g')
" TLogVAR fname
endif
if a:cmd =~ '^\(silent!\?\s\+\)\?!'
" TLogVAR 1
let fname = escape(fname, '%#')
let fname = shellescape(fname)
" TLogVAR fname
elseif a:cmd !~ g:viki#cmd_no_fnameescape
" TLogVAR 2
let fname = fnameescape(fname)
else
" TLogVAR 3
let fname = escape(fname, '%#')
endif
" let fname = escape(simplify(a:fname), '%#')
if a:cmd =~ g:vikiNoWrapper
" TLogDBG a:cmd .' '. fname
" echom 'No wrapper: '. a:cmd .' '. fname
exec a:cmd fname
else
try
if g:vikiHide == 'hide'
" TLogDBG 'hide '. a:cmd .' '. fname
exec 'hide' a:cmd fname
elseif g:vikiHide == 'update'
" TLogDBG 'update | '. a:cmd .' '. fname
update
exec a:cmd fname
else
let pre = ''
if &modified && !&hidden
call inputsave()
let val = input('Viki: Hide/save modified buffer? (HIDE/save/cancel) ')
call inputrestore()
if val =~? '^s\%[ave]$'
update
elseif val =~? '^c\%[ancel]$'
return
else
let pre = 'hide'
endif
echom "Viki: Please set g:vikiHide"
endif
" TLogDBG a:cmd .' '. fname
exec pre a:cmd fname
endif
catch /^Vim\%((\a\+)\)\=:E37/
echoerr "Vim raised E37: You tried to abondon a dirty buffer (see :h E37)"
echoerr "Viki: You may want to reconsider your g:vikiHide or 'hidden' settings"
catch /^Vim\%((\a\+)\)\=:E325/
endtry
endif
endf
" Find the previous heading
function! viki#FindPrevHeading()
let vikisr=@/
let cl = getline('.')
if cl =~ '^\*'
let head = matchstr(cl, '^\*\+')
let head = '*\{1,'. len(head) .'}'
else
let head = '*\+'
endif
call search('\V\^'. head .'\s', 'bW')
let @/=vikisr
endf
" Find the next heading
function! viki#FindNextHeading()
" let pos = getpos('.')
let view = winsaveview()
" TLogVAR pos
let cl = getline('.')
" TLogDBG 'line0='. cl
if cl =~ '^\*'
let head = matchstr(cl, '^\*\+')
let head = '*\{1,'. len(head) .'}'
else
let head = '*\+'
endif
" TLogDBG 'head='. head
" TLogVAR pos
" call setpos('.', pos)
call winrestview(view)
let vikisr = @/
call search('\V\^'. head .'\s', 'W')
let @/=vikisr
endf
" Test whether we want to markup a certain viki name type for the current
" buffer
" viki#IsSupportedType(type, ?types=b:vikiNameTypes)
function! viki#IsSupportedType(type, ...) "{{{3
if a:0 >= 1
let types = a:1
elseif exists('b:vikiNameTypes')
let types = b:vikiNameTypes
else
let types = g:vikiNameTypes
end
if types == ''
return 1
else
" return stridx(b:vikiNameTypes, a:type) >= 0
return types =~# '['. a:type .']'
endif
endf
" Build an rx from a list of names
function! viki#RxFromCollection(coll) "{{{3
" TAssert IsList(a:coll)
let rx = join(a:coll, '\|')
if rx == ''
return ''
else
return '\V\('. rx .'\)'
endif
endf
" Mark inexistent viki names
" VikiMarkInexistent(line1, line2, ?maxcol, ?quick)
" maxcol ... check only up to maxcol
" quick ... check only if the cursor is located after a link
function! s:MarkInexistent(line1, line2, ...) "{{{3
if !exists('b:vikiMarkInexistent') || !b:vikiMarkInexistent
return
endif
if exists('b:vikiPosition')
let li0 = b:vikiPosition.pos[1]
let co0 = b:vikiPosition.pos[2]
let co1 = co0 - 2
else
let li0 = line('.')
let co0 = col('.')
let co1 = co0 - 1
end
if a:0 >= 2 && a:2 > 0 && synIDattr(synID(li0, co1, 1), 'name') !~ '^viki.*Link$'
return
endif
let lazyredraw = &lazyredraw
set lazyredraw
let maxcol = a:0 >= 1 ? (a:1 == -1 ? 9999999 : a:1) : 9999999
if a:line1 > 0
keepjumps call cursor(a:line1, 1)
let min = a:line1
else
go
let min = 1
endif
let max = a:line2 > 0 ? a:line2 : line('$')
if line('.') == 1 && line('$') == max
let b:vikiNamesNull = []
let b:vikiNamesOk = []
else
if !exists('b:vikiNamesNull') | let b:vikiNamesNull = [] | endif
if !exists('b:vikiNamesOk') | let b:vikiNamesOk = [] | endif
endif
let b:vikiNamesNull0 = copy(b:vikiNamesNull)
let b:vikiNamesOk0 = copy(b:vikiNamesOk)
let feedback = (max - min) > b:vikiFeedbackMin
let b:vikiMarkingInexistent = 1
try
if feedback
call tlib#progressbar#Init(line('$'), 'Viki: Mark inexistent %s', 20)
endif
let rx = viki#FindRx()
let pp = 0
let ll = 0
let cc = 0
keepjumps let li = search(rx, 'Wc', max)
let co = col('.')
while li != 0 && !(ll == li && cc == co) && li >= min && li <= max && co <= maxcol
let lic = line('.')
if synIDattr(synID(lic, col('.'), 1), "name") !~ '^vikiFiles'
if feedback
call tlib#progressbar#Display(lic)
endif
let ll = li
let co1 = co - 1
" TLogVAR co1
let def = viki#GetLink(1, getline('.'), co1)
" TAssert IsList(def)
" TLogDBG getline('.')[co1 : -1]
" TLogVAR def
if empty(def)
echom 'Internal error: VikiMarkInexistent: '. co .' '. getline('.')
else
exec viki#SplitDef(def)
" TLogVAR v_part
if v_part =~ '^'. b:vikiSimpleNameSimpleRx .'$'
if v_dest =~ g:vikiSpecialProtocols
" TLogDBG "v_dest =~ g:vikiSpecialProtocols => 0"
let check = 0
elseif v:version >= 700 && viki#IsHyperWord(v_part)
" TLogDBG "viki#IsHyperWord(v_part) => 0"
let check = 0
elseif v_name == g:vikiSelfRef
" TLogDBG "simple self ref"
let check = 0
else
" TLogDBG "else1 => 1"
let check = 1
let partx = escape(v_part, "'\"\\/")
if partx !~ '^\['
let partx = '\<'.partx
endif
if partx !~ '\]$'
let partx = partx.'\>'
endif
endif
elseif v_dest =~ '^'. b:vikiUrlSimpleRx .'$'
" TLogDBG "v_dest =~ '^'. b:vikiUrlSimpleRx .'$' => 0"
let check = 0
let partx = escape(v_part, "'\"\\/")
call filter(b:vikiNamesNull, 'v:val != partx')
if index(b:vikiNamesOk, partx) == -1
call insert(b:vikiNamesOk, partx)
endif
elseif v_part =~ b:vikiExtendedNameSimpleRx
if v_dest =~ '^'. g:vikiSpecialProtocols .':'
" TLogDBG "v_dest =~ '^'. g:vikiSpecialProtocols .':' => 0"
let check = 0
else
" TLogDBG "else2 => 1"