forked from Raku/nqp
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Configure.pl
199 lines (166 loc) · 5.52 KB
/
Configure.pl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
#! perl
# Copyright (C) 2009 The Perl Foundation
use 5.008;
use strict;
use warnings;
use Getopt::Long;
use Cwd;
use lib "tools/lib";
use NQP::Config qw(cmp_rev read_parrot_config slurp system_or_die);
MAIN: {
my %config;
$config{'nqp_config_status'} = join(' ', map { "\"$_\""} @ARGV);
my %options;
GetOptions(\%options, 'help!', 'parrot-config=s', 'prefix=s',
'gen-parrot!', 'gen-parrot-option=s@', 'min-parrot-revision=s');
# Print help if it's requested
if ($options{'help'}) {
print_help();
exit(0);
}
# Save options in config.status
if (open(my $CONFIG_STATUS, '>', 'config.status')) {
print $CONFIG_STATUS
"$^X Configure.pl $config{'nqp_config_status'} \$*\n";
close($CONFIG_STATUS);
}
my $parrot_config_exe = $options{'parrot-config'};
if ($options{'gen-parrot'}) {
my @opts = @{ $options{'gen-parrot-option'} || [] };
push @opts, "--min-parrot-revision=$options{'min-parrot-revision'}"
if $options{'min-parrot-revision'};
my $prefix = $options{'prefix'} || cwd()."/install";
my @cmd = ($^X, "tools/build/gen-parrot.pl", "--prefix=$prefix",
"--optimize", @opts);
print "Generating Parrot ...\n";
print "@cmd\n\n";
system_or_die(@cmd);
# use the newly-built parrot config
$parrot_config_exe = "$prefix/bin/parrot_config";
}
my %parrot_config;
if ($parrot_config_exe) {
%parrot_config = read_parrot_config($parrot_config_exe);
}
else {
# look in some standard locations
%parrot_config = read_parrot_config(qw(
install/bin/parrot_config
parrot_config
));
}
my $errors;
if (!%parrot_config) {
$errors .= "Unable to locate parrot_config\n";
}
%config = (%config, %parrot_config);
my ($revision_want) = $options{'min_parrot-revision'}
|| split(' ', slurp("tools/build/PARROT_REVISION"));
my $revision_have = $config{'parrot::git_describe'} || '';
if ($revision_have && cmp_rev($revision_have, $revision_want) < 0) {
$errors .= "Parrot revision $revision_want required"
. " (currently $revision_have)\n";
}
if ($errors) {
die <<"END";
===SORRY!===
$errors
To automatically checkout (git) and build a copy of parrot $revision_want,
try re-running Configure.pl with the '--gen-parrot' option.
Or, use the the '--parrot-config' option to explicitly specify
the location of parrot_config to be used to build NQP.
END
}
# Verify the Parrot installation is sufficient for building NQP
verify_install(%config);
# Create the Makefile using the information we just got
create_makefile(%config);
my $make = $config{'parrot::make'};
{
no warnings;
print "Cleaning up ...\n";
if (open my $CLEAN, '-|', "$make clean") {
my @slurp = <$CLEAN>;
close($CLEAN);
}
}
print <<"END";
You can now use '$make' to build NQP.
After that, you can use '$make test' to run some tests, and
'$make install' to install NQP.
END
exit 0;
}
sub verify_install {
my %config = @_;
print "Verifying installation...\n";
my $EXE = $config{'parrot::exe'};
my $PARROT_BIN_DIR = $config{'parrot::bindir'};
my $PARROT_VERSION = $config{'parrot::versiondir'};
my $PARROT_LIB_DIR = $config{'parrot::libdir'}.$PARROT_VERSION;
my $PARROT_SRC_DIR = $config{'parrot::srcdir'}.$PARROT_VERSION;
my $PARROT_TOOLS_DIR = "$PARROT_LIB_DIR/tools";
my $PARROT_INCLUDE_DIR = $config{'parrot::includedir'}.$PARROT_VERSION;
my @required_files = (
"$PARROT_BIN_DIR/parrot$EXE",
"$PARROT_BIN_DIR/pbc_to_exe$EXE",
"$PARROT_BIN_DIR/ops2c$EXE",
"$PARROT_TOOLS_DIR/build/pmc2c.pl",
"$PARROT_SRC_DIR",
"$PARROT_SRC_DIR/pmc",
"$PARROT_INCLUDE_DIR",
"$PARROT_INCLUDE_DIR/pmc",
);
my @missing;
for my $reqfile (@required_files) {
push @missing, " $reqfile" unless -e $reqfile;
}
if (@missing) {
my $missing = join("\n", @missing);
die <<"END";
===SORRY!===
I'm missing some needed files in the install directory:
$missing
(Perhaps you need to use Parrot's "make install-dev" target or
install the "parrot-devel" package for your system?)
END
}
1;
}
sub create_makefile {
my %config = @_;
my $maketext = slurp( 'tools/build/Makefile.in' );
$config{'win32_libparrot_copy'} =
$^O eq 'MSWin32'
? 'copy $(PARROT_BIN_DIR)\libparrot.dll .'
: '';
my $makefile = 'Makefile';
$maketext =~ s/@([:\w]+)@/$config{$1} || $config{"parrot::$1"}/ge;
print "\nCreating $makefile ...\n";
open(my $MAKE, '>', $makefile)
or die "Unable to write $makefile\n";
print $MAKE $maketext;
close($MAKE) or die $!;
return;
}
# Print some help text.
sub print_help {
print <<'END';
Configure.pl - NQP Configure
General Options:
--help Show this text
--gen-parrot Download and build a copy of Parrot to use
--prefix=dir Install files in dir
--parrot-config=path/to/parrot_config
Use information from existing parrot_config
--gen-parrot-option='--option=value'
Pass option(s) to --gen-parrot configuration
END
return;
}
# Local Variables:
# mode: cperl
# cperl-indent-level: 4
# fill-column: 100
# End:
# vim: expandtab shiftwidth=4: