wl18xx: add BT/WiFi firmware as per latest TI releases

BT firmware has been updated to v4.7
WiFi firmware has been updated to v8.9.0.0.88

Signed-off-by: Pierluigi Passaro <pierluigi.p@variscite.com>

recipes-connectivity/wlconf/wlconf_8.8.0.bb

@@ -0,0 +1,39 @@
+DESCRIPTION = "Configuration utility for TI wireless drivers"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://README;beginline=1;endline=21;md5=adc05a1903d3f107f85c90328e3a9438"
+
+# Tag: R8.8 (8.8)
+SRCREV = "b23772347318e5e3f724e9686f271efc01512708"
+SRC_URI = "git://git.ti.com/cgit/wilink8-wlan/18xx-ti-utils;protocol=https;branch=master"
+
+S = "${WORKDIR}/git/wlconf"
+
+EXTRA_OEMAKE = "CC="${CC}""
+
+do_install() {
+	install -d ${D}${sbindir}
+	install -d ${D}${sbindir}/wlconf/
+	install -d ${D}${sbindir}/wlconf/official_inis
+	install -d ${D}/lib/firmware/ti-connectivity
+
+	install -m 0755 wlconf ${D}${sbindir}/wlconf/
+	install -m 0755 dictionary.txt ${D}${sbindir}/wlconf/
+	install -m 0755 struct.bin ${D}${sbindir}/wlconf/
+	install -m 0755 default.conf ${D}${sbindir}/wlconf/
+	install -m 0755 wl18xx-conf-default.bin ${D}${sbindir}/wlconf/
+	install -m 0755 wl18xx-conf-default.bin ${D}/lib/firmware/ti-connectivity/wl18xx-conf.bin
+	install -m 0755 README ${D}${sbindir}/wlconf/
+	install -m 0755 example.conf ${D}${sbindir}/wlconf/
+	install -m 0755 example.ini ${D}${sbindir}/wlconf/
+	install -m 0755 configure-device.sh ${D}${sbindir}/wlconf/
+	install -m 0755 ${S}/official_inis/* \
+			${D}${sbindir}/wlconf/official_inis/
+}
+
+FILES:${PN} += " \
+	${sbindir}/wlconf \
+	${sbindir}/wlconf/official_inis \
+	/lib/firmware/ti-connectivity/wl18xx-conf.bin \
+"
+
+FILES:${PN}-dbg += "${sbindir}/wlconf/.debug"

recipes-kernel/linux-firmware/linux-firmware_%.bbappend

@@ -0,0 +1,22 @@
+# Support additional firmware for wl18xx WIFI+BT modules
+
+FILESEXTRAPATHS:prepend := "${THISDIR}/files:"
+
+SRCREV_FORMAT = "linux-firmware"
+
+# TI WiFi FW 8.9.0.0.88 and BT FW 4.7
+SRCREV_tiwlan = "d5c271f60bb2d90b7c2b03ce792d01af2f0a8e44"
+BRANCH_tiwlan = "master"
+SRCREV_tibt = "3aa1d75f3c2ae77f6e4d36194e3d281b899ab149"
+BRANCH_tibt = "master"
+
+SRC_URI:append = " \
+	git://git.ti.com/cgit/wilink8-wlan/wl18xx_fw;protocol=https;branch=${BRANCH_tiwlan};destsuffix=tiwlan;name=tiwlan \
+	git://git.ti.com/cgit/ti-bt/service-packs;protocol=https;branch=${BRANCH_tibt};destsuffix=tibt;name=tibt \
+	file://wl1271-nvs.bin \
+"
+do_install:append() {
+	install -m 0755 ${WORKDIR}/tibt/initscripts/TIInit_*.bts ${D}${nonarch_base_libdir}/firmware/ti-connectivity
+	install -m 0755 ${WORKDIR}/tiwlan/*.bin ${D}${nonarch_base_libdir}/firmware/ti-connectivity
+	install -m 0755 ${WORKDIR}/wl1271-nvs.bin ${D}${nonarch_base_libdir}/firmware/ti-connectivity
+}