-
-
Notifications
You must be signed in to change notification settings - Fork 87
/
vinegar.vim
140 lines (125 loc) · 4.77 KB
/
vinegar.vim
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
" Location: plugin/vinegar.vim
" Maintainer: Tim Pope <http://tpo.pe/>
" Version: 1.0
" GetLatestVimScripts: 5671 1 :AutoInstall: vinegar.vim
if exists("g:loaded_vinegar") || v:version < 700 || &cp
finish
endif
let g:loaded_vinegar = 1
function! s:fnameescape(file) abort
if exists('*fnameescape')
return fnameescape(a:file)
else
return escape(a:file," \t\n*?[{`$\\%#'\"|!<")
endif
endfunction
let s:dotfiles = '\(^\|\s\s\)\zs\.\S\+'
let s:escape = 'substitute(escape(v:val, ".$~"), "*", ".*", "g")'
let g:netrw_list_hide =
\ join(map(split(&wildignore, ','), '"^".' . s:escape . '. "/\\=$"'), ',') . ',^\.\.\=/\=$' .
\ (get(g:, 'netrw_list_hide', '')[-strlen(s:dotfiles)-1:-1] ==# s:dotfiles ? ','.s:dotfiles : '')
if !exists("g:netrw_banner")
let g:netrw_banner = 0
endif
unlet! s:netrw_up
nnoremap <silent> <Plug>VinegarUp :call <SID>opendir('edit')<CR>
if empty(maparg('-', 'n')) && !hasmapto('<Plug>VinegarUp')
nmap - <Plug>VinegarUp
endif
nnoremap <silent> <Plug>VinegarTabUp :call <SID>opendir('tabedit')<CR>
nnoremap <silent> <Plug>VinegarSplitUp :call <SID>opendir('split')<CR>
nnoremap <silent> <Plug>VinegarVerticalSplitUp :call <SID>opendir('vsplit')<CR>
function! s:sort_sequence(suffixes) abort
return '[\/]$,*' . (empty(a:suffixes) ? '' : ',\%(' .
\ join(map(split(a:suffixes, ','), 'escape(v:val, ".*$~")'), '\|') . '\)[*@]\=$')
endfunction
let g:netrw_sort_sequence = s:sort_sequence(&suffixes)
function! s:opendir(cmd) abort
let df = ','.s:dotfiles
if expand('%:t')[0] ==# '.' && g:netrw_list_hide[-strlen(df):-1] ==# df
let g:netrw_list_hide = g:netrw_list_hide[0 : -strlen(df)-1]
endif
if &filetype ==# 'netrw' && len(s:netrw_up)
let basename = fnamemodify(b:netrw_curdir, ':t')
execute s:netrw_up
call s:seek(basename)
elseif expand('%') =~# '^$\|^term:[\/][\/]'
execute a:cmd '.'
else
execute a:cmd '%:h' . (expand('%:p') =~# '^\a\a\+:' ? s:slash() : '')
call s:seek(expand('#:t'))
endif
endfunction
function! s:seek(file) abort
if get(b:, 'netrw_liststyle') == 2
let pattern = '\%(^\|\s\+\)\zs'.escape(a:file, '.*[]~\').'[/*|@=]\=\%($\|\s\+\)'
else
let pattern = '^\%(| \)*'.escape(a:file, '.*[]~\').'[/*|@=]\=\%($\|\t\)'
endif
call search(pattern, 'wc')
return pattern
endfunction
augroup vinegar
autocmd!
autocmd FileType netrw call s:setup_vinegar()
if exists('##OptionSet')
autocmd OptionSet suffixes
\ if s:sort_sequence(v:option_old) ==# get(g:, 'netrw_sort_sequence') |
\ let g:netrw_sort_sequence = s:sort_sequence(v:option_new) |
\ endif
endif
augroup END
function! s:slash() abort
return !exists("+shellslash") || &shellslash ? '/' : '\'
endfunction
function! s:absolutes(first, ...) abort
let files = getline(a:first, a:0 ? a:1 : a:first)
call filter(files, 'v:val !~# "^\" "')
call map(files, "substitute(v:val, '^\\(| \\)*', '', '')")
call map(files, 'b:netrw_curdir . s:slash() . substitute(v:val, "[/*|@=]\\=\\%(\\t.*\\)\\=$", "", "")')
return files
endfunction
function! s:relatives(first, ...) abort
let files = s:absolutes(a:first, a:0 ? a:1 : a:first)
call filter(files, 'v:val !~# "^\" "')
for i in range(len(files))
let relative = fnamemodify(files[i], ':.')
if relative !=# files[i]
let files[i] = '.' . s:slash() . relative
endif
endfor
return files
endfunction
function! s:escaped(first, last) abort
let files = s:relatives(a:first, a:last)
return join(map(files, 's:fnameescape(v:val)'), ' ')
endfunction
" 97f3fbc9596f3997ebf8e30bfdd00ebb34597722
function! s:setup_vinegar() abort
if !exists('s:netrw_up')
let orig = maparg('-', 'n')
if orig =~? '^<plug>' && orig !=# '<Plug>VinegarUp'
let s:netrw_up = 'execute "normal \'.substitute(orig, ' *$', '', '').'"'
elseif orig =~# '^:'
" :exe "norm! 0"|call netrw#LocalBrowseCheck(<SNR>123_NetrwBrowseChgDir(1,'../'))<CR>
let s:netrw_up = substitute(orig, '\c^:\%(<c-u>\)\=\|<cr>$', '', 'g')
else
let s:netrw_up = ''
endif
endif
nmap <buffer> - <Plug>VinegarUp
cnoremap <buffer><expr> <Plug><cfile> get(<SID>relatives('.'),0,"\022\006")
if empty(maparg('<C-R><C-F>', 'c'))
cmap <buffer> <C-R><C-F> <Plug><cfile>
endif
nnoremap <buffer> ~ :edit ~/<CR>
nnoremap <buffer> . :<C-U> <C-R>=<SID>escaped(line('.'), line('.') - 1 + v:count1)<CR><Home>
xnoremap <buffer> . <Esc>: <C-R>=<SID>escaped(line("'<"), line("'>"))<CR><Home>
if empty(mapcheck('y.', 'n'))
nnoremap <silent><buffer> y. :<C-U>call setreg(v:register, join(<SID>absolutes(line('.'), line('.') - 1 + v:count1), "\n")."\n")<CR>
endif
nmap <buffer> ! .!
xmap <buffer> ! .!
exe 'syn match netrwSuffixes =\%(\S\+ \)*\S\+\%('.join(map(split(&suffixes, ','), s:escape), '\|') . '\)[*@]\=\S\@!='
hi def link netrwSuffixes SpecialKey
endfunction