What's wrong with this example

[LukyGuyLucky]

From github
Could anybody figure me out what's wrong with this example?I failed to compile.

Thanks in advance.

Error message:

ex06.v:14:5: error: unexpected name `content_lines`, expecting `{`
   12 |     }
   13 |
   14 |     content_lines := read_file(path)
      |     ~~~~~~~~~~~~~
   15 |     print(content_lines)
   16 | }

ex06.v

import os

fn main() {
    path := './data/file.txt'
    text := 'Full text description.'

    if contents := os.write_file(path, text) or {
        println('Failed while creating file')
        return
    }

    content_lines := read_file(path)    // content_lines=read_file(path) changed = to  :=
    print(content_lines)
}

fn read_file(path string) {
    contents := os.read_file(path.trim_space()) or {
        println('Failed to open $path')
        return
    }

    return contents.split_into_lines()
}

[JalonSolov]

The problem is that that example is 4 years old... badly outdated, compared to current V.

The simplest working replacement is:

import os

fn main() {
        path := 'file.txt'
        text := 'Full text description.'

        os.write_file(path, text) or {
                println('Failed while creating file')
                return
        }

        content_lines := os.read_lines(path)!
        println(content_lines)
}

[spytheman]

import os

fn main() {
    path := './data/file.txt'
    text := 'Full text description.'

    os.write_file(path, text) or {
        println('Failed while creating file')
        return
    }

    content_lines := read_file(path)
    print(content_lines)
}

fn read_file(path string) []string {
    contents := os.read_file(path.trim_space()) or {
        println('Failed to open $path')
        return []
    }
    return contents.split_into_lines()
}

In my opinion the linked example never worked, but perhaps was just a draft.
Note, that it had:
a) fn read_file(path string) {, which is lacking a return type declaration.
b) if contents := os.write_file(path, text) or {, while os.write_file always returned just an error, in case of failure (it returning content just plainly does not make sense ... the function is intended to write a file, not read it).

[LukyGuyLucky]

Learnt.Appreciated!!