[cmake] Add FindDetours for windows

cmake/modules/FindDetours.cmake

@@ -0,0 +1,37 @@
+#.rst:
+# FindDetours
+# --------
+# Finds the Detours library
+#
+# This will define the following target:
+#
+#   windows::Detours - The Detours library
+
+if(NOT TARGET windows::Detours)
+  find_path(DETOURS_INCLUDE_DIR NAMES detours.h
+                                NO_CACHE)
+
+  find_library(DETOURS_LIBRARY_RELEASE NAMES detours
+                                       NO_CACHE)
+  find_library(DETOURS_LIBRARY_DEBUG NAMES detoursd
+                                     NO_CACHE)
+
+  include(SelectLibraryConfigurations)
+  select_library_configurations(DETOURS)
+
+  include(FindPackageHandleStandardArgs)
+  find_package_handle_standard_args(Detours
+                                    REQUIRED_VARS DETOURS_LIBRARY DETOURS_INCLUDE_DIR)
+
+  if(DETOURS_FOUND)
+    add_library(windows::Detours UNKNOWN IMPORTED)
+    set_target_properties(windows::Detours PROPERTIES
+                                           INTERFACE_INCLUDE_DIRECTORIES "${DETOURS_INCLUDE_DIR}"
+                                           IMPORTED_LOCATION "${DETOURS_LIBRARY_RELEASE}")
+    if(DETOURS_LIBRARY_DEBUG)
+      set_target_properties(windows::Detours PROPERTIES
+                                             IMPORTED_LOCATION_DEBUG "${DETOURS_LIBRARY_DEBUG}")
+    endif()
+    set_property(GLOBAL APPEND PROPERTY INTERNAL_DEPS_PROP windows::Detours)
+  endif()
+endif()

cmake/platform/windows/windows.cmake

@@ -1,3 +1,3 @@
-set(PLATFORM_REQUIRED_DEPS D3DX11Effects)
+set(PLATFORM_REQUIRED_DEPS D3DX11Effects Detours)
 set(APP_RENDER_SYSTEM dx11)
 list(APPEND PLATFORM_DEFINES -DNTDDI_VERSION=NTDDI_WINBLUE -D_WIN32_WINNT=_WIN32_WINNT_WINBLUE)

xbmc/windowing/windows/WinSystemWin32DX.cpp

@@ -25,11 +25,6 @@
 #ifndef _M_X64
 #include "utils/SystemInfo.h"
 #endif
-#if _DEBUG
-#pragma comment(lib, "detoursd.lib")
-#else
-#pragma comment(lib, "detours.lib")
-#endif
 #pragma comment(lib, "dxgi.lib")
 #include <windows.h>
 #include <winnt.h>