-
Notifications
You must be signed in to change notification settings - Fork 19
/
engine.vala
581 lines (521 loc) · 21.2 KB
/
engine.vala
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
/*
* Copyright (C) 2011 Daiki Ueno <ueno@unixuser.org>
* Copyright (C) 2011 Red Hat, Inc.
*
* This program is free software; you can redistribute it and/or
* modify it under the terms of the GNU General Public License
* as published by the Free Software Foundation; either version 2
* of the License, or (at your option) any later version.
*
* This program is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU General Public License for more details.
*
* You should have received a copy of the GNU General Public License
* along with this program; if not, write to the Free Software
* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
* 02110-1301, USA.
*/
using Gee;
class SkkEngine : IBus.Engine {
// preferences are shared among SkkEngine instances.
static Preferences preferences;
// dictionaries are shared among SkkEngine instances and
// maintained in the per-class signal handler in main().
static ArrayList<Skk.Dict> dictionaries;
Skk.Context context;
IBus.LookupTable lookup_table;
int pagination_start;
bool show_annotation;
IBus.Property input_mode_prop;
IBus.PropList prop_list;
Map<Skk.InputMode, IBus.Property> input_mode_props =
new HashMap<Skk.InputMode, IBus.Property> ();
Map<Skk.InputMode, string> input_mode_symbols =
new HashMap<Skk.InputMode, string> ();
Map<string, Skk.InputMode> name_input_modes =
new HashMap<string, Skk.InputMode> ();
construct {
// prepare lookup table
lookup_table = new IBus.LookupTable (LOOKUP_TABLE_LABELS.length,
0, true, false);
for (var i = 0; i < LOOKUP_TABLE_LABELS.length; i++) {
var text = new IBus.Text.from_string (LOOKUP_TABLE_LABELS[i]);
lookup_table.set_label (i, text);
}
lookup_table.set_orientation (IBus.Orientation.HORIZONTAL);
// prepare the properties on the lang bar
prop_list = new IBus.PropList ();
var props = new IBus.PropList ();
IBus.Property prop;
prop = register_input_mode_property (Skk.InputMode.HIRAGANA,
"InputMode.Hiragana",
_("Hiragana"),
"あ");
props.append (prop);
prop = register_input_mode_property (Skk.InputMode.KATAKANA,
"InputMode.Katakana",
_("Katakana"),
"ア");
props.append (prop);
prop = register_input_mode_property (Skk.InputMode.HANKAKU_KATAKANA,
"InputMode.HankakuKatakana",
_("HankakuKatakana"),
"_ア");
props.append (prop);
prop = register_input_mode_property (Skk.InputMode.LATIN,
"InputMode.Latin",
_("Latin"),
"_A");
props.append (prop);
prop = register_input_mode_property (Skk.InputMode.WIDE_LATIN,
"InputMode.WideLatin",
_("WideLatin"),
"A");
props.append (prop);
prop = new IBus.Property (
"InputMode",
IBus.PropType.MENU,
new IBus.Text.from_string ("あ"),
null,
new IBus.Text.from_string (_("Switch input mode")),
true,
true,
IBus.PropState.UNCHECKED,
props);
prop_list.append (prop);
input_mode_prop = prop;
prop = new IBus.Property (
"setup",
IBus.PropType.NORMAL,
new IBus.Text.from_string (_("Setup")),
"gtk-preferences",
new IBus.Text.from_string (_("Configure SKK")),
true,
true,
IBus.PropState.UNCHECKED,
null);
prop_list.append (prop);
// initialize libskk
context = new Skk.Context (dictionaries.to_array ());
apply_preferences ();
preferences.value_changed.connect ((name, value) => {
apply_preferences ();
if (name == "dictionaries") {
// SkkEngine.dictionaries should be updated separately
context.dictionaries = SkkEngine.dictionaries.to_array ();
}
});
context.notify["preedit"].connect (() => {
var text = new IBus.Text.from_string (context.preedit);
uint underline_offset, underline_nchars;
context.get_preedit_underline (out underline_offset,
out underline_nchars);
if (0 < underline_nchars) {
text.append_attribute (IBus.AttrType.UNDERLINE,
IBus.AttrUnderline.SINGLE,
(int) underline_offset,
(int) (underline_offset + underline_nchars));
}
update_preedit_text (text,
text.get_length (),
text.get_length () > 0);
});
context.notify["candidates"].connect ((s, p) => {
update_candidates ();
});
context.notify["input-mode"].connect ((s, p) => {
update_input_mode ();
});
update_candidates ();
update_input_mode ();
context.retrieve_surrounding_text.connect (_retrieve_surrounding_text);
context.delete_surrounding_text.connect (_delete_surrounding_text);
}
bool _retrieve_surrounding_text (out string text, out uint cursor_pos) {
weak IBus.Text _text;
uint _cursor_pos, anchor_pos;
get_surrounding_text (out _text, out _cursor_pos, out anchor_pos);
text = _text.text.dup ();
cursor_pos = _cursor_pos;
return true;
}
bool _delete_surrounding_text (int offset, uint nchars) {
delete_surrounding_text (offset, nchars);
return true;
}
void populate_lookup_table () {
lookup_table.clear ();
for (var i = pagination_start;
i < context.candidates.size;
i++) {
var text = new IBus.Text.from_string (
context.candidates[i].output);
lookup_table.append_candidate (text);
}
}
void set_lookup_table_cursor_pos () {
var empty_text = new IBus.Text.from_static_string ("");
var cursor_pos = context.candidates.cursor_pos - pagination_start;
if (cursor_pos >= 0 &&
cursor_pos < lookup_table.get_number_of_candidates ()) {
lookup_table.set_cursor_pos (cursor_pos);
update_lookup_table (lookup_table, true);
var candidate = context.candidates.get ();
if (show_annotation && candidate.annotation != null) {
var text = new IBus.Text.from_string (
candidate.annotation);
update_auxiliary_text (text, true);
} else {
update_auxiliary_text (empty_text, false);
}
} else {
update_lookup_table (lookup_table, false);
update_auxiliary_text (empty_text, false);
}
}
void update_candidates () {
context.candidates.populated.connect (() => {
populate_lookup_table ();
});
context.candidates.notify["cursor-pos"].connect (() => {
set_lookup_table_cursor_pos ();
});
populate_lookup_table ();
set_lookup_table_cursor_pos ();
}
void update_input_mode () {
// update the state of menu item
var _prop = input_mode_props.get (context.input_mode);
_prop.set_state (IBus.PropState.CHECKED);
update_property (_prop);
// update the label of the menu
var symbol = new IBus.Text.from_string (
input_mode_symbols.get (context.input_mode));
input_mode_prop.set_label (symbol);
update_property (input_mode_prop);
}
static Skk.Dict? parse_dict_from_plist (PList plist) throws GLib.Error {
var encoding = plist.get ("encoding") ?? "EUC-JP";
var type = plist.get ("type");
if (type == "file") {
string? file = plist.get ("file");
if (file == null) {
return null;
}
string mode = plist.get ("mode") ?? "readonly";
if (mode == "readonly") {
if (file.has_suffix (".cdb"))
return new Skk.CdbDict (file, encoding);
else
return new Skk.FileDict (file, encoding);
} else if (mode == "readwrite")
return new Skk.UserDict (file, encoding);
} else if (type == "server") {
var host = plist.get ("host") ?? "localhost";
var port = plist.get ("port") ?? "1178";
return new Skk.SkkServ (host, (uint16) int.parse (port), encoding);
}
return null;
}
static void reload_dictionaries () {
SkkEngine.dictionaries.clear ();
Variant? variant = preferences.get ("dictionaries");
assert (variant != null);
string[] strv = variant.dup_strv ();
foreach (var str in strv) {
try {
var plist = new PList (str);
Skk.Dict? dict = parse_dict_from_plist (plist);
if (dict != null)
dictionaries.add (dict);
} catch (PListParseError e) {
stderr.printf ("can't parse plist \"%s\": %s\n",
str, e.message);
} catch (GLib.Error e) {
stderr.printf ("can't open dictionary \"%s\": %s\n",
str, e.message);
}
}
}
void apply_preferences () {
Variant? variant;
variant = preferences.get ("auto_start_henkan_keywords");
assert (variant != null);
context.auto_start_henkan_keywords = variant.get_strv ();
variant = preferences.get ("period_style");
assert (variant != null);
context.period_style = (Skk.PeriodStyle) variant.get_int32 ();
variant = preferences.get ("page_size");
assert (variant != null);
lookup_table.set_page_size (variant.get_int32 ());
variant = preferences.get ("pagination_start");
assert (variant != null);
pagination_start = variant.get_int32 ();
variant = preferences.get ("initial_input_mode");
assert (variant != null);
context.input_mode = (Skk.InputMode) variant.get_int32 ();
variant = preferences.get ("show_annotation");
assert (variant != null);
show_annotation = variant.get_boolean ();
variant = preferences.get ("egg_like_newline");
assert (variant != null);
context.egg_like_newline = variant.get_boolean ();
variant = preferences.get ("typing_rule");
assert (variant != null);
try {
context.typing_rule = new Skk.Rule (variant.get_string ());
} catch (Skk.RuleParseError e) {
}
}
IBus.Property register_input_mode_property (Skk.InputMode mode,
string name,
string label,
string symbol)
{
var prop = new IBus.Property (name,
IBus.PropType.RADIO,
new IBus.Text.from_string (label),
null,
null,
true,
true,
IBus.PropState.UNCHECKED,
null);
input_mode_props.set (mode, prop);
input_mode_symbols.set (mode, symbol);
name_input_modes.set (name, mode);
return prop;
}
string[] LOOKUP_TABLE_LABELS = {"a", "s", "d", "f", "j", "k", "l",
"q", "w", "e", "r", "u", "i", "o",
"z", "x"};
uint get_page_start_cursor_pos () {
var page_size = lookup_table.get_page_size ();
return (lookup_table.get_cursor_pos () / page_size) * page_size;
}
bool process_lookup_table_key_event (uint keyval,
uint keycode,
uint state)
{
if (state == 0 && (keyval == IBus.Page_Up ||
keyval == IBus.KP_Page_Up)) {
var cursor_pos = get_page_start_cursor_pos () - lookup_table.get_page_size ();
if (lookup_table.page_up ()) {
context.candidates.cursor_pos = (int) cursor_pos + pagination_start;
update_lookup_table (lookup_table, true);
}
return true;
}
else if (state == 0 && (keyval == IBus.Page_Down ||
keyval == IBus.KP_Page_Down)) {
var cursor_pos = get_page_start_cursor_pos () + lookup_table.get_page_size ();
if (lookup_table.page_down ()) {
context.candidates.cursor_pos = (int) cursor_pos + pagination_start;
update_lookup_table (lookup_table, true);
}
return true;
}
else if (state == 0 && (keyval == IBus.Up ||
keyval == IBus.Left)) {
if (lookup_table.cursor_up ()) {
update_lookup_table (lookup_table, true);
if (context.candidates.cursor_pos > 0)
context.candidates.cursor_pos--;
}
return true;
}
else if (state == 0 && (keyval == IBus.Down ||
keyval == IBus.Right)) {
if (lookup_table.cursor_down ()) {
update_lookup_table (lookup_table, true);
if (context.candidates.cursor_pos < context.candidates.size - 1)
context.candidates.cursor_pos++;
}
return true;
}
else if (state == 0 && ((unichar) keyval) == 'x') {
if (lookup_table.page_up ()) {
update_lookup_table (lookup_table, true);
var page_size = lookup_table.get_page_size ();
if (context.candidates.cursor_pos > page_size)
context.candidates.cursor_pos -= (int) page_size;
}
return true;
}
else if (state == 0 && keyval == IBus.space) {
if (lookup_table.page_down ()) {
update_lookup_table (lookup_table, true);
var page_size = lookup_table.get_page_size ();
if (context.candidates.cursor_pos < context.candidates.size - page_size)
context.candidates.cursor_pos += (int) page_size;
}
return true;
}
else if (state == 0) {
var page_size = lookup_table.get_page_size ();
string label = ((unichar) keyval).tolower ().to_string ();
for (var index = 0;
index < int.min ((int)page_size, LOOKUP_TABLE_LABELS.length);
index++) {
if (LOOKUP_TABLE_LABELS[index] == label) {
var cursor_pos = get_page_start_cursor_pos () + index;
lookup_table.set_cursor_pos (cursor_pos);
update_lookup_table (lookup_table, true);
context.candidates.cursor_pos = (int) cursor_pos + pagination_start;
context.candidates.select ();
var output = context.poll_output ();
if (output.length > 0) {
var text = new IBus.Text.from_string (output);
commit_text (text);
}
return true;
}
}
}
return false;
}
public override bool process_key_event (uint keyval,
uint keycode,
uint state)
{
if (context.candidates.cursor_pos >= pagination_start &&
process_lookup_table_key_event (keyval, keycode, state)) {
return true;
}
Skk.ModifierType modifiers = (Skk.ModifierType) state;
string? name = null;
unichar code = '\0';
if (keyval == IBus.Tab) {
code = '\t';
}
else if (keyval == IBus.Return) {
code = '\n';
}
else if (keyval == IBus.BackSpace) {
code = '\b';
}
else if (keyval == IBus.Muhenkan) {
name = "lshift";
}
else if (keyval == IBus.Henkan) {
name = "rshift";
}
else if (keyval == IBus.Left) {
name = "Left";
}
else if (keyval == IBus.Right) {
name = "Right";
}
else if (0x20 <= keyval && keyval < 0x7F) {
code = (unichar) keyval;
}
else {
return false;
}
var key = new Skk.KeyEvent (name, code, modifiers);
var retval = context.process_key_event (key);
var output = context.poll_output ();
if (output.length > 0) {
var text = new IBus.Text.from_string (output);
commit_text (text);
}
return retval;
}
public override void enable () {
context.reset ();
// request to use surrounding text feature
get_surrounding_text (null, null, null);
}
public override void disable () {
}
public override void reset () {
context.reset ();
}
public override void focus_in () {
register_properties (prop_list);
context.reset ();
}
public override void focus_out () {
}
public override void property_activate (string prop_name,
uint prop_state)
{
if (prop_name == "setup") {
try {
Process.spawn_command_line_async (
Path.build_filename (Config.LIBEXECDIR,
"ibus-setup-skk"));
} catch (GLib.SpawnError e) {
stderr.printf ("can't spawn ibus-setup-skk: %s\n", e.message);
}
}
else if (prop_name.has_prefix ("InputMode.") &&
prop_state == IBus.PropState.CHECKED) {
context.input_mode = name_input_modes.get (prop_name);
}
}
static bool ibus;
const OptionEntry[] options = {
{"ibus", 'i', 0, OptionArg.NONE, ref ibus,
N_("Component is executed by IBus"), null },
{ null }
};
public static int main (string[] args) {
IBus.init ();
Skk.init ();
Intl.setlocale (LocaleCategory.ALL, "");
Intl.bindtextdomain (Config.GETTEXT_PACKAGE, Config.LOCALEDIR);
Intl.bind_textdomain_codeset (Config.GETTEXT_PACKAGE, "UTF-8");
var context = new OptionContext ("- ibus skk");
context.add_main_entries (options, "ibus-skk");
try {
context.parse (ref args);
} catch (OptionError e) {
stderr.printf ("%s\n", e.message);
return 1;
}
var bus = new IBus.Bus ();
if (!bus.is_connected ()) {
stderr.printf ("Can not connect to ibus-daemon!\n");
return 1;
}
bus.disconnected.connect (() => { IBus.quit (); });
var config = bus.get_config ();
SkkEngine.preferences = new Preferences (config);
SkkEngine.dictionaries = new ArrayList<Skk.Dict> ();
SkkEngine.reload_dictionaries ();
SkkEngine.preferences.value_changed.connect ((name, value) => {
if (name == "dictionaries") {
SkkEngine.reload_dictionaries ();
}
});
var factory = new IBus.Factory (bus.get_connection());
factory.add_engine ("skk", typeof(SkkEngine));
if (ibus) {
bus.request_name ("org.freedesktop.IBus.SKK", 0);
} else {
var component = new IBus.Component (
"org.freedesktop.IBus.SKK",
N_("SKK"), Config.PACKAGE_VERSION, "GPL",
"Daiki Ueno <ueno@unixuser.org>",
"http://code.google.com/p/ibus/",
"",
"ibus-skk");
var engine = new IBus.EngineDesc (
"skk",
"SKK",
"SKK Input Method",
"ja",
"GPL",
"Daiki Ueno <ueno@unixuser.org>",
"%s/icons/ibus-skk.svg".printf (Config.PACKAGE_DATADIR),
"us");
component.add_engine (engine);
bus.register_component (component);
}
IBus.main ();
return 0;
}
}