Add command similar to :GBrowse, that will open a Github page with existing pull request for the current branch?

[vitaly-zdanevich]

Looks like currently there is no such functionality?

[benelan]

That functionality is built into the gh cli. You could make your own vim command, e.g.

if executable("gh")
    command! -nargs=* GBrowsePR exe "!gh pr view --web <args>"
endif

[benelan]

Here it is with fugitive's object completion for specifying the branch. It will still open the PR for the current branch without an argument. If attached to tmux, it will open the PR in a new window for people who use CLI browsers.

function! s:warn(msg)
  echohl WarningMsg | echom a:msg | echohl None
endfunction

function! s:browse_github_pr(args) abort
    if !executable("gh")
        return s:warn("gh cli required: https://cli.github.com/")
    endif

    let s:gh_pr_cmd = (exists("$TMUX")
            \   ? "!tmux new-window -n github_pr "
            \   : "!"
            \ ) . "gh pr view --web --"

    execute s:gh_pr_cmd a:args
endfunction

command! -nargs=? -complete=customlist,fugitive#CompleteObject 
            \ GBrowsePR call s:browse_github_pr(<q-args>)

---

Edit

Here it is with GBrowse's bang to copy functionality:

function! s:warn(msg)
  echohl WarningMsg | echom a:msg | echohl None
endfunction

function! s:browse_github_pr(bang, args) abort
    if !executable("gh")
        return s:warn("gh cli required: https://cli.github.com")
    endif

    let s:url = substitute(
                \   system("gh pr view --json url --jq '.url' -- " . a:args),
                \   '\n\+$', '', ''
                \ )
    echom s:url

    if a:bang && has('clipboard')
        let @+ = s:url
    else
        if !exists('g:loaded_netrw')
            runtime! autoload/netrw.vim
        endif

        if exists('*netrw#BrowseX')
            call netrw#BrowseX(s:url, 0)
        else
            return s:warn("netrw required to open github pull request")
        endif
    endif
endfunction

command! -bang -nargs=? -complete=customlist,fugitive#CompleteObject
            \ GBrowsePR call s:browse_github_pr(<bang>0, <q-args>)