Commit
This commit does not belong to any branch on this repository, and may belong to a fork outside of the repository.
swscale: add a neon version for the nv12 to rgba conversion v2
- Loading branch information
Showing
4 changed files
with
240 additions
and
3 deletions.
There are no files selected for viewing
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
Original file line number | Diff line number | Diff line change |
---|---|---|
@@ -1,4 +1,5 @@ | ||
# OBJS += arm/swscale_unscaled.o | ||
OBJS += arm/swscale_unscaled.o | ||
|
||
# NEON-OBJS += arm/rgb2yuv_neon_32.o | ||
# NEON-OBJS += arm/rgb2yuv_neon_16.o | ||
NEON-OBJS += arm/yuv2rgb_neon.o |
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
Original file line number | Diff line number | Diff line change |
---|---|---|
@@ -0,0 +1,166 @@ | ||
/* | ||
* Copyright (c) 2015 Stupéflix | ||
* | ||
* This file is part of FFmpeg. | ||
* | ||
* FFmpeg is free software; you can redistribute it and/or | ||
* modify it under the terms of the GNU Lesser General Public | ||
* License as published by the Free Software Foundation; either | ||
* version 2.1 of the License, or (at your option) any later version. | ||
* | ||
* FFmpeg is distributed in the hope that it will be useful, | ||
* but WITHOUT ANY WARRANTY; without even the implied warranty of | ||
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU | ||
* Lesser General Public License for more details. | ||
* | ||
* You should have received a copy of the GNU Lesser General Public | ||
* License along with FFmpeg; if not, write to the Free Software | ||
* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA | ||
*/ | ||
|
||
#include "libavutil/arm/asm.S" | ||
|
||
.macro compute_premult half_u half_v | ||
vmov d2, \half_u @ copy left q14 to left q1 | ||
vmov d3, \half_u @ copy left q14 to right q1 | ||
vmov d4, \half_v @ copy left q15 to left q2 | ||
vmov d5, \half_v @ copy left q15 to right q2 | ||
|
||
vzip.16 d2, d3 @ U1U1U2U2U3U3U4U4 | ||
vzip.16 d4, d5 @ V1V1V2V2V3V3V4V4 | ||
|
||
vmull.s16 q8, d4, d1[0] @ V * v2r (left, red) | ||
vmull.s16 q9, d5, d1[0] @ V * v2r (right, red) | ||
vmull.s16 q10, d2, d1[1] @ U * u2g | ||
vmull.s16 q11, d3, d1[1] @ U * u2g | ||
vmlal.s16 q10, d4, d1[2] @ U * u2g + V * v2g (left, green) | ||
vmlal.s16 q11, d5, d1[2] @ U * u2g + V * v2g (right, green) | ||
vmull.s16 q12, d2, d1[3] @ U * u2b (left, blue) | ||
vmull.s16 q13, d3, d1[3] @ U * u2b (right, blue) | ||
.endm | ||
|
||
.macro compute_color dst_comp pre1 pre2 | ||
vadd.s32 q3, q1, \pre1 | ||
vadd.s32 q4, q2, \pre2 | ||
vqrshrun.s32 d10, q3, #13 | ||
vqrshrun.s32 d11, q4, #13 @ q5 = ({q3,q4} + (1<<12)) >> 13 | ||
vqmovn.u16 \dst_comp, q5 @ saturate 16bit -> 8bit | ||
.endm | ||
|
||
.macro compute_rgbx a b c d alpha | ||
compute_color \a, q8, q9 @ r | ||
compute_color \b, q10, q11 @ g | ||
compute_color \c, q12, q13 @ b | ||
vmov.u8 \d, #\alpha @ x | ||
.endm | ||
|
||
.macro compute_half_line dst half_y rgb alpha | ||
vmovl.u8 q7, \half_y @ 8px of Y | ||
vdup.16 q5, r9 | ||
@vsub.s16 q7, q5 | ||
vmull.s16 q1, d14, d0 @ q1 = (srcY - y_offset) * y_coeff (left) | ||
vmull.s16 q2, d15, d0 @ q2 = (srcY - y_offset) * y_coeff (right) | ||
|
||
.ifc \rgb,xrgb | ||
compute_rgbx d15, d12, d13, d14, \alpha | ||
.endif | ||
|
||
.ifc \rgb,rgbx | ||
compute_rgbx d12, d13, d14, d15, \alpha | ||
.endif | ||
|
||
.ifc \rgb,xbgr | ||
compute_rgbx d15, d14, d13, d12, \alpha | ||
.endif | ||
|
||
.ifc \rgb,bgrx | ||
compute_rgbx d14, d13, d12, d15, \alpha | ||
.endif | ||
|
||
vst4.u8 {d12, d13, d14, d15}, [\dst]! | ||
.endm | ||
|
||
.macro declare_func ifmt ofmt rgb alpha | ||
function ff_\ifmt\()_to_\ofmt\()_neon, export=1 | ||
push {r4-r12, lr} | ||
vpush {q4-q7} | ||
ldr r4, [sp, #104] @ r4 = srcY | ||
ldr r5, [sp, #108] @ r5 = linesizeY | ||
ldr r6, [sp, #112] @ r6 = srcC | ||
ldr r7, [sp, #116] @ r7 = linesizeC | ||
ldr r8, [sp, #120] @ r8 = table | ||
ldr r9, [sp, #124] @ r9 = y_offset | ||
ldr r10,[sp, #128] @ r10 = y_coeff | ||
vdup.16 d0, r10 @ d0 = y_coeff | ||
vld1.16 {d1}, [r8] @ d1 = *table | ||
add r11, r2, r3 @ r11 = dst + linesize (dst2) | ||
add r12, r4, r5 @ r12 = srcY + linesizeY (srcY2) | ||
lsl r3, r3, #1 | ||
lsl r5, r5, #1 | ||
lsl r8, r0, #2 | ||
sub r3, r3, r8 @ r3 = linesize * 2 - width * 4 (padding) | ||
sub r5, r5, r0 @ r5 = linesizeY * 2 - width (paddingY) | ||
sub r7, r7, r0 @ r7 = linesizeC * 2 - width (paddingC) | ||
1: | ||
mov r8, r0 @ r8 = width | ||
2: | ||
pld [r6, #64*3] | ||
pld [r4, #64*3] | ||
pld [r12, #64*3] | ||
|
||
vld2.8 {d2, d3}, [r6]! @ q1: interleaved chroma line | ||
vmov.i8 d10, #128 | ||
.ifc \ifmt,nv12 | ||
vsubl.u8 q14, d2, d10 @ q14 = U - 128 | ||
vsubl.u8 q15, d3, d10 @ q15 = V - 128 | ||
.else | ||
vsubl.u8 q14, d3, d10 @ q14 = U - 128 | ||
vsubl.u8 q15, d2, d10 @ q15 = V - 128 | ||
.endif | ||
|
||
compute_premult d28 d30 | ||
|
||
vld1.8 {q7}, [r4]! @ first line of luma | ||
vmov d28, d15 @ save right of the first line of luma for later use | ||
compute_half_line r2, d14, \rgb, \alpha | ||
|
||
vld1.8 {q7}, [r12]! @ second line of luma | ||
vmov d30, d15 @ save right of the second line of luma for later use | ||
compute_half_line r11, d14, \rgb, \alpha | ||
|
||
compute_premult d29, d31 | ||
compute_half_line r2, d28, \rgb, \alpha | ||
compute_half_line r11, d30, \rgb, \alpha | ||
|
||
subs r8, r8, #16 @ width -= 16 | ||
bgt 2b | ||
|
||
add r2, r2, r3 @ dst += padding | ||
add r11, r11, r3 @ dst2 += padding | ||
add r4, r4, r5 @ srcY += paddingY | ||
add r6, r6, r7 @ srcC += paddingC | ||
add r12, r12, r5 @ srcY2 += paddingY | ||
|
||
subs r1, r1, #2 @ height -= 2 | ||
bgt 1b | ||
|
||
vpop {q4-q7} | ||
pop {r4-r12, lr} | ||
mov pc, lr | ||
endfunc | ||
.endm | ||
|
||
.macro declare_rgb_funcs ifmt | ||
declare_func \ifmt, argb, xrgb, 255 | ||
declare_func \ifmt, rgba, rgbx, 255 | ||
declare_func \ifmt, abgr, xbgr, 255 | ||
declare_func \ifmt, bgra, bgrx, 255 | ||
|
||
declare_func \ifmt, 0rgb, xrgb, 0 | ||
declare_func \ifmt, rgb0, rgbx, 0 | ||
declare_func \ifmt, 0bgr, xbgr, 0 | ||
declare_func \ifmt, bgr0, bgrx, 0 | ||
.endm | ||
|
||
declare_rgb_funcs nv12 | ||
declare_rgb_funcs nv21 |
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters