Merge pull request #615 from bastelfreak/systemd

systemd service: Switch erb to epp template

manifests/config.pp

@@ -36,8 +36,24 @@
   if ($consul::init_style_real != 'unmanaged') {
     case $consul::init_style_real {
       'systemd': {
+        $type = if ($config_hash['retry_join'] == undef or $config_hash['retry_join'].length < 2) {
+          'exec'
+        } else {
+          'notify'
+        }
         systemd::unit_file { 'consul.service':
-          content => template('consul/consul.systemd.erb'),
+          content => epp("${module_name}/consul.systemd.epp",
+            {
+              'user'                        => $consul::user,
+              'group'                       => $consul::group,
+              'bin_dir'                     => $consul::bin_dir,
+              'config_dir'                  => $consul::config_dir,
+              'extra_options'               => $consul::extra_options,
+              'allow_binding_to_root_ports' => $allow_binding_to_root_ports,
+              'enable_beta_ui'              => $enable_beta_ui,
+              'type'                        => $type,
+            }
+          ),
           notify  => $notify_service,
         }
       }

templates/consul.systemd.epp

@@ -0,0 +1,33 @@
+<%- | String[1] $user,
+      String[1] $group,
+      Stdlib::Absolutepath $bin_dir,
+      Stdlib::Absolutepath $config_dir,
+      Optional[String] $extra_options,
+      Boolean $allow_binding_to_root_ports,
+      Boolean $enable_beta_ui,
+      Enum['exec', 'notify'] $type,
+| -%>
+# THIS FILE IS MANAGED BY PUPPET
+[Unit]
+Description=Consul Agent
+After=network-online.target
+Wants=network-online.target
+
+[Service]
+Type=<%=$type %>
+<% if $allow_binding_to_root_ports { -%>
+AmbientCapabilities=CAP_NET_BIND_SERVICE
+<% } -%>
+<% if $enable_beta_ui { -%>
+Environment=CONSUL_UI_BETA=true
+<% } -%>
+User=<%= $user %>
+Group=<%= $group %>
+ExecStart=<%= $bin_dir %>/consul agent \
+  -config-dir <%= $config_dir %> <%= $extra_options %>
+ExecReload=/bin/kill -HUP $MAINPID
+Restart=on-failure
+LimitNOFILE=131072
+
+[Install]
+WantedBy=multi-user.target