-
Notifications
You must be signed in to change notification settings - Fork 6
/
xPrint.m
1687 lines (1556 loc) · 70.6 KB
/
xPrint.m
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
(* ::Package:: *)
(************************************************************************)
(* This file was generated automatically by the Mathematica front end. *)
(* It contains Initialization cells from a Notebook file, which *)
(* typically will have the same name as this file except ending in *)
(* ".nb" instead of ".m". *)
(* *)
(* This file is intended to be loaded into the Mathematica kernel using *)
(* the package loading commands Get or Needs. Doing so is equivalent *)
(* to using the Evaluate Initialization Cells menu command in the front *)
(* end. *)
(* *)
(* DO NOT EDIT THIS FILE. This entire file is regenerated *)
(* automatically each time the parent Notebook file is saved in the *)
(* Mathematica front end. Any changes you make to this file will be *)
(* overwritten. *)
(************************************************************************)
xAct`xPrint`$Version={"1.46",{2015,7,3}};
xAct`xPrint`$xPermVersionExpected={"1.0.3",{2009,9,9}};
(* xPrint: Point-and-Click WYSIWYG tensor input for xAct, *)
(* Copyright (C) 2010 Alessandro Stecchina *)
(* This program is free software; you can redistribute it and/or modify
it under the terms of the GNU General Public License as published
by the Free Software Foundation; either version 2 of the License,
or (at your option) any later version.
This program is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
General Public License for more details.
You should have received a copy of the GNU General Public License
along with this program; if not, write to the Free Software
Foundation, Inc., 59 Temple Place-Suite 330, Boston, MA 02111-1307,
USA.
*)
(* :Title: xPrint *)
(* :Author: Alessandro Stecchina *)
(* :Summary: Point-and-Click WYSIWYG tensor input for xAct *)
(* :Brief Discussion:
State-of-the-art palette interface to the xAct suite of Mathematica packages
Select manifolds, tensors, indices and derivative operators via pull-down menus
Real-time wysiwyg tensor object construction
VBundle-constrained menu-driven index selection
Abstract and b and c indices
On-the-fly syntax checking
One-click pasting of formatted tensor objects into notebooks
*)
(* :Context: xAct`xPrint` *)
(* :Copyright: Alessandro Stecchina (2010-2015) *)
(* :History:
Vers. 1.46
3 July 2015
Fixed variable leak in DefBasis and DefChart
Vers. 1.45
19 May 2015
xPrint is on GitHub
Buttons labels reduced to 9
Vers. 1.4
17 Apr 2015
All sectons have the same width as the maipulation section
Many new buttons in Tensor manipulation section
TabView in Tensor manipulation section
Vers. 1.3
8 Apr 2015
Help menu with access to xPrint tutorials
xPrint is now in a single folder with documentation files
xTerior is loaded automatically with xPrint
Algebraic operations buttons added
Exterior forms section added
Gdelta Menu supprts symbolic dimension
Gdelta bug fixed
Upgraded to xAct 1.1.0 and Mathematica 10.x
Vers. 1.1
19 Aug 2010
Label indices
Basis menu now with bases names and colored dots now made with FilledCircle
Primed and double primed indices using Primed and DoublePrimed options
Vers. 1.01
18 Jul 2010
Reduced overall font size
Manifold menu moved on top
Vers. 1.0
20 Jun 2010
WYSIWYG input of derivatives
Solved SlotOftensor problem
Target nb and Lock
Tensor manipulation section started
"About xPrint" help menu item
Splashscreen
Vers. 0.997
Predefined tensor slots are enforced when a metric is not present
Applied dividers to the main sections
Vers. 0.996
Help menu added, linking to xAct documentation
Definition section added using enhanced template technology
Global Environment section added
Vers. 0.995
No-manifold-red-box problem fixed
PasteButton appearance changed to Button
Added:Basis in the Tensor menu
Better handling of indices of Basis and delta
Patch to interpretbox of xTensor to fix the blue-index problem.
Vers. 0.99
b and c index support
parameter menu
OpenerViews
General Settings section
Bases and Charts section
Vers. 0.62
Main menus have been tooltipped
Vers. 0.60
First public release 17 Mar 2010
Derivatives menu
Vers. 0.50
Jan 2010
Jan 29 xPrint name proposed
Manifold and Tensor menus
Created out of interstellar dust
*)
(* :Keywords: *)
(* :Source: xPrint.nb *)
(* :Warning: *)
(* :Mathematica Version: 7.0 and later *)
(* :Limitations: can't prepare Tiramisu...yet *)
If[Unevaluated[xAct`xCore`Private`$LastPackage]===xAct`xCore`Private`$LastPackage,xAct`xCore`Private`$LastPackage="xAct`xPrint`"];
BeginPackage["xAct`xPrint`",{"xAct`xCore`","xAct`xPerm`","xAct`xTensor`","xAct`xCoba`","xAct`xTerior`"}]
If[Not@OrderedQ@Map[Last,{$xPermVersionExpected,xAct`xPerm`$Version}],Throw@Message[General::versions,"xPerm",xAct`xPerm`$Version,$xPermVersionExpected]]
Print[xAct`xCore`Private`bars];
Print["Package xAct`xPrint` version ",$Version[[1]],", ",$Version[[2]]];
Print["Copyright (C) 2010-2015, Alessandro Stecchina, under the General Public License."]
Off[General::shdw]
xAct`xPrint`Disclaimer[]:=Print["These are points 11 and 12 of the General Public License:\n\nBECAUSE THE PROGRAM IS LICENSED FREE OF CHARGE, THERE IS NO WARRANTY FOR THE PROGRAM, TO THE EXTENT PERMITTED BY APPLICABLE LAW. EXCEPT WHEN OTHERWISE STATED IN WRITING THE COPYRIGHT HOLDERS AND/OR OTHER PARTIES PROVIDE THE PROGRAM `AS IS\.b4 WITHOUT WARRANTY OF ANY KIND, EITHER EXPRESSED OR IMPLIED, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE. THE ENTIRE RISK AS TO THE QUALITY AND PERFORMANCE OF THE PROGRAM IS WITH YOU. SHOULD THE PROGRAM PROVE DEFECTIVE, YOU ASSUME THE COST OF ALL NECESSARY SERVICING, REPAIR OR CORRECTION.\n\nIN NO EVENT UNLESS REQUIRED BY APPLICABLE LAW OR AGREED TO IN WRITING WILL ANY COPYRIGHT HOLDER, OR ANY OTHER PARTY WHO MAY MODIFY AND/OR REDISTRIBUTE THE PROGRAM AS PERMITTED ABOVE, BE LIABLE TO YOU FOR DAMAGES, INCLUDING ANY GENERAL, SPECIAL, INCIDENTAL OR CONSEQUENTIAL DAMAGES ARISING OUT OF THE USE OR INABILITY TO USE THE PROGRAM (INCLUDING BUT NOT LIMITED TO LOSS OF DATA OR DATA BEING RENDERED INACCURATE OR LOSSES SUSTAINED BY YOU OR THIRD PARTIES OR A FAILURE OF THE PROGRAM TO OPERATE WITH ANY OTHER PROGRAMS), EVEN IF SUCH HOLDER OR OTHER PARTY HAS BEEN ADVISED OF THE POSSIBILITY OF SUCH DAMAGES."]
On[General::shdw]
If[xAct`xCore`Private`$LastPackage==="xAct`xPrint`",
Unset[xAct`xCore`Private`$LastPackage];
Print[xAct`xCore`Private`bars];
Print["These packages come with ABSOLUTELY NO WARRANTY; for details type Disclaimer[]. This is free software, and you are welcome to redistribute it under certain conditions. See the General Public License for details."];
Print[xAct`xCore`Private`bars]]
(* xPrintPalette::usage = "xPrintPalette creates a session palette for pasting tensor input."; *)
xPrintValidQ::usage = "xPrintValidQ[expr] returns True if expr is syntactically correct and False otherwise.";
(*
DefPrimedBasis::usage = "DefPrimedBasis[basis,vbundle,{c1,...,cn}] defines a basis with primed indices. It passes all its arguments to DefBasis";
DefDoublePrimedBasis::usage = "DefDoublePrimedBasis[basis,vbundle,{c1,...,cn}] defines a basis with double-primed indices. It passes all its arguments to DefBasis";
DefPrimedChart::usage = "DefPrimedChart[basis,vbundle,{c1,...,cn}] defines a chart with primed indices. It passes all its arguments to DefChart";
DefDoublePrimedChart::usage = "DefDoublePrimedChart[basis,vbundle,{c1,...,cn}] defines a chart with double-primed indices. It passes all its arguments to DefChart";
*)
(*
xPrintpaste::usage = "paste the palette";
xPrintPalette::usage = "palette object";
*)
xAct`xCoba`Primed::usage="Primed is an option of DefBasis and DefChart. If True, basis or chart indices are printed with a prime. Default is False";
xAct`xCoba`DoublePrimed::usage="DoublePrimed is an option of DefBasis and DefChart. If True, basis or chart indices are printed with a double-prime. Default is False";
Unprotect[Basis];
SlotsOfTensor[Basis]^:={-All,All};
Protect[Basis];
Begin["`Private`"]
Unprotect[DefBasis];
(*added Primed and DoublePrimed*)
Options[DefBasis]={
BasisColor->RGBColor[1,0,0],
FormatBasis->Automatic,
ProtectNewSymbol:>$ProtectNewSymbols,
Dagger->Real,
ExtendedFrom->Null,
MetricInBasis->{},
BasisChange->Null,
epsilonOrientationOfMetric->{Null,1},
DependenciesOfBasis->{},
DefInfo->{"basis",""},
Master->Null,
Primed->False,
DoublePrimed->False
};
(*
DefBasis[basisname_,vbundle_Symbol,cnumbers_,options___]:=
(*added pr and dpr to local variables and to the list of options, together with Primed and DoublePrimed*)
Module[{bc,pns,dag,ef,mb,mb3,dim,tanb,covdef,info,master,pr,dpr,manifold=BaseOfVBundle[vbundle],tbundle},
{bc,pns,dag,ef,mb,deps,info,master,pr,dpr}={BasisColor,ProtectNewSymbol,Dagger,ExtendedFrom,MetricInBasis,DependenciesOfBasis,DefInfo,Master,Primed,DoublePrimed}/.CheckOptions[options]/.Options[DefBasis];
*)
DefBasis[basisname_,vbundle_,cnumbers_,options:OptionsPattern[]]:=
(*added pr and dpr to local variables and to the list of options, together with Primed and DoublePrimed*)Module[{bc,fb,pns,dag,ef,mb,change,eoom,deps,mb3,dim,tanb,covdef,info,master,pr,dpr,manifold=BaseOfVBundle[vbundle],tbundle},
{bc,fb,pns,dag,ef,mb,change,eoom,deps,info,master,pr,dpr}=OptionValue[{BasisColor,FormatBasis,ProtectNewSymbol,Dagger,ExtendedFrom,MetricInBasis,BasisChange,epsilonOrientationOfMetric,DependenciesOfBasis,DefInfo,Master,Primed,DoublePrimed}];
(**** Checks ****)
(* Check names *)
If[!VBundleQ[vbundle],Throw@Message[DefBasis::unknown,"vbundle",vbundle]];
dim=DimOfVBundle[vbundle];
If[ChartQ[basisname],
If[BasisQ[basisname],
(* The basis already exists. This is a duplicated name *)
Throw@Message[ValidateSymbol::used,basisname,"as a basis"],
(* Coordinate basis being defined. Symbol validation already performed. Do nothing *)
Null
],
(* Noncoordinate basis. Perform symbol validation *)
ValidateSymbol[basisname];
ValidateSymbolInSession[basisname]
];
(* Check cnumbers: heads, length and integer type. Repeated cnumbers are not allowed *)
If[Or[
Head[cnumbers]=!=List,
Union[cnumbers]=!=Sort[cnumbers],
Not[And@@(IntegerQ/@cnumbers)],
Length[cnumbers]=!=dim],
Throw@Message[DefBasis::invalid,cnumbers,"list of cnumbers"]];
(* Check complex option *)
If[FreeQ[{Real,Complex,Conjugate},dag],Throw@Message[DefBasis::invalid,dag,"value for option Dagger"]];
If[DaggerQ[vbundle]&&dag===Real,Throw@Message[DefBasis::error,"Cannot define a real basis on a complex manifold."]];
(* Check dependencies *)
If[Not@Or[ManifoldQ[#],ParameterQ[#]],Throw@Message[DefBasis::invalid,#,"dependency"]]&/@deps;
If[FreeQ[deps,manifold],deps=Prepend[deps,manifold]];
(* Check extension from other basis *)
covdef=If[ef=!=Null,
If[!BasisQ[ef],Throw@Message[DefBasis::unknown,"basis",ef]];
tanb=VBundleOfBasis[ef];
If[TangentBundleOfManifold@BaseOfVBundle@tanb=!=tanb,Throw@Message[DefBasis::invalid,ef,"basis to extend"]];
If[BaseOfVBundle@tanb=!=manifold,Throw@Message[DefBasis::invalid,ef,"basis to extend"]];
PDOfBasis[ef],
Null];
(* Check mb *)
If[mb=!={},
If[MatchQ[mb,{_?MetricQ,basisname|-basisname,_}],
Switch[mb3=mb[[3]],
"Orthogonal"|"Orthonormal",Null,
_List,If[Dimensions[mb3]=!={dim}&&Dimensions[mb3]=!={dim,dim},Throw@Message[DefBasis::invalid,mb3,"array of metric values"]],
_,Throw@Message[DefBasis::invalid,mb3,"metric values specification"]
],
Throw@Message[DefBasis::invalid,mb,"value for option MetricInBasis"]
]
];
(* Check change *)
If[change=!=Null,
If[!MatchQ[change,HoldPattern[CTensor[_?MatrixQ,{-basisname,_?BasisQ},0]]],
Throw@Message[DefBasis::invalid,change,"basis change specification"]]
];
(* Check eoom *)
If[Head[eoom]=!=List||Length[eoom]=!=2,
Throw@Message[DefBasis::invalid,eoom,"value for option epsilonOrientationOfMetric"];
];
If[eoom[[1]]=!=Null&&!MetricQ[eoom[[1]]],
Throw@Message[DefBasis::unknown,"metric",eoom[[1]]];
];
(**** Define basis ****)
xAct`xTensor`Private`MakeDefInfo[DefBasis,basisname,info];
MakexTensions[DefBasis,"Beginning",basisname,vbundle,cnumbers,options];
(* Register *)
AppendTo[$Bases,basisname];
BasisQ[basisname]^=True;
BasisColor[basisname]^=bc;
VBundleOfBasis[basisname]^=vbundle;
basisname/:CNumbersOf[basisname,vbundle]=Sort@cnumbers;
etaOrientation[basisname]^=Signature[cnumbers];
If[eoom[[1]]=!=Null,basisname/:epsilonOrientation[eoom[[1]],basisname]=eoom[[2]]];
DependenciesOfBasis[basisname]^=deps;
DefInfo[basisname]^=info;
xAct`xTensor`Private`SymbolRelations[basisname,master,{vbundle}];
(* Define associated parallel derivative, always real *)
tbundle=TangentBundleOfManifold[manifold];
With[
{indtng=First@GetIndicesOfVBundle[tbundle,1],
pdbasis=If[HasDaggerCharacterQ[basisname],PDOfBasis[Dagger[basisname]],GiveSymbol[PD,basisname]]},
PDOfBasis[basisname]^=pdbasis;
If[dag=!=Conjugate,
(* Quiet OptionValue::nodef because we are passing DefBasis/DefChart options *)
Quiet[
DefCovD[pdbasis[-indtng],vbundle,{ColorString[$PDPostfixSymbol,bc],ColorString[$PDPrefixSymbol,bc]},Torsion:>Not@ChartQ[basisname],Curvature->False,Master->basisname,ExtendedFrom->covdef,DefInfo->If[info===False,False,{"parallel derivative",""}],options],
OptionValue::nodef];
If[Not@ChartQ[basisname],With[{torsion=Torsion[basisname]},xAct`xTensor`Private`SetPrintAs[torsion,ColorString["T",bc]]]];
BasisOfCovD[pdbasis]^=basisname;
If[dag===Complex,Set[Evaluate[MakeDaggerSymbol[pdbasis]],pdbasis]]
]
];
(* Store positions of cnumbers *)
MapIndexed[Set[PNumber[#1,basisname],First[#2]]&,CNumbersOf[basisname,vbundle]];
MapIndexed[Set[PNumber[#1,-basisname],First[#2]]&,CNumbersOf[basisname,vbundle]];
(* Properties of basis under complex conjugation *)
Switch[dag,
Real,Dagger[basisname]^=basisname,
Conjugate,Null,
Complex,
xAct`xTensor`Private`SetDaggerPair[basisname,MakeDaggerSymbol[basisname]];
DefBasis[Dagger[basisname],Dagger[vbundle],cnumbers,Dagger->Conjugate,Master->basisname,options]
];
(* Register change of basis *)
If[change=!=Null,SetBasisChange[change]];
(* Store values of components of some metric in this basis *)
If[mb=!={},Apply[MetricInBasis,mb]];
(* Define associated eta tensors, even for inner vbundles *)
defeta[basisname,dag,info];
(* Format bases elements *)
If[fb=!=Automatic,
If[!MatchQ[fb,{_List,_List}],Throw@Message[DefBasis::invalid,fb,"value for option FormatBasis"]];
FormatUpVectors[fb[[1]],CIndicesOf[-basisname],scalars];
FormatDownVectors[fb[[2]],CIndicesOf[basisname],scalars];
];
MakexTensions[DefBasis,"End",basisname,vbundle,cnumbers,options];
If[pns,Protect[basisname]];
(*added the next lines to launch my internal functions*)
If[pr,xAct`xPrint`Private`PrimedIndexForm[basisname]];
If[dpr,xAct`xPrint`Private`DoublePrimedIndexForm[basisname]];
];
SetNumberOfArguments[DefBasis,{3,Infinity}];
Protect[DefBasis];
Unprotect[DefChart];
(*added Primed and DoublePrimed*)
(*
Options[DefChart]={ChartColor\[Rule]RGBColor[1,0,0],ProtectNewSymbol\[RuleDelayed]$ProtectNewSymbols,Dagger\[Rule]Real,MetricInBasis\[Rule]{},Primed\[Rule]False,
DoublePrimed\[Rule]False};
*)
Options[DefChart]={
ChartColor->RGBColor[1,0,0],
FormatBasis->Automatic,
ProtectNewSymbol:>$ProtectNewSymbols,
Dagger->Real,
MetricInBasis->{},
epsilonOrientationOfMetric->{Null,1},
ExtendedCoordinateDerivatives->True,
DefInfo->{"chart",""},
Primed->False,
DoublePrimed->False
};
DefChart[chartname_,manifold_,cnumbers_,scalars_List,options:OptionsPattern[]]:=
With[{pd=GiveSymbol[PD,chartname],heads=Head/@scalars,index=IndicesOfVBundle[TangentBundleOfManifold[manifold]][[1,1]]},
(*added pr and dpr to local variables and to the list of options, together with Primed and DoublePrimed*)
Module[{cc,fb,pns,dag,eoom,ecd,info,prot,dheads,pheads,pr,dpr},
{cc,fb,pns,dag,eoom,ecd,info,pr,dpr}=OptionValue[{ChartColor,FormatBasis,ProtectNewSymbol,Dagger,epsilonOrientationOfMetric,ExtendedCoordinateDerivatives,DefInfo,Primed,DoublePrimed}];
(* dheads=Map[SymbolJoin["d",#]&,heads];
pheads=Map[SymbolJoin["p",#]&,heads]; *)
(* Checks *)
ValidateSymbol[chartname];
ValidateSymbolInSession[chartname];
If[!ManifoldQ[manifold],Throw@Message[DefChart::unknown,"manifold",manifold]];
If[!IntegerQ[DimOfManifold[manifold]],Throw@Message[DefChart::error,"Chart cannot be defined on a manifold with symbolic dimension."]];
If[Not@And@@Join[IntegerQ/@cnumbers],Throw@Message[DefChart::error,"The cnumbers must be integers."]];
If[DimOfManifold[manifold]!=Length[cnumbers],Throw@Message[DefChart::error,"Incorrect number of cnumbers supplied."]];
If[DimOfManifold[manifold]!=Length[scalars],Throw@Message[DefChart::error,"Incorrect number of scalars supplied."]];
(* Check eoom *)
If[Head[eoom]=!=List||Length[eoom]=!=2,
Throw@Message[DefChart::invalid,eoom,"value for option epsilonOrientationOfMetric"];
];
If[!xTensorQ[#],ValidateSymbol[#]&&ValidateSymbolInSession[#]]&/@heads;
(* ValidateSymbolInSession/@dheads;
ValidateSymbolInSession/@pheads; *)
MakexTensions[DefChart,"Beginning",chartname,manifold,cnumbers,scalars,options];
(* Register *)
xAct`xTensor`Private`MakeDefInfo[DefChart,chartname,info];
ChartQ[chartname]^=True;
ManifoldOfChart[chartname]^=manifold;
ChartColor[chartname]^=cc;
AppendTo[$Charts,chartname];
(* Changes of coordinates *)
xAct`xTensor`Private`SymbolRelations[chartname,Null,{manifold}];
(* Define coordinate scalars if they do not exist yet *)
prot=Unprotect/@heads;
ServantsOf[chartname]^={};
If[!xTensorQ[Head[#]],DefTensor[#,manifold,Master->chartname,DefInfo->If[info===False,False,{"coordinate scalar",""}]]]&/@scalars;
MapIndexed[setinchart[chartname],scalars];
ScalarsOfChart[chartname]^=scalars;
(* ChartRules[chartname]^=Thread@Rule[manifold/@cnumbers,scalars];*)
(* Store coordinate names *)
Inner[Set,Coordinate[#,chartname]&/@cnumbers,heads,List];
(* Define associated mapping to Reals[dim] *)
DefMapping[chartname, manifold-> Reals[DimOfManifold[manifold]],ImmersionQ->True,SubmersionQ->True,InverseMapping->Automatic];
With[{inv=InverseMapping[chartname]},ChartIMapQ[inv]^=True];
(* Define associated basis, which in turn defines the parallel derivative. Turn off formating. Quiet OptionValue::nodef because we are passing DefChart options *)
Quiet[DefBasis[chartname,TangentBundleOfManifold[manifold],cnumbers,FormatBasis->Automatic,DefInfo->{"basis","Coordinated basis."},options,BasisColor->cc],OptionValue::nodef];
(* Define shortcuts for basis elements
Inner[Hold,Through[dheads[index_]],basis[{#,chartname},index]&/@cnumbers,List]/.basis\[Rule]Basis/.Hold\[Rule]SetDelayed;
Inner[Hold,Through[pheads[index_]],basis[{#,-chartname},index]&/@cnumbers,List]/.basis\[Rule]Basis/.Hold\[Rule]SetDelayed;*)
(* Define position vector *)
(* Format bases elements *)
If[fb=!=Automatic,
If[!MatchQ[fb,{_,_}],Throw@Message[DefChart::invalid,fb,"value for option FormatBasis"]];
FormatUpVectors[fb[[1]],CIndicesOf[-chartname],scalars];
FormatDownVectors[fb[[2]],CIndicesOf[chartname],scalars];
];
(* If MetricInBasis is specified, should we automatically compute Christoffels? *)
(* Any derivative of a coordinate scalar field gives a Basis vector *)
Inner[coordinateder[chartname,ecd],heads,cnumbers,List];
MakexTensions[DefChart,"End",chartname,manifold,cnumbers,scalars,options];
Protect[Evaluate[prot]];
];
(*added the next lines to launch my internal functions*)
If[pr,xAct`xPrint`Private`PrimedIndexForm[chartname]];
If[dpr,xAct`xPrint`Private`DoublePrimedIndexForm[chartname]];
];
SetNumberOfArguments[DefChart,{4,Infinity}];
Protect[DefChart];
(* If you do not like these initial settings, just comment-out any of the following 6 lines of code *)
$CovDFormat="Postfix"; (* no Covariant Deltas initially *)
ABCOnQ=False; (* Automatic basis contraction start *)
$PrePrint=ScreenDollarIndices;
$DefInfoQ=False; (* No Def-inition info messages *)
$UndefInfoQ=False; (* No Undef-inition info messages *)
$CVVerbose=False; (* Component Value verbose off*)
(*-------------------------------------------------------------------------------------------*)
PostfixStyleQ:=$CovDFormat=="Postfix"; (* turn it into a switch *)
IndicesScreenedQ:=$PrePrint==ScreenDollarIndices ;(* turn it into a switch *)
manifold="";
LieDSymbol="\[ScriptCapitalL]";
SimpleManipulationQ:=True ;
indexform=unprimed
xPrintValidQ[expr_]:=Check[Validate[expr];True,False]//Quiet
SetAttributes[xPrintValidQ,HoldFirst];
(*------------------------------------------------------------*)
basisreset[basis_]:=(Table[basischoice[k]=basis,{k,30}];cbasischoice[1]=basis;)
(* lblposreset=Table[lblpos[k]=1;linput[k]=Null,{k,30}]; *)
labelreset=Table[label[k]="";linput[k]=Null,{k,30}];
(*------------------------------------------------------------*)
idxup[cdup_,basis_]:=cdup/;basis===AIndex
idxup[cdup_,basis_]:={cdup,basis}
(*------------------------------------------------------------*)
idxdown[cdown_,basis_]:=-cdown/;basis===AIndex
idxdown[cdown_,basis_]:={If[MemberQ[(IndicesOfVBundle@VBundleOfBasis[basis])[[1]],cdown],-cdown,cdown],-basis}
(*------------------------------------------------------------*)
idx[int_Integer]:=If[up[int]==="",-down[int],up[int]]/;basischoice[int]===AIndex
idx[int_Integer]:=If[up[int]==="",{If[MemberQ[(IndicesOfVBundle@TangentBundleOfManifold[manifold])[[1]],down[int]],-down[int],down[int]],-basischoice[int]},{up[int],basischoice[int]}]
(*------------------------------------------------------------*)
lblsign[int_]:=Which[lblpos[int]==1,-1,lblpos[int]==2,1]
slot[int_Integer,tensorhead_]:=Switch[
Which[tensorhead===Gdelta,GdeltaSlots[gdslots]TangentBundleOfManifold[manifold],
True,SlotsOfTensor[tensorhead]][[int]],
Labels,LI@label[int],
-Labels,-LI@label[int],
_,idx[int]]
(*
slot[int_Integer,tensorhead_]:=If[SlotsOfTensor[tensorhead][[int]]===Labels||SlotsOfTensor[tensorhead][[int]]===-Labels,lblsign[int]LI@label[int],idx[int]]
*)
(*------------------------------------------------------------*)
cidx[int_Integer]:=If[cup[int]==="",-cdown[int],cup[int]]/;cbasischoice[int]===AIndex
cidx[int_Integer]:=If[cup[int]==="",{If[MemberQ[(IndicesOfVBundle@TangentBundleOfManifold[manifold])[[1]],cdown[int]],-cdown[int],cdown[int]],-cbasischoice[int]},{cup[int],cbasischoice[int]}]
(*------------------------------------------------------------*)
GdeltaSlots[gdslots_]:=Join[ConstantArray[-1,gdslots],ConstantArray[1,gdslots]]
(*------------------------------------------------------------*)
pastedexpr:=Which[
manifold==="","No Manifold",
tensorhead==="" && cdchoice==="","No expression",
tensorhead===delta && \[Not]MetricEndowedQ[TangentBundleOfManifold[manifold]]&&(down[1]===""||up[2]===""),"Not a tensor",
tensorhead===Basis &&\[Not]MetricEndowedQ[TangentBundleOfManifold[manifold]]&& (down[1]===""||up[2]===""),"Not a tensor",
tensorhead===Gdelta &&\[Not]MetricEndowedQ[TangentBundleOfManifold[manifold]]&& Or@@Flatten@Table[{down[ii]==="",up[ii+gdslots]===""},{ii,gdslots}],"Not a tensor",
tensorhead=!="",completetensor[tensorhead],
cdchoice===LieD,"LieD" (* this value is not used *),
cdchoice===ParamD &¶mchoice=!="","ParamD" (* this value is not used *),
cdchoice===OverDot,"OverDot" (* this value is not used *),
cdchoice===Bracket && (cdown[1]=!=""||cup[1]=!=""),(Bracket@@Table[cidx[k],{k,1}])[] ,
cdchoice=!=""&& (cdown[1]=!=""||cup[1]=!=""),(cdchoice@@Table[cidx[k],{k,1}])[] ,
cdchoice=!="","No Cov. Derivative"
]
(*------------------------------------------------------------*)
(*
completetensor[tensorhead_?xTensorQ]:=If[xPrintValidQ[
tensorhead@@Table[
idx[k],
{k,Which[tensorhead===Gdelta,2gdslots,
tensorhead===delta,2,
tensorhead===Basis,2,
True,Length@SlotsOfTensor[tensorhead]]//Evaluate}
]//Evaluate],
tensorhead@@Table[
idx[k],
{k,Which[tensorhead===Gdelta,2gdslots,
tensorhead===delta,2,
tensorhead===Basis,2,
True,Length@SlotsOfTensor[tensorhead]]//Evaluate}
] //ScreenDollarIndices
, "Not a tensor"
]
*)
completetensor[tensorhead_?xTensorQ]:=If[xPrintValidQ[
tensorhead@@Table[
slot[k,tensorhead],
{k,Which[tensorhead===Gdelta,2gdslots,
True,Length@SlotsOfTensor[tensorhead]]//Evaluate}
]//Evaluate],
tensorhead@@Table[
slot[k,tensorhead],
{k,Which[tensorhead===Gdelta,2gdslots,
tensorhead===delta,2,
tensorhead===Basis,2,
True,Length@SlotsOfTensor[tensorhead]]//Evaluate}
] //ScreenDollarIndices
, "Not a tensor"
]
completetensor[tensorhead_]:= "Not a tensor"
(*------------------------------------------------------------*)
(* My cnumbersof function *)
cnumbersof[basis_]:=CNumbersOf[basis ]/;basis=!=AIndex
cnumbersof[basis_]:={}
(*------------------------------------------------------------*)
abstractandbasesall:={AIndex}~Join~$Bases
(*------------------------------------------------------------*)
abstractandbases[manifold_]:={AIndex}~Join~Select[$Bases,(VBundleOfBasis[#]===TangentBundleOfManifold[manifold])&]
(*------------------------------------------------------------*)
(* this function also displays the basis name *)
abstractandbasesdisks[manifold_]:={Style["\[FilledCircle]"<>" "<>"AIndex",Black]}~Join~(MapThread[Style["\[FilledCircle]"<>" "<>ToString@#2,#1]&,{BasisColor/@Select[$Bases,(VBundleOfBasis[#]===TangentBundleOfManifold[manifold])&],Select[$Bases,(VBundleOfBasis[#]===TangentBundleOfManifold[manifold])&]}])
(*------------------------------------------------------------*)
tensormenuselection[manifold_]:=($Tensors\[Intersection]VisitorsOf[manifold])\[Union]{delta,Gdelta,Basis}/;$Manifolds=!={}&&manifold=!=""
tensormenuselection[manifold_]:={}
(*------------------------------------------------------------*)
(* all derivatives operators on a manifold *)
derivativesmenuselection[manifold_]:={PD,Diff,LieD,Bracket}~Join~(($CovDs\[Intersection]VisitorsOf[manifold])\[Union]{ParamD,OverDot})/;$Manifolds=!={}&&manifold=!=""
derivativesmenuselection[manifold_]:={}
(*------------------------------------------------------------*)
(* all commutable derivatives operators on a manifold *)
commderivativesmenuselection[manifold_]:={PD}~Join~($CovDs\[Intersection]VisitorsOf[manifold])/;$Manifolds=!={}&&manifold=!=""
commderivativesmenuselection[manifold_]:={}
(*------------------------------------------------------------*)
BracketTagUp[basis_]:="Bracket"<>"_"<>ToString[basis]<>"_"<>"Tag"<>"Up"
BracketTagsListUp:=BracketTagUp/@abstractandbasesall
BracketTagDown[basis_]:="Bracket"<>"_"<>ToString[basis]<>"_"<>"Tag"<>"Down"
BracketTagsListDown:=BracketTagDown/@abstractandbasesall
(*------------------------------------------------------------*)
StringTagPrefixUp[cdchoice_,basis_]:=ToString[cdchoice]<>"_"<>ToString[basis]<>"_"<>"Tag"<>"PrefixUp"
StringTagPrefixDown[cdchoice_,basis_]:=ToString[cdchoice]<>"_"<>ToString[basis]<>"_"<>"Tag"<>"PrefixDown"
StringTagsListPrefixUp:=Outer[StringTagPrefixUp,$CovDs,abstractandbasesall]//Flatten
StringTagsListPrefixDown:=Outer[StringTagPrefixDown,$CovDs,abstractandbasesall]//Flatten
(*
StringTagPostfix[cdchoice_]:=ToString[cdchoice]<>"Tag"<>"Postfix"
StringTagsListPostfix:=StringTagPostfix/@$CovDs
*)
(*------------------------------------------------------------*)
ButtonLabelStyle[x_]:=Style[x,9]
(*------------------------------------------------------------*)
PrimedIndexForm[basis_]:=(Unprotect[IndexForm];
IndexForm[{ind_Integer,basis}]:=ColorString[StringJoin[CIndexForm[ind,basis],"'"],BasisColor[basis]];
IndexForm[{ind_,basis}]:=ColorString[StringJoin[IndexForm[ind],"'"],BasisColor[basis]];
Protect[IndexForm];)
(*------------------------------------------------------------*)
(*
DefPrimedBasis[basis_,x__]:=(DefBasis[basis,x];PrimedIndexForm[basis]);
DefPrimedChart[chart_,x__]:=(DefChart[chart,x];PrimedIndexForm[chart]);
*)
(*------------------------------------------------------------*)
DoublePrimedIndexForm[basis_]:=(
Unprotect[IndexForm];
IndexForm[{ind_Integer,basis}]:=ColorString[StringJoin[CIndexForm[ind,basis],"''"],BasisColor[basis]];
IndexForm[{ind_,basis}]:=ColorString[StringJoin[IndexForm[ind],"''"],BasisColor[basis]];
Protect[IndexForm];
)
(*------------------------------------------------------------*)
(*
DefDoublePrimedBasis[basis_,x__]:=(DefBasis[basis,x];DoublePrimedIndexForm[basis]);
DefDoublePrimedChart[chart_,x__]:=(DefChart[chart,x];DoublePrimedIndexForm[chart]);
*)
(*------------------------------------------------------------*)
(* Diff *)
MakeExpression[TagBox[expr_,"DiffTag"],form_]:=
HoldComplete[expr]/.RowBox[{"d",x_}]:>Diff[ToExpression@x]
(*------------------------------------------------------------*)
(* LieD *)
MakeExpression[TagBox[expr_,"LieTag"],form_]:=(*HoldComplete[expr]/.RowBox[{SubscriptBox["\[ScriptCapitalL]",x_],y_}]\[RuleDelayed]LieD[ToExpression@x][ToExpression@y]*)
HoldComplete[expr]/.RowBox[{SubscriptBox[lie_,x_],y_}]:>LieD[ToExpression@x][ToExpression@y]
(*------------------------------------------------------------*)
(* Bracket *)
MakeExpression[TagBox[expr_,brtag_?(MemberQ[BracketTagsListUp,#]&)],form_]:=HoldComplete[expr]/.SuperscriptBox[
RowBox[{"[",RowBox[{v1_,",",v2_}],"]"}], z_]:>Bracket[ToExpression@v1,ToExpression@v2][idxup[ToExpression@z,Symbol@StringSplit[brtag,"_"][[2]]]]
MakeExpression[TagBox[expr_,brtag_?(MemberQ[BracketTagsListDown,#]&)],form_]:=HoldComplete[expr]/.SubscriptBox[
RowBox[{"[",RowBox[{v1_,",",v2_}],"]"}], z_]:>Bracket[ToExpression@v1,ToExpression@v2][idxdown[ToExpression@z,Symbol@StringSplit[brtag,"_"][[2]]]]
(*------------------------------------------------------------*)
(* OLD Bracket *)
(*
MakeExpression[TagBox[expr_,brtag_?(MemberQ[BracketTagsListUp,#]&)],form_]:=HoldComplete[expr]/.SuperscriptBox[
RowBox[{"[",RowBox[{v1_,",",v2_}],"]"}], z_]\[RuleDelayed]Bracket[idxup[ToExpression@z,Symbol@StringSplit[brtag,"_"][[2]]]][ToExpression@v1,ToExpression@v2]
MakeExpression[TagBox[expr_,brtag_?(MemberQ[BracketTagsListDown,#]&)],form_]:=HoldComplete[expr]/.SubscriptBox[
RowBox[{"[",RowBox[{v1_,",",v2_}],"]"}], z_]\[RuleDelayed]Bracket[idxdown[ToExpression@z,Symbol@StringSplit[brtag,"_"][[2]]]][ToExpression@v1,ToExpression@v2]
*)
(*------------------------------------------------------------*)
(* CovDs Up and Prefix *)
(* In the following code, I do not need to check too much der_, since I know it is acceptable from the tag*)
(* if the tag has been recognized, than der_ must be acceptable*)
MakeExpression[TagBox[expr_,cdtag_?(MemberQ[StringTagsListPrefixUp,#]&)],form_]:=HoldComplete[expr]/.
RowBox[{SuperscriptBox[der_, x_],y_}]:>(Symbol@First@StringSplit[cdtag,"_"])[idxup[ToExpression@x,Symbol@StringSplit[cdtag,"_"][[2]]]][ToExpression@y]
(* CovDs Down and Prefix *)
(* In the following code, I do not need to check too much der_, since I know it is acceptable from the tag*)
(* if the tag has been recognized, than der_ must be acceptable*)
MakeExpression[TagBox[expr_,cdtag_?(MemberQ[StringTagsListPrefixDown,#]&)],form_]:=HoldComplete[expr]/.RowBox[{SubscriptBox[der_, x_],y_}]:>(Symbol@First@StringSplit[cdtag,"_"])[idxdown[ToExpression@x,Symbol@StringSplit[cdtag,"_"][[2]]]][ToExpression@y]
HelpMenuContents:={"xPrint Doc":>NotebookOpen[FileNameJoin[{First@FileNames["xAct",$Path],"xPrint","Documentation","English","xPrintDoc.nb"}]],"xPrint tutorials":>NotebookOpen[SystemDialogInput["FileOpen",FileNameJoin[{First@FileNames["xAct",$Path],"xPrint","Documentation","English","Tutorials"}]]],
Delimiter,
"xCore Doc":>NotebookOpen[FileNameJoin[{First@FileNames["xAct",$Path],"Documentation","English","xCoreDoc.nb"}]],
"xPerm Doc":>NotebookOpen[FileNameJoin[{First@FileNames["xAct",$Path],"Documentation","English","xPermDoc.nb"}]],
Delimiter,
"xTensor Doc":> NotebookOpen[FileNameJoin[{First@FileNames["xAct",$Path],"Documentation","English","xTensorDoc.nb"}]],
"xTensor Ref. Guide":>NotebookOpen[FileNameJoin[{First@FileNames["xAct",$Path],"Documentation","English","xTensorRefGuide.nb"}]],
Delimiter,
"xCoba Doc":>NotebookOpen[FileNameJoin[{First@FileNames["xAct",$Path],"Documentation","English","xCobaDoc.nb"}]],
"xCoba Doc2":>NotebookOpen[FileNameJoin[{First@FileNames["xAct",$Path],"Documentation","English","xCobaDoc2.nb"}]],
Delimiter,
"xTerior Doc":>NotebookOpen[FileNameJoin[{First@FileNames["xAct",$Path],"Documentation","English","xTeriorDoc.nb"}]],
Delimiter,
"xTras Doc":>SystemOpen[FileNameJoin[{First@FileNames["xAct",$Path],"Documentation","English","xTras.pdf"}]],
"SymManipulator Doc":>NotebookOpen[FileNameJoin[{First@FileNames["xAct",$Path],"Documentation","English","SymManipulatorDoc.nb"}]],
"xPert Doc":>NotebookOpen[FileNameJoin[{First@FileNames["xAct",$Path],"Documentation","English","xPertDoc.nb"}]],
"Harmonics Doc":>NotebookOpen[FileNameJoin[{First@FileNames["xAct",$Path],"Documentation","English","HarmonicsDoc.nb"}]],
"Invar Doc":>NotebookOpen[FileNameJoin[{First@FileNames["xAct",$Path],"Documentation","English","InvarDoc.nb"}]],
"Spinors Doc":>NotebookOpen[FileNameJoin[{First@FileNames["xAct",$Path],"Documentation","English","SpinorsDoc.nb"}]],
Delimiter,
"xPrint site":>SystemOpen["http://sites.google.com/site/xprintforxact/"],
"xAct site":>SystemOpen["http://xAct.es.html"](*SystemOpen["http://metric.iem.csic.es/Martin-Garcia/xAct/index.html"]*) ,
"xAct group":>SystemOpen["http://groups.google.com/group/xact/topics?hl=en"],
Delimiter,
"About xPrint...":>DisplaySplash[5]}
HelpMenu:=Tooltip[ActionMenu[
Graphics[{
{RGBColor[0.689647, 0.761166, 0.805478],
Disk[{0, 0}, 0.1]},
{GrayLevel[0], Circle[{0, 0}, 0.1],
Style[Inset["\<\"?\"\>", {0.01, 0}], "Label",
FontSize->11]}},
ImageSize->{20, 20},BaselinePosition->Bottom], HelpMenuContents,
Appearance->None,
BaseStyle->"puL",
FrameMargins->{{0, 0}, {-2, -2}},
ImageSize->{20, 20}],"Help for working with xAct"]
pastebutton[Diff]:=Button[ToExpression@RowBox[{
"d", "[", TagBox[
FrameBox["form"],
"Placeholder"], "]"}],
NotebookWrite[nb,TagBox[
RowBox[{
"d",
RowBox[{"(",TagBox[
FrameBox["form"],
"Placeholder"],")"}]}],
"DiffTag"],Placeholder]
,ImageSize->{im,45},Background-> LightGray,Appearance->Button]&
(*------------------------------------------------------------*)
pastebutton[OverDot]:=Button[ToExpression@OverscriptBox[
RowBox[{"(",TagBox[
FrameBox["tensor"],
"Placeholder"],")"}] , "."],
NotebookWrite[nb,OverscriptBox[
RowBox[{"(",TagBox[
FrameBox["tensor"],
"Placeholder"],")"}] , "."],Placeholder]
,ImageSize->{im,45},Background-> LightGray,Appearance->Button]&
(*------------------------------------------------------------*)
pastebutton[ParamD/;paramchoice=!=""]:=Button[ToExpression@RowBox[{
RowBox[{"ParamD", "[",ToString@ paramchoice, "]"}], "[", TagBox[
FrameBox["tensor"],
"Placeholder"], "]"}],
NotebookWrite[nb,RowBox[{
RowBox[{"ParamD", "[",ToString@ paramchoice, "]"}], "[", TagBox[
FrameBox["tensor"],
"Placeholder"], "]"}],Placeholder]
,ImageSize->{im,45},Background-> LightGray,Appearance->Button]&
(*------------------------------------------------------------*)
pastebutton[LieD]:=Button[ToExpression@TagBox[
RowBox[{
SubscriptBox["\[ScriptCapitalL]",
TagBox[
FrameBox["v"],
"Placeholder"]],
RowBox[{"(",TagBox[
FrameBox["tensor"],
"Placeholder"],")"}]}],
"LieTag"],
NotebookWrite[nb,TagBox[
RowBox[{
SubscriptBox[StyleBox[LieDSymbol,FontColor->Black],
TagBox[ FrameBox["v"],
"Placeholder"]],
RowBox[{"(",TagBox[
FrameBox["tensor"],
"Placeholder"],")"}]}],
"LieTag"],Placeholder]
,ImageSize->{im,45},Background-> LightGray,Appearance->Button]&
(*------------------------------------------------------------*)
pastebutton[Bracket/;(cup[1]=!="")]:=Button[Bracket[ToExpression@TagBox[
FrameBox["vect1"],
"Placeholder"],ToExpression@TagBox[
FrameBox["vect2"],
"Placeholder"]][cidx[1]]//DisplayForm,
NotebookWrite[nb,TagBox[
SuperscriptBox[
RowBox[{"[",
TagBox[
FrameBox["vect1"],
"Placeholder"], ",",
TagBox[
FrameBox["vect2"],
"Placeholder"], "]"}], StyleBox[ToString[cup[1]],BasisColor[cbasischoice[1]]]],
BracketTagUp[cbasischoice[1]]],Placeholder]
,ImageSize->{im,45},Background-> LightGray,Appearance->Button]&
pastebutton[Bracket/;(cdown[1]=!="")]:=Button[Bracket[ToExpression@TagBox[
FrameBox["vect1"],
"Placeholder"],ToExpression@TagBox[
FrameBox["vect2"],
"Placeholder"]][cidx[1]]//DisplayForm,
NotebookWrite[nb,TagBox[
SubscriptBox[
RowBox[{"[",
TagBox[
FrameBox["vect1"],
"Placeholder"], ",",
TagBox[
FrameBox["vect2"],
"Placeholder"], "]"}], StyleBox[ToString[cdown[1]],BasisColor[cbasischoice[1]]]],
BracketTagDown[cbasischoice[1]]],Placeholder]
,ImageSize->{im,45},Background-> LightGray,Appearance->Button]&
(*------------------------------------------------------------*)
(* OLD Bracket *)
(*pastebutton[Bracket/;(cup[1]=!="")]:=Button[Bracket[cidx[1]][ToExpression@TagBox[
FrameBox["vect1"],
"Placeholder"],ToExpression@TagBox[
FrameBox["vect2"],
"Placeholder"]]//DisplayForm,
NotebookWrite[nb,TagBox[
SuperscriptBox[
RowBox[{"[",
TagBox[
FrameBox["vect1"],
"Placeholder"], ",",
TagBox[
FrameBox["vect2"],
"Placeholder"], "]"}], StyleBox[ToString[cup[1]],BasisColor[cbasischoice[1]]]],
BracketTagUp[cbasischoice[1]]],Placeholder]
,ImageSize\[Rule]{im,45},Background\[Rule] LightGray,Appearance\[Rule]Button]&
pastebutton[Bracket/;(cdown[1]=!="")]:=Button[Bracket[cidx[1]][ToExpression@TagBox[
FrameBox["vect1"],
"Placeholder"],ToExpression@TagBox[
FrameBox["vect2"],
"Placeholder"]]//DisplayForm,
NotebookWrite[nb,TagBox[
SubscriptBox[
RowBox[{"[",
TagBox[
FrameBox["vect1"],
"Placeholder"], ",",
TagBox[
FrameBox["vect2"],
"Placeholder"], "]"}], StyleBox[ToString[cdown[1]],BasisColor[cbasischoice[1]]]],
BracketTagDown[cbasischoice[1]]],Placeholder]
,ImageSize\[Rule]{im,45},Background\[Rule] LightGray,Appearance\[Rule]Button]&
*)
(*------------------------------------------------------------*)
pastebutton[cdchoice_?CovDQ/;(cdown[1]=!="")]:=Button[(cdchoice@cidx[1])[ToExpression@TagBox[
FrameBox["tensor"],
"Placeholder"]],
NotebookWrite[nb,TagBox[
RowBox[{
SubscriptBox[Last@SymbolOfCovD[cdchoice], StyleBox[ToString[cdown[1]],BasisColor[cbasischoice[1]]]],
RowBox[{"(",TagBox[
FrameBox["tensor"],
"Placeholder"],")"}]}],
StringTagPrefixDown[cdchoice,cbasischoice[1]]],Placeholder]
,ImageSize->{im,45},Background-> LightGray,Appearance->Button]&
pastebutton[cdchoice_?CovDQ/;(cup[1]=!="")]:=Button[(cdchoice@cidx[1])[ToExpression@TagBox[
FrameBox["tensor"],
"Placeholder"]],
NotebookWrite[nb,TagBox[
RowBox[{
SuperscriptBox[Last@SymbolOfCovD[cdchoice], StyleBox[ToString[cup[1]],BasisColor[cbasischoice[1]]]],
RowBox[{"(",TagBox[
FrameBox["tensor"],
"Placeholder"],")"}]}],
StringTagPrefixUp[cdchoice,cbasischoice[1]]],Placeholder]
,ImageSize->{im,45},Background-> LightGray,Appearance->Button]&
(*------------------------------------------------------------*)
(* In all other cases, PasteButton works well, since we are pasting a complete expresssion or an incomplete one, but already taken care of with pasteexpr *)
pastebutton[cdchoice_]:=Tooltip[PasteButton[nb,
#,#,ImageSize->{im,45},Background-> LightGray,Appearance->Button],"PasteButton"]&
DisplaySplash[t_]:=(splashnb=CreateWindow[DocumentNotebook[{
TextCell["xPrint for xAct", "Title", TextAlignment->Center,FontColor->White,FontSlant->Italic],
TextCell["Version "<>First@xAct`xPrint`$Version,"Subtitle",TextAlignment->Center,FontColor->White],TextCell["created\n by\nAlessandro Stecchina","Subtitle",TextAlignment->Center,FontColor->White],TextCell["Copyright (C) 2009-"<>DateString["Year"]<>" by Alessandro Stecchina\nunder the General Public License\n
These packages come with ABSOLUTELY NO WARRANTY;\n for details type Disclaimer[]. This is free software, and you are welcome to redistribute it under certain conditions. See the General Public License for details.","Section",FontColor->White]}],ShowCellBracket->False,Deployed->True,ShowGroupOpener->False,WindowSize->{752,600},WindowMovable->False, WindowElements->{},WindowFrame->"ThinFrame",Background->Black,WindowTitle->"Splash and Copyright Notice"];
Pause[t];
NotebookClose[splashnb];)
ManifoldMenu:=Item[Dynamic[Tooltip[PopupMenu[Dynamic[manifold],Union@$Manifolds,Alignment->Right,BaseStyle->"puL",Appearance->ActionMenu,ImageSize->{Automatic,20},FrameMargins->Small],"Manifold Menu"],UpdateInterval->5 ],Alignment->Center]
SortCovDsButton:=Button["//SortCovDs"//ButtonLabelStyle,
Switch[SimpleManipulationQ,
True,NotebookWrite[nb,Cell["//SortCovDs", "Input"],After],False,
NotebookWrite[nb,
Cell[BoxData[
RowBox[{"//",
RowBox[{
RowBox[{"SortCovDs", "[",
RowBox[{ TagBox[
FrameBox["#"],
"Placeholder"]
, ",",TagBox[
FrameBox["covd"],
"Placeholder"]
}], "]"}], "&"}]}]], "Input"],After]]
,ImageSize->85,
Background->Switch[SimpleManipulationQ,True,Automatic,False,Yellow]]
BracketToCovDButton:=Button["//BracketToCovD"//ButtonLabelStyle,
Switch[SimpleManipulationQ,
True,NotebookWrite[nb,Cell["//BracketToCovD", "Input"],After],False,
NotebookWrite[nb,
Cell[BoxData[
RowBox[{"//",
RowBox[{
RowBox[{"BracketToCovD", "[",
RowBox[{ TagBox[
FrameBox["#"],
"Placeholder"]
, ",",TagBox[
FrameBox["covd"],
"Placeholder"]
}], "]"}], "&"}]}]], "Input"],After]]
,ImageSize->85,
Background->Switch[SimpleManipulationQ,True,Automatic,False,Yellow]]
ChangeCovDButton:=Button["//ChangeCovD"//ButtonLabelStyle,
Switch[SimpleManipulationQ,
True,NotebookWrite[nb,Cell["//ChangeCovD", "Input"],After],False,
NotebookWrite[nb,
Cell[BoxData[
RowBox[{"//",
RowBox[{
RowBox[{"ChangeCovD", "[",
RowBox[{"#", ",", TagBox[
FrameBox["from covd1"],
"Placeholder"]
, ",",TagBox[
FrameBox["to covd2"],
"Placeholder"]
}], "]"}], "&"}]}]], "Input"],After]]
,ImageSize->85,
Background->Switch[SimpleManipulationQ,True,Automatic,False,Yellow]]
TraceBasisDummyButton:=Button["//TrBasisDummy"//ButtonLabelStyle,
Switch[SimpleManipulationQ,
True,
NotebookWrite[nb,Cell[BoxData[
RowBox[{"//","TraceBasisDummy"}]], "Input"],After],
False,
NotebookWrite[nb,
Cell[BoxData[
RowBox[{"//","TraceBasisDummy", "[",
"#", ",", TagBox[
FrameBox["indices"],
"Placeholder"], "]","&"}]], "Input"],After]]
,ImageSize->85,
Background->Switch[SimpleManipulationQ,True,Automatic,False,Yellow]]
ToBasisButton:=Button["//ToBasis"//ButtonLabelStyle,
Switch[SimpleManipulationQ,
True,
NotebookWrite[nb,Cell[BoxData[
RowBox[{"//","ToBasis", "[",
TagBox[
FrameBox["basis"],
"Placeholder"], "]"}]], "Input"],After],
False,
NotebookWrite[nb,
Cell[BoxData[
RowBox[{"//","ToBasis", "[",
TagBox[
FrameBox["basis"],
"Placeholder"], "]", "[",
RowBox[{
"#", ",", TagBox[
FrameBox["indices"],
"Placeholder"], "]","&"}]}]], "Input"],After]]
,ImageSize->85,
Background->Switch[SimpleManipulationQ,True,Automatic,False,Yellow]]
FreeToBasisButton:=Button["//FreeToBasis"//ButtonLabelStyle,
Switch[SimpleManipulationQ,
True,
NotebookWrite[nb,Cell[BoxData[
RowBox[{"//","FreeToBasis", "[",
TagBox[
FrameBox["basis"],
"Placeholder"], "]"}]], "Input"],After],
False,
NotebookWrite[nb,
Cell[BoxData[
RowBox[{"//","FreeToBasis", "[",
TagBox[
FrameBox["basis"],
"Placeholder"], "]", "[",
RowBox[{
"#", ",", TagBox[
FrameBox["indices"],
"Placeholder"], "]","&"}]}]], "Input"],After]]
,ImageSize->85,
Background->Switch[SimpleManipulationQ,True,Automatic,False,Yellow]]
DummyToBasisButton:=Button["//DummyToBasis"//ButtonLabelStyle,
Switch[SimpleManipulationQ,
True,
NotebookWrite[nb,Cell[BoxData[
RowBox[{"//","DummyToBasis", "[",
TagBox[
FrameBox["basis"],
"Placeholder"], "]"}]], "Input"],After],
False,
NotebookWrite[nb,
Cell[BoxData[
RowBox[{"//","DummyToBasis", "[",
TagBox[
FrameBox["basis"],
"Placeholder"], "]", "[",
RowBox[{
"#", ",", TagBox[
FrameBox["indices"],
"Placeholder"], "]","&"}]}]], "Input"],After]]
,ImageSize->85,
Background->Switch[SimpleManipulationQ,True,Automatic,False,Yellow]]
SeparateBasisButton:=Button["//SeparateBasis"//ButtonLabelStyle,
Switch[SimpleManipulationQ,
True,NotebookWrite[nb,Cell["//SeparateBasis", "Input"],After],False,
NotebookWrite[nb,
Cell[BoxData[
RowBox[{"//","SeparateBasis", "[",
TagBox[
FrameBox["basis"],
"Placeholder"], "]", "[",
RowBox[{