-
Notifications
You must be signed in to change notification settings - Fork 0
/
tetris.asm
2621 lines (2564 loc) · 45.8 KB
/
tetris.asm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
; 1996 RoVadSoft - Tetris
; 2020 Адаптировано для кроссассемблера тем же автором, но под ником VadRov
; Copyright (C) 2020, VadRov, all right reserved.
; https://www.youtube.com/@VadRov
; https://dzen.ru/vadrov
; https://vk.com/vadrov
; https://t.me/vadrov_channel
; Мини-Тетрис для ZX-Spectrum
device zxspectrum48
PRINT_INV_MSK equ %11111110 ;битовая маска режима инверсии
PRINT_OVR_MSK equ %11111101 ;битовая маска режима наложения
PRINT_UTD_MSK equ %11111011 ;битовая маска режима печати
PRINT_BFNT_MSK equ %11110111 ;битовая маска толщины шрифта
PRINT_VERT_MSK equ %11101111 ;битовая маска типа строки
PRINT_UDG_MSK equ %11011111 ;битовая маска режима UDG (символы пользователя)
PRINT_INK_MSK equ %11111000 ;битовая маска чернил
PRINT_PAP_MSK equ %11000111 ;битовая маска бумаги
PRINT_BRT_MSK equ %10111111 ;битовая маска яркости
PRINT_FLH_MSK equ %01111111 ;битовая маска мигания
org 50000
tetris
di
ld sp,49999
;вход начальная инициализация
ld hl,0 ;инициализация счетчика максимальных очков
ld (hiscore),hl
ld (in_time),hl ;инициализация времени лучшей игры
;байт конфигурации:
;бит 7 - звуковые эффекты 1 - вкл./0 - выкл.
;бит 6 - цвет фигур: 1 - разноцветные/0 - одноцветные
;бит 5 - режим "одной фигуры" 1 - вкл./0 - выкл.,
;бит 4 - контур фигуры на дне стакана 1 - вкл./0 - выкл.
;бит 3 - текстура на блоках 1 - вкл./0 - выкл. (при 0 недоступен контур)
;биты 2,1,0 - определяют номер фигуры из блока figures для режима "одной фигуры"
ld a,%11011000
ld (config),a
bit 3,a
ld a,17
jr z,tetris1
xor a
tetris1
ld (block_output_texture+1),a
ei
ld a,56
ld (color_attr),a
call select_keys
; call 49152
;вход новая игра
newgame
call inter_init ;инициализация режима прерывания 2 обеспечивающего:
;- звуковые эффекты,
;- опрос управляющих клавиш,
;- таймер (секундомер)
ld hl,0
ld (score),hl ;инициализация счетчика очков для новой игры
ld (lines),hl ;инициализация заполненных линий
ld a,0 ;инициализация текущих атрибутов экрана
ld (color_attr),a
ld (stakan_vodka_color),a ;желательно, чтобы цвет "бумаги" и "чернил" совпадали
rra ;бордюр в цвет фона экрана
rra
rra
and 7
out (#fe),a
call clrscr ;очистка экрана
call stakan ;отрисовка стакана
ld hl,interface_string ;надписи на экране
call print
call prn_best_result ;печать лучшего результата в игре
call figure_list ;вывод списка фигур
ld hl,statistics_fig ;инициализация статистики появления фигур
ld (hl),0
ld de,statistics_fig+1
ld bc,14-1
ldir
ld de,fig ;распаковка текущей псевдослучайной фигуры в буфер
call copyfig
call rotation_fig_rnd ;поворот фигруы на псевдослучайное число оборотов
ld a,c ;атрибуты текущей фигуры
ld (attr),a
xor a
ld (tick),a ;инициализация таймера
ld (sec),a
ld (min),a
ld (contour_shift),a ;инициализация смещения для контура фигуры внизу стакана
inc a
ld (level),a ;инициализация уровня игры
call time1 ;вывод текущего времени игры (00:00)
;новая фигура
newfig
ld hl,0
ld (contour_pos),hl ;инициализация положения контура фигуры на дне стакана
call figure_statictics ;вывод статистики по фигурам
ld iy,stakan_vodka_color
call lines_clear ;проверка и удаление заполненных рядов в стакане
;(на выходе в a' количество заполненных линий)
call scoreupdate ;обновление очков игры
call prnscore ;вывод очков игры
call levupd ;расчет уровня (скорости игры)
ld de,next_fig ;распаковка следующей псевдослучайной фигуры в буфер
call copyfig
call rotation_fig_rnd ;поворот следующей фигуры на rnd оборотов
ld a,c ;атрибуты следующей фигуры
ld (next_attr),a
ld hl,#5800+2*32+25 ;вывод на экран следующей фигуры
ld de,next_fig
call block_output_var
ld a,(attr)
ld b,a ;в b - атрибуты текущей фигуры
ld hl,#5800+0*32+15 ;адрес начальной позиция текущей фигуры в области атрибутов
push hl
exx
pop hl
exx
xor a
call saveloadfig ;делаем копию фигуры во вспомогательном буфере
newfig0
call block_check ;проверка: можно ли выводить фигуру в новых координатах?
or a
jp z,newfig1
ld de,#5800+0*32+15 ;конец игры, если вывод фигуры невозможен в начальной позиции
ex de,hl
and a
sbc hl,de
ex de,hl
jr nz,newfig0_
ld hl,(hiscore) ;обновление максимального счета игры, если текущий счет был больше
ld de,(score)
and a
sbc hl,de
jr nc,gameover
ld (hiscore),de
ld hl,in_time
ld bc,(sec)
ld (hl),c ;секунды
inc hl
ld (hl),b ;минуты
gameover
call inter_deinit ;включение стандартных прерываний спектрума
call screen_off
jp newgame
newfig0_ ;блок на дне
push hl
ld hl,sndfx1 ;звук фигуры, упавшей на дно
ld a,1
call newfx
pop hl
exx
ld c,0
exx
ld a,(config)
bit 4,a
call nz,print_contour ;стираем контур
ld c,b
call block_output ;обновляем блок
;стирание следующей фигуры
ld hl,#5800+2*32+25
ld de,next_fig
ld c,(iy)
call block_output_var
;следующую фигуру делаем текущей
ld a,(next_attr)
ld (attr),a
ld hl,next_fig
ld de,fig
ld bc,4
ldir
jp newfig
newfig1
xor a
ld (flag_update),a
ld a,(level)
ld c,a
ld a,15
sub c
;цикл задержки, в процессе которого опрашивается клавиатура
;и задается положение фигуры в соответствии с управляющим воздействием
newfig2
push af
ld a,(config)
bit 4,a
call nz,check_contour
halt
call block_update
ld a,(inkey)
inc a
jr nz,newfig3
newfig2_1
pop af
dec a
jr nz,newfig2
exx
ld de,32
add hl,de
exx
jp newfig0
newfig3
ld a,(slip_inkey) ;проверяем на "залипщие" клавищи
or a
jr z,newfig3_1 ;"залипаний" нет
ld a,(inkey)
bit 0,a ;запрещаем "залипать" клавише управления вращением фигуры
jr z,newfig2_1
bit 2,a ;запрещаем "залипать" клавише управления паузой в игре
jr z,newfig2_1
bit 4,a ;запрещаем "залипать" клавише управления ускоренным падением фигуры
jr z,newfig2_1
ld a,(slip_count) ;остальным клавишам управления разрешаем "залипать",
cp 4 ;но с заданным периодом повтора нажатия
jr c,newfig2_1
xor a ;сбрасываем счетчик "залипания"
ld (slip_count),a
newfig3_1
ld a,(inkey)
rrca
call nc,rotate
rrca
call nc,right
rrca
call nc,pause
rrca
call nc,left
rrca
call nc,drop
newfig4
pop af
jp newfig2
;плавное "выключение" экрана
screen_off
ld e,4
ld c,7
screen_off1
ld hl,#5800
ld b,6
screen_off1_1
halt
djnz screen_off1_1
ld b,3
screen_off2
ld a,(hl)
and c
ld (hl),a
inc l
jr nz,screen_off2
inc h
djnz screen_off2
srl c
dec e
jr nz,screen_off1
ret
;обновление фигуры на экране
block_update
ld a,(flag_update) ;проверяем флаг обновления
or a
ret nz
inc a
ld (flag_update),a
call figure_reset ;стираем фигуру
exx
push hl
exx
pop hl
ld a,1 ;копируем фигуру в основной буфер из вспомогательного
call saveloadfig
call figure_set ;выводим фигуру
ret
;вращение
rotate
push af
ld de,tmp_fig
call rotfig ;вращаем фигуру
call block_check ;проверяем возможность вывода
or a
jr nz,rotate1 ;вывод невозможен
rotate0 ;вращение успешно
push hl ;выдаем звуковой эффект и обновляем фигуру на экране дальше по коду
ld hl,sndfx3
ld a,1
call newfx
pop hl
xor a
ld (flag_update),a
rotate0_1
pop af
ret
rotate1
xor a ;при невозможности вывода фигуры после вращения
call saveloadfig ;восстанавливаем фигуру во временном буфере из буфера текущей фигуры
jr rotate0_1
;движение фигуры вправо
right
push af
exx
inc hl
exx
call block_check ;проверяем возможность вывода
or a
jr z,right2
exx
dec hl
exx
right1
pop af
ret
right2
xor a
ld (flag_update),a
jr z,right1
;движение фигуры влево
left
push af
exx
dec hl
exx
call block_check ;проверяем возможность вывода
or a
jr z,right2
exx
inc hl
exx
jr right1
;ускоренное движение фигуры вниз
drop
push af
push hl
ld hl,sndfx2
ld a,1
call newfx
pop hl
xor a
ld (drop_flag),a
drop1
exx
ld de,32
add hl,de
exx
call block_check ;проверяем возможность вывода
or a
jr nz,drop3
ld a,(drop_flag)
or a
jr nz,drop2
inc a
ld (drop_flag),a
drop2
xor a
ld (flag_update),a
halt
call block_update
jr drop1
drop3
exx
ld de,-32
add hl,de
exx
pop af
ret
;пауза в игре
pause
di
push af
push bc
ld bc,0
pause1
dec bc
ld a,b
or c
jr nz,pause1
pause2 ;ожидание нажатия любой клавиши
xor a ;старщий байт адреса сброшен в 0 (выбраны все полуряды)
in a,(#fe)
cpl
and 31
jr z,pause2
pop bc
pop af
ei
ret
;выводит фигуру и контур
figure_set
;вывод контура фигуры внизу стакана
exx
ld c,1
exx
ld a,(config)
bit 4,a
call nz,print_contour
;вывод фигуры
ld c,b
call block_output
ret
;стирает фигуру и контур
figure_reset
;стирание контура фигуры
exx
ld c,0
exx
ld a,(config)
bit 4,a
call nz,print_contour
;стирание фигуры
ld c,(iy)
call block_output
ret
;пересчет заполненных линий
;пересчет очков в зависимости от количества заполненных линий
;количество новых линий в a'
scoreupdate
ex af,af'
ld e,a
ex af,af'
inc e
dec e
ret z
ld d,0
ld hl,(lines)
add hl,de
ld (lines),hl
ld b,e ;начисление очков за заполнение линий по алгоритму:
ld de,10 ;1 линия - 10 очков
ld hl,(score) ;2 линии - 25 очков
newfig_add_score ;3 линии - 45 очков
add hl,de ;4 линии - 70 очков
push hl
ld hl,5
add hl,de
ex de,hl
pop hl
djnz newfig_add_score
ld (score),hl
ret
;выводит картинки фигур для статистики
figure_list
xor a
ld b,7
ld hl,#5800+1*32+2
figure_list1
push af
push bc
push hl
ld de,fig
call copyfig1
pop hl
call block_output
pop bc
pop af
inc a
ld de,96
add hl,de
djnz figure_list1
ret
;выводит статистику по фигурам
figure_statictics
ld hl,statistics_fig
ld d,7
ld ix,stat_at
ld iy,0
figure_statictics1
ld a,7
sub d
ld e,a
add a,a
add a,e
add a,3
ld (ix+1),a
push de
push hl
ld hl,stat_at
call print
pop hl
pop de
ld c,(hl)
inc hl
ld b,(hl)
inc hl
add iy,bc
ld a,5
call print_dec
dec d
jr nz,figure_statictics1
ld hl,stat_alls
call print
push iy
pop bc
ld a,5
call print_dec
ret
;опрос управляющих клавиш клавиатуры
;в d состояние клавиш управления(бит сброшен - клавиша нажата)
;0 бит - вращение
;1 бит - вправо
;2 бит - пауза
;3 бит - влево
;4 бит - падение
keys
ld d,255
ld hl,key_drop
call inputkey
rl d
ld hl,key_left
call inputkey
rl d
ld hl,key_pause
call inputkey
rl d
ld hl,key_right
call inputkey
rl d
ld hl,key_rotate
call inputkey
rl d
ld hl,slip_count
ld a,(inkey) ;проверка на залипшие клавиши
cp d
ld a,d
jr z,keys1
ld (inkey),a
xor a
ld (slip_inkey),a ;инициализируем флаг
ld (hl),a ;и счетчик залипания
ret
keys1
ld a,1
ld (slip_inkey),a
inc (hl) ;увеличиваем счетчик залипания
ret
; рассчитывает уровень игры в зависимости от количества заполненных линий
; уровень увеличивается через каждые 10 заполненных линий
levupd
ld hl,lines_at
call print
ld bc,(lines)
push bc
ld a,5
call print_dec
pop hl
ld de,10
xor a
levupd1
inc a
or a
sbc hl,de
jr nc,levupd1
ld (level),a
push af
ld hl,level_at
call print
pop af
ld b,0
ld c,a
ld a,5
call print_dec
ret
;генерирует псевдослучайную фигуру и распаковывает ее в буфер по адресу в de
;на выходе в C атрибут фигуры (согласно настройки бита 6 конфигурации)
;работает с байтом конфигурации по адресу config:
;бит 6 - цвет фигур: 1 - разноцветные/0 - одноцветные,
;бит 5 - режим "одной фигуры" 1 - вкл./0 - выкл.,
;биты 2,1,0 - определяют номер фигуры из блока figures для режима "одной фигуры"
copyfig
ld ix,config ;адрес байта конфигурации
ld a,(ix) ;в режиме одной фигуры номер фигуры биты 2,1,0
ld c,7
bit 5,a ;проверка режима работы случайная/постоянная фигура
jr z,copyfig0
and c ;защита от дурака (номер фигуры только от 0 до 6)
cp c
jr nz,copyfig1
xor a
jr copyfig1
copyfig0
ld a,r ;в а состояние регистра регенерации r
and c
cp c
jr z,copyfig0
copyfig1
ld hl,statistics_fig
push af
push de
add a,a
ld d,0
ld e,a
add hl,de
ld e,(hl)
inc hl
ld d,(hl)
inc de
ld (hl),d
dec hl
ld (hl),e
pop de
pop af
ld hl,figures
ld b,0
ld c,a
add hl,bc
;разноцветной/одноцветный режим
cpl ;инвертируем биты
rlca
rlca
rlca
and 8+16+32
ld c,a
ld a,(stakan_vodka_color)
ld b,a
and 8+16+32
cp c
jr nz,copyfig2
cpl
and 8+16+32
ld c,a
copyfig2
ld a,b
rra
rra
rra
and 7
or c
ld c,a
push de
xor a
ld (de),a
inc de
ld b,3
copyfig3
rld ;Старшая тетрада (биты 7... 4) ячейки памяти hl переносится
;в младшую тетраду аккумулятора (биты 3...0),
;младшая тетрада аккумулятора переносится в младшую тетраду ячейки памяти,
;а младшая тетрада ячейки памяти — в старшую тетраду ячейки памяти
ld (de),a
inc de
djnz copyfig3
pop de
ret
;ротация фигуры на псевдослучайное число оборотов
;адрес фигуры по адресу в de
rotation_fig_rnd
ld a,r
rra
rra
rra
and 7
ret z
ld b,a
rotation_fig_rnd1
call rotfig
djnz rotation_fig_rnd1
ret
;стакан
stakan
ld ix,stakan_data1
ld c,0
ld b,24
stakan1
ld (ix+1),c
push bc
push ix
pop hl
call print
pop bc
inc c
djnz stakan1
ld hl,vadsoft_txt
jp print
;вывод текущих очков игры
prnscore
ld hl,score_at
call print
ld bc,(score)
ld a,5
jp print_dec
;вывод лучшего результата и времени, за которое он был достигнут
prn_best_result
ld hl,hiscore_at
call print
ld bc,(hiscore)
ld a,5
call print_dec
ld hl,intime_at
call print
ld hl,(in_time)
ld b,0
ld c,h
ld a,128+2
call print_dec
ld a,":"
call printsym
ld c,l
ld a,128+2
jp print_dec
lines_light
call lines_check ;определяем количество заполненных строк и их адреса
ex af,af'
ld b,a
ex af,af'
inc b
dec b
ret z ;если заполненных строк нет, то уходим
xor a
ld (mig),a
ld a,6
lines_light_mig
push af
exx
ld c,a
exx
ld c,5
lines_light0
push bc
ld ix,lines_table
lines_light1
ld l,(ix)
inc ix
ld h,(ix)
inc ix
ld e,c
dec e
ld d,0
push hl
add hl,de
pop de
push hl
ld a,10
sub c
ld h,0
ld l,a
add hl,de
ex de,hl
pop hl
exx
ld a,c
exx
cp 1
push bc
jr nz,lines_light2
ld a,(stakan_vodka_color)
ld c,a
jr lines_light3
lines_light2
ld c,%00010000
ld a,(mig)
or c
ld c,a
lines_light3
ld (hl),c
ld (de),a
pop bc
djnz lines_light1
halt
pop bc
dec c
jr nz,lines_light0
ld a,(mig)
xor 64
ld (mig),a
pop af
dec a
jr nz,lines_light_mig
ret
;ищет заполненные линии стакана и записывает их адреса в table_str
;на выходе в a' количество заполненных линий
lines_check
ld b,23
ld hl,#5800+23*32+12
ex af,af'
xor a
ex af,af'
exx
ld a,(stakan_vodka_color)
and %00111000
ld b,a
exx
ld ix,lines_table
lines_check1
push hl
push bc
ld b,10
call cpir_paper
pop bc
pop hl
jr z,lines_check2
ex af,af'
inc a
ex af,af'
ld (ix),l
inc ix
ld (ix),h
inc ix
lines_check2
ld de,-32
add hl,de
djnz lines_check1
ret
;убирает заполненные линии стакана
lines_clear
call lines_light
ex af,af'
ld b,a
ex af,af'
inc b
dec b
ret z ;если заполненных строк нет, то уходим
ld a,b
ld hl,sndfx4 ;звук - удаление рядов
call newfx
ld ix,lines_table
ld de,0
lines_clear1
push bc
push de
ld l,(ix) ;в hl адрес заполненной строки
inc ix
ld h,(ix)
inc ix
add hl,de
ld a,h ;по адресу определяем номер строки
ld b,l ;номер и будет означать сколько раз сдвигать пробегать по строкам для сдвига
rl b
rla
rl b
rla
rl b
rla
and 31
ld b,a
jr z,lines_clear4
lines_clear2
push bc
push hl
ld de,-32
add hl,de
pop de
push hl
push de
push hl
ld a,h
add a,a
add a,a
add a,a
and #7f
ld h,a
ld a,d
add a,a
add a,a
add a,a
and #7f
ld d,a
ld b,8
lines_clear3
push bc
push de
push hl
ld bc,10
ldir
pop hl
pop de
pop bc
inc h
inc d
djnz lines_clear3
pop hl
pop de
ld bc,10
ldir
pop hl
pop bc
djnz lines_clear2
pop hl
pop bc
ld de,32
add hl,de
ex de,hl
djnz lines_clear1
ret
lines_clear4
pop bc
ret
;поиск (до первого совпадения) в строке знакоместа с атрибутом в b', где учитывается только цвет "бумаги"
;если поиск успешен, то на выходе установлен флаг нуля Z, при этом в b обратный порядковый номер
;если арибут не найден, то флаг нуля на выходе сброшен
cpir_paper
ld a,(hl)
and %00111000
exx
cp b
exx
ret z
inc hl
dec b
jr nz,cpir_paper
ld c,2 ;сброс флага нуля
dec c
ret
;запоминает/восстанавливает в буфер/из буфера текущую фигуру
;a = 0 - запонимает, а отличное от 0 - восстанавливает
saveloadfig
push bc
push de
push hl
ld hl,fig
ld de,tmp_fig
or a
jr z,saveloadfig1
ex de,hl
saveloadfig1
ld bc,4
ldir
pop hl
pop de
pop bc
ret
;вращение фигуры (адрес фигуры в de)
rotfig
push bc
push de
push hl
ex de,hl
push hl
ld c,(hl)
inc hl
ld b,(hl)
inc hl
ld e,(hl)
inc hl
ld d,(hl)
pop hl
ld lx,4
rotfig1
xor a
rr c
rla
rr b
rla
rr e
rla
rr d
rla
ld (hl),a
inc hl
dec lx
jr nz, rotfig1
pop hl
pop de
pop bc
ret
;проверка возможности вывода фигуры с адреса в hl'
;hl - текущая позиция (адрес) фигуры в области атрибутов
;hl' - предполагаемая позиция (адрес) фигуры в области атрибутов
;на выходе а = 0, если Ок, иначе а = 1
block_check
ld de,fig ;текущая фигура
ld a,(stakan_vodka_color)
and %00111000
exx
ld de,tmp_fig ;предполагаемая фигура
push bc
push hl
inc hl
inc hl
inc hl
ld b,4
ld c,a
block_check1
ld a,(de)
push bc
ld b,4
block_check2
rra
jr nc,block_check3
;проверка на выход фигуры за пределы стакана
ex af,af'
ld a,l
and 31
cp 12
jr c,block_check2_1
cp 22
jr nc,block_check2_1
ld a,h